src/compiler/aliencomp.lisp

   1 ;;;; transforms and other stuff used to compile ALIEN operations
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!C")
  13 \f
  14 ;;;; DEFKNOWNs
  15
  16 (defknown %sap-alien (system-area-pointer alien-type) alien-value
  17   (flushable movable))
  18 (defknown alien-sap (alien-value) system-area-pointer
  19   (flushable movable))
  20
  21 (defknown slot (alien-value symbol) t
  22   (flushable recursive))
  23 (defknown %set-slot (alien-value symbol t) t
  24   (recursive))
  25 (defknown %slot-addr (alien-value symbol) (alien (* t))
  26   (flushable movable recursive))
  27
  28 (defknown deref (alien-value &rest index) t
  29   (flushable))
  30 (defknown %set-deref (alien-value t &rest index) t
  31   ())
  32 (defknown %deref-addr (alien-value &rest index) (alien (* t))
  33   (flushable movable))
  34
  35 (defknown %heap-alien (heap-alien-info) t
  36   (flushable))
  37 (defknown %set-heap-alien (heap-alien-info t) t
  38   ())
  39 (defknown %heap-alien-addr (heap-alien-info) (alien (* t))
  40   (flushable movable))
  41
  42 (defknown make-local-alien (local-alien-info) t
  43   ())
  44 (defknown note-local-alien-type (local-alien-info t) null
  45   ())
  46 (defknown local-alien (local-alien-info t) t
  47   (flushable))
  48 (defknown %local-alien-forced-to-memory-p (local-alien-info) (member t nil)
  49   (movable))
  50 (defknown %set-local-alien (local-alien-info t t) t
  51   ())
  52 (defknown %local-alien-addr (local-alien-info t) (alien (* t))
  53   (flushable movable))
  54 (defknown dispose-local-alien (local-alien-info t) t
  55   ())
  56
  57 (defknown %cast (alien-value alien-type) alien
  58   (flushable movable))
  59
  60 (defknown naturalize (t alien-type) alien
  61   (flushable movable))
  62 (defknown deport (alien alien-type) t
  63   (flushable movable))
  64 (defknown deport-alloc (alien alien-type) t
  65   (flushable movable))
  66 (defknown %alien-value (system-area-pointer unsigned-byte alien-type) t
  67   (flushable))
  68 (defknown (setf %alien-value) (t system-area-pointer unsigned-byte alien-type) t
  69   ())
  70
  71 (defknown alien-funcall (alien-value &rest *) *
  72   (any recursive))
  73 \f
  74 ;;;; cosmetic transforms
  75
  76 (deftransform slot ((object slot)
  77                     ((alien (* t)) symbol))
  78   '(slot (deref object) slot))
  79
  80 (deftransform %set-slot ((object slot value)
  81                          ((alien (* t)) symbol t))
  82   '(%set-slot (deref object) slot value))
  83
  84 (deftransform %slot-addr ((object slot)
  85                           ((alien (* t)) symbol))
  86   '(%slot-addr (deref object) slot))
  87 \f
  88 ;;;; SLOT support
  89
  90 (defun find-slot-offset-and-type (alien slot)
  91   (unless (constant-lvar-p slot)
  92     (give-up-ir1-transform
  93      "The slot is not constant, so access cannot be open coded."))
  94   (let ((type (lvar-type alien)))
  95     (unless (alien-type-type-p type)
  96       (give-up-ir1-transform))
  97     (let ((alien-type (alien-type-type-alien-type type)))
  98       (unless (alien-record-type-p alien-type)
  99         (give-up-ir1-transform))
 100       (let* ((slot-name (lvar-value slot))
 101              (field (find slot-name (alien-record-type-fields alien-type)
 102                           :key #'alien-record-field-name)))
 103         (unless field
 104           (abort-ir1-transform "~S~% doesn't have a slot named ~S"
 105                                type slot-name))
 106         (values (alien-record-field-offset field)
 107                 (alien-record-field-type field))))))
 108
 109 #+nil ;; Shouldn't be necessary.
 110 (defoptimizer (slot derive-type) ((alien slot))
 111   (block nil
 112     (catch 'give-up-ir1-transform
 113       (multiple-value-bind (slot-offset slot-type)
 114           (find-slot-offset-and-type alien slot)
 115         (declare (ignore slot-offset))
 116         (return (make-alien-type-type slot-type))))
 117     *wild-type*))
 118
 119 (deftransform slot ((alien slot) * * :important t)
 120   (multiple-value-bind (slot-offset slot-type)
 121       (find-slot-offset-and-type alien slot)
 122     `(%alien-value (alien-sap alien)
 123                    ,slot-offset
 124                    ',slot-type)))
 125
 126 #+nil ;; ### But what about coercions?
 127 (defoptimizer (%set-slot derive-type) ((alien slot value))
 128   (block nil
 129     (catch 'give-up-ir1-transform
 130       (multiple-value-bind (slot-offset slot-type)
 131           (find-slot-offset-and-type alien slot)
 132         (declare (ignore slot-offset))
 133         (let ((type (make-alien-type-type slot-type)))
 134           (assert-lvar-type value type)
 135           (return type))))
 136     *wild-type*))
 137
 138 (deftransform %set-slot ((alien slot value) * * :important t)
 139   (multiple-value-bind (slot-offset slot-type)
 140       (find-slot-offset-and-type alien slot)
 141     `(setf (%alien-value (alien-sap alien)
 142                          ,slot-offset
 143                          ',slot-type)
 144            value)))
 145
 146 (defoptimizer (%slot-addr derive-type) ((alien slot))
 147   (block nil
 148     (catch 'give-up-ir1-transform
 149       (multiple-value-bind (slot-offset slot-type)
 150           (find-slot-offset-and-type alien slot)
 151         (declare (ignore slot-offset))
 152         (return (make-alien-type-type
 153                  (make-alien-pointer-type :to slot-type)))))
 154     *wild-type*))
 155
 156 (deftransform %slot-addr ((alien slot) * * :important t)
 157   (multiple-value-bind (slot-offset slot-type)
 158       (find-slot-offset-and-type alien slot)
 159     (/noshow "in DEFTRANSFORM %SLOT-ADDR, creating %SAP-ALIEN")
 160     `(%sap-alien (sap+ (alien-sap alien) (/ ,slot-offset sb!vm:n-byte-bits))
 161                  ',(make-alien-pointer-type :to slot-type))))
 162 \f
 163 ;;;; DEREF support
 164
 165 (defun find-deref-alien-type (alien)
 166   (let ((alien-type (lvar-type alien)))
 167     (unless (alien-type-type-p alien-type)
 168       (give-up-ir1-transform))
 169     (let ((alien-type (alien-type-type-alien-type alien-type)))
 170       (if (alien-type-p alien-type)
 171           alien-type
 172           (give-up-ir1-transform)))))
 173
 174 (defun find-deref-element-type (alien)
 175   (let ((alien-type (find-deref-alien-type alien)))
 176     (typecase alien-type
 177       (alien-pointer-type
 178        (alien-pointer-type-to alien-type))
 179       (alien-array-type
 180        (alien-array-type-element-type alien-type))
 181       (t
 182        (give-up-ir1-transform)))))
 183
 184 (defun compute-deref-guts (alien indices)
 185   (let ((alien-type (find-deref-alien-type alien)))
 186     (typecase alien-type
 187       (alien-pointer-type
 188        (when (cdr indices)
 189          (abort-ir1-transform "too many indices for pointer deref: ~W"
 190                               (length indices)))
 191        (let ((element-type (alien-pointer-type-to alien-type)))
 192          (unless element-type
 193            (give-up-ir1-transform "unable to open code deref of wild pointer type"))
 194          (if indices
 195              (let ((bits (alien-type-bits element-type))
 196                    (alignment (alien-type-alignment element-type)))
 197                (unless bits
 198                  (abort-ir1-transform "unknown element size"))
 199                (unless alignment
 200                  (abort-ir1-transform "unknown element alignment"))
 201                (values '(offset)
 202                        `(* offset
 203                            ,(align-offset bits alignment))
 204                        element-type))
 205              (values nil 0 element-type))))
 206       (alien-array-type
 207        (let* ((element-type (alien-array-type-element-type alien-type))
 208               (bits (alien-type-bits element-type))
 209               (alignment (alien-type-alignment element-type))
 210               (dims (alien-array-type-dimensions alien-type)))
 211          (unless (= (length indices) (length dims))
 212            (give-up-ir1-transform "incorrect number of indices"))
 213          (unless bits
 214            (give-up-ir1-transform "Element size is unknown."))
 215          (unless alignment
 216            (give-up-ir1-transform "Element alignment is unknown."))
 217          (if (null dims)
 218              (values nil 0 element-type)
 219              (let* ((arg (gensym))
 220                     (args (list arg))
 221                     (offsetexpr arg))
 222                (dolist (dim (cdr dims))
 223                  (let ((arg (gensym)))
 224                    (push arg args)
 225                    (setf offsetexpr `(+ (* ,offsetexpr ,dim) ,arg))))
 226                (values (reverse args)
 227                        `(* ,offsetexpr
 228                            ,(align-offset bits alignment))
 229                        element-type)))))
 230       (t
 231        (abort-ir1-transform "~S not either a pointer or array type."
 232                             alien-type)))))
 233
 234 #+nil ;; Shouldn't be necessary.
 235 (defoptimizer (deref derive-type) ((alien &rest noise))
 236   (declare (ignore noise))
 237   (block nil
 238     (catch 'give-up-ir1-transform
 239       (return (make-alien-type-type (find-deref-element-type alien))))
 240     *wild-type*))
 241
 242 (deftransform deref ((alien &rest indices) * * :important t)
 243   (multiple-value-bind (indices-args offset-expr element-type)
 244       (compute-deref-guts alien indices)
 245     `(lambda (alien ,@indices-args)
 246        (%alien-value (alien-sap alien)
 247                      ,offset-expr
 248                      ',element-type))))
 249
 250 #+nil ;; ### Again, the value might be coerced.
 251 (defoptimizer (%set-deref derive-type) ((alien value &rest noise))
 252   (declare (ignore noise))
 253   (block nil
 254     (catch 'give-up-ir1-transform
 255       (let ((type (make-alien-type-type
 256                    (make-alien-pointer-type
 257                     :to (find-deref-element-type alien)))))
 258         (assert-lvar-type value type)
 259         (return type)))
 260     *wild-type*))
 261
 262 (deftransform %set-deref ((alien value &rest indices) * * :important t)
 263   (multiple-value-bind (indices-args offset-expr element-type)
 264       (compute-deref-guts alien indices)
 265     `(lambda (alien value ,@indices-args)
 266        (setf (%alien-value (alien-sap alien)
 267                            ,offset-expr
 268                            ',element-type)
 269              value))))
 270
 271 (defoptimizer (%deref-addr derive-type) ((alien &rest noise))
 272   (declare (ignore noise))
 273   (block nil
 274     (catch 'give-up-ir1-transform
 275       (return (make-alien-type-type
 276                (make-alien-pointer-type
 277                 :to (find-deref-element-type alien)))))
 278     *wild-type*))
 279
 280 (deftransform %deref-addr ((alien &rest indices) * * :important t)
 281   (multiple-value-bind (indices-args offset-expr element-type)
 282       (compute-deref-guts alien indices)
 283     (/noshow "in DEFTRANSFORM %DEREF-ADDR, creating (LAMBDA .. %SAP-ALIEN)")
 284     `(lambda (alien ,@indices-args)
 285        (%sap-alien (sap+ (alien-sap alien) (/ ,offset-expr sb!vm:n-byte-bits))
 286                    ',(make-alien-pointer-type :to element-type)))))
 287 \f
 288 ;;;; support for aliens on the heap
 289
 290 (defun heap-alien-sap-and-type (info)
 291   (unless (constant-lvar-p info)
 292     (give-up-ir1-transform "info not constant; can't open code"))
 293   (let ((info (lvar-value info)))
 294     (values (heap-alien-info-sap-form info)
 295             (heap-alien-info-type info))))
 296
 297 #+nil ; shouldn't be necessary
 298 (defoptimizer (%heap-alien derive-type) ((info))
 299   (block nil
 300     (catch 'give-up
 301       (multiple-value-bind (sap type) (heap-alien-sap-and-type info)
 302         (declare (ignore sap))
 303         (return (make-alien-type-type type))))
 304     *wild-type*))
 305
 306 (deftransform %heap-alien ((info) ((constant-arg heap-alien-info)) * :important t)
 307   (multiple-value-bind (sap type) (heap-alien-sap-and-type info)
 308     `(%alien-value ,sap 0 ',type)))
 309
 310 #+nil ;; ### Again, deposit value might change the type.
 311 (defoptimizer (%set-heap-alien derive-type) ((info value))
 312   (block nil
 313     (catch 'give-up-ir1-transform
 314       (multiple-value-bind (sap type) (heap-alien-sap-and-type info)
 315         (declare (ignore sap))
 316         (let ((type (make-alien-type-type type)))
 317           (assert-lvar-type value type)
 318           (return type))))
 319     *wild-type*))
 320
 321 (deftransform %set-heap-alien ((info value) (heap-alien-info *) * :important t)
 322   (multiple-value-bind (sap type) (heap-alien-sap-and-type info)
 323     `(setf (%alien-value ,sap 0 ',type) value)))
 324
 325 (defoptimizer (%heap-alien-addr derive-type) ((info))
 326   (block nil
 327     (catch 'give-up-ir1-transform
 328       (multiple-value-bind (sap type) (heap-alien-sap-and-type info)
 329         (declare (ignore sap))
 330         (return (make-alien-type-type (make-alien-pointer-type :to type)))))
 331     *wild-type*))
 332
 333 (deftransform %heap-alien-addr ((info) * * :important t)
 334   (multiple-value-bind (sap type) (heap-alien-sap-and-type info)
 335     (/noshow "in DEFTRANSFORM %HEAP-ALIEN-ADDR, creating %SAP-ALIEN")
 336     `(%sap-alien ,sap ',(make-alien-pointer-type :to type))))
 337
 338 \f
 339 ;;;; support for local (stack or register) aliens
 340
 341 (defun alien-info-constant-or-abort (info)
 342   (unless (constant-lvar-p info)
 343     (abort-ir1-transform "Local alien info isn't constant?")))
 344
 345 (deftransform make-local-alien ((info) * * :important t)
 346   (alien-info-constant-or-abort info)
 347   (let* ((info (lvar-value info))
 348          (alien-type (local-alien-info-type info))
 349          (bits (alien-type-bits alien-type)))
 350     (unless bits
 351       (abort-ir1-transform "unknown size: ~S" (unparse-alien-type alien-type)))
 352     (/noshow "in DEFTRANSFORM MAKE-LOCAL-ALIEN" info)
 353     (/noshow (local-alien-info-force-to-memory-p info))
 354     (/noshow alien-type (unparse-alien-type alien-type) (alien-type-bits alien-type))
 355     (if (local-alien-info-force-to-memory-p info)
 356         #!+(or x86 x86-64)
 357         `(%primitive alloc-alien-stack-space
 358                      ,(ceiling (alien-type-bits alien-type)
 359                                sb!vm:n-byte-bits))
 360         #!-(or x86 x86-64)
 361         `(%primitive alloc-number-stack-space
 362                      ,(ceiling (alien-type-bits alien-type)
 363                                sb!vm:n-byte-bits))
 364         (let* ((alien-rep-type-spec (compute-alien-rep-type alien-type))
 365                (alien-rep-type (specifier-type alien-rep-type-spec)))
 366           (cond ((csubtypep (specifier-type 'system-area-pointer)
 367                             alien-rep-type)
 368                  '(int-sap 0))
 369                 ((ctypep 0 alien-rep-type) 0)
 370                 ((ctypep 0.0f0 alien-rep-type) 0.0f0)
 371                 ((ctypep 0.0d0 alien-rep-type) 0.0d0)
 372                 (t
 373                  (compiler-error
 374                   "Aliens of type ~S cannot be represented immediately."
 375                   (unparse-alien-type alien-type))))))))
 376
 377 (deftransform note-local-alien-type ((info var) * * :important t)
 378   (alien-info-constant-or-abort info)
 379   (let ((info (lvar-value info)))
 380     (unless (local-alien-info-force-to-memory-p info)
 381       (let ((var-node (lvar-uses var)))
 382         (when (and (ref-p var-node)
 383                    (constant-reference-p var-node))
 384           (propagate-to-refs (ref-leaf var-node)
 385                              (specifier-type
 386                               (compute-alien-rep-type
 387                                (local-alien-info-type info))))))))
 388   nil)
 389
 390 (deftransform local-alien ((info var) * * :important t)
 391   (alien-info-constant-or-abort info)
 392   (let* ((info (lvar-value info))
 393          (alien-type (local-alien-info-type info)))
 394     (/noshow "in DEFTRANSFORM LOCAL-ALIEN" info alien-type)
 395     (/noshow (local-alien-info-force-to-memory-p info))
 396     (if (local-alien-info-force-to-memory-p info)
 397         `(%alien-value var 0 ',alien-type)
 398         `(naturalize var ',alien-type))))
 399
 400 (deftransform %local-alien-forced-to-memory-p ((info) * * :important t)
 401   (alien-info-constant-or-abort info)
 402   (let ((info (lvar-value info)))
 403     (local-alien-info-force-to-memory-p info)))
 404
 405 (deftransform %set-local-alien ((info var value) * * :important t)
 406   (alien-info-constant-or-abort info)
 407   (let* ((info (lvar-value info))
 408          (alien-type (local-alien-info-type info)))
 409     (if (local-alien-info-force-to-memory-p info)
 410         `(setf (%alien-value var 0 ',alien-type) value)
 411         '(error "This should be eliminated as dead code."))))
 412
 413 (defoptimizer (%local-alien-addr derive-type) ((info var))
 414   (declare (ignore var))
 415   (if (constant-lvar-p info)
 416       (let* ((info (lvar-value info))
 417              (alien-type (local-alien-info-type info)))
 418         (make-alien-type-type (make-alien-pointer-type :to alien-type)))
 419       *wild-type*))
 420
 421 (deftransform %local-alien-addr ((info var) * * :important t)
 422   (alien-info-constant-or-abort info)
 423   (let* ((info (lvar-value info))
 424          (alien-type (local-alien-info-type info)))
 425     (/noshow "in DEFTRANSFORM %LOCAL-ALIEN-ADDR, creating %SAP-ALIEN")
 426     (if (local-alien-info-force-to-memory-p info)
 427         `(%sap-alien var ',(make-alien-pointer-type :to alien-type))
 428         (error "This shouldn't happen."))))
 429
 430 ;; DISPOSE-LOCAL-ALIEN can't happens on x86[-64].
 431 ;; A transform of it is just misdirection.
 432 #!-(or x86 x86-64)
 433 (deftransform dispose-local-alien ((info var) * * :important t)
 434   (alien-info-constant-or-abort info)
 435   (let* ((info (lvar-value info))
 436          (alien-type (local-alien-info-type info)))
 437     (if (local-alien-info-force-to-memory-p info)
 438         `(%primitive dealloc-number-stack-space
 439                           ,(ceiling (alien-type-bits alien-type)
 440                                     sb!vm:n-byte-bits))
 441       nil)))
 442 \f
 443 ;;;; %CAST
 444
 445 (defoptimizer (%cast derive-type) ((alien type))
 446   (declare (ignore alien))
 447   (or (when (constant-lvar-p type)
 448         (let ((alien-type (lvar-value type)))
 449           (when (alien-type-p alien-type)
 450             (make-alien-type-type alien-type))))
 451       *wild-type*))
 452
 453 (deftransform %cast ((alien target-type) * * :important t)
 454   (unless (constant-lvar-p target-type)
 455     (give-up-ir1-transform
 456      "The alien type is not constant, so access cannot be open coded."))
 457   (let ((target-type (lvar-value target-type)))
 458     (cond ((or (alien-pointer-type-p target-type)
 459                (alien-array-type-p target-type)
 460                (alien-fun-type-p target-type))
 461            `(naturalize (alien-sap alien) ',target-type))
 462           (t
 463            (abort-ir1-transform "cannot cast to alien type ~S" target-type)))))
 464 \f
 465 ;;;; ALIEN-SAP, %SAP-ALIEN, %ADDR, etc.
 466
 467 (deftransform alien-sap ((alien) * * :important t)
 468   (let ((alien-node (lvar-uses alien)))
 469     (typecase alien-node
 470       (combination
 471        (splice-fun-args alien '%sap-alien 2)
 472        '(lambda (sap type)
 473           (declare (ignore type))
 474           sap))
 475       (t
 476        (give-up-ir1-transform)))))
 477
 478 (defoptimizer (%sap-alien derive-type) ((sap type))
 479   (declare (ignore sap))
 480   (if (constant-lvar-p type)
 481       (make-alien-type-type (lvar-value type))
 482       *wild-type*))
 483
 484 (deftransform %sap-alien ((sap type) * * :important t)
 485   (give-up-ir1-transform
 486    ;; FIXME: The hardcoded newline here causes more-than-usually
 487    ;; screwed-up formatting of the optimization note output.
 488    "could not optimize away %SAP-ALIEN: forced to do runtime ~@
 489     allocation of alien-value structure"))
 490 \f
 491 ;;;; NATURALIZE/DEPORT/EXTRACT/DEPOSIT magic
 492
 493 (flet ((%computed-lambda (compute-lambda type)
 494          (declare (type function compute-lambda))
 495          (unless (constant-lvar-p type)
 496            (give-up-ir1-transform
 497             "The type is not constant at compile time; can't open code."))
 498          (handler-case
 499              (let ((result (funcall compute-lambda (lvar-value type))))
 500                (/noshow "in %COMPUTED-LAMBDA" (lvar-value type) result)
 501                result)
 502            (error (condition)
 503                   (compiler-error "~A" condition)))))
 504   (deftransform naturalize ((object type) * * :important t)
 505     (%computed-lambda #'compute-naturalize-lambda type))
 506   (deftransform deport ((alien type) * * :important t)
 507     (%computed-lambda #'compute-deport-lambda type))
 508   (deftransform deport-alloc ((alien type) * * :important t)
 509     (%computed-lambda #'compute-deport-alloc-lambda type))
 510   (deftransform %alien-value ((sap offset type) * * :important t)
 511     (%computed-lambda #'compute-extract-lambda type))
 512   (deftransform (setf %alien-value) ((value sap offset type) * * :important t)
 513     (%computed-lambda #'compute-deposit-lambda type)))
 514 \f
 515 ;;;; a hack to clean up divisions
 516
 517 (defun count-low-order-zeros (thing)
 518   (typecase thing
 519     (lvar
 520      (if (constant-lvar-p thing)
 521          (count-low-order-zeros (lvar-value thing))
 522          (count-low-order-zeros (lvar-uses thing))))
 523     (combination
 524      (case (let ((name (lvar-fun-name (combination-fun thing))))
 525              (or (modular-version-info name :untagged nil) name))
 526        ((+ -)
 527         (let ((min most-positive-fixnum)
 528               (itype (specifier-type 'integer)))
 529           (dolist (arg (combination-args thing) min)
 530             (if (csubtypep (lvar-type arg) itype)
 531                 (setf min (min min (count-low-order-zeros arg)))
 532                 (return 0)))))
 533        (*
 534         (let ((result 0)
 535               (itype (specifier-type 'integer)))
 536           (dolist (arg (combination-args thing) result)
 537             (if (csubtypep (lvar-type arg) itype)
 538                 (setf result (+ result (count-low-order-zeros arg)))
 539                 (return 0)))))
 540        (ash
 541         (let ((args (combination-args thing)))
 542           (if (= (length args) 2)
 543               (let ((amount (second args)))
 544                 (if (constant-lvar-p amount)
 545                     (max (+ (count-low-order-zeros (first args))
 546                             (lvar-value amount))
 547                          0)
 548                     0))
 549               0)))
 550        (t
 551         0)))
 552     (integer
 553      (if (zerop thing)
 554          most-positive-fixnum
 555          (do ((result 0 (1+ result))
 556               (num thing (ash num -1)))
 557              ((logbitp 0 num) result))))
 558     (cast
 559      (count-low-order-zeros (cast-value thing)))
 560     (t
 561      0)))
 562
 563 (deftransform / ((numerator denominator) (integer integer))
 564   "convert x/2^k to shift"
 565   (unless (constant-lvar-p denominator)
 566     (give-up-ir1-transform))
 567   (let* ((denominator (lvar-value denominator))
 568          (bits (1- (integer-length denominator))))
 569     (unless (and (> denominator 0) (= (ash 1 bits) denominator))
 570       (give-up-ir1-transform))
 571     (let ((alignment (count-low-order-zeros numerator)))
 572       (unless (>= alignment bits)
 573         (give-up-ir1-transform))
 574       `(ash numerator ,(- bits)))))
 575
 576 (deftransform ash ((value amount))
 577   (let ((value-node (lvar-uses value)))
 578     (unless (combination-p value-node)
 579       (give-up-ir1-transform))
 580     (let ((inside-fun-name (lvar-fun-name (combination-fun value-node))))
 581       (multiple-value-bind (prototype width)
 582           (modular-version-info inside-fun-name :untagged nil)
 583         (unless (eq (or prototype inside-fun-name) 'ash)
 584           (give-up-ir1-transform))
 585         (when (and width (not (constant-lvar-p amount)))
 586           (give-up-ir1-transform))
 587         (let ((inside-args (combination-args value-node)))
 588           (unless (= (length inside-args) 2)
 589             (give-up-ir1-transform))
 590           (let ((inside-amount (second inside-args)))
 591             (unless (and (constant-lvar-p inside-amount)
 592                          (not (minusp (lvar-value inside-amount))))
 593               (give-up-ir1-transform)))
 594           (splice-fun-args value inside-fun-name 2)
 595           (if width
 596               `(lambda (value amount1 amount2)
 597                  (logand (ash value (+ amount1 amount2))
 598                          ,(1- (ash 1 (+ width (lvar-value amount))))))
 599               `(lambda (value amount1 amount2)
 600                  (ash value (+ amount1 amount2)))))))))
 601 \f
 602 ;;;; ALIEN-FUNCALL support
 603
 604 (deftransform alien-funcall ((function &rest args)
 605                              ((alien (* t)) &rest *) *
 606                              :important t)
 607   (let ((names (make-gensym-list (length args))))
 608     (/noshow "entering first DEFTRANSFORM ALIEN-FUNCALL" function args)
 609     `(lambda (function ,@names)
 610        (alien-funcall (deref function) ,@names))))
 611
 612 #-sb-xc-host
 613 (defun find-saved-fp-and-pc (fp)
 614   (dolist (x *saved-fp-and-pcs*)
 615     (declare (type (simple-array word (2)) x))
 616     (when (#!+stack-grows-downward-not-upward
 617            sap>
 618            #!-stack-grows-downward-not-upward
 619            sap<
 620            (int-sap (aref x 0)) fp)
 621       (return (values (int-sap (aref x 0)) (int-sap (aref x 1)))))))
 622
 623 (deftransform alien-funcall ((function &rest args) * * :node node :important t)
 624   (let ((type (lvar-type function)))
 625     (unless (alien-type-type-p type)
 626       (give-up-ir1-transform "can't tell function type at compile time"))
 627     (/noshow "entering second DEFTRANSFORM ALIEN-FUNCALL" function)
 628     (let ((alien-type (alien-type-type-alien-type type)))
 629       (unless (alien-fun-type-p alien-type)
 630         (give-up-ir1-transform))
 631       (let ((arg-types (alien-fun-type-arg-types alien-type)))
 632         (unless (= (length args) (length arg-types))
 633           (abort-ir1-transform
 634            "wrong number of arguments; expected ~W, got ~W"
 635            (length arg-types)
 636            (length args)))
 637         (collect ((params) (deports))
 638           (dolist (arg-type arg-types)
 639             (let ((param (gensym)))
 640               (params param)
 641               (deports `(deport ,param ',arg-type))))
 642           ;; Build BODY from the inside out.
 643           (let ((return-type (alien-fun-type-result-type alien-type))
 644                 ;; Innermost, we DEPORT the parameters (e.g. by taking SAPs
 645                 ;; to them) and do the call.
 646                 (body `(%alien-funcall (deport function ',alien-type)
 647                                        ',alien-type
 648                                        ,@(deports))))
 649             ;; Wrap that in a WITH-PINNED-OBJECTS to ensure the values
 650             ;; the SAPs are taken for won't be moved by the GC. (If
 651             ;; needed: some alien types won't need it).
 652             (setf body `(maybe-with-pinned-objects ,(params) ,arg-types
 653                           ,body))
 654             ;; Around that handle any memory allocation that's needed.
 655             ;; Mostly the DEPORT-ALLOC alien-type-methods are just an
 656             ;; identity operation, but for example for deporting a
 657             ;; Unicode string we need to convert the string into an
 658             ;; octet array. This step needs to be done before the pinning
 659             ;; to ensure we pin the right objects, so it can't be combined
 660             ;; with the deporting.
 661             ;; -- JES 2006-03-16
 662             (loop for param in (params)
 663                   for arg-type in arg-types
 664                   do (setf body
 665                            `(let ((,param (deport-alloc ,param ',arg-type)))
 666                               ,body)))
 667             (if (alien-values-type-p return-type)
 668                 (collect ((temps) (results))
 669                   (dolist (type (alien-values-type-values return-type))
 670                     (let ((temp (gensym)))
 671                       (temps temp)
 672                       (results `(naturalize ,temp ',type))))
 673                   (setf body
 674                         `(multiple-value-bind ,(temps) ,body
 675                            (values ,@(results)))))
 676                 (setf body `(naturalize ,body ',return-type)))
 677             ;; Remember this frame to make sure that we can get back
 678             ;; to it later regardless of how the foreign stack looks
 679             ;; like.
 680             #!+c-stack-is-control-stack
 681             (when (policy node (= 3 alien-funcall-saves-fp-and-pc))
 682               (setf body `(invoke-with-saved-fp-and-pc (lambda () ,body))))
 683             (/noshow "returning from DEFTRANSFORM ALIEN-FUNCALL" (params) body)
 684             `(lambda (function ,@(params))
 685                (declare (optimize (let-conversion 3)))
 686                ,body)))))))
 687
 688 (defoptimizer (%alien-funcall derive-type) ((function type &rest args))
 689   (declare (ignore function args))
 690   (unless (constant-lvar-p type)
 691     (error "Something is broken."))
 692   (let ((type (lvar-value type)))
 693     (unless (alien-fun-type-p type)
 694       (error "Something is broken."))
 695     (values-specifier-type
 696      (compute-alien-rep-type
 697       (alien-fun-type-result-type type)
 698       :result))))
 699
 700 (defoptimizer (%alien-funcall ltn-annotate)
 701               ((function type &rest args) node ltn-policy)
 702   (declare (ignore type ltn-policy))
 703   (setf (basic-combination-info node) :funny)
 704   (setf (node-tail-p node) nil)
 705   (annotate-ordinary-lvar function)
 706   (dolist (arg args)
 707     (annotate-ordinary-lvar arg)))
 708
 709 ;;; We support both the stdcall and cdecl calling conventions on win32 by
 710 ;;; resetting ESP after the foreign function returns. This way it works
 711 ;;; correctly whether the party that is supposed to pop arguments from
 712 ;;; the stack is the caller (cdecl) or the callee (stdcall).
 713 (defoptimizer (%alien-funcall ir2-convert)
 714               ((function type &rest args) call block)
 715   (let ((type (if (constant-lvar-p type)
 716                   (lvar-value type)
 717                   (error "Something is broken.")))
 718         (lvar (node-lvar call))
 719         ;; KLUDGE: On ARM systems our register pressure is so high
 720         ;; that if we process register args before stack args we end
 721         ;; up with all of our non-descriptor regs either
 722         ;; component-live (NFP) or wired (everything else) and can't
 723         ;; actually process the stack args.  Processing the arguments
 724         ;; in reverse order here doesn't change the semantics, but we
 725         ;; deal with all of the stack arguments before the wired
 726         ;; register arguments become live.
 727         (args #!-arm args #!+arm (reverse args))
 728         #!+c-stack-is-control-stack
 729         (stack-pointer (make-stack-pointer-tn)))
 730     (multiple-value-bind (nsp stack-frame-size arg-tns result-tns)
 731         (make-call-out-tns type)
 732       #!+x86
 733       (vop set-fpu-word-for-c call block)
 734       ;; Save the stack pointer, it will get aligned and subtracting
 735       ;; the size will not restore the original value, and some
 736       ;; things, like SB-C::CALL-VARIABLE, use the stack pointer to
 737       ;; calculate the number of saved values.
 738       ;; See alien.impure.lisp/:stack-misalignment
 739       #!+c-stack-is-control-stack
 740       (vop current-stack-pointer call block stack-pointer)
 741       (vop alloc-number-stack-space call block stack-frame-size nsp)
 742       ;; KLUDGE: This is where the second half of the ARM
 743       ;; register-pressure change lives (see above).
 744       (dolist (tn #!-arm arg-tns #!+arm (reverse arg-tns))
 745         ;; On PPC, TN might be a list. This is used to indicate
 746         ;; something special needs to happen. See below.
 747         ;;
 748         ;; FIXME: We should implement something better than this.
 749         (let* ((first-tn (if (listp tn) (car tn) tn))
 750                (arg (pop args))
 751                (sc (tn-sc first-tn))
 752                (scn (sc-number sc))
 753                (move-arg-vops (svref (sc-move-arg-vops sc) scn)))
 754           (aver arg)
 755           (unless (= (length move-arg-vops) 1)
 756             (error "no unique move-arg-vop for moves in SC ~S" (sc-name sc)))
 757           #!+(or x86 x86-64) (emit-move-arg-template call
 758                                                      block
 759                                                      (first move-arg-vops)
 760                                                      (lvar-tn call block arg)
 761                                                      nsp
 762                                                      first-tn)
 763           #!-(or x86 x86-64)
 764           (cond
 765             #!+arm-softfp
 766             ((and (proper-list-of-length-p tn 3)
 767                   (symbolp (third tn)))
 768              (emit-template call block
 769                             (template-or-lose (third tn))
 770                             (reference-tn (lvar-tn call block arg) nil)
 771                             (reference-tn-list (butlast tn) t)))
 772             (t
 773              (let ((temp-tn (make-representation-tn
 774                              (tn-primitive-type first-tn) scn)))
 775                (emit-move call
 776                           block
 777                           (lvar-tn call block arg)
 778                           temp-tn)
 779                (emit-move-arg-template call
 780                                        block
 781                                        (first move-arg-vops)
 782                                        temp-tn
 783                                        nsp
 784                                        first-tn))))
 785           #!+(and ppc darwin)
 786           (when (listp tn)
 787             ;; This means that we have a float arg that we need to
 788             ;; also copy to some int regs. The list contains the TN
 789             ;; for the float as well as the TNs to use for the int
 790             ;; arg.
 791             (destructuring-bind (float-tn i1-tn &optional i2-tn)
 792                 tn
 793               (if i2-tn
 794                   (vop sb!vm::move-double-to-int-arg call block
 795                        float-tn i1-tn i2-tn)
 796                   (vop sb!vm::move-single-to-int-arg call block
 797                        float-tn i1-tn))))))
 798       (aver (null args))
 799       (let ((result-tns (ensure-list result-tns)))
 800         (vop* call-out call block
 801               ((lvar-tn call block function)
 802                (reference-tn-list (remove-if-not #'tn-p (flatten-list arg-tns)) nil))
 803               ((reference-tn-list (remove-if-not #'tn-p result-tns) t)))
 804         #!-c-stack-is-control-stack
 805         (vop dealloc-number-stack-space call block stack-frame-size)
 806         #!+c-stack-is-control-stack
 807         (vop reset-stack-pointer call block stack-pointer)
 808         #!+x86
 809         (vop set-fpu-word-for-lisp call block)
 810         (cond
 811           #!+arm-softfp
 812           ((and lvar
 813                 (proper-list-of-length-p result-tns 3)
 814                 (symbolp (third result-tns)))
 815            (emit-template call block
 816                           (template-or-lose (third result-tns))
 817                           (reference-tn-list (butlast result-tns) nil)
 818                           (reference-tn (car (ir2-lvar-locs (lvar-info lvar))) t)))
 819           (t
 820            (move-lvar-result call block result-tns lvar)))))))