src/code/condition.lisp

   1 ;;;; stuff originally from CMU CL's error.lisp which can or should
   2 ;;;; come late (mostly related to the CONDITION class itself)
   3 ;;;;
   4
   5 ;;;; This software is part of the SBCL system. See the README file for
   6 ;;;; more information.
   7 ;;;;
   8 ;;;; This software is derived from the CMU CL system, which was
   9 ;;;; written at Carnegie Mellon University and released into the
  10 ;;;; public domain. The software is in the public domain and is
  11 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  12 ;;;; files for more information.
  13
  14 (in-package "SB!KERNEL")
  15 \f
  16 ;;;; the CONDITION class
  17
  18 (/show0 "condition.lisp 20")
  19
  20 (eval-when (:compile-toplevel :load-toplevel :execute)
  21
  22 (/show0 "condition.lisp 24")
  23
  24 (def!struct (condition-classoid (:include classoid)
  25                                 (:constructor make-condition-classoid))
  26   ;; list of CONDITION-SLOT structures for the direct slots of this
  27   ;; class
  28   (slots nil :type list)
  29   ;; list of CONDITION-SLOT structures for all of the effective class
  30   ;; slots of this class
  31   (class-slots nil :type list)
  32   ;; report function or NIL
  33   (report nil :type (or function null))
  34   ;; list of specifications of the form
  35   ;;
  36   ;;   (INITARG INITFORM THUNK)
  37   ;;
  38   ;; where THUNK, when called without arguments, returns the value for
  39   ;; INITARG.
  40   (direct-default-initargs () :type list)
  41   ;; class precedence list as a list of CLASS objects, with all
  42   ;; non-CONDITION classes removed
  43   (cpl () :type list)
  44   ;; a list of all the effective instance allocation slots of this
  45   ;; class that have a non-constant initform or default-initarg.
  46   ;; Values for these slots must be computed in the dynamic
  47   ;; environment of MAKE-CONDITION.
  48   (hairy-slots nil :type list))
  49
  50 (/show0 "condition.lisp 49")
  51
  52 ) ; EVAL-WHEN
  53
  54 (!defstruct-with-alternate-metaclass condition
  55   :slot-names (actual-initargs assigned-slots)
  56   :boa-constructor %make-condition-object
  57   :superclass-name t
  58   :metaclass-name condition-classoid
  59   :metaclass-constructor make-condition-classoid
  60   :dd-type structure)
  61
  62 (defstruct (condition-slot (:copier nil))
  63   (name (missing-arg) :type symbol)
  64   ;; list of all applicable initargs
  65   (initargs (missing-arg) :type list)
  66   ;; names of reader and writer functions
  67   (readers (missing-arg) :type list)
  68   (writers (missing-arg) :type list)
  69   ;; true if :INITFORM was specified
  70   (initform-p (missing-arg) :type (member t nil))
  71   ;; the initform if :INITFORM was specified, otherwise NIL
  72   (initform nil :type t)
  73   ;; if this is a function, call it with no args to get the initform value
  74   (initfunction (missing-arg) :type t)
  75   ;; allocation of this slot, or NIL until defaulted
  76   (allocation nil :type (member :instance :class nil))
  77   ;; If ALLOCATION is :CLASS, this is a cons whose car holds the value
  78   (cell nil :type (or cons null))
  79   ;; slot documentation
  80   (documentation nil :type (or string null)))
  81
  82 ;;; KLUDGE: It's not clear to me why CONDITION-CLASS has itself listed
  83 ;;; in its CPL, while other classes derived from CONDITION-CLASS don't
  84 ;;; have themselves listed in their CPLs. This behavior is inherited
  85 ;;; from CMU CL, and didn't seem to be explained there, and I haven't
  86 ;;; figured out whether it's right. -- WHN 19990612
  87 (eval-when (:compile-toplevel :load-toplevel :execute)
  88   (/show0 "condition.lisp 103")
  89   (let ((condition-class (locally
  90                            ;; KLUDGE: There's a DEFTRANSFORM
  91                            ;; FIND-CLASSOID for constant class names
  92                            ;; which creates fast but
  93                            ;; non-cold-loadable, non-compact code. In
  94                            ;; this context, we'd rather have compact,
  95                            ;; cold-loadable code. -- WHN 19990928
  96                            (declare (notinline find-classoid))
  97                            (find-classoid 'condition))))
  98     (setf (condition-classoid-cpl condition-class)
  99           (list condition-class)))
 100   (/show0 "condition.lisp 103"))
 101
 102 (setf (condition-classoid-report (locally
 103                                    ;; KLUDGE: There's a DEFTRANSFORM
 104                                    ;; FIND-CLASSOID for constant class
 105                                    ;; names which creates fast but
 106                                    ;; non-cold-loadable, non-compact
 107                                    ;; code. In this context, we'd
 108                                    ;; rather have compact,
 109                                    ;; cold-loadable code. -- WHN
 110                                    ;; 19990928
 111                                    (declare (notinline find-classoid))
 112                                    (find-classoid 'condition)))
 113       (lambda (cond stream)
 114         (format stream "Condition ~S was signalled." (type-of cond))))
 115
 116 (eval-when (:compile-toplevel :load-toplevel :execute)
 117
 118 (defun find-condition-layout (name parent-types)
 119   (let* ((cpl (remove-duplicates
 120                (reverse
 121                 (reduce #'append
 122                         (mapcar (lambda (x)
 123                                   (condition-classoid-cpl
 124                                    (find-classoid x)))
 125                                 parent-types)))))
 126          (cond-layout (info :type :compiler-layout 'condition))
 127          (olayout (info :type :compiler-layout name))
 128          ;; FIXME: Does this do the right thing in case of multiple
 129          ;; inheritance? A quick look at DEFINE-CONDITION didn't make
 130          ;; it obvious what ANSI intends to be done in the case of
 131          ;; multiple inheritance, so it's not actually clear what the
 132          ;; right thing is..
 133          (new-inherits
 134           (order-layout-inherits (concatenate 'simple-vector
 135                                               (layout-inherits cond-layout)
 136                                               (mapcar #'classoid-layout cpl)))))
 137     (if (and olayout
 138              (not (mismatch (layout-inherits olayout) new-inherits)))
 139         olayout
 140         (make-layout :classoid (make-undefined-classoid name)
 141                      :inherits new-inherits
 142                      :depthoid -1
 143                      :length (layout-length cond-layout)))))
 144
 145 ) ; EVAL-WHEN
 146
 147 ;;; FIXME: ANSI's definition of DEFINE-CONDITION says
 148 ;;;   Condition reporting is mediated through the PRINT-OBJECT method
 149 ;;;   for the condition type in question, with *PRINT-ESCAPE* always
 150 ;;;   being nil. Specifying (:REPORT REPORT-NAME) in the definition of
 151 ;;;   a condition type C is equivalent to:
 152 ;;;     (defmethod print-object ((x c) stream)
 153 ;;;       (if *print-escape* (call-next-method) (report-name x stream)))
 154 ;;; The current code doesn't seem to quite match that.
 155 (def!method print-object ((x condition) stream)
 156   (if *print-escape*
 157       (if (and (typep x 'simple-condition) (slot-value x 'format-control))
 158           (print-unreadable-object (x stream :type t :identity t)
 159             (write (simple-condition-format-control x)
 160                    :stream stream
 161                    :lines 1))
 162           (print-unreadable-object (x stream :type t :identity t)))
 163       ;; KLUDGE: A comment from CMU CL here said
 164       ;;   7/13/98 BUG? CPL is not sorted and results here depend on order of
 165       ;;   superclasses in define-condition call!
 166       (dolist (class (condition-classoid-cpl (classoid-of x))
 167                      (error "no REPORT? shouldn't happen!"))
 168         (let ((report (condition-classoid-report class)))
 169           (when report
 170             (return (funcall report x stream)))))))
 171 \f
 172 ;;;; slots of CONDITION objects
 173
 174 (defvar *empty-condition-slot* '(empty))
 175
 176 (defun find-slot-default (class slot)
 177   (let ((initargs (condition-slot-initargs slot))
 178         (cpl (condition-classoid-cpl class)))
 179     ;; When CLASS or a superclass has a default initarg for SLOT, use
 180     ;; that.
 181     (dolist (class cpl)
 182       (let ((direct-default-initargs
 183               (condition-classoid-direct-default-initargs class)))
 184         (dolist (initarg initargs)
 185           (let ((initfunction (third (assoc initarg direct-default-initargs))))
 186             (when initfunction
 187               (return-from find-slot-default (funcall initfunction)))))))
 188
 189     ;; Otherwise use the initform of SLOT, if there is one.
 190     (if (condition-slot-initform-p slot)
 191         (let ((initfun (condition-slot-initfunction slot)))
 192           (aver (functionp initfun))
 193           (funcall initfun))
 194         (error "unbound condition slot: ~S" (condition-slot-name slot)))))
 195
 196 (defun find-condition-class-slot (condition-class slot-name)
 197   (dolist (sclass
 198            (condition-classoid-cpl condition-class)
 199            (error "There is no slot named ~S in ~S."
 200                   slot-name condition-class))
 201     (dolist (slot (condition-classoid-slots sclass))
 202       (when (eq (condition-slot-name slot) slot-name)
 203         (return-from find-condition-class-slot slot)))))
 204
 205 (defun condition-writer-function (condition new-value name)
 206   (dolist (cslot (condition-classoid-class-slots
 207                   (layout-classoid (%instance-layout condition)))
 208                  (setf (getf (condition-assigned-slots condition) name)
 209                        new-value))
 210     (when (eq (condition-slot-name cslot) name)
 211       (return (setf (car (condition-slot-cell cslot)) new-value)))))
 212
 213 (defun condition-reader-function (condition name)
 214   (let ((class (layout-classoid (%instance-layout condition))))
 215     (dolist (cslot (condition-classoid-class-slots class))
 216       (when (eq (condition-slot-name cslot) name)
 217         (return-from condition-reader-function
 218                      (car (condition-slot-cell cslot)))))
 219     (let ((val (getf (condition-assigned-slots condition) name
 220                      *empty-condition-slot*)))
 221       (if (eq val *empty-condition-slot*)
 222           (let ((actual-initargs (condition-actual-initargs condition))
 223                 (slot (find-condition-class-slot class name)))
 224             (unless slot
 225               (error "missing slot ~S of ~S" name condition))
 226             (do ((initargs actual-initargs (cddr initargs)))
 227                 ((endp initargs)
 228                  (setf (getf (condition-assigned-slots condition) name)
 229                        (find-slot-default class slot)))
 230               (when (member (car initargs) (condition-slot-initargs slot))
 231                 (return-from condition-reader-function
 232                   (setf (getf (condition-assigned-slots condition)
 233                               name)
 234                         (cadr initargs))))))
 235           val))))
 236 \f
 237 ;;;; MAKE-CONDITION
 238
 239 (defun allocate-condition (type &rest initargs)
 240   (let* ((classoid (if (symbolp type)
 241                        (find-classoid type nil)
 242                        type))
 243          (class (typecase classoid
 244                   (condition-classoid classoid)
 245                   (class
 246                    (return-from allocate-condition
 247                      (apply #'allocate-condition (class-name classoid) initargs)))
 248                   (classoid
 249                    (error 'simple-type-error
 250                           :datum classoid
 251                           :expected-type 'condition-class
 252                           :format-control "~S is not a condition class."
 253                           :format-arguments (list type)))
 254                   (t
 255                    (error 'simple-type-error
 256                           :datum type
 257                           :expected-type 'condition-class
 258                           :format-control
 259                           "~S does not designate a condition class."
 260                           :format-arguments (list type)))))
 261          (condition (%make-condition-object initargs '())))
 262     (setf (%instance-layout condition) (classoid-layout class))
 263     (values condition class)))
 264
 265 (defun make-condition (type &rest initargs)
 266   #!+sb-doc
 267   "Make an instance of a condition object using the specified initargs."
 268   ;; Note: ANSI specifies no exceptional situations in this function.
 269   ;; signalling simple-type-error would not be wrong.
 270   (multiple-value-bind (condition class)
 271       (apply #'allocate-condition type initargs)
 272
 273     ;; Set any class slots with initargs present in this call.
 274     (dolist (cslot (condition-classoid-class-slots class))
 275       (dolist (initarg (condition-slot-initargs cslot))
 276         (let ((val (getf initargs initarg *empty-condition-slot*)))
 277           (unless (eq val *empty-condition-slot*)
 278             (setf (car (condition-slot-cell cslot)) val)))))
 279
 280     ;; Default any slots with non-constant defaults now.
 281     (dolist (hslot (condition-classoid-hairy-slots class))
 282       (when (dolist (initarg (condition-slot-initargs hslot) t)
 283               (unless (eq (getf initargs initarg *empty-condition-slot*)
 284                           *empty-condition-slot*)
 285                 (return nil)))
 286         (setf (getf (condition-assigned-slots condition)
 287                     (condition-slot-name hslot))
 288               (find-slot-default class hslot))))
 289
 290     condition))
 291
 292 \f
 293 ;;;; DEFINE-CONDITION
 294
 295 (eval-when (:compile-toplevel :load-toplevel :execute)
 296 (defun %compiler-define-condition (name direct-supers layout
 297                                    all-readers all-writers)
 298   (with-single-package-locked-error
 299       (:symbol name "defining ~A as a condition")
 300     (sb!xc:proclaim `(ftype (function (t) t) ,@all-readers))
 301     (sb!xc:proclaim `(ftype (function (t t) t) ,@all-writers))
 302     (multiple-value-bind (class old-layout)
 303         (insured-find-classoid name
 304                                #'condition-classoid-p
 305                                #'make-condition-classoid)
 306       (setf (layout-classoid layout) class)
 307       (setf (classoid-direct-superclasses class)
 308             (mapcar #'find-classoid direct-supers))
 309       (cond ((not old-layout)
 310              (register-layout layout))
 311             ((not *type-system-initialized*)
 312              (setf (layout-classoid old-layout) class)
 313              (setq layout old-layout)
 314              (unless (eq (classoid-layout class) layout)
 315                (register-layout layout)))
 316             ((redefine-layout-warning "current"
 317                                       old-layout
 318                                       "new"
 319                                       (layout-length layout)
 320                                       (layout-inherits layout)
 321                                       (layout-depthoid layout)
 322                                       (layout-n-untagged-slots layout))
 323              (register-layout layout :invalidate t))
 324             ((not (classoid-layout class))
 325              (register-layout layout)))
 326
 327       (setf (layout-info layout)
 328             (locally
 329                 ;; KLUDGE: There's a FIND-CLASS DEFTRANSFORM for constant class
 330                 ;; names which creates fast but non-cold-loadable, non-compact
 331                 ;; code. In this context, we'd rather have compact, cold-loadable
 332                 ;; code. -- WHN 19990928
 333                 (declare (notinline find-classoid))
 334               (layout-info (classoid-layout (find-classoid 'condition)))))
 335
 336       (setf (find-classoid name) class)
 337
 338       ;; Initialize CPL slot.
 339       (setf (condition-classoid-cpl class)
 340             (remove-if-not #'condition-classoid-p
 341                            (std-compute-class-precedence-list class)))))
 342   (values))
 343 ) ; EVAL-WHEN
 344
 345 ;;; Compute the effective slots of CLASS, copying inherited slots and
 346 ;;; destructively modifying direct slots.
 347 ;;;
 348 ;;; FIXME: It'd be nice to explain why it's OK to destructively modify
 349 ;;; direct slots. Presumably it follows from the semantics of
 350 ;;; inheritance and redefinition of conditions, but finding the cite
 351 ;;; and documenting it here would be good. (Or, if this is not in fact
 352 ;;; ANSI-compliant, fixing it would also be good.:-)
 353 (defun compute-effective-slots (class)
 354   (collect ((res (copy-list (condition-classoid-slots class))))
 355     (dolist (sclass (cdr (condition-classoid-cpl class)))
 356       (dolist (sslot (condition-classoid-slots sclass))
 357         (let ((found (find (condition-slot-name sslot) (res)
 358                            :key #'condition-slot-name)))
 359           (cond (found
 360                  (setf (condition-slot-initargs found)
 361                        (union (condition-slot-initargs found)
 362                               (condition-slot-initargs sslot)))
 363                  (unless (condition-slot-initform-p found)
 364                    (setf (condition-slot-initform-p found)
 365                          (condition-slot-initform-p sslot))
 366                    (setf (condition-slot-initform found)
 367                          (condition-slot-initform sslot))
 368                    (setf (condition-slot-initfunction sslot)
 369                          (condition-slot-initfunction found)))
 370                  (unless (condition-slot-allocation found)
 371                    (setf (condition-slot-allocation found)
 372                          (condition-slot-allocation sslot))))
 373                 (t
 374                  (res (copy-structure sslot)))))))
 375     (res)))
 376
 377 ;;; Early definitions of slot accessor creators.
 378 ;;;
 379 ;;; Slot accessors must be generic functions, but ANSI does not seem
 380 ;;; to specify any of them, and we cannot support it before end of
 381 ;;; warm init. So we use ordinary functions inside SBCL, and switch to
 382 ;;; GFs only at the end of building.
 383 (declaim (notinline install-condition-slot-reader
 384                     install-condition-slot-writer))
 385 (defun install-condition-slot-reader (name condition slot-name)
 386   (declare (ignore condition))
 387   (setf (fdefinition name)
 388         (lambda (condition)
 389           (condition-reader-function condition slot-name))))
 390 (defun install-condition-slot-writer (name condition slot-name)
 391   (declare (ignore condition))
 392   (setf (fdefinition name)
 393         (lambda (new-value condition)
 394           (condition-writer-function condition new-value slot-name))))
 395
 396 (defvar *define-condition-hooks* nil)
 397
 398 (defun %set-condition-report (name report)
 399   (setf (condition-classoid-report (find-classoid name))
 400         report))
 401
 402 (defun %define-condition (name parent-types layout slots documentation
 403                           direct-default-initargs all-readers all-writers
 404                           source-location)
 405   (with-single-package-locked-error
 406       (:symbol name "defining ~A as a condition")
 407     (%compiler-define-condition name parent-types layout all-readers all-writers)
 408     (sb!c:with-source-location (source-location)
 409       (setf (layout-source-location layout)
 410             source-location))
 411     (let ((class (find-classoid name)))
 412       (setf (condition-classoid-slots class) slots
 413             (condition-classoid-direct-default-initargs class) direct-default-initargs
 414             (fdocumentation name 'type) documentation)
 415
 416       (dolist (slot slots)
 417
 418         ;; Set up reader and writer functions.
 419         (let ((slot-name (condition-slot-name slot)))
 420           (dolist (reader (condition-slot-readers slot))
 421             (install-condition-slot-reader reader name slot-name))
 422           (dolist (writer (condition-slot-writers slot))
 423             (install-condition-slot-writer writer name slot-name))))
 424
 425       ;; Compute effective slots and set up the class and hairy slots
 426       ;; (subsets of the effective slots.)
 427       (setf (condition-classoid-hairy-slots class) '())
 428       (let ((eslots (compute-effective-slots class))
 429             (e-def-initargs
 430              (reduce #'append
 431                      (mapcar #'condition-classoid-direct-default-initargs
 432                              (condition-classoid-cpl class)))))
 433         (dolist (slot eslots)
 434           (ecase (condition-slot-allocation slot)
 435             (:class
 436              (unless (condition-slot-cell slot)
 437                (setf (condition-slot-cell slot)
 438                      (list (if (condition-slot-initform-p slot)
 439                                (let ((initfun (condition-slot-initfunction slot)))
 440                                  (aver (functionp initfun))
 441                                  (funcall initfun))
 442                                *empty-condition-slot*))))
 443              (push slot (condition-classoid-class-slots class)))
 444             ((:instance nil)
 445              (setf (condition-slot-allocation slot) :instance)
 446              ;; FIXME: isn't this "always hairy"?
 447              (when (or (functionp (condition-slot-initfunction slot))
 448                        (dolist (initarg (condition-slot-initargs slot) nil)
 449                          (when (functionp (third (assoc initarg e-def-initargs)))
 450                            (return t))))
 451                (push slot (condition-classoid-hairy-slots class)))))))
 452       (when (boundp '*define-condition-hooks*)
 453         (dolist (fun *define-condition-hooks*)
 454           (funcall fun class))))
 455     name))
 456
 457 (defmacro define-condition (name (&rest parent-types) (&rest slot-specs)
 458                                  &body options)
 459   #!+sb-doc
 460   "DEFINE-CONDITION Name (Parent-Type*) (Slot-Spec*) Option*
 461    Define NAME as a condition type. This new type inherits slots and its
 462    report function from the specified PARENT-TYPEs. A slot spec is a list of:
 463      (slot-name :reader <rname> :initarg <iname> {Option Value}*
 464
 465    The DEFINE-CLASS slot options :ALLOCATION, :INITFORM, [slot] :DOCUMENTATION
 466    and :TYPE and the overall options :DEFAULT-INITARGS and
 467    [type] :DOCUMENTATION are also allowed.
 468
 469    The :REPORT option is peculiar to DEFINE-CONDITION. Its argument is either
 470    a string or a two-argument lambda or function name. If a function, the
 471    function is called with the condition and stream to report the condition.
 472    If a string, the string is printed.
 473
 474    Condition types are classes, but (as allowed by ANSI and not as described in
 475    CLtL2) are neither STANDARD-OBJECTs nor STRUCTURE-OBJECTs. WITH-SLOTS and
 476    SLOT-VALUE may not be used on condition objects."
 477   (let* ((parent-types (or parent-types '(condition)))
 478          (layout (find-condition-layout name parent-types))
 479          (documentation nil)
 480          (report nil)
 481          (direct-default-initargs ()))
 482     (collect ((slots)
 483               (all-readers nil append)
 484               (all-writers nil append))
 485       (dolist (spec slot-specs)
 486         (when (keywordp spec)
 487           (warn "Keyword slot name indicates probable syntax error:~%  ~S"
 488                 spec))
 489         (let* ((spec (if (consp spec) spec (list spec)))
 490                (slot-name (first spec))
 491                (allocation :instance)
 492                (initform-p nil)
 493                documentation
 494                initform)
 495           (collect ((initargs)
 496                     (readers)
 497                     (writers))
 498             (do ((options (rest spec) (cddr options)))
 499                 ((null options))
 500               (unless (and (consp options) (consp (cdr options)))
 501                 (error "malformed condition slot spec:~%  ~S." spec))
 502               (let ((arg (second options)))
 503                 (case (first options)
 504                   (:reader (readers arg))
 505                   (:writer (writers arg))
 506                   (:accessor
 507                    (readers arg)
 508                    (writers `(setf ,arg)))
 509                   (:initform
 510                    (when initform-p
 511                      (error "more than one :INITFORM in ~S" spec))
 512                    (setq initform-p t)
 513                    (setq initform arg))
 514                   (:initarg (initargs arg))
 515                   (:allocation
 516                    (setq allocation arg))
 517                   (:documentation
 518                    (when documentation
 519                      (error "more than one :DOCUMENTATION in ~S" spec))
 520                    (unless (stringp arg)
 521                      (error "slot :DOCUMENTATION argument is not a string: ~S"
 522                             arg))
 523                    (setq documentation arg))
 524                   (:type)
 525                   (t
 526                    (error "unknown slot option:~%  ~S" (first options))))))
 527
 528             (all-readers (readers))
 529             (all-writers (writers))
 530             (slots `(make-condition-slot
 531                      :name ',slot-name
 532                      :initargs ',(initargs)
 533                      :readers ',(readers)
 534                      :writers ',(writers)
 535                      :initform-p ',initform-p
 536                      :documentation ',documentation
 537                      :initform ,(when initform-p `',initform)
 538                      :initfunction ,(when initform-p
 539                                       `#'(lambda () ,initform))
 540                      :allocation ',allocation)))))
 541
 542       (dolist (option options)
 543         (unless (consp option)
 544           (error "bad option:~%  ~S" option))
 545         (case (first option)
 546           (:documentation (setq documentation (second option)))
 547           (:report
 548            (let ((arg (second option)))
 549              (setq report
 550                    (if (stringp arg)
 551                        `#'(lambda (condition stream)
 552                             (declare (ignore condition))
 553                             (write-string ,arg stream))
 554                        `#'(lambda (condition stream)
 555                             (funcall #',arg condition stream))))))
 556           (:default-initargs
 557            (doplist (initarg initform) (rest option)
 558              (push ``(,',initarg ,',initform ,#'(lambda () ,initform))
 559                    direct-default-initargs)))
 560           (t
 561            (error "unknown option: ~S" (first option)))))
 562
 563       `(progn
 564          (eval-when (:compile-toplevel)
 565            (%compiler-define-condition ',name ',parent-types ',layout
 566                                        ',(all-readers) ',(all-writers)))
 567          (eval-when (:load-toplevel :execute)
 568            (%define-condition ',name
 569                               ',parent-types
 570                               ',layout
 571                               (list ,@(slots))
 572                               ,documentation
 573                               (list ,@direct-default-initargs)
 574                               ',(all-readers)
 575                               ',(all-writers)
 576                               (sb!c:source-location))
 577            ;; This needs to be after %DEFINE-CONDITION in case :REPORT
 578            ;; is a lambda referring to condition slot accessors:
 579            ;; they're not proclaimed as functions before it has run if
 580            ;; we're under EVAL or loaded as source.
 581            (%set-condition-report ',name ,report)
 582            ',name)))))
 583 \f
 584 ;;;; various CONDITIONs specified by ANSI
 585
 586 (define-condition serious-condition (condition) ())
 587
 588 (define-condition error (serious-condition) ())
 589
 590 (define-condition warning (condition) ())
 591 (define-condition style-warning (warning) ())
 592
 593 (defun simple-condition-printer (condition stream)
 594   (let ((control (simple-condition-format-control condition)))
 595     (if control
 596         (apply #'format stream
 597                control
 598                (simple-condition-format-arguments condition))
 599         (error "No format-control for ~S" condition))))
 600
 601 (define-condition simple-condition ()
 602   ((format-control :reader simple-condition-format-control
 603                    :initarg :format-control
 604                    :initform nil
 605                    :type format-control)
 606    (format-arguments :reader simple-condition-format-arguments
 607                      :initarg :format-arguments
 608                      :initform nil
 609                      :type list))
 610   (:report simple-condition-printer))
 611
 612 (define-condition simple-warning (simple-condition warning) ())
 613
 614 (define-condition simple-error (simple-condition error) ())
 615
 616 (define-condition storage-condition (serious-condition) ())
 617
 618 (define-condition type-error (error)
 619   ((datum :reader type-error-datum :initarg :datum)
 620    (expected-type :reader type-error-expected-type :initarg :expected-type))
 621   (:report
 622    (lambda (condition stream)
 623      (format stream
 624              "~@<The value ~2I~:_~S ~I~_is not of type ~2I~_~S.~:>"
 625              (type-error-datum condition)
 626              (type-error-expected-type condition)))))
 627
 628 (def!method print-object ((condition type-error) stream)
 629   (if (and *print-escape*
 630            (slot-boundp condition 'expected-type)
 631            (slot-boundp condition 'datum))
 632       (flet ((maybe-string (thing)
 633                (ignore-errors
 634                  (write-to-string thing :lines 1 :readably nil :array nil :pretty t))))
 635         (let ((type (maybe-string (type-error-expected-type condition)))
 636               (datum (maybe-string (type-error-datum condition))))
 637           (if (and type datum)
 638               (print-unreadable-object (condition stream :type t)
 639                 (format stream "~@<expected-type: ~A ~_datum: ~A~:@>" type datum))
 640               (call-next-method))))
 641       (call-next-method)))
 642
 643 ;;; not specified by ANSI, but too useful not to have around.
 644 (define-condition simple-style-warning (simple-condition style-warning) ())
 645 (define-condition simple-type-error (simple-condition type-error) ())
 646
 647 ;; Can't have a function called SIMPLE-TYPE-ERROR or TYPE-ERROR...
 648 (declaim (ftype (sfunction (t t t &rest t) nil) bad-type))
 649 (defun bad-type (datum type control &rest arguments)
 650   (error 'simple-type-error
 651          :datum datum
 652          :expected-type type
 653          :format-control control
 654          :format-arguments arguments))
 655
 656 (define-condition program-error (error) ())
 657 (define-condition parse-error   (error) ())
 658 (define-condition control-error (error) ())
 659 (define-condition stream-error  (error)
 660   ((stream :reader stream-error-stream :initarg :stream)))
 661
 662 (define-condition end-of-file (stream-error) ()
 663   (:report
 664    (lambda (condition stream)
 665      (format stream
 666              "end of file on ~S"
 667              (stream-error-stream condition)))))
 668
 669 (define-condition closed-stream-error (stream-error) ()
 670   (:report
 671    (lambda (condition stream)
 672      (format stream "~S is closed" (stream-error-stream condition)))))
 673
 674 (define-condition file-error (error)
 675   ((pathname :reader file-error-pathname :initarg :pathname))
 676   (:report
 677    (lambda (condition stream)
 678      (format stream "error on file ~S" (file-error-pathname condition)))))
 679
 680 (define-condition package-error (error)
 681   ((package :reader package-error-package :initarg :package)))
 682
 683 (define-condition cell-error (error)
 684   ((name :reader cell-error-name :initarg :name)))
 685
 686 (def!method print-object ((condition cell-error) stream)
 687   (if (and *print-escape* (slot-boundp condition 'name))
 688       (print-unreadable-object (condition stream :type t :identity t)
 689         (princ (cell-error-name condition) stream))
 690       (call-next-method)))
 691
 692 (define-condition unbound-variable (cell-error) ()
 693   (:report
 694    (lambda (condition stream)
 695      (format stream
 696              "The variable ~S is unbound."
 697              (cell-error-name condition)))))
 698
 699 (define-condition undefined-function (cell-error) ()
 700   (:report
 701    (lambda (condition stream)
 702      (let ((*package* (find-package :keyword)))
 703        (format stream
 704                "The function ~S is undefined."
 705                (cell-error-name condition))))))
 706
 707 (define-condition special-form-function (undefined-function) ()
 708   (:report
 709    (lambda (condition stream)
 710      (format stream
 711              "Cannot FUNCALL the SYMBOL-FUNCTION of special operator ~S."
 712              (cell-error-name condition)))))
 713
 714 (define-condition arithmetic-error (error)
 715   ((operation :reader arithmetic-error-operation
 716               :initarg :operation
 717               :initform nil)
 718    (operands :reader arithmetic-error-operands
 719              :initarg :operands))
 720   (:report (lambda (condition stream)
 721              (format stream
 722                      "arithmetic error ~S signalled"
 723                      (type-of condition))
 724              (when (arithmetic-error-operation condition)
 725                (format stream
 726                        "~%Operation was ~S, operands ~S."
 727                        (arithmetic-error-operation condition)
 728                        (arithmetic-error-operands condition))))))
 729
 730 (define-condition division-by-zero         (arithmetic-error) ())
 731 (define-condition floating-point-overflow  (arithmetic-error) ())
 732 (define-condition floating-point-underflow (arithmetic-error) ())
 733 (define-condition floating-point-inexact   (arithmetic-error) ())
 734 (define-condition floating-point-invalid-operation (arithmetic-error) ())
 735
 736 (define-condition print-not-readable (error)
 737   ((object :reader print-not-readable-object :initarg :object))
 738   (:report
 739    (lambda (condition stream)
 740      (let ((obj (print-not-readable-object condition))
 741            (*print-array* nil))
 742        (format stream "~S cannot be printed readably." obj)))))
 743
 744 (define-condition reader-error (parse-error stream-error) ()
 745   (:report (lambda (condition stream)
 746              (%report-reader-error condition stream))))
 747
 748 ;;; a READER-ERROR whose REPORTing is controlled by FORMAT-CONTROL and
 749 ;;; FORMAT-ARGS (the usual case for READER-ERRORs signalled from
 750 ;;; within SBCL itself)
 751 ;;;
 752 ;;; (Inheriting CL:SIMPLE-CONDITION here isn't quite consistent with
 753 ;;; the letter of the ANSI spec: this is not a condition signalled by
 754 ;;; SIGNAL when a format-control is supplied by the function's first
 755 ;;; argument. It seems to me (WHN) to be basically in the spirit of
 756 ;;; the spec, but if not, it'd be straightforward to do our own
 757 ;;; DEFINE-CONDITION SB-INT:SIMPLISTIC-CONDITION with
 758 ;;; FORMAT-CONTROL and FORMAT-ARGS slots, and use that condition in
 759 ;;; place of CL:SIMPLE-CONDITION here.)
 760 (define-condition simple-reader-error (reader-error simple-condition)
 761   ()
 762   (:report (lambda (condition stream)
 763              (%report-reader-error condition stream :simple t))))
 764
 765 ;;; base REPORTing of a READER-ERROR
 766 ;;;
 767 ;;; When SIMPLE, we expect and use SIMPLE-CONDITION-ish FORMAT-CONTROL
 768 ;;; and FORMAT-ARGS slots.
 769 (defun %report-reader-error (condition stream &key simple position)
 770   (let ((error-stream (stream-error-stream condition)))
 771     (pprint-logical-block (stream nil)
 772       (if simple
 773           (apply #'format stream
 774                  (simple-condition-format-control condition)
 775                  (simple-condition-format-arguments condition))
 776           (prin1 (class-name (class-of condition)) stream))
 777       (format stream "~2I~@[~_~_~:{~:(~A~): ~S~:^, ~:_~}~]~_~_Stream: ~S"
 778               (stream-error-position-info error-stream position)
 779               error-stream))))
 780 \f
 781 ;;;; special SBCL extension conditions
 782
 783 ;;; an error apparently caused by a bug in SBCL itself
 784 ;;;
 785 ;;; Note that we don't make any serious effort to use this condition
 786 ;;; for *all* errors in SBCL itself. E.g. type errors and array
 787 ;;; indexing errors can occur in functions called from SBCL code, and
 788 ;;; will just end up as ordinary TYPE-ERROR or invalid index error,
 789 ;;; because the signalling code has no good way to know that the
 790 ;;; underlying problem is a bug in SBCL. But in the fairly common case
 791 ;;; that the signalling code does know that it's found a bug in SBCL,
 792 ;;; this condition is appropriate, reusing boilerplate and helping
 793 ;;; users to recognize it as an SBCL bug.
 794 (define-condition bug (simple-error)
 795   ()
 796   (:report
 797    (lambda (condition stream)
 798      (format stream
 799              "~@<  ~? ~:@_~?~:>"
 800              (simple-condition-format-control condition)
 801              (simple-condition-format-arguments condition)
 802              "~@<This is probably a bug in SBCL itself. (Alternatively, ~
 803               SBCL might have been corrupted by bad user code, e.g. by an ~
 804               undefined Lisp operation like ~S, or by stray pointers from ~
 805               alien code or from unsafe Lisp code; or there might be a bug ~
 806               in the OS or hardware that SBCL is running on.) If it seems to ~
 807               be a bug in SBCL itself, the maintainers would like to know ~
 808               about it. Bug reports are welcome on the SBCL ~
 809               mailing lists, which you can find at ~
 810               <http://sbcl.sourceforge.net/>.~:@>"
 811              '((fmakunbound 'compile))))))
 812
 813 (define-condition simple-storage-condition (storage-condition simple-condition)
 814   ())
 815
 816 ;;; a condition for use in stubs for operations which aren't supported
 817 ;;; on some platforms
 818 ;;;
 819 ;;; E.g. in sbcl-0.7.0.5, it might be appropriate to do something like
 820 ;;;   #-(or freebsd linux)
 821 ;;;   (defun load-foreign (&rest rest)
 822 ;;;     (error 'unsupported-operator :name 'load-foreign))
 823 ;;;   #+(or freebsd linux)
 824 ;;;   (defun load-foreign ... actual definition ...)
 825 ;;; By signalling a standard condition in this case, we make it
 826 ;;; possible for test code to distinguish between (1) intentionally
 827 ;;; unimplemented and (2) unintentionally just screwed up somehow.
 828 ;;; (Before this condition was defined, test code tried to deal with
 829 ;;; this by checking for FBOUNDP, but that didn't work reliably. In
 830 ;;; sbcl-0.7.0, a package screwup left the definition of
 831 ;;; LOAD-FOREIGN in the wrong package, so it was unFBOUNDP even on
 832 ;;; architectures where it was supposed to be supported, and the
 833 ;;; regression tests cheerfully passed because they assumed that
 834 ;;; unFBOUNDPness meant they were running on an system which didn't
 835 ;;; support the extension.)
 836 (define-condition unsupported-operator (simple-error) ())
 837 \f
 838 ;;; (:ansi-cl :function remove)
 839 ;;; (:ansi-cl :section (a b c))
 840 ;;; (:ansi-cl :glossary "similar")
 841 ;;;
 842 ;;; (:sbcl :node "...")
 843 ;;; (:sbcl :variable *ed-functions*)
 844 ;;;
 845 ;;; FIXME: this is not the right place for this.
 846 (defun print-reference (reference stream)
 847   (ecase (car reference)
 848     (:amop
 849      (format stream "AMOP")
 850      (format stream ", ")
 851      (destructuring-bind (type data) (cdr reference)
 852        (ecase type
 853          (:readers "Readers for ~:(~A~) Metaobjects"
 854                    (substitute #\  #\- (symbol-name data)))
 855          (:initialization
 856           (format stream "Initialization of ~:(~A~) Metaobjects"
 857                   (substitute #\  #\- (symbol-name data))))
 858          (:generic-function (format stream "Generic Function ~S" data))
 859          (:function (format stream "Function ~S" data))
 860          (:section (format stream "Section ~{~D~^.~}" data)))))
 861     (:ansi-cl
 862      (format stream "The ANSI Standard")
 863      (format stream ", ")
 864      (destructuring-bind (type data) (cdr reference)
 865        (ecase type
 866          (:function (format stream "Function ~S" data))
 867          (:special-operator (format stream "Special Operator ~S" data))
 868          (:macro (format stream "Macro ~S" data))
 869          (:section (format stream "Section ~{~D~^.~}" data))
 870          (:glossary (format stream "Glossary entry for ~S" data))
 871          (:issue (format stream "writeup for Issue ~A" data)))))
 872     (:sbcl
 873      (format stream "The SBCL Manual")
 874      (format stream ", ")
 875      (destructuring-bind (type data) (cdr reference)
 876        (ecase type
 877          (:node (format stream "Node ~S" data))
 878          (:variable (format stream "Variable ~S" data))
 879          (:function (format stream "Function ~S" data)))))
 880     ;; FIXME: other documents (e.g. CLIM, Franz documentation :-)
 881     ))
 882 (define-condition reference-condition ()
 883   ((references :initarg :references :reader reference-condition-references)))
 884 (defvar *print-condition-references* t)
 885 (def!method print-object :around ((o reference-condition) s)
 886   (call-next-method)
 887   (unless (or *print-escape* *print-readably*)
 888     (when (and *print-condition-references*
 889                (reference-condition-references o))
 890       (format s "~&See also:~%")
 891       (pprint-logical-block (s nil :per-line-prefix "  ")
 892         (do* ((rs (reference-condition-references o) (cdr rs))
 893               (r (car rs) (car rs)))
 894              ((null rs))
 895           (print-reference r s)
 896           (unless (null (cdr rs))
 897             (terpri s)))))))
 898
 899 (define-condition simple-reference-error (reference-condition simple-error)
 900   ())
 901
 902 (define-condition simple-reference-warning (reference-condition simple-warning)
 903   ())
 904
 905 (define-condition arguments-out-of-domain-error
 906     (arithmetic-error reference-condition)
 907   ())
 908
 909 (define-condition duplicate-definition (reference-condition warning)
 910   ((name :initarg :name :reader duplicate-definition-name))
 911   (:report (lambda (c s)
 912              (format s "~@<Duplicate definition for ~S found in ~
 913                         one file.~@:>"
 914                      (duplicate-definition-name c))))
 915   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 916
 917 (define-condition constant-modified (reference-condition warning)
 918   ((fun-name :initarg :fun-name :reader constant-modified-fun-name))
 919   (:report (lambda (c s)
 920              (format s "~@<Destructive function ~S called on ~
 921                         constant data.~@:>"
 922                      (constant-modified-fun-name c))))
 923   (:default-initargs :references (list '(:ansi-cl :special-operator quote)
 924                                        '(:ansi-cl :section (3 2 2 3)))))
 925
 926 (define-condition package-at-variance (reference-condition simple-warning)
 927   ()
 928   (:default-initargs :references (list '(:ansi-cl :macro defpackage)
 929                                        '(:sbcl :variable *on-package-variance*))))
 930
 931 (define-condition package-at-variance-error (reference-condition simple-condition
 932                                              package-error)
 933   ()
 934   (:default-initargs :references (list '(:ansi-cl :macro defpackage))))
 935
 936 (define-condition defconstant-uneql (reference-condition error)
 937   ((name :initarg :name :reader defconstant-uneql-name)
 938    (old-value :initarg :old-value :reader defconstant-uneql-old-value)
 939    (new-value :initarg :new-value :reader defconstant-uneql-new-value))
 940   (:report
 941    (lambda (condition stream)
 942      (format stream
 943              "~@<The constant ~S is being redefined (from ~S to ~S)~@:>"
 944              (defconstant-uneql-name condition)
 945              (defconstant-uneql-old-value condition)
 946              (defconstant-uneql-new-value condition))))
 947   (:default-initargs :references (list '(:ansi-cl :macro defconstant)
 948                                        '(:sbcl :node "Idiosyncrasies"))))
 949
 950 (define-condition array-initial-element-mismatch
 951     (reference-condition simple-warning)
 952   ()
 953   (:default-initargs
 954       :references (list
 955                    '(:ansi-cl :function make-array)
 956                    '(:ansi-cl :function sb!xc:upgraded-array-element-type))))
 957
 958 (define-condition type-warning (reference-condition simple-warning)
 959   ()
 960   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 961 (define-condition type-style-warning (reference-condition simple-style-warning)
 962   ()
 963   (:default-initargs :references (list '(:sbcl :node "Handling of Types"))))
 964
 965 (define-condition local-argument-mismatch (reference-condition simple-warning)
 966   ()
 967   (:default-initargs :references (list '(:ansi-cl :section (3 2 2 3)))))
 968
 969 (define-condition format-args-mismatch (reference-condition)
 970   ()
 971   (:default-initargs :references (list '(:ansi-cl :section (22 3 10 2)))))
 972
 973 (define-condition format-too-few-args-warning
 974     (format-args-mismatch simple-warning)
 975   ())
 976 (define-condition format-too-many-args-warning
 977     (format-args-mismatch simple-style-warning)
 978   ())
 979
 980 (define-condition implicit-generic-function-warning (style-warning)
 981   ((name :initarg :name :reader implicit-generic-function-name))
 982   (:report
 983    (lambda (condition stream)
 984      (format stream "~@<Implicitly creating new generic function ~
 985                      ~/sb-impl::print-symbol-with-prefix/.~:@>"
 986              (implicit-generic-function-name condition)))))
 987
 988 (define-condition extension-failure (reference-condition simple-error)
 989   ())
 990
 991 (define-condition structure-initarg-not-keyword
 992     (reference-condition simple-style-warning)
 993   ()
 994   (:default-initargs :references (list '(:ansi-cl :section (2 4 8 13)))))
 995
 996 #!+sb-package-locks
 997 (progn
 998
 999 (define-condition package-lock-violation (package-error
1000                                           reference-condition
1001                                           simple-condition)
1002   ((current-package :initform *package*
1003                     :reader package-lock-violation-in-package))
1004   (:report
1005    (lambda (condition stream)
1006      (let ((control (simple-condition-format-control condition))
1007            (error-package (package-name
1008                            (package-error-package condition)))
1009            (current-package (package-name
1010                              (package-lock-violation-in-package condition))))
1011        (format stream "~@<Lock on package ~A violated~@[~{ when ~?~}~] ~
1012                        while in package ~A.~:@>"
1013                error-package
1014                (when control
1015                  (list control (simple-condition-format-arguments condition)))
1016                current-package))))
1017   ;; no :default-initargs -- reference-stuff provided by the
1018   ;; signalling form in target-package.lisp
1019   #!+sb-doc
1020   (:documentation
1021    "Subtype of CL:PACKAGE-ERROR. A subtype of this error is signalled
1022 when a package-lock is violated."))
1023
1024 (define-condition package-locked-error (package-lock-violation) ()
1025   #!+sb-doc
1026   (:documentation
1027    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1028 signalled when an operation on a package violates a package lock."))
1029
1030 (define-condition symbol-package-locked-error (package-lock-violation)
1031   ((symbol :initarg :symbol :reader package-locked-error-symbol))
1032   #!+sb-doc
1033   (:documentation
1034    "Subtype of SB-EXT:PACKAGE-LOCK-VIOLATION. An error of this type is
1035 signalled when an operation on a symbol violates a package lock. The
1036 symbol that caused the violation is accessed by the function
1037 SB-EXT:PACKAGE-LOCKED-ERROR-SYMBOL."))
1038
1039 ) ; progn
1040
1041 (define-condition undefined-alien-error (cell-error) ()
1042   (:report
1043    (lambda (condition stream)
1044      (if (slot-boundp condition 'name)
1045          (format stream "Undefined alien: ~S" (cell-error-name condition))
1046          (format stream "Undefined alien symbol.")))))
1047
1048 (define-condition undefined-alien-variable-error (undefined-alien-error) ()
1049   (:report
1050    (lambda (condition stream)
1051      (declare (ignore condition))
1052      (format stream "Attempt to access an undefined alien variable."))))
1053
1054 (define-condition undefined-alien-function-error (undefined-alien-error) ()
1055   (:report
1056    (lambda (condition stream)
1057      (if (and (slot-boundp condition 'name)
1058               (cell-error-name condition))
1059          (format stream "The alien function ~s is undefined."
1060                  (cell-error-name condition))
1061          (format stream "Attempt to call an undefined alien function.")))))
1062
1063 \f
1064 ;;;; various other (not specified by ANSI) CONDITIONs
1065 ;;;;
1066 ;;;; These might logically belong in other files; they're here, after
1067 ;;;; setup of CONDITION machinery, only because that makes it easier to
1068 ;;;; get cold init to work.
1069
1070 ;;; OAOOM warning: see cross-condition.lisp
1071 (define-condition encapsulated-condition (condition)
1072   ((condition :initarg :condition :reader encapsulated-condition)))
1073
1074 ;;; KLUDGE: a condition for floating point errors when we can't or
1075 ;;; won't figure out what type they are. (In FreeBSD and OpenBSD we
1076 ;;; don't know how, at least as of sbcl-0.6.7; in Linux we probably
1077 ;;; know how but the old code was broken by the conversion to POSIX
1078 ;;; signal handling and hasn't been fixed as of sbcl-0.6.7.)
1079 ;;;
1080 ;;; FIXME: Perhaps this should also be a base class for all
1081 ;;; floating point exceptions?
1082 (define-condition floating-point-exception (arithmetic-error)
1083   ((flags :initarg :traps
1084           :initform nil
1085           :reader floating-point-exception-traps))
1086   (:report (lambda (condition stream)
1087              (format stream
1088                      "An arithmetic error ~S was signalled.~%"
1089                      (type-of condition))
1090              (let ((traps (floating-point-exception-traps condition)))
1091                (if traps
1092                    (format stream
1093                            "Trapping conditions are: ~%~{ ~S~^~}~%"
1094                            traps)
1095                    (write-line
1096                     "No traps are enabled? How can this be?"
1097                     stream))))))
1098
1099 (define-condition invalid-array-index-error (type-error)
1100   ((array :initarg :array :reader invalid-array-index-error-array)
1101    (axis :initarg :axis :reader invalid-array-index-error-axis))
1102   (:report
1103    (lambda (condition stream)
1104      (let ((array (invalid-array-index-error-array condition)))
1105        (format stream "Index ~W out of bounds for ~@[axis ~W of ~]~S, ~
1106                        should be nonnegative and <~W."
1107                (type-error-datum condition)
1108                (when (> (array-rank array) 1)
1109                  (invalid-array-index-error-axis condition))
1110                (type-of array)
1111                ;; Extract the bound from (INTEGER 0 (BOUND))
1112                (caaddr (type-error-expected-type condition)))))))
1113
1114 (define-condition invalid-array-error (reference-condition type-error) ()
1115   (:report
1116    (lambda (condition stream)
1117      (let ((*print-array* nil))
1118        (format stream
1119                "~@<Displaced array originally of type ~S has been invalidated ~
1120                 due its displaced-to array ~S having become too small to hold ~
1121                 it: the displaced array's dimensions have all been set to zero ~
1122                 to trap accesses to it.~:@>"
1123                (type-error-expected-type condition)
1124                (array-displacement (type-error-datum condition))))))
1125   (:default-initargs
1126       :references
1127       (list '(:ansi-cl :function adjust-array))))
1128
1129 (define-condition index-too-large-error (type-error)
1130   ()
1131   (:report
1132    (lambda (condition stream)
1133      (format stream
1134              "The index ~S is too large."
1135              (type-error-datum condition)))))
1136
1137 (define-condition bounding-indices-bad-error (reference-condition type-error)
1138   ((object :reader bounding-indices-bad-object :initarg :object))
1139   (:report
1140    (lambda (condition stream)
1141      (let* ((datum (type-error-datum condition))
1142             (start (car datum))
1143             (end (cdr datum))
1144             (object (bounding-indices-bad-object condition)))
1145        (etypecase object
1146          (sequence
1147           (format stream
1148                   "The bounding indices ~S and ~S are bad ~
1149                    for a sequence of length ~S."
1150                   start end (length object)))
1151          (array
1152           ;; from WITH-ARRAY-DATA
1153           (format stream
1154                   "The START and END parameters ~S and ~S are ~
1155                    bad for an array of total size ~S."
1156                   start end (array-total-size object)))))))
1157   (:default-initargs
1158       :references
1159       (list '(:ansi-cl :glossary "bounding index designator")
1160             '(:ansi-cl :issue "SUBSEQ-OUT-OF-BOUNDS:IS-AN-ERROR"))))
1161
1162 (define-condition nil-array-accessed-error (reference-condition type-error)
1163   ()
1164   (:report (lambda (condition stream)
1165              (declare (ignore condition))
1166              (format stream
1167                      "An attempt to access an array of element-type ~
1168                       NIL was made.  Congratulations!")))
1169   (:default-initargs
1170       :references (list '(:ansi-cl :function sb!xc:upgraded-array-element-type)
1171                         '(:ansi-cl :section (15 1 2 1))
1172                         '(:ansi-cl :section (15 1 2 2)))))
1173
1174 (define-condition namestring-parse-error (parse-error)
1175   ((complaint :reader namestring-parse-error-complaint :initarg :complaint)
1176    (args :reader namestring-parse-error-args :initarg :args :initform nil)
1177    (namestring :reader namestring-parse-error-namestring :initarg :namestring)
1178    (offset :reader namestring-parse-error-offset :initarg :offset))
1179   (:report
1180    (lambda (condition stream)
1181      (format stream
1182              "parse error in namestring: ~?~%  ~A~%  ~V@T^"
1183              (namestring-parse-error-complaint condition)
1184              (namestring-parse-error-args condition)
1185              (namestring-parse-error-namestring condition)
1186              (namestring-parse-error-offset condition)))))
1187
1188 (define-condition simple-package-error (simple-condition package-error) ())
1189
1190 (define-condition simple-reader-package-error (simple-reader-error package-error) ())
1191
1192 (define-condition reader-eof-error (end-of-file)
1193   ((context :reader reader-eof-error-context :initarg :context))
1194   (:report
1195    (lambda (condition stream)
1196      (format stream
1197              "unexpected end of file on ~S ~A"
1198              (stream-error-stream condition)
1199              (reader-eof-error-context condition)))))
1200
1201 (define-condition reader-impossible-number-error (simple-reader-error)
1202   ((error :reader reader-impossible-number-error-error :initarg :error))
1203   (:report
1204    (lambda (condition stream)
1205      (let ((error-stream (stream-error-stream condition)))
1206        (format stream
1207                "READER-ERROR ~@[at ~W ~]on ~S:~%~?~%Original error: ~A"
1208                (file-position-or-nil-for-error error-stream) error-stream
1209                (simple-condition-format-control condition)
1210                (simple-condition-format-arguments condition)
1211                (reader-impossible-number-error-error condition))))))
1212
1213 (define-condition standard-readtable-modified-error (reference-condition error)
1214   ((operation :initarg :operation :reader standard-readtable-modified-operation))
1215   (:report (lambda (condition stream)
1216              (format stream "~S would modify the standard readtable."
1217                      (standard-readtable-modified-operation condition))))
1218   (:default-initargs :references `((:ansi-cl :section (2 1 1 2))
1219                                    (:ansi-cl :glossary "standard readtable"))))
1220
1221 (define-condition standard-pprint-dispatch-table-modified-error
1222     (reference-condition error)
1223   ((operation :initarg :operation
1224               :reader standard-pprint-dispatch-table-modified-operation))
1225   (:report (lambda (condition stream)
1226              (format stream "~S would modify the standard pprint dispatch table."
1227                      (standard-pprint-dispatch-table-modified-operation
1228                       condition))))
1229   (:default-initargs
1230       :references `((:ansi-cl :glossary "standard pprint dispatch table"))))
1231
1232 (define-condition timeout (serious-condition)
1233   ((seconds :initarg :seconds :initform nil :reader timeout-seconds))
1234   (:report (lambda (condition stream)
1235              (format stream "Timeout occurred~@[ after ~A seconds~]."
1236                      (timeout-seconds condition)))))
1237
1238 (define-condition io-timeout (stream-error timeout)
1239   ((direction :reader io-timeout-direction :initarg :direction))
1240   (:report
1241    (lambda (condition stream)
1242      (declare (type stream stream))
1243      (format stream
1244              "I/O timeout while doing ~(~A~) on ~S."
1245              (io-timeout-direction condition)
1246              (stream-error-stream condition)))))
1247
1248 (define-condition deadline-timeout (timeout) ()
1249   (:report (lambda (condition stream)
1250              (format stream "A deadline was reached after ~A seconds."
1251                      (timeout-seconds condition)))))
1252
1253 (define-condition declaration-type-conflict-error (reference-condition
1254                                                    simple-error)
1255   ()
1256   (:default-initargs
1257       :format-control "symbol ~S cannot be both the name of a type and the name of a declaration"
1258     :references (list '(:ansi-cl :section (3 8 21)))))
1259
1260 ;;; Single stepping conditions
1261
1262 (define-condition step-condition ()
1263   ((form :initarg :form :reader step-condition-form))
1264
1265   #!+sb-doc
1266   (:documentation "Common base class of single-stepping conditions.
1267 STEP-CONDITION-FORM holds a string representation of the form being
1268 stepped."))
1269
1270 #!+sb-doc
1271 (setf (fdocumentation 'step-condition-form 'function)
1272       "Form associated with the STEP-CONDITION.")
1273
1274 (define-condition step-form-condition (step-condition)
1275   ((args :initarg :args :reader step-condition-args))
1276   (:report
1277    (lambda (condition stream)
1278      (let ((*print-circle* t)
1279            (*print-pretty* t)
1280            (*print-readably* nil))
1281        (format stream
1282                  "Evaluating call:~%~<  ~@;~A~:>~%~
1283                   ~:[With arguments:~%~{  ~S~%~}~;With unknown arguments~]~%"
1284                (list (step-condition-form condition))
1285                (eq (step-condition-args condition) :unknown)
1286                (step-condition-args condition)))))
1287   #!+sb-doc
1288   (:documentation "Condition signalled by code compiled with
1289 single-stepping information when about to execute a form.
1290 STEP-CONDITION-FORM holds the form, STEP-CONDITION-PATHNAME holds the
1291 pathname of the original file or NIL, and STEP-CONDITION-SOURCE-PATH
1292 holds the source-path to the original form within that file or NIL.
1293 Associated with this condition are always the restarts STEP-INTO,
1294 STEP-NEXT, and STEP-CONTINUE."))
1295
1296 (define-condition step-result-condition (step-condition)
1297   ((result :initarg :result :reader step-condition-result)))
1298
1299 #!+sb-doc
1300 (setf (fdocumentation 'step-condition-result 'function)
1301       "Return values associated with STEP-VALUES-CONDITION as a list,
1302 or the variable value associated with STEP-VARIABLE-CONDITION.")
1303
1304 (define-condition step-values-condition (step-result-condition)
1305   ()
1306   #!+sb-doc
1307   (:documentation "Condition signalled by code compiled with
1308 single-stepping information after executing a form.
1309 STEP-CONDITION-FORM holds the form, and STEP-CONDITION-RESULT holds
1310 the values returned by the form as a list. No associated restarts."))
1311
1312 (define-condition step-finished-condition (step-condition)
1313   ()
1314   (:report
1315    (lambda (condition stream)
1316      (declare (ignore condition))
1317      (format stream "Returning from STEP")))
1318   #!+sb-doc
1319   (:documentation "Condition signaled when STEP returns."))
1320 \f
1321 ;;; A knob for muffling warnings, mostly for use while loading files.
1322 (defvar *muffled-warnings* 'uninteresting-redefinition
1323   "A type that ought to specify a subtype of WARNING.  Whenever a
1324 warning is signaled, if the warning if of this type and is not
1325 handled by any other handler, it will be muffled.")
1326 \f
1327 ;;; Various STYLE-WARNING signaled in the system.
1328 ;; For the moment, we're only getting into the details for function
1329 ;; redefinitions, but other redefinitions could be done later
1330 ;; (e.g. methods).
1331 (define-condition redefinition-warning (style-warning)
1332   ((name
1333     :initarg :name
1334     :reader redefinition-warning-name)
1335    (new-location
1336     :initarg :new-location
1337     :reader redefinition-warning-new-location)))
1338
1339 (define-condition function-redefinition-warning (redefinition-warning)
1340   ((new-function
1341     :initarg :new-function
1342     :reader function-redefinition-warning-new-function)))
1343
1344 (define-condition redefinition-with-defun (function-redefinition-warning)
1345   ()
1346   (:report (lambda (warning stream)
1347              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1348                              in DEFUN"
1349                      (redefinition-warning-name warning)))))
1350
1351 (define-condition redefinition-with-defmacro (function-redefinition-warning)
1352   ()
1353   (:report (lambda (warning stream)
1354              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1355                              in DEFMACRO"
1356                      (redefinition-warning-name warning)))))
1357
1358 (define-condition redefinition-with-defgeneric (redefinition-warning)
1359   ()
1360   (:report (lambda (warning stream)
1361              (format stream "redefining ~/sb-impl::print-symbol-with-prefix/ ~
1362                              in DEFGENERIC"
1363                      (redefinition-warning-name warning)))))
1364
1365 (define-condition redefinition-with-defmethod (redefinition-warning)
1366   ((qualifiers :initarg :qualifiers
1367                :reader redefinition-with-defmethod-qualifiers)
1368    (specializers :initarg :specializers
1369                  :reader redefinition-with-defmethod-specializers)
1370    (new-location :initarg :new-location
1371                  :reader redefinition-with-defmethod-new-location)
1372    (old-method :initarg :old-method
1373                :reader redefinition-with-defmethod-old-method))
1374   (:report (lambda (warning stream)
1375              (format stream "redefining ~S~{ ~S~} ~S in DEFMETHOD"
1376                      (redefinition-warning-name warning)
1377                      (redefinition-with-defmethod-qualifiers warning)
1378                      (redefinition-with-defmethod-specializers warning)))))
1379
1380 ;;;; Deciding which redefinitions are "interesting".
1381
1382 (defun function-file-namestring (function)
1383   #!+sb-eval
1384   (when (typep function 'sb!eval:interpreted-function)
1385     (return-from function-file-namestring
1386       (sb!c:definition-source-location-namestring
1387           (sb!eval:interpreted-function-source-location function))))
1388   (let* ((fun (sb!kernel:%fun-fun function))
1389          (code (sb!kernel:fun-code-header fun))
1390          (debug-info (sb!kernel:%code-debug-info code))
1391          (debug-source (when debug-info
1392                          (sb!c::debug-info-source debug-info)))
1393          (namestring (when debug-source
1394                        (sb!c::debug-source-namestring debug-source))))
1395     namestring))
1396
1397 (defun interesting-function-redefinition-warning-p (warning old)
1398   (let ((new (function-redefinition-warning-new-function warning))
1399         (source-location (redefinition-warning-new-location warning)))
1400     (or
1401      ;; compiled->interpreted is interesting.
1402      (and (typep old 'compiled-function)
1403           (typep new '(not compiled-function)))
1404      ;; fin->regular is interesting except for interpreted->compiled.
1405      (and (typep old '(and funcallable-instance
1406                            #!+sb-eval (not sb!eval:interpreted-function)))
1407           (typep new '(not funcallable-instance)))
1408      ;; different file or unknown location is interesting.
1409      (let* ((old-namestring (function-file-namestring old))
1410             (new-namestring
1411              (or (function-file-namestring new)
1412                  (when source-location
1413                    (sb!c::definition-source-location-namestring source-location)))))
1414        (and (or (not old-namestring)
1415                 (not new-namestring)
1416                 (not (string= old-namestring new-namestring))))))))
1417
1418 (defun uninteresting-ordinary-function-redefinition-p (warning)
1419   (and
1420    ;; There's garbage in various places when the first DEFUN runs in
1421    ;; cold-init.
1422    sb!kernel::*cold-init-complete-p*
1423    (typep warning 'redefinition-with-defun)
1424    ;; Shared logic.
1425    (let ((name (redefinition-warning-name warning)))
1426      (not (interesting-function-redefinition-warning-p
1427            warning (or (fdefinition name) (macro-function name)))))))
1428
1429 (defun uninteresting-macro-redefinition-p (warning)
1430   (and
1431    (typep warning 'redefinition-with-defmacro)
1432    ;; Shared logic.
1433    (let ((name (redefinition-warning-name warning)))
1434      (not (interesting-function-redefinition-warning-p
1435            warning (or (macro-function name) (fdefinition name)))))))
1436
1437 (defun uninteresting-generic-function-redefinition-p (warning)
1438   (and
1439    (typep warning 'redefinition-with-defgeneric)
1440    ;; Can't use the shared logic above, since GF's don't get a "new"
1441    ;; definition -- rather the FIN-FUNCTION is set.
1442    (let* ((name (redefinition-warning-name warning))
1443           (old (fdefinition name))
1444           (old-location (when (typep old 'generic-function)
1445                           (sb!pcl::definition-source old)))
1446           (old-namestring (when old-location
1447                             (sb!c:definition-source-location-namestring old-location)))
1448           (new-location (redefinition-warning-new-location warning))
1449           (new-namestring (when new-location
1450                            (sb!c:definition-source-location-namestring new-location))))
1451      (and old-namestring
1452           new-namestring
1453           (string= old-namestring new-namestring)))))
1454
1455 (defun uninteresting-method-redefinition-p (warning)
1456   (and
1457    (typep warning 'redefinition-with-defmethod)
1458    ;; Can't use the shared logic above, since GF's don't get a "new"
1459    ;; definition -- rather the FIN-FUNCTION is set.
1460    (let* ((old-method (redefinition-with-defmethod-old-method warning))
1461           (old-location (sb!pcl::definition-source old-method))
1462           (old-namestring (when old-location
1463                             (sb!c:definition-source-location-namestring old-location)))
1464           (new-location (redefinition-warning-new-location warning))
1465           (new-namestring (when new-location
1466                             (sb!c:definition-source-location-namestring new-location))))
1467          (and new-namestring
1468               old-namestring
1469               (string= new-namestring old-namestring)))))
1470
1471 (deftype uninteresting-redefinition ()
1472   '(or (satisfies uninteresting-ordinary-function-redefinition-p)
1473        (satisfies uninteresting-macro-redefinition-p)
1474        (satisfies uninteresting-generic-function-redefinition-p)
1475        (satisfies uninteresting-method-redefinition-p)))
1476
1477 (define-condition redefinition-with-deftransform (redefinition-warning)
1478   ((transform :initarg :transform
1479               :reader redefinition-with-deftransform-transform))
1480   (:report (lambda (warning stream)
1481              (format stream "Overwriting ~S"
1482                      (redefinition-with-deftransform-transform warning)))))
1483 \f
1484 ;;; Various other STYLE-WARNINGS
1485 (define-condition dubious-asterisks-around-variable-name
1486     (style-warning simple-condition)
1487   ()
1488   (:report (lambda (warning stream)
1489              (format stream "~@?, even though the name follows~@
1490 the usual naming convention (names like *FOO*) for special variables"
1491                      (simple-condition-format-control warning)
1492                      (simple-condition-format-arguments warning)))))
1493
1494 (define-condition asterisks-around-lexical-variable-name
1495     (dubious-asterisks-around-variable-name)
1496   ())
1497
1498 (define-condition asterisks-around-constant-variable-name
1499     (dubious-asterisks-around-variable-name)
1500   ())
1501
1502 ;; We call this UNDEFINED-ALIEN-STYLE-WARNING because there are some
1503 ;; subclasses of ERROR above having to do with undefined aliens.
1504 (define-condition undefined-alien-style-warning (style-warning)
1505   ((symbol :initarg :symbol :reader undefined-alien-symbol))
1506   (:report (lambda (warning stream)
1507              (format stream "Undefined alien: ~S"
1508                      (undefined-alien-symbol warning)))))
1509
1510 #!+sb-eval
1511 (define-condition lexical-environment-too-complex (style-warning)
1512   ((form :initarg :form :reader lexical-environment-too-complex-form)
1513    (lexenv :initarg :lexenv :reader lexical-environment-too-complex-lexenv))
1514   (:report (lambda (warning stream)
1515              (format stream
1516                      "~@<Native lexical environment too complex for ~
1517                          SB-EVAL to evaluate ~S, falling back to ~
1518                          SIMPLE-EVAL-IN-LEXENV.  Lexenv: ~S~:@>"
1519                      (lexical-environment-too-complex-form warning)
1520                      (lexical-environment-too-complex-lexenv warning)))))
1521
1522 ;; Although this has -ERROR- in the name, it's just a STYLE-WARNING.
1523 (define-condition character-decoding-error-in-comment (style-warning)
1524   ((stream :initarg :stream :reader decoding-error-in-comment-stream)
1525    (position :initarg :position :reader decoding-error-in-comment-position))
1526   (:report (lambda (warning stream)
1527              (format stream
1528                       "Character decoding error in a ~A-comment at ~
1529                       position ~A reading source stream ~A, ~
1530                       resyncing."
1531                       (decoding-error-in-comment-macro warning)
1532                       (decoding-error-in-comment-position warning)
1533                       (decoding-error-in-comment-stream warning)))))
1534
1535 (define-condition character-decoding-error-in-macro-char-comment
1536     (character-decoding-error-in-comment)
1537   ((char :initform #\; :initarg :char
1538          :reader character-decoding-error-in-macro-char-comment-char)))
1539
1540 (define-condition character-decoding-error-in-dispatch-macro-char-comment
1541     (character-decoding-error-in-comment)
1542   ;; ANSI doesn't give a way for a reader function invoked by a
1543   ;; dispatch macro character to determine which dispatch character
1544   ;; was used, so if a user wants to signal one of these from a custom
1545   ;; comment reader, he'll have to supply the :DISP-CHAR himself.
1546   ((disp-char :initform #\# :initarg :disp-char
1547               :reader character-decoding-error-in-macro-char-comment-disp-char)
1548    (sub-char :initarg :sub-char
1549              :reader character-decoding-error-in-macro-char-comment-sub-char)))
1550
1551 (defun decoding-error-in-comment-macro (warning)
1552   (etypecase warning
1553     (character-decoding-error-in-macro-char-comment
1554      (character-decoding-error-in-macro-char-comment-char warning))
1555     (character-decoding-error-in-dispatch-macro-char-comment
1556      (format
1557       nil "~C~C"
1558       (character-decoding-error-in-macro-char-comment-disp-char warning)
1559       (character-decoding-error-in-macro-char-comment-sub-char warning)))))
1560
1561 (define-condition deprecated-eval-when-situations (style-warning)
1562   ((situations :initarg :situations
1563                :reader deprecated-eval-when-situations-situations))
1564   (:report (lambda (warning stream)
1565              (format stream "using deprecated EVAL-WHEN situation names~{ ~S~}"
1566                      (deprecated-eval-when-situations-situations warning)))))
1567
1568 (define-condition proclamation-mismatch (condition)
1569   ((kind :initarg :kind :reader proclamation-mismatch-kind)
1570    (description :initarg :description :reader proclamation-mismatch-description :initform nil)
1571    (name :initarg :name :reader proclamation-mismatch-name)
1572    (old :initarg :old :reader proclamation-mismatch-old)
1573    (new :initarg :new :reader proclamation-mismatch-new))
1574   (:report
1575    (lambda (condition stream)
1576      ;; if we later decide we want package-qualified names, bind
1577      ;; *PACKAGE* to (find-package "KEYWORD") here.
1578      (format stream
1579              "~@<The new ~A proclamation for~@[ ~A~] ~S~
1580               ~@:_~2@T~S~@:_~
1581               does not match the old ~4:*~A~3* proclamation~
1582               ~@:_~2@T~S~@:>"
1583              (proclamation-mismatch-kind condition)
1584              (proclamation-mismatch-description condition)
1585              (proclamation-mismatch-name condition)
1586              (proclamation-mismatch-new condition)
1587              (proclamation-mismatch-old condition)))))
1588
1589 (define-condition type-proclamation-mismatch (proclamation-mismatch)
1590   ()
1591   (:default-initargs :kind 'type))
1592
1593 (define-condition type-proclamation-mismatch-warning (style-warning
1594                                                       type-proclamation-mismatch)
1595   ())
1596
1597 (defun type-proclamation-mismatch-warn (name old new &optional description)
1598   (warn 'type-proclamation-mismatch-warning
1599         :name name :old old :new new :description description))
1600
1601 (define-condition ftype-proclamation-mismatch (proclamation-mismatch)
1602   ()
1603   (:default-initargs :kind 'ftype))
1604
1605 (define-condition ftype-proclamation-mismatch-warning (style-warning
1606                                                        ftype-proclamation-mismatch)
1607   ())
1608
1609 (defun ftype-proclamation-mismatch-warn (name old new &optional description)
1610   (warn 'ftype-proclamation-mismatch-warning
1611         :name name :old old :new new :description description))
1612
1613 (define-condition ftype-proclamation-mismatch-error (error
1614                                                      ftype-proclamation-mismatch)
1615   ()
1616   (:default-initargs :kind 'ftype :description "known function"))
1617
1618 \f
1619 ;;;; deprecation conditions
1620
1621 (define-condition deprecation-condition ()
1622   ((name :initarg :name :reader deprecated-name)
1623    (replacements :initarg :replacements :reader deprecated-name-replacements)
1624    (since :initarg :since :reader deprecated-since)
1625    (runtime-error :initarg :runtime-error :reader deprecated-name-runtime-error)))
1626
1627 (def!method print-object ((condition deprecation-condition) stream)
1628   (let ((*package* (find-package :keyword)))
1629     (if *print-escape*
1630         (print-unreadable-object (condition stream :type t)
1631           (apply #'format
1632                  stream "~S is deprecated.~
1633                          ~#[~; Use ~S instead.~; ~
1634                                Use ~S or ~S instead.~:; ~
1635                                Use~@{~#[~; or~] ~S~^,~} instead.~]"
1636                   (deprecated-name condition)
1637                   (deprecated-name-replacements condition)))
1638         (apply #'format
1639                stream "~@<~S has been deprecated as of SBCL ~A.~
1640                        ~#[~; Use ~S instead.~; ~
1641                              Use ~S or ~S instead.~:; ~
1642                              Use~@{~#[~; or~] ~S~^,~:_~} instead.~]~:@>"
1643                 (deprecated-name condition)
1644                 (deprecated-since condition)
1645                 (deprecated-name-replacements condition)))))
1646
1647 (define-condition early-deprecation-warning (style-warning deprecation-condition)
1648   ())
1649
1650 (def!method print-object :after ((warning early-deprecation-warning) stream)
1651   (unless *print-escape*
1652     (let ((*package* (find-package :keyword)))
1653       (format stream "~%~@<~:@_In future SBCL versions ~S will signal a full warning ~
1654                       at compile-time.~:@>"
1655               (deprecated-name warning)))))
1656
1657 (define-condition late-deprecation-warning (warning deprecation-condition)
1658   ())
1659
1660 (def!method print-object :after ((warning late-deprecation-warning) stream)
1661   (unless *print-escape*
1662     (when (deprecated-name-runtime-error warning)
1663       (let ((*package* (find-package :keyword)))
1664         (format stream "~%~@<~:@_In future SBCL versions ~S will signal a runtime error.~:@>"
1665                 (deprecated-name warning))))))
1666
1667 (define-condition final-deprecation-warning (warning deprecation-condition)
1668   ())
1669
1670 (def!method print-object :after ((warning final-deprecation-warning) stream)
1671   (unless *print-escape*
1672     (when (deprecated-name-runtime-error warning)
1673       (let ((*package* (find-package :keyword)))
1674         (format stream "~%~@<~:@_An error will be signaled at runtime for ~S.~:@>"
1675                 (deprecated-name warning))))))
1676
1677 (define-condition deprecation-error (error deprecation-condition)
1678   ())
1679 \f
1680 ;;;; restart definitions
1681
1682 (define-condition abort-failure (control-error) ()
1683   (:report
1684    "An ABORT restart was found that failed to transfer control dynamically."))
1685
1686 (defun abort (&optional condition)
1687   #!+sb-doc
1688   "Transfer control to a restart named ABORT, signalling a CONTROL-ERROR if
1689    none exists."
1690   (invoke-restart (find-restart-or-control-error 'abort condition))
1691   ;; ABORT signals an error in case there was a restart named ABORT
1692   ;; that did not transfer control dynamically. This could happen with
1693   ;; RESTART-BIND.
1694   (error 'abort-failure))
1695
1696 (defun muffle-warning (&optional condition)
1697   #!+sb-doc
1698   "Transfer control to a restart named MUFFLE-WARNING, signalling a
1699    CONTROL-ERROR if none exists."
1700   (invoke-restart (find-restart-or-control-error 'muffle-warning condition)))
1701
1702 (defun try-restart (name condition &rest arguments)
1703   (let ((restart (find-restart name condition)))
1704     (when restart
1705       (apply #'invoke-restart restart arguments))))
1706
1707 (macrolet ((define-nil-returning-restart (name args doc)
1708              #!-sb-doc (declare (ignore doc))
1709              `(defun ,name (,@args &optional condition)
1710                 #!+sb-doc ,doc
1711                 (try-restart ',name condition ,@args))))
1712   (define-nil-returning-restart continue ()
1713     "Transfer control to a restart named CONTINUE, or return NIL if none exists.")
1714   (define-nil-returning-restart store-value (value)
1715     "Transfer control and VALUE to a restart named STORE-VALUE, or
1716 return NIL if none exists.")
1717   (define-nil-returning-restart use-value (value)
1718     "Transfer control and VALUE to a restart named USE-VALUE, or
1719 return NIL if none exists.")
1720   (define-nil-returning-restart print-unreadably ()
1721     "Transfer control to a restart named SB-EXT:PRINT-UNREADABLY, or
1722 return NIL if none exists."))
1723
1724 ;;; single-stepping restarts
1725
1726 (macrolet ((def (name doc)
1727                #!-sb-doc (declare (ignore doc))
1728                `(defun ,name (condition)
1729                  #!+sb-doc ,doc
1730                  (invoke-restart (find-restart-or-control-error ',name condition)))))
1731   (def step-continue
1732       "Transfers control to the STEP-CONTINUE restart associated with
1733 the condition, continuing execution without stepping. Signals a
1734 CONTROL-ERROR if the restart does not exist.")
1735   (def step-next
1736       "Transfers control to the STEP-NEXT restart associated with the
1737 condition, executing the current form without stepping and continuing
1738 stepping with the next form. Signals CONTROL-ERROR is the restart does
1739 not exists.")
1740   (def step-into
1741       "Transfers control to the STEP-INTO restart associated with the
1742 condition, stepping into the current form. Signals a CONTROL-ERROR is
1743 the restart does not exist."))
1744
1745 ;;; Compiler macro magic
1746
1747 (define-condition compiler-macro-keyword-problem ()
1748   ((argument :initarg :argument :reader compiler-macro-keyword-argument))
1749   (:report (lambda (condition stream)
1750              (format stream "~@<Argument ~S in keyword position is not ~
1751                              a self-evaluating symbol, preventing compiler-macro ~
1752                              expansion.~@:>"
1753                      (compiler-macro-keyword-argument condition)))))
1754
1755 (/show0 "condition.lisp end of file")