src/code/fop.lisp

   1 ;;;; FOP definitions
   2
   3 (in-package "SB!FASL")
   4
   5 ;;; Bind STACK-VAR and PTR-VAR to the start of a subsequence of
   6 ;;; the fop stack of length COUNT, then execute BODY.
   7 ;;; Within the body, FOP-STACK-REF is used in lieu of SVREF
   8 ;;; to elide bounds checking.
   9 (defmacro with-fop-stack (((stack-var &optional stack-expr) ptr-var count)
  10                           &body body)
  11   `(macrolet ((fop-stack-ref (i)
  12                 `(locally
  13                      #-sb-xc-host
  14                      (declare (optimize (sb!c::insert-array-bounds-checks 0)))
  15                    (svref ,',stack-var (truly-the index ,i)))))
  16      (let* (,@(when stack-expr
  17                 (list `(,stack-var (the simple-vector ,stack-expr))))
  18             (,ptr-var (truly-the index (fop-stack-pop-n ,stack-var ,count))))
  19        ,@body)))
  20
  21 ;;; Define NAME as a fasl operation, with op-code FOP-CODE.
  22 ;;; PUSHP describes what the body does to the fop stack:
  23 ;;;   T   - The result of the body is pushed on the fop stack.
  24 ;;;   NIL - The result of the body is discarded.
  25 ;;; In either case, the body is permitted to pop the stack.
  26 ;;;
  27 (defmacro !define-fop (fop-code &rest stuff)
  28   (multiple-value-bind (name allowp operands stack-args pushp forms)
  29       (let ((allowp (if (eq (car stuff) :not-host)
  30                         (progn (pop stuff) (or #+sb-xc t))
  31                         t)))
  32         (destructuring-bind ((name &optional arglist (pushp t)) . forms) stuff
  33           (aver (member pushp '(nil t)))
  34           (multiple-value-bind (operands stack-args)
  35               (if (atom (car arglist))
  36                   (values nil arglist)
  37                   (ecase (caar arglist)
  38                     (:operands (values (cdar arglist) (cdr arglist)))))
  39             (assert (<= (length operands) 3))
  40             (values name allowp operands stack-args pushp forms))))
  41     `(progn
  42        (defun ,name (.fasl-input. ,@operands)
  43          (declare (ignorable .fasl-input.))
  44          ,@(if allowp
  45                `((macrolet
  46                    ((fasl-input () '(truly-the fasl-input .fasl-input.))
  47                     (fasl-input-stream () '(%fasl-input-stream (fasl-input)))
  48                     (operand-stack () '(%fasl-input-stack (fasl-input)))
  49                     (skip-until () '(%fasl-input-skip-until (fasl-input))))
  50                   ,@(if (null stack-args)
  51                         forms
  52                         (with-unique-names (stack ptr)
  53                          `((with-fop-stack ((,stack (operand-stack))
  54                                             ,ptr ,(length stack-args))
  55                              (multiple-value-bind ,stack-args
  56                                  (values ,@(loop for i below (length stack-args)
  57                                                  collect `(fop-stack-ref (+ ,ptr ,i))))
  58                                ,@forms)))))))
  59                `((declare (ignore ,@operands))
  60                  (error ,(format nil "Not-host fop invoked: ~A" name)))))
  61        (!%define-fop ',name ,fop-code ,(length operands) ,(if pushp 1 0)))))
  62
  63 (defun !%define-fop (name base-opcode n-operands pushp)
  64   (declare (type (mod 4) n-operands))
  65   ;; If at least one non-stack operand is present, the same fop function
  66   ;; appears in 4 consecutive cells in the fop table, with the low 2 bits
  67   ;; of the fopcode determining the number of additional bytes to read
  68   ;; for the first operand. The second and third operands are varint-encoded.
  69   (let ((n-slots (if (plusp n-operands) 4 1)))
  70     (unless (zerop (mod base-opcode n-slots))
  71       (error "Opcode for fop ~S must be a multiple of ~D" name n-slots))
  72     (loop for opcode from base-opcode below (+ base-opcode n-slots)
  73           for function = (svref **fop-funs** opcode)
  74           when (functionp function)
  75           do (let ((oname (nth-value 2 (function-lambda-expression function))))
  76                (when (and oname (not (eq oname name)))
  77                  (error "fop ~S with opcode ~D conflicts with fop ~S."
  78                         name opcode oname))))
  79     (let ((existing-opcode (get name 'opcode)))
  80       (when (and existing-opcode (/= existing-opcode base-opcode))
  81         (error "multiple codes for fop name ~S: ~D and ~D"
  82                name base-opcode existing-opcode)))
  83     (setf (get name 'opcode) base-opcode)
  84     ;; The low 2 bits of the opcode comprise the length modifier if there is
  85     ;; at least one non-stack integer operand.
  86     ;; If there is more than 1, they follow, using varint encoding.
  87     (dotimes (j n-slots)
  88       (let ((opcode (+ base-opcode j)))
  89         (setf (svref **fop-funs** opcode) (symbol-function name)
  90               (aref (car **fop-signatures**) opcode) n-operands
  91               (sbit (cdr **fop-signatures**) opcode) pushp))))
  92   name)
  93
  94 ;;; a helper function for reading string values from FASL files: sort
  95 ;;; of like READ-SEQUENCE specialized for files of (UNSIGNED-BYTE 8),
  96 ;;; with an automatic conversion from (UNSIGNED-BYTE 8) into CHARACTER
  97 ;;; for each element read
  98 (defun read-string-as-bytes (stream string &optional (length (length string)))
  99   (declare (type (simple-array character (*)) string)
 100            (type index length)
 101            (optimize speed))
 102   (with-fast-read-byte ((unsigned-byte 8) stream)
 103     (dotimes (i length)
 104       (setf (aref string i)
 105             (sb!xc:code-char (fast-read-byte)))))
 106   string)
 107 (defun read-base-string-as-bytes (stream string &optional (length (length string)))
 108   (declare (type (simple-array base-char (*)) string)
 109            (type index length)
 110            (optimize speed))
 111   (with-fast-read-byte ((unsigned-byte 8) stream)
 112     (dotimes (i length)
 113       (setf (aref string i)
 114             (sb!xc:code-char (fast-read-byte)))))
 115   string)
 116 #!+(and sb-unicode (host-feature sb-xc))
 117 (defun read-string-as-unsigned-byte-32
 118     (stream string &optional (length (length string)))
 119   (declare (type (simple-array character (*)) string)
 120            (type index length)
 121            (optimize speed))
 122   (with-fast-read-byte ((unsigned-byte 8) stream)
 123     (dotimes (i length)
 124       (setf (aref string i)
 125             (sb!xc:code-char (fast-read-u-integer 4)))))
 126   string)
 127 \f
 128 ;;;; miscellaneous fops
 129
 130 ;;; Setting this variable causes execution of a FOP-NOP4 to produce
 131 ;;; output to *DEBUG-IO*. This can be handy when trying to follow the
 132 ;;; progress of FASL loading.
 133 #!+sb-show
 134 (defvar *show-fop-nop4-p* nil)
 135
 136 ;;; CMU CL had a single no-op fop, FOP-NOP, with fop code 0. Since 0
 137 ;;; occurs disproportionately often in fasl files for other reasons,
 138 ;;; FOP-NOP is less than ideal for writing human-readable patterns
 139 ;;; into fasl files for debugging purposes. There's no shortage of
 140 ;;; unused fop codes, so we add this second NOP, which reads 4
 141 ;;; arbitrary bytes and discards them.
 142 (!define-fop 137 (fop-nop4 () nil)
 143   (let ((arg (read-arg 4 (fasl-input-stream))))
 144     (declare (ignorable arg))
 145     #!+sb-show
 146     (when *show-fop-nop4-p*
 147       (format *debug-io* "~&/FOP-NOP4 ARG=~W=#X~X~%" arg arg))))
 148
 149 (!define-fop 0 (fop-nop () nil))
 150 (!define-fop 1 (fop-pop (x) nil) (push-fop-table x (fasl-input)))
 151 (!define-fop 2 (fop-empty-list) nil)
 152 (!define-fop 3 (fop-truth) t)
 153 (!define-fop 4 (fop-push ((:operands index)))
 154   (ref-fop-table (fasl-input) index))
 155 (!define-fop 9 (fop-move-to-table (x))
 156   (push-fop-table x (fasl-input))
 157   x)
 158
 159 (!define-fop 66 :not-host (fop-misc-trap)
 160   (make-unbound-marker))
 161
 162 (!define-fop 76 (fop-character ((:operands char-code)))
 163   (code-char char-code))
 164
 165 ;; %MAKE-INSTANCE does not exist on the host.
 166 (!define-fop 48 :not-host (fop-struct ((:operands size) layout))
 167   (let ((res (%make-instance size)) ; number of words excluding header
 168         ;; Discount the layout from number of user-visible words.
 169         (n-data-words (- size sb!vm:instance-data-start)))
 170     (setf (%instance-layout res) layout)
 171     (with-fop-stack ((stack (operand-stack)) ptr n-data-words)
 172       (declare (type index ptr))
 173       (let ((bitmap (layout-bitmap layout)))
 174         ;; Values on the stack are in the same order as in the structure itself.
 175         (do ((i sb!vm:instance-data-start (1+ i)))
 176             ((>= i size))
 177           (declare (type index i))
 178           (let ((val (fop-stack-ref ptr)))
 179             (if (logbitp i bitmap)
 180                 (setf (%instance-ref res i) val)
 181                 (setf (%raw-instance-ref/word res i) val))
 182             (incf ptr)))))
 183     res))
 184
 185 (!define-fop 45 (fop-layout (name inherits depthoid length bitmap))
 186   (find-and-init-or-check-layout name length inherits depthoid bitmap))
 187
 188 ;; Allocate a CLOS object. This is used when the compiler detects that
 189 ;; MAKE-LOAD-FORM returned a simple use of MAKE-LOAD-FORM-SAVING-SLOTS,
 190 ;; or possibly a hand-written equivalent (however unlikely).
 191 (!define-fop 68 :not-host (fop-allocate-instance (name) nil)
 192   (let ((instance (allocate-instance (find-class (the symbol name)))))
 193     (push-fop-table instance (fasl-input))))
 194
 195 ;; Fill in object slots as dictated by the second return value from
 196 ;; MAKE-LOAD-FORM-SAVING-SLOTS.
 197 ;; This wants a 'count' as the first item in the SLOT-NAMES argument
 198 ;; rather than using read-arg because many calls of this might share
 199 ;; the list, which must be constructed into the fop-table no matter what.
 200 (!define-fop 69 :not-host (fop-set-slot-values (slot-names obj) nil)
 201   (let* ((n-slots (pop slot-names))
 202          (stack (operand-stack))
 203          (ptr (fop-stack-pop-n stack n-slots)))
 204       (dotimes (i n-slots)
 205         (let ((val (svref stack (+ ptr i)))
 206               (slot-name (pop slot-names)))
 207           (if (unbound-marker-p val)
 208               ;; SLOT-MAKUNBOUND-USING-CLASS might do something nonstandard.
 209               (slot-makunbound obj slot-name)
 210               (setf (slot-value obj slot-name) val))))))
 211
 212 (!define-fop 64 (fop-end-group () nil)
 213   (/show0 "THROWing FASL-GROUP-END")
 214   (throw 'fasl-group-end t))
 215
 216 ;;; We used to have FOP-NORMAL-LOAD as 81 and FOP-MAYBE-COLD-LOAD as
 217 ;;; 82 until GENESIS learned how to work with host symbols and
 218 ;;; packages directly instead of piggybacking on the host code.
 219
 220 (!define-fop 62 (fop-verify-table-size () nil)
 221   (let ((expected-index (read-word-arg (fasl-input-stream))))
 222     (unless (= (svref (%fasl-input-table (fasl-input)) 0) expected-index)
 223       (bug "fasl table of improper size"))))
 224 (!define-fop 63 (fop-verify-empty-stack () nil)
 225   (unless (fop-stack-empty-p (operand-stack))
 226     (bug "fasl stack not empty when it should be")))
 227 \f
 228 ;;;; fops for loading symbols
 229
 230 (defstruct (undefined-package (:copier nil))
 231   (error nil :read-only t))
 232 (declaim (freeze-type undefined-package))
 233
 234 ;; Cold load has its own implementation of all symbol fops,
 235 ;; but we have to execute define-fop now to assign their numbers.
 236 (labels #+sb-xc-host ()
 237         #-sb-xc-host
 238         ((read-symbol-name (length+flag fasl-input)
 239            (let* ((namelen (ash (the fixnum length+flag) -1))
 240                   (base-p (logand length+flag 1))
 241                   (elt-type (if (eql base-p 1) 'base-char 'character))
 242                   (buffer (%fasl-input-name-buffer fasl-input))
 243                   (string (the string (svref buffer base-p))))
 244              (when (< (length string) namelen) ; grow
 245                (setf string (make-string namelen :element-type elt-type)
 246                      (svref buffer base-p) string))
 247              (funcall (if (eql base-p 1)
 248                           'read-base-string-as-bytes
 249                           'read-string-as-unsigned-byte-32)
 250                       (%fasl-input-stream fasl-input) string namelen)
 251              (values string namelen elt-type)))
 252          (aux-fop-intern (length+flag package fasl-input)
 253            (multiple-value-bind (name length elt-type)
 254                (read-symbol-name length+flag fasl-input)
 255              (if (undefined-package-p package)
 256                  (error 'simple-package-error
 257                         :format-control "Error finding package for symbol ~s:~% ~a"
 258                         :format-arguments
 259                         (list (subseq name 0 length)
 260                               (undefined-package-error package)))
 261                  (push-fop-table (without-package-locks
 262                                   (%intern name length package elt-type))
 263                                  fasl-input))))
 264          ;; Symbol-hash is usually computed lazily and memoized into a symbol.
 265          ;; Laziness slightly improves the speed of allocation.
 266          ;; But when loading fasls, the time spent in the loader totally swamps
 267          ;; any time savings of not precomputing symbol-hash.
 268          ;; INTERN hashes everything anyway, so let's be consistent
 269          ;; and precompute the hashes of uninterned symbols too.
 270          (ensure-hashed (symbol)
 271            (ensure-symbol-hash symbol)
 272            symbol))
 273
 274   #-sb-xc-host (declare (inline ensure-hashed))
 275   (!define-fop 80 :not-host (fop-lisp-symbol-save ((:operands length+flag)))
 276     (aux-fop-intern length+flag *cl-package* (fasl-input)))
 277   (!define-fop 84 :not-host (fop-keyword-symbol-save ((:operands length+flag)))
 278     (aux-fop-intern length+flag *keyword-package* (fasl-input)))
 279   (!define-fop #xF0 :not-host (fop-symbol-in-package-save ((:operands length+flag pkg-index)))
 280     (aux-fop-intern length+flag (ref-fop-table (fasl-input) pkg-index) (fasl-input)))
 281
 282   (!define-fop 96 :not-host (fop-uninterned-symbol-save ((:operands length+flag)))
 283     (multiple-value-bind (name len) (read-symbol-name length+flag (fasl-input))
 284       (push-fop-table (ensure-hashed (make-symbol (subseq name 0 len)))
 285                       (fasl-input))))
 286
 287   (!define-fop 104 :not-host (fop-copy-symbol-save ((:operands table-index)))
 288     (push-fop-table (ensure-hashed
 289                      (copy-symbol (ref-fop-table (fasl-input) table-index)))
 290                     (fasl-input))))
 291
 292 (!define-fop 44 (fop-package (pkg-designator))
 293   (find-undeleted-package-or-lose pkg-designator))
 294
 295 (!define-fop 156 :not-host (fop-named-package-save ((:operands length)) nil)
 296   (let ((package-name (make-string length)))
 297     #!-sb-unicode (read-string-as-bytes (fasl-input-stream) package-name)
 298     #!+sb-unicode (read-string-as-unsigned-byte-32 (fasl-input-stream) package-name)
 299     (push-fop-table
 300      (handler-case (find-undeleted-package-or-lose package-name)
 301        (simple-package-error (c)
 302          (make-undefined-package :error (princ-to-string c))))
 303      (fasl-input))))
 304 \f
 305 ;;;; fops for loading numbers
 306
 307 ;;; Load a signed integer LENGTH bytes long from FASL-INPUT-STREAM.
 308 (defun load-s-integer (length fasl-input-stream)
 309   (declare (fixnum length)
 310            (optimize speed))
 311   (with-fast-read-byte ((unsigned-byte 8) fasl-input-stream)
 312     (do* ((index length (1- index))
 313           (byte 0 (fast-read-byte))
 314           (result 0 (+ result (ash byte bits)))
 315           (bits 0 (+ bits 8)))
 316          ((= index 0)
 317           (if (logbitp 7 byte)          ; look at sign bit
 318               (- result (ash 1 bits))
 319               result))
 320       (declare (fixnum index byte bits)))))
 321
 322 (!define-fop 36 (fop-integer ((:operands n-bytes)))
 323   (load-s-integer n-bytes (fasl-input-stream)))
 324
 325 (!define-fop 34 (fop-word-integer)
 326   (with-fast-read-byte ((unsigned-byte 8) (fasl-input-stream))
 327     (fast-read-s-integer #.sb!vm:n-word-bytes)))
 328
 329 (!define-fop 35 (fop-byte-integer)
 330   ;; FIXME: WITH-FAST-READ-BYTE for exactly 1 byte is not really faster/better
 331   ;; than regular READ-BYTE. The expansion of READ-ARG corroborates this claim.
 332   (with-fast-read-byte ((unsigned-byte 8) (fasl-input-stream))
 333     (fast-read-s-integer 1)))
 334
 335 ;; No %MAKE-RATIO on host
 336 (!define-fop 70 :not-host (fop-ratio (num den)) (%make-ratio num den))
 337
 338 ;; No %MAKE-COMPLEX on host
 339 (!define-fop 71 :not-host (fop-complex (realpart imagpart))
 340   (%make-complex realpart imagpart))
 341
 342 (macrolet ((fast-read-single-float ()
 343              '(make-single-float (fast-read-s-integer 4)))
 344            (fast-read-double-float ()
 345              '(let ((lo (fast-read-u-integer 4)))
 346                (make-double-float (fast-read-s-integer 4) lo))))
 347   (macrolet ((define-complex-fop (opcode name type)
 348                (let ((reader (symbolicate "FAST-READ-" type)))
 349                  `(!define-fop ,opcode (,name)
 350                       (with-fast-read-byte ((unsigned-byte 8) (fasl-input-stream))
 351                         (complex (,reader) (,reader))))))
 352              (define-float-fop (opcode name type)
 353                (let ((reader (symbolicate "FAST-READ-" type)))
 354                  `(!define-fop ,opcode (,name)
 355                     (with-fast-read-byte ((unsigned-byte 8) (fasl-input-stream))
 356                       (,reader))))))
 357     (define-complex-fop 72 fop-complex-single-float single-float)
 358     (define-complex-fop 73 fop-complex-double-float double-float)
 359     #!+long-float
 360     (define-complex-fop 67 fop-complex-long-float long-float)
 361     (define-float-fop 46 fop-single-float single-float)
 362     (define-float-fop 47 fop-double-float double-float)
 363     #!+long-float
 364     (define-float-fop 52 fop-long-float long-float)))
 365
 366 #!+sb-simd-pack
 367 (!define-fop 88 (fop-simd-pack)
 368   (with-fast-read-byte ((unsigned-byte 8) (fasl-input-stream))
 369     (%make-simd-pack (fast-read-s-integer 8)
 370                      (fast-read-u-integer 8)
 371                      (fast-read-u-integer 8))))
 372 \f
 373 ;;;; loading lists
 374
 375 (defun fop-list-from-stack (stack n)
 376   ;; N is 0-255 when called from FOP-LIST,
 377   ;; but it is as large as ARRAY-RANK-LIMIT in FOP-ARRAY.
 378   (declare (type (unsigned-byte 16) n)
 379            (optimize (speed 3)))
 380   (with-fop-stack ((stack) ptr n)
 381     (do* ((i (+ ptr n) (1- i))
 382           (res () (cons (fop-stack-ref i) res)))
 383          ((= i ptr) res)
 384       (declare (type index i)))))
 385
 386 (!define-fop 33 (fop-list)
 387   (fop-list-from-stack (operand-stack) (read-byte-arg (fasl-input-stream))))
 388 (!define-fop 16 (fop-list*)
 389   ;; N is the number of cons cells (0 is ok)
 390   (let ((n (read-byte-arg (fasl-input-stream))))
 391     (with-fop-stack ((stack (operand-stack)) ptr (1+ n))
 392       (do* ((i (+ ptr n) (1- i))
 393             (res (fop-stack-ref (+ ptr n))
 394                  (cons (fop-stack-ref i) res)))
 395            ((= i ptr) res)
 396         (declare (type index i))))))
 397
 398 (macrolet ((frob (name op fun n)
 399              (let ((args (make-gensym-list n)))
 400                `(!define-fop ,op (,name ,args) (,fun ,@args)))))
 401
 402   (frob fop-list-1 17 list 1)
 403   (frob fop-list-2 18 list 2)
 404   (frob fop-list-3 19 list 3)
 405   (frob fop-list-4 20 list 4)
 406   (frob fop-list-5 21 list 5)
 407   (frob fop-list-6 22 list 6)
 408   (frob fop-list-7 23 list 7)
 409   (frob fop-list-8 24 list 8)
 410
 411   (frob fop-list*-1 25 list* 2)
 412   (frob fop-list*-2 26 list* 3)
 413   (frob fop-list*-3 27 list* 4)
 414   (frob fop-list*-4 28 list* 5)
 415   (frob fop-list*-5 29 list* 6)
 416   (frob fop-list*-6 30 list* 7)
 417   (frob fop-list*-7 31 list* 8)
 418   (frob fop-list*-8 32 list* 9))
 419 \f
 420 ;;;; fops for loading arrays
 421
 422 (!define-fop 100 :not-host (fop-base-string ((:operands length)))
 423   (logically-readonlyize
 424    (read-base-string-as-bytes (fasl-input-stream)
 425                               (make-string length :element-type 'base-char))))
 426
 427 ;; FIXME: can save space by UTF-8 encoding, or use 1 bit to indicate pure ASCII
 428 ;; in the fasl even though the result will be a non-base string.
 429 #!+sb-unicode
 430 (!define-fop 160 :not-host (fop-character-string ((:operands length)))
 431   (logically-readonlyize
 432    (read-string-as-unsigned-byte-32 (fasl-input-stream)
 433                                     (make-string length))))
 434
 435 (!define-fop 92 (fop-vector ((:operands size)))
 436   (if (zerop size)
 437       #()
 438       (let ((res (make-array size))
 439             (stack (operand-stack)))
 440         (declare (fixnum size))
 441         (let ((ptr (fop-stack-pop-n stack size)))
 442           (replace res stack :start2 ptr))
 443         (logically-readonlyize res))))
 444
 445 ;; No MAKE-ARRAY-HEADER on host
 446 (!define-fop 89 :not-host (fop-array (vec))
 447   (let* ((rank (read-word-arg (fasl-input-stream)))
 448          (length (length vec))
 449          (res (make-array-header sb!vm:simple-array-widetag rank)))
 450     (declare (simple-array vec)
 451              (type (unsigned-byte #.(- sb!vm:n-word-bits sb!vm:n-widetag-bits)) rank))
 452     (set-array-header res vec length nil 0
 453                       (fop-list-from-stack (operand-stack) rank)
 454                       nil t)
 455     res))
 456
 457 (defglobal **saetp-bits-per-length**
 458     (let ((array (make-array (1+ sb!vm:widetag-mask)
 459                              :element-type '(unsigned-byte 8)
 460                              :initial-element 255)))
 461       (loop for saetp across sb!vm:*specialized-array-element-type-properties*
 462             do
 463             (setf (aref array (sb!vm:saetp-typecode saetp))
 464                   (sb!vm:saetp-n-bits saetp)))
 465       array)
 466     "255 means bad entry.")
 467 (declaim (type (simple-array (unsigned-byte 8) (#.(1+ sb!vm:widetag-mask)))
 468                **saetp-bits-per-length**))
 469
 470 ;; No ALLOCATE-VECTOR on host (nor READ-N-BYTES)
 471 (!define-fop 43 :not-host (fop-spec-vector)
 472   (let* ((length (read-word-arg (fasl-input-stream)))
 473          (widetag (read-byte-arg (fasl-input-stream)))
 474          (bits-per-length (aref **saetp-bits-per-length** widetag))
 475          (bits (progn (aver (< bits-per-length 255))
 476                       (* length bits-per-length)))
 477          (bytes (ceiling bits sb!vm:n-byte-bits))
 478          (words (ceiling bytes sb!vm:n-word-bytes))
 479          (vector (if (and (= widetag sb!vm:simple-vector-widetag)
 480                           (= words 0))
 481                      #()
 482                      (logically-readonlyize
 483                       (allocate-vector widetag length words)))))
 484     (declare (type index length bytes words)
 485              (type word bits))
 486     (read-n-bytes (fasl-input-stream) vector 0 bytes)
 487     vector))
 488
 489 (!define-fop 53 (fop-eval (expr)) ; This seems to be unused
 490   (if (skip-until)
 491       expr
 492       (eval expr)))
 493
 494 (!define-fop 54 (fop-eval-for-effect (expr) nil) ; This seems to be unused
 495   (unless (skip-until)
 496     (eval expr))
 497   nil)
 498
 499 (defun fop-funcall* (input-stream stack skipping)
 500  (let ((argc (read-byte-arg input-stream)))
 501    (with-fop-stack ((stack) ptr (1+ argc))
 502      (unless skipping
 503        (do ((i (+ ptr argc))
 504             (args))
 505            ((= i ptr) (apply (fop-stack-ref i) args))
 506          (declare (type index i))
 507          (push (fop-stack-ref i) args)
 508          (decf i))))))
 509
 510 ;; FIXME: there should be a syntax to share these identical bodies
 511 (!define-fop 55 (fop-funcall)
 512   (fop-funcall* (fasl-input-stream) (operand-stack) (skip-until)))
 513 (!define-fop 56 (fop-funcall-for-effect () nil)
 514   (fop-funcall* (fasl-input-stream) (operand-stack) (skip-until)))
 515
 516 ;;; For LOAD-TIME-VALUE which is used for MAKE-LOAD-FORM
 517 (!define-fop 57 (fop-funcall-no-skip)
 518   (fop-funcall* (fasl-input-stream) (operand-stack) nil))
 519 \f
 520 ;;;; fops for fixing up circularities
 521
 522 (!define-fop 200 (fop-rplaca (val) nil)
 523   (let ((obj (ref-fop-table (fasl-input) (read-word-arg (fasl-input-stream))))
 524         (idx (read-word-arg (fasl-input-stream))))
 525     (setf (car (nthcdr idx obj)) val)))
 526
 527 (!define-fop 201 (fop-rplacd (val) nil)
 528   (let ((obj (ref-fop-table (fasl-input) (read-word-arg (fasl-input-stream))))
 529         (idx (read-word-arg (fasl-input-stream))))
 530     (setf (cdr (nthcdr idx obj)) val)))
 531
 532 (!define-fop 202 (fop-svset (val) nil)
 533   (let* ((obi (read-word-arg (fasl-input-stream)))
 534          (obj (ref-fop-table (fasl-input) obi))
 535          (idx (read-word-arg (fasl-input-stream))))
 536     (if (%instancep obj) ; suspicious. should have been FOP-STRUCTSET
 537         #+sb-xc (setf (%instance-ref obj idx) val)
 538         #-sb-xc (bug "%instance-set?")
 539         (setf (svref obj idx) val))))
 540
 541 (!define-fop 204 :not-host (fop-structset (val) nil)
 542   (setf (%instance-ref (ref-fop-table (fasl-input)
 543                                       (read-word-arg (fasl-input-stream)))
 544                        (read-word-arg (fasl-input-stream)))
 545         val))
 546
 547 ;;; In the original CMUCL code, this actually explicitly declared PUSHP
 548 ;;; to be T, even though that's what it defaults to in DEFINE-FOP.
 549 (!define-fop 203 (fop-nthcdr (obj))
 550   (nthcdr (read-word-arg (fasl-input-stream)) obj))
 551 \f
 552 ;;;; fops for loading functions
 553
 554 ;;; (In CMU CL there was a FOP-CODE-FORMAT (47) which was
 555 ;;; conventionally placed at the beginning of each fasl file to test
 556 ;;; for compatibility between the fasl file and the CMU CL which
 557 ;;; loaded it. In SBCL, this functionality has been replaced by
 558 ;;; putting the implementation and version in required fields in the
 559 ;;; fasl file header.)
 560
 561 ;; Cold-load calls COLD-LOAD-CODE instead
 562 (!define-fop #xE0 :not-host (fop-code ((:operands n-code-bytes n-boxed-words nfuns)))
 563   ;; add 1 word for the toplevel-p flag and one for the debug-info
 564   (with-fop-stack ((stack (operand-stack)) ptr (+ n-boxed-words 2))
 565     (load-code nfuns n-boxed-words n-code-bytes stack ptr (fasl-input))))
 566
 567 ;; this gets you an #<fdefn> object, not the result of (FDEFINITION x)
 568 ;; cold-loader uses COLD-FDEFINITION-OBJECT instead.
 569 (!define-fop 60 :not-host (fop-fdefn (name))
 570   (awhen (deprecated-thing-p 'function name) ; returns the stage of deprecation
 571     (pushnew (list* it name :function)
 572              (%fasl-input-deprecated-stuff (fasl-input)) :test 'equal))
 573   (find-or-create-fdefn name))
 574
 575 (!define-fop 65 :not-host (fop-known-fun (name))
 576   (%coerce-name-to-fun name))
 577
 578 #!-(or x86 (and x86-64 (not immobile-space)))
 579 (!define-fop 61 :not-host (fop-sanctify-for-execution (component))
 580   (sb!vm:sanctify-for-execution component)
 581   component)
 582
 583 ;;; Modify a slot in a CONSTANTS object.
 584 (!define-fop 140 :not-host (fop-alter-code ((:operands index) code value) nil)
 585   (setf (code-header-ref code index) value)
 586   (values))
 587
 588 (!define-fop #xFC :not-host (fop-fun-entry ((:operands fun-index)
 589                                             code-object name arglist type info))
 590   (let ((fun (%code-entry-point code-object fun-index)))
 591     (setf (%simple-fun-name fun) name)
 592     (setf (%simple-fun-arglist fun) arglist)
 593     (setf (%simple-fun-type fun) type)
 594     (setf (%simple-fun-info fun) info)
 595     fun))
 596 \f
 597 ;;;; Some Dylan FOPs used to live here. By 1 November 1998 the code
 598 ;;;; was sufficiently stale that the functions it called were no
 599 ;;;; longer defined, so I (William Harold Newman) deleted it.
 600 ;;;;
 601 ;;;; In case someone in the future is trying to make sense of FOP layout,
 602 ;;;; it might be worth recording that the Dylan FOPs were
 603 ;;;;    100 FOP-DYLAN-SYMBOL-SAVE
 604 ;;;;    101 FOP-SMALL-DYLAN-SYMBOL-SAVE
 605 ;;;;    102 FOP-DYLAN-KEYWORD-SAVE
 606 ;;;;    103 FOP-SMALL-DYLAN-KEYWORD-SAVE
 607 ;;;;    104 FOP-DYLAN-VARINFO-VALUE
 608 \f
 609 ;;;; assemblerish fops
 610
 611 (!define-fop 144 (fop-assembler-code)
 612   (error "cannot load assembler code except at cold load"))
 613
 614 (!define-fop 145 (fop-assembler-routine)
 615   (error "cannot load assembler code except at cold load"))
 616
 617 (!define-fop 146 :not-host (fop-symbol-tls-fixup (code-object kind symbol))
 618   (sb!vm:fixup-code-object code-object
 619                            (read-word-arg (fasl-input-stream))
 620                            (ensure-symbol-tls-index symbol)
 621                            kind)
 622   code-object)
 623
 624 #!+immobile-space
 625 (!define-fop 134 :not-host (fop-immobile-obj-fixup (code-object kind obj))
 626   (sb!vm:fixup-code-object code-object
 627                            (read-word-arg (fasl-input-stream))
 628                            (get-lisp-obj-address obj) ; OBJ can't move
 629                            kind :immobile-object)
 630   code-object)
 631
 632 #!+immobile-code
 633 (progn
 634   (!define-fop 133 :not-host (fop-named-call-fixup (code-object kind name))
 635     (sb!vm:fixup-code-object code-object
 636                              (read-word-arg (fasl-input-stream))
 637                              (sb!vm::fdefn-entry-address name)
 638                              kind :named-call)
 639     code-object)
 640
 641   (!define-fop 135 :not-host (fop-static-call-fixup (code-object kind name))
 642     (sb!vm:fixup-code-object code-object
 643                              (read-word-arg (fasl-input-stream))
 644                              (sb!vm::function-raw-address name)
 645                              kind)
 646     code-object))
 647
 648 (!define-fop 147 :not-host (fop-foreign-fixup (code-object kind))
 649   (let* ((len (read-byte-arg (fasl-input-stream)))
 650          (sym (make-string len :element-type 'base-char)))
 651     (read-n-bytes (fasl-input-stream) sym 0 len)
 652     (sb!vm:fixup-code-object code-object
 653                              (read-word-arg (fasl-input-stream))
 654                              (foreign-symbol-address sym)
 655                              kind)
 656     code-object))
 657
 658 (!define-fop 148 :not-host (fop-assembler-fixup (code-object kind routine))
 659   (multiple-value-bind (value found) (gethash routine *assembler-routines*)
 660     (unless found
 661       (error "undefined assembler routine: ~S" routine))
 662     (sb!vm:fixup-code-object code-object (read-word-arg (fasl-input-stream))
 663                              value kind))
 664   code-object)
 665
 666 (!define-fop 149 :not-host (fop-code-object-fixup (code-object kind))
 667     ;; Note: We don't have to worry about GC moving the code-object after
 668     ;; the GET-LISP-OBJ-ADDRESS and before that value is deposited, because
 669     ;; we can only use code-object fixups when code-objects don't move.
 670   (sb!vm:fixup-code-object code-object (read-word-arg (fasl-input-stream))
 671                            (get-lisp-obj-address code-object) kind)
 672   code-object)
 673
 674 #!+linkage-table
 675 (!define-fop 150 :not-host (fop-foreign-dataref-fixup (code-object kind))
 676   (let* ((len (read-byte-arg (fasl-input-stream)))
 677          (sym (make-string len :element-type 'base-char)))
 678     (read-n-bytes (fasl-input-stream) sym 0 len)
 679     (sb!vm:fixup-code-object code-object
 680                              (read-word-arg (fasl-input-stream))
 681                              (foreign-symbol-address sym t)
 682                              kind)
 683     code-object))
 684
 685 ;;; FOPs needed for implementing an IF operator in a FASL
 686
 687 ;;; Skip until a FOP-MAYBE-STOP-SKIPPING with the same POSITION is
 688 ;;; executed. While skipping, we execute most FOPs normally, except
 689 ;;; for ones that a) funcall/eval b) start skipping. This needs to
 690 ;;; be done to ensure that the fop table gets populated correctly
 691 ;;; regardless of the execution path.
 692 (!define-fop 151 (fop-skip (position) nil)
 693   (unless (skip-until)
 694     (setf (skip-until) position))
 695   (values))
 696
 697 ;;; As before, but only start skipping if the top of the FOP stack is NIL.
 698 (!define-fop 152 (fop-skip-if-false (position condition) nil)
 699   (unless (or condition (skip-until))
 700     (setf (skip-until) position))
 701   (values))
 702
 703 ;;; If skipping, pop the top of the stack and discard it. Needed for
 704 ;;; ensuring that the stack stays balanced when skipping.
 705 (!define-fop 153 (fop-drop-if-skipping () nil)
 706   (when (skip-until)
 707     (fop-stack-pop-n (operand-stack) 1))
 708   (values))
 709
 710 ;;; If skipping, push a dummy value on the stack. Needed for
 711 ;;; ensuring that the stack stays balanced when skipping.
 712 (!define-fop 154 (fop-push-nil-if-skipping () nil)
 713   (when (skip-until)
 714     (push-fop-stack nil (fasl-input)))
 715   (values))
 716
 717 ;;; Stop skipping if the top of the stack matches SKIP-UNTIL
 718 (!define-fop 155 (fop-maybe-stop-skipping (label) nil)
 719   (when (eql (skip-until) label)
 720     (setf (skip-until) nil))
 721   (values))
 722
 723 ;;; Primordial layouts.
 724 (macrolet ((frob (&rest specs)
 725              `(progn
 726                 (defun known-layout-fop (name)
 727                   (case name
 728                     ,@(mapcar (lambda (spec) `((,(cadr spec)) ,(car spec)))
 729                               specs)))
 730                 ,@(mapcar (lambda (spec)
 731                             `(!define-fop ,(car spec)
 732                                           (,(symbolicate "FOP-LAYOUT-OF-"
 733                                                          (cadr spec)))
 734                                           (find-layout ',(cadr spec))))
 735                           specs))))
 736   (frob (#x6c t)
 737         (#x6d structure-object)
 738         (#x6f definition-source-location)
 739         (#x70 sb!c::debug-fun)
 740         (#x71 sb!c::compiled-debug-fun)
 741         (#x72 sb!c::debug-info)
 742         (#x73 sb!c::compiled-debug-info)
 743         (#x74 sb!c::debug-source)
 744         (#x75 defstruct-description)
 745         (#x76 defstruct-slot-description)))