src/pcl/methods.lisp

   1 ;;;; This software is part of the SBCL system. See the README file for
   2 ;;;; more information.
   3
   4 ;;;; This software is derived from software originally released by Xerox
   5 ;;;; Corporation. Copyright and release statements follow. Later modifications
   6 ;;;; to the software are in the public domain and are provided with
   7 ;;;; absolutely no warranty. See the COPYING and CREDITS files for more
   8 ;;;; information.
   9
  10 ;;;; copyright information from original PCL sources:
  11 ;;;;
  12 ;;;; Copyright (c) 1985, 1986, 1987, 1988, 1989, 1990 Xerox Corporation.
  13 ;;;; All rights reserved.
  14 ;;;;
  15 ;;;; Use and copying of this software and preparation of derivative works based
  16 ;;;; upon this software are permitted. Any distribution of this software or
  17 ;;;; derivative works must comply with all applicable United States export
  18 ;;;; control laws.
  19 ;;;;
  20 ;;;; This software is made available AS IS, and Xerox Corporation makes no
  21 ;;;; warranty about the software, its performance or its conformity to any
  22 ;;;; specification.
  23
  24 (in-package "SB-PCL")
  25 \f
  26 ;;; methods
  27 ;;;
  28 ;;; Methods themselves are simple inanimate objects. Most properties of
  29 ;;; methods are immutable, methods cannot be reinitialized. The following
  30 ;;; properties of methods can be changed:
  31 ;;;   METHOD-GENERIC-FUNCTION
  32 \f
  33 ;;; initialization
  34 ;;;
  35 ;;; Error checking is done in before methods. Because of the simplicity of
  36 ;;; standard method objects the standard primary method can fill the slots.
  37 ;;;
  38 ;;; Methods are not reinitializable.
  39
  40 (define-condition metaobject-initialization-violation
  41     (reference-condition simple-error)
  42   ())
  43
  44 (macrolet ((def (name args control)
  45                `(defmethod ,name ,args
  46                  (declare (ignore initargs))
  47                  (error 'metaobject-initialization-violation
  48                   :format-control ,(format nil "~@<~A~@:>" control)
  49                   :format-arguments (list ',name)
  50                   :references (list '(:amop :initialization method))))))
  51   (def reinitialize-instance ((method method) &rest initargs)
  52     "Method objects cannot be redefined by ~S.")
  53   (def change-class ((method method) new &rest initargs)
  54     "Method objects cannot be redefined by ~S.")
  55   ;; NEW being a subclass of method is dealt with in the general
  56   ;; method of CHANGE-CLASS
  57   (def update-instance-for-redefined-class ((method method) added discarded
  58                                             plist &rest initargs)
  59     "No behaviour specified for ~S on method objects.")
  60   (def update-instance-for-different-class (old (new method) &rest initargs)
  61     "No behaviour specified for ~S on method objects.")
  62   (def update-instance-for-different-class ((old method) new &rest initargs)
  63     "No behaviour specified for ~S on method objects."))
  64
  65 (define-condition invalid-method-initarg (simple-program-error)
  66   ((method :initarg :method :reader invalid-method-initarg-method))
  67   (:report
  68    (lambda (c s)
  69      (format s "~@<In initialization of ~S:~2I~_~?~@:>"
  70              (invalid-method-initarg-method c)
  71              (simple-condition-format-control c)
  72              (simple-condition-format-arguments c)))))
  73
  74 (defun invalid-method-initarg (method format-control &rest args)
  75   (error 'invalid-method-initarg :method method
  76          :format-control format-control :format-arguments args))
  77
  78 (defun check-documentation (method doc)
  79   (unless (or (null doc) (stringp doc))
  80     (invalid-method-initarg method "~@<~S of ~S is neither ~S nor a ~S.~@:>"
  81                             :documentation doc 'null 'string)))
  82 (defun check-lambda-list (method ll)
  83   nil)
  84
  85 (defun check-method-function (method fun)
  86   (unless (functionp fun)
  87     (invalid-method-initarg method "~@<~S of ~S is not a ~S.~@:>"
  88                             :function fun 'function)))
  89
  90 (defun check-qualifiers (method qualifiers)
  91   (flet ((improper-list ()
  92            (invalid-method-initarg method
  93                                    "~@<~S of ~S is an improper list.~@:>"
  94                                    :qualifiers qualifiers)))
  95     (dolist-carefully (q qualifiers improper-list)
  96       (unless (and q (atom q))
  97         (invalid-method-initarg method
  98                                 "~@<~S, in ~S ~S, is not a non-~S atom.~@:>"
  99                                 q :qualifiers qualifiers 'null)))))
 100
 101 (defun check-slot-name (method name)
 102   (unless (symbolp name)
 103     (invalid-method-initarg "~@<~S of ~S is not a ~S.~@:>"
 104                             :slot-name name 'symbol)))
 105
 106 (defun check-specializers (method specializers)
 107   (flet ((improper-list ()
 108            (invalid-method-initarg method
 109                                    "~@<~S of ~S is an improper list.~@:>"
 110                                    :specializers specializers)))
 111     (dolist-carefully (s specializers improper-list)
 112       (unless (specializerp s)
 113         (invalid-method-initarg method
 114                                 "~@<~S, in ~S ~S, is not a ~S.~@:>"
 115                                 s :specializers specializers 'specializer)))
 116     ;; KLUDGE: ANSI says that it's not valid to have methods
 117     ;; specializing on classes which are "not defined", leaving
 118     ;; unclear what the definedness of a class is; AMOP suggests that
 119     ;; forward-referenced-classes, since they have proper names and
 120     ;; all, are at least worthy of some level of definition.  We allow
 121     ;; methods specialized on forward-referenced-classes, but it's
 122     ;; non-portable and potentially dubious, so
 123     (let ((frcs (remove-if-not #'forward-referenced-class-p specializers)))
 124       (unless (null frcs)
 125         (style-warn "~@<Defining a method using ~
 126                      ~V[~;~1{~S~}~;~1{~S and ~S~}~:;~{~#[~;and ~]~S~^, ~}~] ~
 127                      as ~2:*~V[~;a specializer~:;specializers~].~@:>"
 128                     (length frcs) frcs)))))
 129
 130 (defmethod shared-initialize :before
 131     ((method standard-method) slot-names &key
 132      qualifiers lambda-list specializers function documentation)
 133   (declare (ignore slot-names))
 134   ;; FIXME: it's not clear to me (CSR, 2006-08-09) why methods get
 135   ;; this extra paranoia and nothing else does; either everything
 136   ;; should be aggressively checking initargs, or nothing much should.
 137   ;; In either case, it would probably be better to have :type
 138   ;; declarations in slots, which would then give a suitable type
 139   ;; error (if we implement type-checking for slots...) rather than
 140   ;; this hand-crafted thing.
 141   (check-qualifiers method qualifiers)
 142   (check-lambda-list method lambda-list)
 143   (check-specializers method specializers)
 144   (check-method-function method function)
 145   (check-documentation method documentation))
 146
 147 (defmethod shared-initialize :before
 148     ((method standard-accessor-method) slot-names &key
 149      slot-name slot-definition)
 150   (declare (ignore slot-names))
 151   (unless slot-definition
 152     (check-slot-name method slot-name)))
 153
 154 (defmethod shared-initialize :after ((method standard-method) slot-names
 155                                      &rest initargs &key ((method-cell method-cell)))
 156   (declare (ignore slot-names method-cell))
 157   (initialize-method-function initargs method))
 158 \f
 159 (defvar *the-class-generic-function*
 160   (find-class 'generic-function))
 161 (defvar *the-class-standard-generic-function*
 162   (find-class 'standard-generic-function))
 163 \f
 164 (defmethod shared-initialize :before
 165            ((generic-function standard-generic-function)
 166             slot-names
 167             &key (name nil namep)
 168                  (lambda-list () lambda-list-p)
 169                  argument-precedence-order
 170                  declarations
 171                  documentation
 172                  (method-class nil method-class-supplied-p)
 173                  (method-combination nil method-combination-supplied-p))
 174   (declare (ignore slot-names
 175                    declarations argument-precedence-order documentation
 176                    lambda-list lambda-list-p))
 177
 178   (when namep
 179     (set-fun-name generic-function name))
 180
 181   (flet ((initarg-error (initarg value string)
 182            (error "when initializing the generic function ~S:~%~
 183                    The ~S initialization argument was: ~A.~%~
 184                    It must be ~A."
 185                   generic-function initarg value string)))
 186     (cond (method-class-supplied-p
 187            (when (symbolp method-class)
 188              (setq method-class (find-class method-class)))
 189            (unless (and (classp method-class)
 190                         (*subtypep (class-eq-specializer method-class)
 191                                    *the-class-method*))
 192              (initarg-error :method-class
 193                             method-class
 194                             "a subclass of the class METHOD"))
 195            (setf (slot-value generic-function 'method-class) method-class))
 196           ((slot-boundp generic-function 'method-class))
 197           (t
 198            (initarg-error :method-class
 199                           "not supplied"
 200                           "a subclass of the class METHOD")))
 201     (cond (method-combination-supplied-p
 202            (unless (method-combination-p method-combination)
 203              (initarg-error :method-combination
 204                             method-combination
 205                             "a method combination object")))
 206           ((slot-boundp generic-function '%method-combination))
 207           (t
 208            (initarg-error :method-combination
 209                           "not supplied"
 210                           "a method combination object")))))
 211 \f
 212 (defun find-generic-function (name &optional (errorp t))
 213   (let ((fun (and (fboundp name) (fdefinition name))))
 214     (cond
 215       ((and fun (typep fun 'generic-function)) fun)
 216       (errorp (error "No generic function named ~S." name))
 217       (t nil))))
 218
 219 (defun real-add-named-method (generic-function-name qualifiers
 220                               specializers lambda-list &rest other-initargs)
 221   (unless (and (fboundp generic-function-name)
 222                (typep (fdefinition generic-function-name) 'generic-function))
 223     (style-warn "implicitly creating new generic function ~S"
 224                 generic-function-name))
 225   (let* ((existing-gf (find-generic-function generic-function-name nil))
 226          (generic-function
 227           (if existing-gf
 228               (ensure-generic-function
 229                generic-function-name
 230                :generic-function-class (class-of existing-gf))
 231               (ensure-generic-function generic-function-name)))
 232          (proto (method-prototype-for-gf generic-function-name)))
 233     ;; FIXME: Destructive modification of &REST list.
 234     (setf (getf (getf other-initargs 'plist) :name)
 235           (make-method-spec generic-function qualifiers specializers))
 236     (let ((new (apply #'make-instance (class-of proto)
 237                       :qualifiers qualifiers :specializers specializers
 238                       :lambda-list lambda-list other-initargs)))
 239       (add-method generic-function new)
 240       new)))
 241
 242 (define-condition find-method-length-mismatch
 243     (reference-condition simple-error)
 244   ()
 245   (:default-initargs :references (list '(:ansi-cl :function find-method))))
 246
 247 (defun real-get-method (generic-function qualifiers specializers
 248                         &optional (errorp t)
 249                         always-check-specializers)
 250   (let ((lspec (length specializers))
 251         (methods (generic-function-methods generic-function)))
 252     (when (or methods always-check-specializers)
 253       (let ((nreq (length (arg-info-metatypes (gf-arg-info
 254                                                generic-function)))))
 255         ;; Since we internally bypass FIND-METHOD by using GET-METHOD
 256         ;; instead we need to to this here or users may get hit by a
 257         ;; failed AVER instead of a sensible error message.
 258         (when (/= lspec nreq)
 259           (error
 260            'find-method-length-mismatch
 261            :format-control
 262            "~@<The generic function ~S takes ~D required argument~:P; ~
 263             was asked to find a method with specializers ~S~@:>"
 264            :format-arguments (list generic-function nreq specializers)))))
 265     (let ((hit
 266            (dolist (method methods)
 267              (let ((mspecializers (method-specializers method)))
 268                (aver (= lspec (length mspecializers)))
 269                (when (and (equal qualifiers (method-qualifiers method))
 270                           (every #'same-specializer-p specializers
 271                                  (method-specializers method)))
 272                  (return method))))))
 273       (cond (hit hit)
 274             ((null errorp) nil)
 275             (t
 276              (error "~@<There is no method on ~S with ~
 277                     ~:[no qualifiers~;~:*qualifiers ~S~] ~
 278                     and specializers ~S.~@:>"
 279                     generic-function qualifiers specializers))))))
 280
 281 (defmethod find-method ((generic-function standard-generic-function)
 282                         qualifiers specializers &optional (errorp t))
 283   ;; ANSI about FIND-METHOD: "The specializers argument contains the
 284   ;; parameter specializers for the method. It must correspond in
 285   ;; length to the number of required arguments of the generic
 286   ;; function, or an error is signaled."
 287   ;;
 288   ;; This error checking is done by REAL-GET-METHOD.
 289   (real-get-method
 290    generic-function qualifiers
 291    ;; ANSI for FIND-METHOD seems to imply that in fact specializers
 292    ;; should always be passed in parsed form instead of being parsed
 293    ;; at this point.  Since there's no ANSI-blessed way of getting an
 294    ;; EQL specializer, that seems unnecessarily painful, so we are
 295    ;; nice to our users.  -- CSR, 2007-06-01
 296    (parse-specializers generic-function specializers) errorp t))
 297 \f
 298 ;;; Compute various information about a generic-function's arglist by looking
 299 ;;; at the argument lists of the methods. The hair for trying not to use
 300 ;;; &REST arguments lives here.
 301 ;;;  The values returned are:
 302 ;;;    number-of-required-arguments
 303 ;;;       the number of required arguments to this generic-function's
 304 ;;;       discriminating function
 305 ;;;    &rest-argument-p
 306 ;;;       whether or not this generic-function's discriminating
 307 ;;;       function takes an &rest argument.
 308 ;;;    specialized-argument-positions
 309 ;;;       a list of the positions of the arguments this generic-function
 310 ;;;       specializes (e.g. for a classical generic-function this is the
 311 ;;;       list: (1)).
 312 (defmethod compute-discriminating-function-arglist-info
 313            ((generic-function standard-generic-function))
 314   ;;(declare (values number-of-required-arguments &rest-argument-p
 315   ;;             specialized-argument-postions))
 316   (let ((number-required nil)
 317         (restp nil)
 318         (specialized-positions ())
 319         (methods (generic-function-methods generic-function)))
 320     (dolist (method methods)
 321       (multiple-value-setq (number-required restp specialized-positions)
 322         (compute-discriminating-function-arglist-info-internal
 323          generic-function method number-required restp specialized-positions)))
 324     (values number-required restp (sort specialized-positions #'<))))
 325
 326 (defun compute-discriminating-function-arglist-info-internal
 327        (generic-function method number-of-requireds restp
 328         specialized-argument-positions)
 329   (declare (ignore generic-function)
 330            (type (or null fixnum) number-of-requireds))
 331   (let ((requireds 0))
 332     (declare (fixnum requireds))
 333     ;; Go through this methods arguments seeing how many are required,
 334     ;; and whether there is an &rest argument.
 335     (dolist (arg (method-lambda-list method))
 336       (cond ((eq arg '&aux) (return))
 337             ((memq arg '(&optional &rest &key))
 338              (return (setq restp t)))
 339             ((memq arg lambda-list-keywords))
 340             (t (incf requireds))))
 341     ;; Now go through this method's type specifiers to see which
 342     ;; argument positions are type specified. Treat T specially
 343     ;; in the usual sort of way. For efficiency don't bother to
 344     ;; keep specialized-argument-positions sorted, rather depend
 345     ;; on our caller to do that.
 346     (let ((pos 0))
 347       (dolist (type-spec (method-specializers method))
 348         (unless (eq type-spec *the-class-t*)
 349           (pushnew pos specialized-argument-positions))
 350         (incf pos)))
 351     ;; Finally merge the values for this method into the values
 352     ;; for the exisiting methods and return them. Note that if
 353     ;; num-of-requireds is NIL it means this is the first method
 354     ;; and we depend on that.
 355     (values (min (or number-of-requireds requireds) requireds)
 356             (or restp
 357                 (and number-of-requireds (/= number-of-requireds requireds)))
 358             specialized-argument-positions)))
 359
 360 (defun make-discriminating-function-arglist (number-required-arguments restp)
 361   (nconc (let ((args nil))
 362            (dotimes (i number-required-arguments)
 363              (push (format-symbol *package* ;; ! is this right?
 364                                   "Discriminating Function Arg ~D"
 365                                   i)
 366                    args))
 367            (nreverse args))
 368          (when restp
 369                `(&rest ,(format-symbol *package*
 370                                        "Discriminating Function &rest Arg")))))
 371 \f
 372 (defmethod generic-function-argument-precedence-order
 373     ((gf standard-generic-function))
 374   (aver (eq *boot-state* 'complete))
 375   (loop with arg-info = (gf-arg-info gf)
 376         with lambda-list = (arg-info-lambda-list arg-info)
 377         for argument-position in (arg-info-precedence arg-info)
 378         collect (nth argument-position lambda-list)))
 379
 380 (defmethod generic-function-lambda-list ((gf generic-function))
 381   (gf-lambda-list gf))
 382
 383 (defmethod gf-fast-method-function-p ((gf standard-generic-function))
 384   (gf-info-fast-mf-p (slot-value gf 'arg-info)))
 385
 386 (defmethod initialize-instance :after ((gf standard-generic-function)
 387                                        &key (lambda-list nil lambda-list-p)
 388                                        argument-precedence-order)
 389   (with-slots (arg-info) gf
 390     (if lambda-list-p
 391         (set-arg-info gf
 392                       :lambda-list lambda-list
 393                       :argument-precedence-order argument-precedence-order)
 394         (set-arg-info gf))
 395     (when (arg-info-valid-p arg-info)
 396       (update-dfun gf))))
 397
 398 (defmethod reinitialize-instance :around
 399     ((gf standard-generic-function) &rest args &key
 400      (lambda-list nil lambda-list-p) (argument-precedence-order nil apo-p))
 401   (let ((old-mc (generic-function-method-combination gf)))
 402     (prog1 (call-next-method)
 403       ;; KLUDGE: EQ is too strong a test.
 404       (unless (eq old-mc (generic-function-method-combination gf))
 405         (flush-effective-method-cache gf))
 406       (cond
 407         ((and lambda-list-p apo-p)
 408          (set-arg-info gf
 409                        :lambda-list lambda-list
 410                        :argument-precedence-order argument-precedence-order))
 411         (lambda-list-p (set-arg-info gf :lambda-list lambda-list))
 412         (t (set-arg-info gf)))
 413       (when (arg-info-valid-p (gf-arg-info gf))
 414         (update-dfun gf))
 415       (map-dependents gf (lambda (dependent)
 416                            (apply #'update-dependent gf dependent args))))))
 417
 418 (declaim (special *lazy-dfun-compute-p*))
 419
 420 (defun set-methods (gf methods)
 421   (setf (generic-function-methods gf) nil)
 422   (loop (when (null methods) (return gf))
 423         (real-add-method gf (pop methods) methods)))
 424
 425 (define-condition new-value-specialization (reference-condition error)
 426   ((%method :initarg :method :reader new-value-specialization-method))
 427   (:report
 428    (lambda (c s)
 429      (format s "~@<Cannot add method ~S to ~S, as it specializes the ~
 430                 new-value argument.~@:>"
 431              (new-value-specialization-method c)
 432              #'(setf slot-value-using-class))))
 433   (:default-initargs :references
 434       (list '(:sbcl :node "Metaobject Protocol")
 435             '(:amop :generic-function (setf slot-value-using-class)))))
 436
 437 (defun real-add-method (generic-function method &optional skip-dfun-update-p)
 438   (when (method-generic-function method)
 439     (error "~@<The method ~S is already part of the generic ~
 440             function ~S; it can't be added to another generic ~
 441             function until it is removed from the first one.~@:>"
 442            method (method-generic-function method)))
 443   (flet ((similar-lambda-lists-p (method-a method-b)
 444            (multiple-value-bind (a-nreq a-nopt a-keyp a-restp)
 445                (analyze-lambda-list (method-lambda-list method-a))
 446              (multiple-value-bind (b-nreq b-nopt b-keyp b-restp)
 447                  (analyze-lambda-list (method-lambda-list method-b))
 448                (and (= a-nreq b-nreq)
 449                     (= a-nopt b-nopt)
 450                     (eq (or a-keyp a-restp)
 451                         (or b-keyp b-restp)))))))
 452     (let ((lock (gf-lock generic-function)))
 453       ;; HANDLER-CASE takes care of releasing the lock and enabling
 454       ;; interrupts before going forth with the error.
 455       (handler-case
 456           ;; System lock because interrupts need to be disabled as
 457           ;; well: it would be bad to unwind and leave the gf in an
 458           ;; inconsistent state.
 459           (sb-thread::with-recursive-system-spinlock (lock)
 460             (let* ((qualifiers (method-qualifiers method))
 461                    (specializers (method-specializers method))
 462                    (existing (get-method generic-function
 463                                          qualifiers
 464                                          specializers
 465                                          nil)))
 466
 467               ;; If there is already a method like this one then we must get
 468               ;; rid of it before proceeding.  Note that we call the generic
 469               ;; function REMOVE-METHOD to remove it rather than doing it in
 470               ;; some internal way.
 471               (when (and existing (similar-lambda-lists-p existing method))
 472                 (remove-method generic-function existing))
 473
 474               ;; KLUDGE: We have a special case here, as we disallow
 475               ;; specializations of the NEW-VALUE argument to (SETF
 476               ;; SLOT-VALUE-USING-CLASS).  GET-ACCESSOR-METHOD-FUNCTION is
 477               ;; the optimizing function here: it precomputes the effective
 478               ;; method, assuming that there is no dispatch to be done on
 479               ;; the new-value argument.
 480               (when (and (eq generic-function #'(setf slot-value-using-class))
 481                          (not (eq *the-class-t* (first specializers))))
 482                 (error 'new-value-specialization :method  method))
 483
 484               (setf (method-generic-function method) generic-function)
 485               (pushnew method (generic-function-methods generic-function))
 486               (dolist (specializer specializers)
 487                 (add-direct-method specializer method))
 488
 489               ;; KLUDGE: SET-ARG-INFO contains the error-detecting logic for
 490               ;; detecting attempts to add methods with incongruent lambda
 491               ;; lists.  However, according to Gerd Moellmann on cmucl-imp,
 492               ;; it also depends on the new method already having been added
 493               ;; to the generic function.  Therefore, we need to remove it
 494               ;; again on error:
 495               (let ((remove-again-p t))
 496                 (unwind-protect
 497                      (progn
 498                        (set-arg-info generic-function :new-method method)
 499                        (setq remove-again-p nil))
 500                   (when remove-again-p
 501                     (remove-method generic-function method))))
 502
 503               ;; KLUDGE II: ANSI saith that it is not an error to add a
 504               ;; method with invalid qualifiers to a generic function of the
 505               ;; wrong kind; it's only an error at generic function
 506               ;; invocation time; I dunno what the rationale was, and it
 507               ;; sucks.  Nevertheless, it's probably a programmer error, so
 508               ;; let's warn anyway. -- CSR, 2003-08-20
 509               (let ((mc (generic-function-method-combination generic-functioN)))
 510                 (cond
 511                   ((eq mc *standard-method-combination*)
 512                    (when (and qualifiers
 513                               (or (cdr qualifiers)
 514                                   (not (memq (car qualifiers)
 515                                              '(:around :before :after)))))
 516                      (warn "~@<Invalid qualifiers for standard method ~
 517                             combination in method ~S:~2I~_~S.~@:>"
 518                            method qualifiers)))
 519                   ((short-method-combination-p mc)
 520                    (let ((mc-name (method-combination-type-name mc)))
 521                      (when (or (null qualifiers)
 522                                (cdr qualifiers)
 523                                (and (neq (car qualifiers) :around)
 524                                     (neq (car qualifiers) mc-name)))
 525                        (warn "~@<Invalid qualifiers for ~S method combination ~
 526                               in method ~S:~2I~_~S.~@:>"
 527                              mc-name method qualifiers))))))
 528
 529               (unless skip-dfun-update-p
 530                 (update-ctors 'add-method
 531                               :generic-function generic-function
 532                               :method method)
 533                 (update-dfun generic-function))
 534               (map-dependents generic-function
 535                               (lambda (dep)
 536                                 (update-dependent generic-function
 537                                                   dep 'add-method method)))))
 538         (serious-condition (c)
 539           (error c)))))
 540   generic-function)
 541
 542 (defun real-remove-method (generic-function method)
 543   (when (eq generic-function (method-generic-function method))
 544     (let ((lock (gf-lock generic-function)))
 545       ;; System lock because interrupts need to be disabled as well:
 546       ;; it would be bad to unwind and leave the gf in an inconsistent
 547       ;; state.
 548       (sb-thread::with-recursive-system-spinlock (lock)
 549         (let* ((specializers (method-specializers method))
 550                (methods (generic-function-methods generic-function))
 551                (new-methods (remove method methods)))
 552           (setf (method-generic-function method) nil
 553                 (generic-function-methods generic-function) new-methods)
 554           (dolist (specializer (method-specializers method))
 555             (remove-direct-method specializer method))
 556           (set-arg-info generic-function)
 557           (update-ctors 'remove-method
 558                         :generic-function generic-function
 559                         :method method)
 560           (update-dfun generic-function)
 561           (map-dependents generic-function
 562                           (lambda (dep)
 563                             (update-dependent generic-function
 564                                               dep 'remove-method method)))))))
 565   generic-function)
 566 \f
 567 (defun compute-applicable-methods-function (generic-function arguments)
 568   (values (compute-applicable-methods-using-types
 569            generic-function
 570            (types-from-args generic-function arguments 'eql))))
 571
 572 (defmethod compute-applicable-methods
 573     ((generic-function generic-function) arguments)
 574   (values (compute-applicable-methods-using-types
 575            generic-function
 576            (types-from-args generic-function arguments 'eql))))
 577
 578 (defmethod compute-applicable-methods-using-classes
 579     ((generic-function generic-function) classes)
 580   (compute-applicable-methods-using-types
 581    generic-function
 582    (types-from-args generic-function classes 'class-eq)))
 583
 584 (defun proclaim-incompatible-superclasses (classes)
 585   (setq classes (mapcar (lambda (class)
 586                           (if (symbolp class)
 587                               (find-class class)
 588                               class))
 589                         classes))
 590   (dolist (class classes)
 591     (dolist (other-class classes)
 592       (unless (eq class other-class)
 593         (pushnew other-class (class-incompatible-superclass-list class))))))
 594
 595 (defun superclasses-compatible-p (class1 class2)
 596   (let ((cpl1 (cpl-or-nil class1))
 597         (cpl2 (cpl-or-nil class2)))
 598     (dolist (sc1 cpl1 t)
 599       (dolist (ic (class-incompatible-superclass-list sc1))
 600         (when (memq ic cpl2)
 601           (return-from superclasses-compatible-p nil))))))
 602
 603 (mapc
 604  #'proclaim-incompatible-superclasses
 605  '(;; superclass class
 606    (built-in-class std-class structure-class) ; direct subclasses of pcl-class
 607    (standard-class funcallable-standard-class)
 608    ;; superclass metaobject
 609    (class eql-specializer class-eq-specializer method method-combination
 610     generic-function slot-definition)
 611    ;; metaclass built-in-class
 612    (number sequence character           ; direct subclasses of t, but not array
 613     standard-object structure-object)   ;                        or symbol
 614    (number array character symbol       ; direct subclasses of t, but not
 615     standard-object structure-object)   ;                        sequence
 616    (complex float rational)             ; direct subclasses of number
 617    (integer ratio)                      ; direct subclasses of rational
 618    (list vector)                        ; direct subclasses of sequence
 619    (cons null)                          ; direct subclasses of list
 620    (string bit-vector)                  ; direct subclasses of vector
 621    ))
 622 \f
 623 (defmethod same-specializer-p ((specl1 specializer) (specl2 specializer))
 624   (eql specl1 specl2))
 625
 626 (defmethod same-specializer-p ((specl1 class) (specl2 class))
 627   (eq specl1 specl2))
 628
 629 (defmethod specializer-class ((specializer class))
 630   specializer)
 631
 632 (defmethod same-specializer-p ((specl1 class-eq-specializer)
 633                                (specl2 class-eq-specializer))
 634   (eq (specializer-class specl1) (specializer-class specl2)))
 635
 636 (defmethod same-specializer-p ((specl1 eql-specializer)
 637                                (specl2 eql-specializer))
 638   (eq (specializer-object specl1) (specializer-object specl2)))
 639
 640 (defmethod specializer-class ((specializer eql-specializer))
 641   (class-of (slot-value specializer 'object)))
 642
 643 (defun specializer-class-or-nil (specializer)
 644   (and (standard-specializer-p specializer)
 645        (specializer-class specializer)))
 646
 647 (defun error-need-at-least-n-args (function n)
 648   (error 'simple-program-error
 649          :format-control "~@<The function ~2I~_~S ~I~_requires ~
 650                           at least ~W argument~:P.~:>"
 651          :format-arguments (list function n)))
 652
 653 (defun types-from-args (generic-function arguments &optional type-modifier)
 654   (multiple-value-bind (nreq applyp metatypes nkeys arg-info)
 655       (get-generic-fun-info generic-function)
 656     (declare (ignore applyp metatypes nkeys))
 657     (let ((types-rev nil))
 658       (dotimes-fixnum (i nreq)
 659         i
 660         (unless arguments
 661           (error-need-at-least-n-args (generic-function-name generic-function)
 662                                       nreq))
 663         (let ((arg (pop arguments)))
 664           (push (if type-modifier `(,type-modifier ,arg) arg) types-rev)))
 665       (values (nreverse types-rev) arg-info))))
 666
 667 (defun get-wrappers-from-classes (nkeys wrappers classes metatypes)
 668   (let* ((w wrappers) (w-tail w) (mt-tail metatypes))
 669     (dolist (class (if (listp classes) classes (list classes)))
 670       (unless (eq t (car mt-tail))
 671         (let ((c-w (class-wrapper class)))
 672           (unless c-w (return-from get-wrappers-from-classes nil))
 673           (if (eql nkeys 1)
 674               (setq w c-w)
 675               (setf (car w-tail) c-w
 676                     w-tail (cdr w-tail)))))
 677       (setq mt-tail (cdr mt-tail)))
 678     w))
 679
 680 (defun sdfun-for-caching (gf classes)
 681   (let ((types (mapcar #'class-eq-type classes)))
 682     (multiple-value-bind (methods all-applicable-and-sorted-p)
 683         (compute-applicable-methods-using-types gf types)
 684       (let ((generator (get-secondary-dispatch-function1
 685                         gf methods types nil t all-applicable-and-sorted-p)))
 686         (make-callable gf methods generator
 687                        nil (mapcar #'class-wrapper classes))))))
 688
 689 (defun value-for-caching (gf classes)
 690   (let ((methods (compute-applicable-methods-using-types
 691                    gf (mapcar #'class-eq-type classes))))
 692     (method-plist-value (car methods) :constant-value)))
 693
 694 (defun default-secondary-dispatch-function (generic-function)
 695   (lambda (&rest args)
 696     (let ((methods (compute-applicable-methods generic-function args)))
 697       (if methods
 698           (let ((emf (get-effective-method-function generic-function
 699                                                     methods)))
 700             (invoke-emf emf args))
 701           (apply #'no-applicable-method generic-function args)))))
 702
 703 (defun list-eq (x y)
 704   (loop (when (atom x) (return (eq x y)))
 705         (when (atom y) (return nil))
 706         (unless (eq (car x) (car y)) (return nil))
 707         (setq x (cdr x)
 708               y (cdr y))))
 709
 710 (defvar *std-cam-methods* nil)
 711
 712 (defun compute-applicable-methods-emf (generic-function)
 713   (if (eq *boot-state* 'complete)
 714       (let* ((cam (gdefinition 'compute-applicable-methods))
 715              (cam-methods (compute-applicable-methods-using-types
 716                            cam (list `(eql ,generic-function) t))))
 717         (values (get-effective-method-function cam cam-methods)
 718                 (list-eq cam-methods
 719                          (or *std-cam-methods*
 720                              (setq *std-cam-methods*
 721                                    (compute-applicable-methods-using-types
 722                                     cam (list `(eql ,cam) t)))))))
 723       (values #'compute-applicable-methods-function t)))
 724
 725 (defun compute-applicable-methods-emf-std-p (gf)
 726   (gf-info-c-a-m-emf-std-p (gf-arg-info gf)))
 727
 728 (defvar *old-c-a-m-gf-methods* nil)
 729
 730 (defun update-all-c-a-m-gf-info (c-a-m-gf)
 731   (let ((methods (generic-function-methods c-a-m-gf)))
 732     (if (and *old-c-a-m-gf-methods*
 733              (every (lambda (old-method)
 734                       (member old-method methods))
 735                     *old-c-a-m-gf-methods*))
 736         (let ((gfs-to-do nil)
 737               (gf-classes-to-do nil))
 738           (dolist (method methods)
 739             (unless (member method *old-c-a-m-gf-methods*)
 740               (let ((specl (car (method-specializers method))))
 741                 (if (eql-specializer-p specl)
 742                     (pushnew (specializer-object specl) gfs-to-do)
 743                     (pushnew (specializer-class specl) gf-classes-to-do)))))
 744           (map-all-generic-functions
 745            (lambda (gf)
 746              (when (or (member gf gfs-to-do)
 747                        (dolist (class gf-classes-to-do nil)
 748                          (member class
 749                                  (class-precedence-list (class-of gf)))))
 750                (update-c-a-m-gf-info gf)))))
 751         (map-all-generic-functions #'update-c-a-m-gf-info))
 752     (setq *old-c-a-m-gf-methods* methods)))
 753
 754 (defun update-gf-info (gf)
 755   (update-c-a-m-gf-info gf)
 756   (update-gf-simple-accessor-type gf))
 757
 758 (defun update-c-a-m-gf-info (gf)
 759   (unless (early-gf-p gf)
 760     (multiple-value-bind (c-a-m-emf std-p)
 761         (compute-applicable-methods-emf gf)
 762       (let ((arg-info (gf-arg-info gf)))
 763         (setf (gf-info-static-c-a-m-emf arg-info) c-a-m-emf)
 764         (setf (gf-info-c-a-m-emf-std-p arg-info) std-p)))))
 765
 766 (defun update-gf-simple-accessor-type (gf)
 767   (let ((arg-info (gf-arg-info gf)))
 768     (setf (gf-info-simple-accessor-type arg-info)
 769           (let* ((methods (generic-function-methods gf))
 770                  (class (and methods (class-of (car methods))))
 771                  (type
 772                   (and class
 773                        (cond ((or (eq class *the-class-standard-reader-method*)
 774                                   (eq class *the-class-global-reader-method*))
 775                               'reader)
 776                              ((or (eq class *the-class-standard-writer-method*)
 777                                   (eq class *the-class-global-writer-method*))
 778                               'writer)
 779                              ((or (eq class *the-class-standard-boundp-method*)
 780                                   (eq class *the-class-global-boundp-method*))
 781                               'boundp)))))
 782             (when (and (gf-info-c-a-m-emf-std-p arg-info)
 783                        type
 784                        (dolist (method (cdr methods) t)
 785                          (unless (eq class (class-of method)) (return nil)))
 786                        (eq (generic-function-method-combination gf)
 787                            *standard-method-combination*))
 788               type)))))
 789
 790
 791 ;;; CMUCL (Gerd's PCL, 2002-04-25) comment:
 792 ;;;
 793 ;;; Return two values.  First value is a function to be stored in
 794 ;;; effective slot definition SLOTD for reading it with
 795 ;;; SLOT-VALUE-USING-CLASS, setting it with (SETF
 796 ;;; SLOT-VALUE-USING-CLASS) or testing it with
 797 ;;; SLOT-BOUNDP-USING-CLASS.  GF is one of these generic functions,
 798 ;;; TYPE is one of the symbols READER, WRITER, BOUNDP.  CLASS is
 799 ;;; SLOTD's class.
 800 ;;;
 801 ;;; Second value is true if the function returned is one of the
 802 ;;; optimized standard functions for the purpose, which are used
 803 ;;; when only standard methods are applicable.
 804 ;;;
 805 ;;; FIXME: Change all these wacky function names to something sane.
 806 (defun get-accessor-method-function (gf type class slotd)
 807   (let* ((std-method (standard-svuc-method type))
 808          (str-method (structure-svuc-method type))
 809          (types1 `((eql ,class) (class-eq ,class) (eql ,slotd)))
 810          (types (if (eq type 'writer) `(t ,@types1) types1))
 811          (methods (compute-applicable-methods-using-types gf types))
 812          (std-p (null (cdr methods))))
 813     (values
 814      (if std-p
 815          (get-optimized-std-accessor-method-function class slotd type)
 816          (let* ((optimized-std-fun
 817                  (get-optimized-std-slot-value-using-class-method-function
 818                   class slotd type))
 819                 (method-alist
 820                  `((,(car (or (member std-method methods)
 821                               (member str-method methods)
 822                               (bug "error in ~S"
 823                                    'get-accessor-method-function)))
 824                     ,optimized-std-fun)))
 825                 (wrappers
 826                  (let ((wrappers (list (wrapper-of class)
 827                                        (class-wrapper class)
 828                                        (wrapper-of slotd))))
 829                    (if (eq type 'writer)
 830                        (cons (class-wrapper *the-class-t*) wrappers)
 831                        wrappers)))
 832                 (sdfun (get-secondary-dispatch-function
 833                         gf methods types method-alist wrappers)))
 834            (get-accessor-from-svuc-method-function class slotd sdfun type)))
 835      std-p)))
 836
 837 ;;; used by OPTIMIZE-SLOT-VALUE-BY-CLASS-P (vector.lisp)
 838 (defun update-slot-value-gf-info (gf type)
 839   (unless *new-class*
 840     (update-std-or-str-methods gf type))
 841   (when (and (standard-svuc-method type) (structure-svuc-method type))
 842     (flet ((update-accessor-info (class)
 843              (when (class-finalized-p class)
 844                (dolist (slotd (class-slots class))
 845                  (compute-slot-accessor-info slotd type gf)))))
 846       (if *new-class*
 847           (update-accessor-info *new-class*)
 848           (map-all-classes #'update-accessor-info 'slot-object)))))
 849
 850 (defvar *standard-slot-value-using-class-method* nil)
 851 (defvar *standard-setf-slot-value-using-class-method* nil)
 852 (defvar *standard-slot-boundp-using-class-method* nil)
 853 (defvar *condition-slot-value-using-class-method* nil)
 854 (defvar *condition-setf-slot-value-using-class-method* nil)
 855 (defvar *condition-slot-boundp-using-class-method* nil)
 856 (defvar *structure-slot-value-using-class-method* nil)
 857 (defvar *structure-setf-slot-value-using-class-method* nil)
 858 (defvar *structure-slot-boundp-using-class-method* nil)
 859
 860 (defun standard-svuc-method (type)
 861   (case type
 862     (reader *standard-slot-value-using-class-method*)
 863     (writer *standard-setf-slot-value-using-class-method*)
 864     (boundp *standard-slot-boundp-using-class-method*)))
 865
 866 (defun set-standard-svuc-method (type method)
 867   (case type
 868     (reader (setq *standard-slot-value-using-class-method* method))
 869     (writer (setq *standard-setf-slot-value-using-class-method* method))
 870     (boundp (setq *standard-slot-boundp-using-class-method* method))))
 871
 872 (defun condition-svuc-method (type)
 873   (case type
 874     (reader *condition-slot-value-using-class-method*)
 875     (writer *condition-setf-slot-value-using-class-method*)
 876     (boundp *condition-slot-boundp-using-class-method*)))
 877
 878 (defun set-condition-svuc-method (type method)
 879   (case type
 880     (reader (setq *condition-slot-value-using-class-method* method))
 881     (writer (setq *condition-setf-slot-value-using-class-method* method))
 882     (boundp (setq *condition-slot-boundp-using-class-method* method))))
 883
 884 (defun structure-svuc-method (type)
 885   (case type
 886     (reader *structure-slot-value-using-class-method*)
 887     (writer *structure-setf-slot-value-using-class-method*)
 888     (boundp *structure-slot-boundp-using-class-method*)))
 889
 890 (defun set-structure-svuc-method (type method)
 891   (case type
 892     (reader (setq *structure-slot-value-using-class-method* method))
 893     (writer (setq *structure-setf-slot-value-using-class-method* method))
 894     (boundp (setq *structure-slot-boundp-using-class-method* method))))
 895
 896 (defun update-std-or-str-methods (gf type)
 897   (dolist (method (generic-function-methods gf))
 898     (let ((specls (method-specializers method)))
 899       (when (and (or (not (eq type 'writer))
 900                      (eq (pop specls) *the-class-t*))
 901                  (every #'classp specls))
 902         (cond ((and (eq (class-name (car specls)) 'std-class)
 903                     (eq (class-name (cadr specls)) 'standard-object)
 904                     (eq (class-name (caddr specls))
 905                         'standard-effective-slot-definition))
 906                (set-standard-svuc-method type method))
 907               ((and (eq (class-name (car specls)) 'condition-class)
 908                     (eq (class-name (cadr specls)) 'condition)
 909                     (eq (class-name (caddr specls))
 910                         'condition-effective-slot-definition))
 911                (set-condition-svuc-method type method))
 912               ((and (eq (class-name (car specls)) 'structure-class)
 913                     (eq (class-name (cadr specls)) 'structure-object)
 914                     (eq (class-name (caddr specls))
 915                         'structure-effective-slot-definition))
 916                (set-structure-svuc-method type method)))))))
 917
 918 (defun mec-all-classes-internal (spec precompute-p)
 919   (let ((wrapper (class-wrapper (specializer-class spec))))
 920     (unless (or (not wrapper) (invalid-wrapper-p wrapper))
 921       (cons (specializer-class spec)
 922             (and (classp spec)
 923                  precompute-p
 924                  (not (or (eq spec *the-class-t*)
 925                           (eq spec *the-class-slot-object*)
 926                           (eq spec *the-class-standard-object*)
 927                           (eq spec *the-class-structure-object*)))
 928                  (let ((sc (class-direct-subclasses spec)))
 929                    (when sc
 930                      (mapcan (lambda (class)
 931                                (mec-all-classes-internal class precompute-p))
 932                              sc))))))))
 933
 934 (defun mec-all-classes (spec precompute-p)
 935   (let ((classes (mec-all-classes-internal spec precompute-p)))
 936     (if (null (cdr classes))
 937         classes
 938         (let* ((a-classes (cons nil classes))
 939                (tail classes))
 940           (loop (when (null (cdr tail))
 941                   (return (cdr a-classes)))
 942                 (let ((class (cadr tail))
 943                       (ttail (cddr tail)))
 944                   (if (dolist (c ttail nil)
 945                         (when (eq class c) (return t)))
 946                       (setf (cdr tail) (cddr tail))
 947                       (setf tail (cdr tail)))))))))
 948
 949 (defun mec-all-class-lists (spec-list precompute-p)
 950   (if (null spec-list)
 951       (list nil)
 952       (let* ((car-all-classes (mec-all-classes (car spec-list)
 953                                                precompute-p))
 954              (all-class-lists (mec-all-class-lists (cdr spec-list)
 955                                                    precompute-p)))
 956         (mapcan (lambda (list)
 957                   (mapcar (lambda (c) (cons c list)) car-all-classes))
 958                 all-class-lists))))
 959
 960 (defun make-emf-cache (generic-function valuep cache classes-list new-class)
 961   (let* ((arg-info (gf-arg-info generic-function))
 962          (nkeys (arg-info-nkeys arg-info))
 963          (metatypes (arg-info-metatypes arg-info))
 964          (wrappers (unless (eq nkeys 1) (make-list nkeys)))
 965          (precompute-p (gf-precompute-dfun-and-emf-p arg-info)))
 966     (flet ((add-class-list (classes)
 967              (when (or (null new-class) (memq new-class classes))
 968                (let ((%wrappers (get-wrappers-from-classes
 969                                  nkeys wrappers classes metatypes)))
 970                  (when (and %wrappers (not (probe-cache cache %wrappers)))
 971                    (let ((value (cond ((eq valuep t)
 972                                        (sdfun-for-caching generic-function
 973                                                           classes))
 974                                       ((eq valuep :constant-value)
 975                                        (value-for-caching generic-function
 976                                                           classes)))))
 977                      ;; need to get them again, as finalization might
 978                      ;; have happened in between, which would
 979                      ;; invalidate wrappers.
 980                      (let ((wrappers (get-wrappers-from-classes
 981                                       nkeys wrappers classes metatypes)))
 982                        (when (if (atom wrappers)
 983                                  (not (invalid-wrapper-p wrappers))
 984                                  (every (complement #'invalid-wrapper-p)
 985                                         wrappers))
 986                          (setq cache (fill-cache cache wrappers value))))))))))
 987       (if classes-list
 988           (mapc #'add-class-list classes-list)
 989           (dolist (method (generic-function-methods generic-function))
 990             (mapc #'add-class-list
 991                   (mec-all-class-lists (method-specializers method)
 992                                        precompute-p))))
 993       cache)))
 994
 995 (defmacro class-test (arg class)
 996   (cond
 997     ((eq class *the-class-t*) t)
 998     ((eq class *the-class-slot-object*)
 999      `(not (typep (classoid-of ,arg) 'built-in-classoid)))
1000     ((eq class *the-class-standard-object*)
1001      `(or (std-instance-p ,arg) (fsc-instance-p ,arg)))
1002     ((eq class *the-class-funcallable-standard-object*)
1003      `(fsc-instance-p ,arg))
1004     (t
1005      `(typep ,arg ',(class-name class)))))
1006
1007 (defmacro class-eq-test (arg class)
1008   `(eq (class-of ,arg) ',class))
1009
1010 (defmacro eql-test (arg object)
1011   `(eql ,arg ',object))
1012
1013 (defun dnet-methods-p (form)
1014   (and (consp form)
1015        (or (eq (car form) 'methods)
1016            (eq (car form) 'unordered-methods))))
1017
1018 ;;; This is CASE, but without gensyms.
1019 (defmacro scase (arg &rest clauses)
1020   `(let ((.case-arg. ,arg))
1021      (cond ,@(mapcar (lambda (clause)
1022                        (list* (cond ((null (car clause))
1023                                      nil)
1024                                     ((consp (car clause))
1025                                      (if (null (cdar clause))
1026                                          `(eql .case-arg.
1027                                                ',(caar clause))
1028                                          `(member .case-arg.
1029                                                   ',(car clause))))
1030                                     ((member (car clause) '(t otherwise))
1031                                      `t)
1032                                     (t
1033                                      `(eql .case-arg. ',(car clause))))
1034                               nil
1035                               (cdr clause)))
1036                      clauses))))
1037
1038 (defmacro mcase (arg &rest clauses) `(scase ,arg ,@clauses))
1039
1040 (defun generate-discrimination-net (generic-function methods types sorted-p)
1041   (let* ((arg-info (gf-arg-info generic-function))
1042          (c-a-m-emf-std-p (gf-info-c-a-m-emf-std-p arg-info))
1043          (precedence (arg-info-precedence arg-info)))
1044     (generate-discrimination-net-internal
1045      generic-function methods types
1046      (lambda (methods known-types)
1047        (if (or sorted-p
1048                (and c-a-m-emf-std-p
1049                     (block one-order-p
1050                       (let ((sorted-methods nil))
1051                         (map-all-orders
1052                          (copy-list methods) precedence
1053                          (lambda (methods)
1054                            (when sorted-methods (return-from one-order-p nil))
1055                            (setq sorted-methods methods)))
1056                         (setq methods sorted-methods))
1057                       t)))
1058            `(methods ,methods ,known-types)
1059            `(unordered-methods ,methods ,known-types)))
1060      (lambda (position type true-value false-value)
1061        (let ((arg (dfun-arg-symbol position)))
1062          (if (eq (car type) 'eql)
1063              (let* ((false-case-p (and (consp false-value)
1064                                        (or (eq (car false-value) 'scase)
1065                                            (eq (car false-value) 'mcase))
1066                                        (eq arg (cadr false-value))))
1067                     (false-clauses (if false-case-p
1068                                        (cddr false-value)
1069                                        `((t ,false-value))))
1070                     (case-sym (if (and (dnet-methods-p true-value)
1071                                        (if false-case-p
1072                                            (eq (car false-value) 'mcase)
1073                                            (dnet-methods-p false-value)))
1074                                   'mcase
1075                                   'scase))
1076                     (type-sym `(,(cadr type))))
1077                `(,case-sym ,arg
1078                            (,type-sym ,true-value)
1079                            ,@false-clauses))
1080              `(if ,(let ((arg (dfun-arg-symbol position)))
1081                      (case (car type)
1082                        (class    `(class-test    ,arg ,(cadr type)))
1083                        (class-eq `(class-eq-test ,arg ,(cadr type)))))
1084                   ,true-value
1085                   ,false-value))))
1086      #'identity)))
1087
1088 (defun class-from-type (type)
1089   (if (or (atom type) (eq (car type) t))
1090       *the-class-t*
1091       (case (car type)
1092         (and (dolist (type (cdr type) *the-class-t*)
1093                (when (and (consp type) (not (eq (car type) 'not)))
1094                  (return (class-from-type type)))))
1095         (not *the-class-t*)
1096         (eql (class-of (cadr type)))
1097         (class-eq (cadr type))
1098         (class (cadr type)))))
1099
1100 (defun precompute-effective-methods (gf caching-p &optional classes-list-p)
1101   (let* ((arg-info (gf-arg-info gf))
1102          (methods (generic-function-methods gf))
1103          (precedence (arg-info-precedence arg-info))
1104          (*in-precompute-effective-methods-p* t)
1105          (classes-list nil))
1106     (generate-discrimination-net-internal
1107      gf methods nil
1108      (lambda (methods known-types)
1109        (when methods
1110          (when classes-list-p
1111            (push (mapcar #'class-from-type known-types) classes-list))
1112          (let ((no-eql-specls-p (not (methods-contain-eql-specializer-p
1113                                       methods))))
1114            (map-all-orders
1115             methods precedence
1116             (lambda (methods)
1117               (get-secondary-dispatch-function1
1118                gf methods known-types
1119                nil caching-p no-eql-specls-p))))))
1120      (lambda (position type true-value false-value)
1121        (declare (ignore position type true-value false-value))
1122        nil)
1123      (lambda (type)
1124        (if (and (consp type) (eq (car type) 'eql))
1125            `(class-eq ,(class-of (cadr type)))
1126            type)))
1127     classes-list))
1128
1129 ;;; We know that known-type implies neither new-type nor `(not ,new-type).
1130 (defun augment-type (new-type known-type)
1131   (if (or (eq known-type t)
1132           (eq (car new-type) 'eql))
1133       new-type
1134       (let ((so-far (if (and (consp known-type) (eq (car known-type) 'and))
1135                         (cdr known-type)
1136                         (list known-type))))
1137         (unless (eq (car new-type) 'not)
1138           (setq so-far
1139                 (mapcan (lambda (type)
1140                           (unless (*subtypep new-type type)
1141                             (list type)))
1142                         so-far)))
1143         (if (null so-far)
1144             new-type
1145             `(and ,new-type ,@so-far)))))
1146
1147 (defun generate-discrimination-net-internal
1148     (gf methods types methods-function test-fun type-function)
1149   (let* ((arg-info (gf-arg-info gf))
1150          (precedence (arg-info-precedence arg-info))
1151          (nreq (arg-info-number-required arg-info))
1152          (metatypes (arg-info-metatypes arg-info)))
1153     (labels ((do-column (p-tail contenders known-types)
1154                (if p-tail
1155                    (let* ((position (car p-tail))
1156                           (known-type (or (nth position types) t)))
1157                      (if (eq (nth position metatypes) t)
1158                          (do-column (cdr p-tail) contenders
1159                                     (cons (cons position known-type)
1160                                           known-types))
1161                          (do-methods p-tail contenders
1162                                      known-type () known-types)))
1163                    (funcall methods-function contenders
1164                             (let ((k-t (make-list nreq)))
1165                               (dolist (index+type known-types)
1166                                 (setf (nth (car index+type) k-t)
1167                                       (cdr index+type)))
1168                               k-t))))
1169              (do-methods (p-tail contenders known-type winners known-types)
1170                ;; CONTENDERS
1171                ;;   is a (sorted) list of methods that must be discriminated.
1172                ;; KNOWN-TYPE
1173                ;;   is the type of this argument, constructed from tests
1174                ;;   already made.
1175                ;; WINNERS
1176                ;;   is a (sorted) list of methods that are potentially
1177                ;;   applicable after the discrimination has been made.
1178                (if (null contenders)
1179                    (do-column (cdr p-tail)
1180                               winners
1181                               (cons (cons (car p-tail) known-type)
1182                                     known-types))
1183                    (let* ((position (car p-tail))
1184                           (method (car contenders))
1185                           (specl (nth position (method-specializers method)))
1186                           (type (funcall type-function
1187                                          (type-from-specializer specl))))
1188                      (multiple-value-bind (app-p maybe-app-p)
1189                          (specializer-applicable-using-type-p type known-type)
1190                        (flet ((determined-to-be (truth-value)
1191                                 (if truth-value app-p (not maybe-app-p)))
1192                               (do-if (truth &optional implied)
1193                                 (let ((ntype (if truth type `(not ,type))))
1194                                   (do-methods p-tail
1195                                     (cdr contenders)
1196                                     (if implied
1197                                         known-type
1198                                         (augment-type ntype known-type))
1199                                     (if truth
1200                                         (append winners `(,method))
1201                                         winners)
1202                                     known-types))))
1203                          (cond ((determined-to-be nil) (do-if nil t))
1204                                ((determined-to-be t)   (do-if t   t))
1205                                (t (funcall test-fun position type
1206                                            (do-if t) (do-if nil))))))))))
1207       (do-column precedence methods ()))))
1208
1209 (defun compute-secondary-dispatch-function (generic-function net &optional
1210                                             method-alist wrappers)
1211   (function-funcall (compute-secondary-dispatch-function1 generic-function net)
1212                     method-alist wrappers))
1213
1214 (defvar *eq-case-table-limit* 15)
1215 (defvar *case-table-limit* 10)
1216
1217 (defun compute-mcase-parameters (case-list)
1218   (unless (eq t (caar (last case-list)))
1219     (error "The key for the last case arg to mcase was not T"))
1220   (let* ((eq-p (dolist (case case-list t)
1221                  (unless (or (eq (car case) t)
1222                              (symbolp (caar case)))
1223                    (return nil))))
1224          (len (1- (length case-list)))
1225          (type (cond ((= len 1)
1226                       :simple)
1227                      ((<= len
1228                           (if eq-p
1229                               *eq-case-table-limit*
1230                               *case-table-limit*))
1231                       :assoc)
1232                      (t
1233                       :hash-table))))
1234     (list eq-p type)))
1235
1236 (defmacro mlookup (key info default &optional eq-p type)
1237   (unless (or (eq eq-p t) (null eq-p))
1238     (bug "Invalid eq-p argument: ~S" eq-p))
1239   (ecase type
1240     (:simple
1241      `(if (locally
1242             (declare (optimize (inhibit-warnings 3)))
1243             (,(if eq-p 'eq 'eql) ,key (car ,info)))
1244           (cdr ,info)
1245           ,default))
1246     (:assoc
1247      `(dolist (e ,info ,default)
1248         (when (locally
1249                 (declare (optimize (inhibit-warnings 3)))
1250                 (,(if eq-p 'eq 'eql) (car e) ,key))
1251           (return (cdr e)))))
1252     (:hash-table
1253      `(gethash ,key ,info ,default))))
1254
1255 (defun net-test-converter (form)
1256   (if (atom form)
1257       (default-test-converter form)
1258       (case (car form)
1259         ((invoke-effective-method-function invoke-fast-method-call
1260           invoke-effective-narrow-method-function)
1261          '.call.)
1262         (methods
1263          '.methods.)
1264         (unordered-methods
1265          '.umethods.)
1266         (mcase
1267          `(mlookup ,(cadr form)
1268                    nil
1269                    nil
1270                    ,@(compute-mcase-parameters (cddr form))))
1271         (t (default-test-converter form)))))
1272
1273 (defun net-code-converter (form)
1274   (if (atom form)
1275       (default-code-converter form)
1276       (case (car form)
1277         ((methods unordered-methods)
1278          (let ((gensym (gensym)))
1279            (values gensym
1280                    (list gensym))))
1281         (mcase
1282          (let ((mp (compute-mcase-parameters (cddr form)))
1283                (gensym (gensym)) (default (gensym)))
1284            (values `(mlookup ,(cadr form) ,gensym ,default ,@mp)
1285                    (list gensym default))))
1286         (t
1287          (default-code-converter form)))))
1288
1289 (defun net-constant-converter (form generic-function)
1290   (or (let ((c (methods-converter form generic-function)))
1291         (when c (list c)))
1292       (if (atom form)
1293           (default-constant-converter form)
1294           (case (car form)
1295             (mcase
1296              (let* ((mp (compute-mcase-parameters (cddr form)))
1297                     (list (mapcar (lambda (clause)
1298                                     (let ((key (car clause))
1299                                           (meth (cadr clause)))
1300                                       (cons (if (consp key) (car key) key)
1301                                             (methods-converter
1302                                              meth generic-function))))
1303                                   (cddr form)))
1304                     (default (car (last list))))
1305                (list (list* :mcase mp (nbutlast list))
1306                      (cdr default))))
1307             (t
1308              (default-constant-converter form))))))
1309
1310 (defun methods-converter (form generic-function)
1311   (cond ((and (consp form) (eq (car form) 'methods))
1312          (cons '.methods.
1313                (get-effective-method-function1 generic-function (cadr form))))
1314         ((and (consp form) (eq (car form) 'unordered-methods))
1315          (default-secondary-dispatch-function generic-function))))
1316
1317 (defun convert-methods (constant method-alist wrappers)
1318   (if (and (consp constant)
1319            (eq (car constant) '.methods.))
1320       (funcall (cdr constant) method-alist wrappers)
1321       constant))
1322
1323 (defun convert-table (constant method-alist wrappers)
1324   (cond ((and (consp constant)
1325               (eq (car constant) :mcase))
1326          (let ((alist (mapcar (lambda (k+m)
1327                                 (cons (car k+m)
1328                                       (convert-methods (cdr k+m)
1329                                                        method-alist
1330                                                        wrappers)))
1331                               (cddr constant)))
1332                (mp (cadr constant)))
1333            (ecase (cadr mp)
1334              (:simple
1335               (car alist))
1336              (:assoc
1337               alist)
1338              (:hash-table
1339               (let ((table (make-hash-table :test (if (car mp) 'eq 'eql))))
1340                 (dolist (k+m alist)
1341                   (setf (gethash (car k+m) table) (cdr k+m)))
1342                 table)))))))
1343
1344 (defun compute-secondary-dispatch-function1 (generic-function net
1345                                              &optional function-p)
1346   (cond
1347    ((and (eq (car net) 'methods) (not function-p))
1348     (get-effective-method-function1 generic-function (cadr net)))
1349    (t
1350     (let* ((name (generic-function-name generic-function))
1351            (arg-info (gf-arg-info generic-function))
1352            (metatypes (arg-info-metatypes arg-info))
1353            (nargs (length metatypes))
1354            (applyp (arg-info-applyp arg-info))
1355            (fmc-arg-info (cons nargs applyp))
1356            (arglist (if function-p
1357                         (make-dfun-lambda-list nargs applyp)
1358                         (make-fast-method-call-lambda-list nargs applyp))))
1359       (multiple-value-bind (cfunction constants)
1360           (get-fun1 `(lambda
1361                       ,arglist
1362                       ,@(unless function-p
1363                           `((declare (ignore .pv. .next-method-call.))))
1364                       (locally (declare #.*optimize-speed*)
1365                                (let ((emf ,net))
1366                                  ,(make-emf-call nargs applyp 'emf))))
1367                     #'net-test-converter
1368                     #'net-code-converter
1369                     (lambda (form)
1370                       (net-constant-converter form generic-function)))
1371         (lambda (method-alist wrappers)
1372           (let* ((alist (list nil))
1373                  (alist-tail alist))
1374             (dolist (constant constants)
1375               (let* ((a (or (dolist (a alist nil)
1376                               (when (eq (car a) constant)
1377                                 (return a)))
1378                             (cons constant
1379                                   (or (convert-table
1380                                        constant method-alist wrappers)
1381                                       (convert-methods
1382                                        constant method-alist wrappers)))))
1383                      (new (list a)))
1384                 (setf (cdr alist-tail) new)
1385                 (setf alist-tail new)))
1386             (let ((function (apply cfunction (mapcar #'cdr (cdr alist)))))
1387               (if function-p
1388                   function
1389                   (make-fast-method-call
1390                    :function (set-fun-name function `(sdfun-method ,name))
1391                    :arg-info fmc-arg-info))))))))))
1392
1393 (defvar *show-make-unordered-methods-emf-calls* nil)
1394
1395 (defun make-unordered-methods-emf (generic-function methods)
1396   (when *show-make-unordered-methods-emf-calls*
1397     (format t "~&make-unordered-methods-emf ~S~%"
1398             (generic-function-name generic-function)))
1399   (lambda (&rest args)
1400     (let* ((types (types-from-args generic-function args 'eql))
1401            (smethods (sort-applicable-methods generic-function
1402                                               methods
1403                                               types))
1404            (emf (get-effective-method-function generic-function smethods)))
1405       (invoke-emf emf args))))
1406 \f
1407 ;;; The value returned by compute-discriminating-function is a function
1408 ;;; object. It is called a discriminating function because it is called
1409 ;;; when the generic function is called and its role is to discriminate
1410 ;;; on the arguments to the generic function and then call appropriate
1411 ;;; method functions.
1412 ;;;
1413 ;;; A discriminating function can only be called when it is installed as
1414 ;;; the funcallable instance function of the generic function for which
1415 ;;; it was computed.
1416 ;;;
1417 ;;; More precisely, if compute-discriminating-function is called with
1418 ;;; an argument <gf1>, and returns a result <df1>, that result must
1419 ;;; not be passed to apply or funcall directly. Rather, <df1> must be
1420 ;;; stored as the funcallable instance function of the same generic
1421 ;;; function <gf1> (using SET-FUNCALLABLE-INSTANCE-FUNCTION). Then the
1422 ;;; generic function can be passed to funcall or apply.
1423 ;;;
1424 ;;; An important exception is that methods on this generic function are
1425 ;;; permitted to return a function which itself ends up calling the value
1426 ;;; returned by a more specific method. This kind of `encapsulation' of
1427 ;;; discriminating function is critical to many uses of the MOP.
1428 ;;;
1429 ;;; As an example, the following canonical case is legal:
1430 ;;;
1431 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1432 ;;;     (let ((std (call-next-method)))
1433 ;;;       (lambda (arg)
1434 ;;;         (print (list 'call-to-gf gf arg))
1435 ;;;         (funcall std arg))))
1436 ;;;
1437 ;;; Because many discriminating functions would like to use a dynamic
1438 ;;; strategy in which the precise discriminating function changes with
1439 ;;; time it is important to specify how a discriminating function is
1440 ;;; permitted itself to change the funcallable instance function of the
1441 ;;; generic function.
1442 ;;;
1443 ;;; Discriminating functions may set the funcallable instance function
1444 ;;; of the generic function, but the new value must be generated by making
1445 ;;; a call to COMPUTE-DISCRIMINATING-FUNCTION. This is to ensure that any
1446 ;;; more specific methods which may have encapsulated the discriminating
1447 ;;; function will get a chance to encapsulate the new, inner discriminating
1448 ;;; function.
1449 ;;;
1450 ;;; This implies that if a discriminating function wants to modify itself
1451 ;;; it should first store some information in the generic function proper,
1452 ;;; and then call compute-discriminating-function. The appropriate method
1453 ;;; on compute-discriminating-function will see the information stored in
1454 ;;; the generic function and generate a discriminating function accordingly.
1455 ;;;
1456 ;;; The following is an example of a discriminating function which modifies
1457 ;;; itself in accordance with this protocol:
1458 ;;;
1459 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1460 ;;;     (lambda (arg)
1461 ;;;      (cond (<some condition>
1462 ;;;             <store some info in the generic function>
1463 ;;;             (set-funcallable-instance-function
1464 ;;;               gf
1465 ;;;               (compute-discriminating-function gf))
1466 ;;;             (funcall gf arg))
1467 ;;;            (t
1468 ;;;             <call-a-method-of-gf>))))
1469 ;;;
1470 ;;; Whereas this code would not be legal:
1471 ;;;
1472 ;;;   (defmethod compute-discriminating-function ((gf my-generic-function))
1473 ;;;     (lambda (arg)
1474 ;;;      (cond (<some condition>
1475 ;;;             (set-funcallable-instance-function
1476 ;;;               gf
1477 ;;;               (lambda (a) ..))
1478 ;;;             (funcall gf arg))
1479 ;;;            (t
1480 ;;;             <call-a-method-of-gf>))))
1481 ;;;
1482 ;;; NOTE:  All the examples above assume that all instances of the class
1483 ;;;     my-generic-function accept only one argument.
1484
1485 (defun slot-value-using-class-dfun (class object slotd)
1486   (declare (ignore class))
1487   (function-funcall (slot-definition-reader-function slotd) object))
1488
1489 (defun setf-slot-value-using-class-dfun (new-value class object slotd)
1490   (declare (ignore class))
1491   (function-funcall (slot-definition-writer-function slotd) new-value object))
1492
1493 (defun slot-boundp-using-class-dfun (class object slotd)
1494   (declare (ignore class))
1495   (function-funcall (slot-definition-boundp-function slotd) object))
1496
1497 (defun special-case-for-compute-discriminating-function-p (gf)
1498   (or (eq gf #'slot-value-using-class)
1499       (eq gf #'(setf slot-value-using-class))
1500       (eq gf #'slot-boundp-using-class)))
1501
1502 (defmethod compute-discriminating-function ((gf standard-generic-function))
1503   (let ((dfun-state (slot-value gf 'dfun-state)))
1504     (when (special-case-for-compute-discriminating-function-p gf)
1505       ;; if we have a special case for
1506       ;; COMPUTE-DISCRIMINATING-FUNCTION, then (at least for the
1507       ;; special cases implemented as of 2006-05-09) any information
1508       ;; in the cache is misplaced.
1509       (aver (null dfun-state)))
1510     (typecase dfun-state
1511       (null
1512        (when (eq gf #'compute-applicable-methods)
1513          (update-all-c-a-m-gf-info gf))
1514        (cond
1515          ((eq gf #'slot-value-using-class)
1516           (update-slot-value-gf-info gf 'reader)
1517           #'slot-value-using-class-dfun)
1518          ((eq gf #'(setf slot-value-using-class))
1519           (update-slot-value-gf-info gf 'writer)
1520           #'setf-slot-value-using-class-dfun)
1521          ((eq gf #'slot-boundp-using-class)
1522           (update-slot-value-gf-info gf 'boundp)
1523           #'slot-boundp-using-class-dfun)
1524          ((gf-precompute-dfun-and-emf-p (slot-value gf 'arg-info))
1525           (make-final-dfun gf))
1526          (t
1527           (make-initial-dfun gf))))
1528       (function dfun-state)
1529       (cons (car dfun-state)))))
1530
1531 (defmethod update-gf-dfun ((class std-class) gf)
1532   (let ((*new-class* class)
1533         (arg-info (gf-arg-info gf)))
1534     (cond
1535       ((special-case-for-compute-discriminating-function-p gf))
1536       ((gf-precompute-dfun-and-emf-p arg-info)
1537        (multiple-value-bind (dfun cache info)
1538            (make-final-dfun-internal gf)
1539          (update-dfun gf dfun cache info))))))
1540 \f
1541 (defmethod (setf class-name) (new-value class)
1542   (let ((classoid (wrapper-classoid (class-wrapper class))))
1543     (if (and new-value (symbolp new-value))
1544         (setf (classoid-name classoid) new-value)
1545         (setf (classoid-name classoid) nil)))
1546   (reinitialize-instance class :name new-value)
1547   new-value)
1548
1549 (defmethod (setf generic-function-name) (new-value generic-function)
1550   (reinitialize-instance generic-function :name new-value)
1551   new-value)
1552 \f
1553 (defmethod function-keyword-parameters ((method standard-method))
1554   (multiple-value-bind (nreq nopt keysp restp allow-other-keys-p
1555                         keywords keyword-parameters)
1556       (analyze-lambda-list (if (consp method)
1557                                (early-method-lambda-list method)
1558                                (method-lambda-list method)))
1559     (declare (ignore nreq nopt keysp restp keywords))
1560     (values keyword-parameters allow-other-keys-p)))
1561
1562 (defun method-ll->generic-function-ll (ll)
1563   (multiple-value-bind
1564       (nreq nopt keysp restp allow-other-keys-p keywords keyword-parameters)
1565       (analyze-lambda-list ll)
1566     (declare (ignore nreq nopt keysp restp allow-other-keys-p keywords))
1567     (remove-if (lambda (s)
1568                  (or (memq s keyword-parameters)
1569                      (eq s '&allow-other-keys)))
1570                ll)))
1571 \f
1572 ;;; This is based on the rules of method lambda list congruency
1573 ;;; defined in the spec. The lambda list it constructs is the pretty
1574 ;;; union of the lambda lists of the generic function and of all its
1575 ;;; methods.  It doesn't take method applicability into account at all
1576 ;;; yet.
1577
1578 ;;; (Notice that we ignore &AUX variables as they're not part of the
1579 ;;; "public interface" of a function.)
1580
1581 (defmethod generic-function-pretty-arglist
1582            ((generic-function standard-generic-function))
1583   (let ((gf-lambda-list (generic-function-lambda-list generic-function))
1584         (methods (generic-function-methods generic-function)))
1585     (if (null methods)
1586         gf-lambda-list
1587         (multiple-value-bind (gf.required gf.optional gf.rest gf.keys gf.allowp)
1588             (%split-arglist gf-lambda-list)
1589           ;; Possibly extend the keyword parameters of the gf by
1590           ;; additional key parameters of its methods:
1591           (let ((methods.keys nil) (methods.allowp nil))
1592             (dolist (m methods)
1593               (multiple-value-bind (m.keyparams m.allow-other-keys)
1594                   (function-keyword-parameters m)
1595                 (setq methods.keys (union methods.keys m.keyparams :key #'maybe-car))
1596                 (setq methods.allowp (or methods.allowp m.allow-other-keys))))
1597             (let ((arglist '()))
1598               (when (or gf.allowp methods.allowp)
1599                 (push '&allow-other-keys arglist))
1600               (when (or gf.keys methods.keys)
1601                 ;; We make sure that the keys of the gf appear before
1602                 ;; those of its methods, since they're probably more
1603                 ;; generally appliable.
1604                 (setq arglist (nconc (list '&key) gf.keys
1605                                      (nset-difference methods.keys gf.keys)
1606                                      arglist)))
1607               (when gf.rest
1608                 (setq arglist (nconc (list '&rest gf.rest) arglist)))
1609               (when gf.optional
1610                 (setq arglist (nconc (list '&optional) gf.optional arglist)))
1611               (nconc gf.required arglist)))))))
1612
1613 (defun maybe-car (thing)
1614   (if (listp thing)
1615       (car thing)
1616       thing))
1617
1618
1619 (defun %split-arglist (lambda-list)
1620   ;; This function serves to shrink the number of returned values of
1621   ;; PARSE-LAMBDA-LIST to something handier.
1622   (multiple-value-bind (required optional restp rest keyp keys allowp
1623                         auxp aux morep more-context more-count)
1624       (parse-lambda-list lambda-list)
1625     (declare (ignore restp keyp auxp aux morep))
1626     (declare (ignore more-context more-count))
1627     (values required optional rest keys allowp)))