src/code/signal.lisp

   1 ;;;; handling UNIX signals
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!UNIX")
  13 \f
  14 ;;;; macros for dynamically enabling and disabling signal handling
  15
  16 ;;; Notes on how the without-interrupts/with-interrupts stuff works:
  17 ;;;
  18 ;;; Before invoking the supplied handler for any of the signals that
  19 ;;; can be blocked, the C interrupt support code checks to see whether
  20 ;;; *interrupts-enabled* has been bound to NIL. If so, it saves the
  21 ;;; signal number and the value of the signal mask (from the signal
  22 ;;; context), sets the signal mask to block all blockable signals,
  23 ;;; sets *interrupt-pending* and returns without handling the signal.
  24 ;;;
  25 ;;; When we drop out the without interrupts, we check to see whether
  26 ;;; *INTERRUPT-PENDING* has been set. If so, we call
  27 ;;; RECEIVE-PENDING-INTERRUPT, which generates a SIGTRAP. The C code
  28 ;;; invokes the handler for the saved signal instead of the SIGTRAP
  29 ;;; after replacing the signal mask in the signal context with the
  30 ;;; saved value. When that hander returns, the original signal mask is
  31 ;;; installed, allowing any other pending signals to be handled.
  32 ;;;
  33 ;;; This means that the cost of WITHOUT-INTERRUPTS is just a special
  34 ;;; binding in the case when no signals are delivered (the normal
  35 ;;; case). It's only when a signal is actually delivered that we use
  36 ;;; any system calls, and by then the cost of the extra system calls
  37 ;;; are lost in the noise when compared with the cost of delivering
  38 ;;; the signal in the first place.
  39 ;;;
  40 ;;; The conditional bindings done by this code here are worth the
  41 ;;; trouble as binding is more expensive then read & test -- so
  42 ;;;  (if *foo*
  43 ;;;      (foo)
  44 ;;;      (let ((*foo* t))
  45 ;;;        (foo)))
  46 ;;; is faster then
  47 ;;;  (let ((*foo* t))
  48 ;;;    (foo))
  49 ;;; provided that the first branch is true "often enough".
  50
  51 (!defvar *interrupts-enabled* t)
  52 (!defvar *interrupt-pending* nil)
  53 #!+sb-thruption (!defvar *thruption-pending* nil)
  54 (!defvar *allow-with-interrupts* t)
  55 ;;; This is to support signal handlers that want to return to the
  56 ;;; interrupted context without leaving anything extra on the stack. A
  57 ;;; simple
  58 ;;;
  59 ;;;  (without-interrupts
  60 ;;;   (unblock-deferrable-signals)
  61 ;;;   (allow-with-interrupts ...))
  62 ;;;
  63 ;;; would not cut it, as upon leaving WITHOUT-INTERRUPTS the pending
  64 ;;; handlers is run with stuff from the function in which this is
  65 ;;; still on the stack.
  66 (!defvar *unblock-deferrables-on-enabling-interrupts-p* nil)
  67
  68 (defmacro without-interrupts (&body body)
  69   "Executes BODY with all deferrable interrupts disabled. Deferrable
  70 interrupts arriving during execution of the BODY take effect after BODY has
  71 been executed.
  72
  73 Deferrable interrupts include most blockable POSIX signals, and
  74 SB-THREAD:INTERRUPT-THREAD. Does not interfere with garbage collection, and
  75 unlike in many traditional Lisps using userspace threads, in SBCL
  76 WITHOUT-INTERRUPTS does not inhibit scheduling of other threads.
  77
  78 Binds ALLOW-WITH-INTERRUPTS and WITH-LOCAL-INTERRUPTS as a local macros.
  79
  80 ALLOW-WITH-INTERRUPTS allows the WITH-INTERRUPTS to take effect during the
  81 dynamic scope of its body, unless there is an outer WITHOUT-INTERRUPTS without
  82 a corresponding ALLOW-WITH-INTERRUPTS.
  83
  84 WITH-LOCAL-INTERRUPTS executes its body with interrupts enabled provided that
  85 for there is an ALLOW-WITH-INTERRUPTS for every WITHOUT-INTERRUPTS surrounding
  86 the current one. WITH-LOCAL-INTERRUPTS is equivalent to:
  87
  88   (allow-with-interrupts (with-interrupts ...))
  89
  90 Care must be taken not to let either ALLOW-WITH-INTERRUPTS or
  91 WITH-LOCAL-INTERRUPTS appear in a function that escapes from inside the
  92 WITHOUT-INTERRUPTS in:
  93
  94   (without-interrupts
  95     ;; The body of the lambda would be executed with WITH-INTERRUPTS allowed
  96     ;; regardless of the interrupt policy in effect when it is called.
  97     (lambda () (allow-with-interrupts ...)))
  98
  99   (without-interrupts
 100     ;; The body of the lambda would be executed with interrupts enabled
 101     ;; regardless of the interrupt policy in effect when it is called.
 102     (lambda () (with-local-interrupts ...)))
 103 "
 104   (with-unique-names (outer-allow-with-interrupts without-interrupts-body)
 105     `(dx-flet ((,without-interrupts-body ()
 106               (declare (disable-package-locks allow-with-interrupts
 107                                               with-local-interrupts))
 108               (macrolet
 109                   ((allow-with-interrupts
 110                      (&body allow-forms)
 111                      `(let ((*allow-with-interrupts*
 112                              ,',outer-allow-with-interrupts))
 113                         ,@allow-forms))
 114                    (with-local-interrupts
 115                      (&body with-forms)
 116                      `(let ((*allow-with-interrupts*
 117                              ,',outer-allow-with-interrupts)
 118                             (*interrupts-enabled*
 119                              ,',outer-allow-with-interrupts))
 120                         (when ,',outer-allow-with-interrupts
 121                           (when *unblock-deferrables-on-enabling-interrupts-p*
 122                             (setq *unblock-deferrables-on-enabling-interrupts-p*
 123                                   nil)
 124                             (sb!unix::unblock-deferrable-signals))
 125                           (when (or *interrupt-pending*
 126                                     #!+sb-thruption *thruption-pending*)
 127                             (receive-pending-interrupt)))
 128                         (locally ,@with-forms))))
 129                 (let ((*interrupts-enabled* nil)
 130                       (,outer-allow-with-interrupts *allow-with-interrupts*)
 131                       (*allow-with-interrupts* nil))
 132                   (declare (ignorable ,outer-allow-with-interrupts))
 133                   (declare (enable-package-locks allow-with-interrupts
 134                                                  with-local-interrupts))
 135                   ,@body))))
 136        (if *interrupts-enabled*
 137            (unwind-protect
 138                 (,without-interrupts-body)
 139              ;; If we were interrupted in the protected section,
 140              ;; then the interrupts are still blocked and it remains
 141              ;; so until the pending interrupt is handled.
 142              ;;
 143              ;; If we were not interrupted in the protected section,
 144              ;; but here, then even if the interrupt handler enters
 145              ;; another WITHOUT-INTERRUPTS, the pending interrupt will be
 146              ;; handled immediately upon exit from said
 147              ;; WITHOUT-INTERRUPTS, so it is as if nothing has happened.
 148              (when (or *interrupt-pending*
 149                        #!+sb-thruption *thruption-pending*)
 150                (receive-pending-interrupt)))
 151            (,without-interrupts-body)))))
 152
 153 (defmacro with-interrupts (&body body)
 154   "Executes BODY with deferrable interrupts conditionally enabled. If there
 155 are pending interrupts they take effect prior to executing BODY.
 156
 157 As interrupts are normally allowed WITH-INTERRUPTS only makes sense if there
 158 is an outer WITHOUT-INTERRUPTS with a corresponding ALLOW-WITH-INTERRUPTS:
 159 interrupts are not enabled if any outer WITHOUT-INTERRUPTS is not accompanied
 160 by ALLOW-WITH-INTERRUPTS."
 161   (with-unique-names (allowp enablep)
 162     ;; We could manage without ENABLEP here, but that would require
 163     ;; taking extra care not to ever have *ALLOW-WITH-INTERRUPTS* NIL
 164     ;; and *INTERRUPTS-ENABLED* T -- instead of risking future breakage
 165     ;; we take the tiny hit here.
 166     `(let* ((,allowp *allow-with-interrupts*)
 167             (,enablep *interrupts-enabled*)
 168             (*interrupts-enabled* (or ,enablep ,allowp)))
 169        (when (and ,allowp (not ,enablep))
 170          (when *unblock-deferrables-on-enabling-interrupts-p*
 171            (setq *unblock-deferrables-on-enabling-interrupts-p* nil)
 172            (sb!unix::unblock-deferrable-signals))
 173          (when (or *interrupt-pending*
 174                    #!+sb-thruption *thruption-pending*)
 175            (receive-pending-interrupt)))
 176        (locally ,@body))))
 177
 178 (defmacro allow-with-interrupts (&body body)
 179   (declare (ignore body))
 180   (error "~S is valid only inside ~S."
 181          'allow-with-interrupts 'without-interrupts))
 182
 183 (defmacro with-local-interrupts (&body body)
 184   (declare (ignore body))
 185   (error "~S is valid only inside ~S."
 186          'with-local-interrupts 'without-interrupts))
 187
 188 ;;; A low-level operation that assumes that *INTERRUPTS-ENABLED* is
 189 ;;; false, *ALLOW-WITH-INTERRUPTS* is true and deferrable signals are
 190 ;;; unblocked.
 191 (defun %check-interrupts ()
 192   ;; Here we check for pending interrupts first, because reading a
 193   ;; special is faster then binding it!
 194   (when (or *interrupt-pending* #!+sb-thruption *thruption-pending*)
 195     (let ((*interrupts-enabled* t))
 196       (receive-pending-interrupt))))