src/code/cross-sap.lisp

   1 ;;;; support and placeholders for System Area Pointers (SAPs) in the host
   2 ;;;; Common Lisp at cross-compile time
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!SYS")
  14
  15 ;;; SYSTEM-AREA-POINTER is not a primitive type in ANSI Common Lisp,
  16 ;;; so we need a compound type to represent it in the host Common Lisp
  17 ;;; at cross-compile time:
  18 (defstruct (system-area-pointer (:constructor int-sap (int))
  19                                 (:conc-name "SAP-"))
  20   ;; the integer representation of the address
  21   (int nil :type unsigned-byte :read-only t))
  22
  23 ;;; cross-compilation-host analogues of target-CMU CL primitive SAP operations
  24 (defun sap+ (sap offset)
  25   (declare (type system-area-pointer sap) (type sap-int offset))
  26   (make-sap :int (+ (sap-int sap) offset)))
  27 #.`(progn
  28      ,@(mapcar (lambda (info)
  29                  (destructuring-bind (sap-fun int-fun) info
  30                    `(defun ,sap-fun (x y)
  31                       (,int-fun (sap-int x) (sap-int y)))))
  32                '((sap< <) (sap<= <=) (sap= =) (sap>= >=) (sap> >) (sap- -))))
  33
  34 ;;; dummies, defined so that we can declare they never return and
  35 ;;; thereby eliminate a thundering herd of optimization notes along
  36 ;;; the lines of "can't optimize this expression because we don't know
  37 ;;; the return type of SAP-REF-8"
  38 (defun sap-ref-stub (name)
  39   (error "~S doesn't make sense on cross-compilation host." name))
  40 #.`(progn
  41      ,@(mapcan (lambda (name)
  42                  `((declaim (ftype (function (system-area-pointer fixnum) nil)
  43                                    ,name))
  44                    (defun ,name (sap offset)
  45                      (declare (ignore sap offset))
  46                      (sap-ref-stub ',name))
  47                    ,@(let ((setter-stub (gensym "SETTER-STUB-")))
  48                        `((defun ,setter-stub (foo sap offset)
  49                            (declare (ignore foo sap offset))
  50                            (sap-ref-stub '(setf ,name)))
  51                          (defsetf ,name ,setter-stub)))))
  52                '(sap-ref-8
  53                  sap-ref-16
  54                  sap-ref-32
  55                  sap-ref-64
  56                  sap-ref-sap
  57                  sap-ref-word
  58                  sap-ref-single
  59                  sap-ref-double
  60                  signed-sap-ref-8
  61                  signed-sap-ref-16
  62                  signed-sap-ref-32
  63                  signed-sap-ref-64
  64                  signed-sap-ref-word)))