src/code/target-extensions.lisp

   1 ;;;; This file contains things for the extensions packages (SB-EXT and
   2 ;;;; also "internal extensions" SB-INT) which can't be built at
   3 ;;;; cross-compile time, and perhaps also some things which might as
   4 ;;;; well not be built at cross-compile time because they're not
   5 ;;;; needed then. Things which can't be built at cross-compile time
   6 ;;;; (e.g. because they need machinery which only exists inside SBCL's
   7 ;;;; implementation of the LISP package) do not belong in this file.
   8
   9 ;;;; This software is part of the SBCL system. See the README file for
  10 ;;;; more information.
  11 ;;;;
  12 ;;;; This software is derived from the CMU CL system, which was
  13 ;;;; written at Carnegie Mellon University and released into the
  14 ;;;; public domain. The software is in the public domain and is
  15 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  16 ;;;; files for more information.
  17
  18 (in-package "SB!IMPL")
  19 \f
  20 ;;;; variables initialization and shutdown sequences
  21
  22 ;;; (Most of the save-a-core functionality is defined later, in its
  23 ;;; own file, but we'd like to have these symbols declared special and
  24 ;;; initialized ASAP.)
  25
  26 (declaim (type list *save-hooks* *init-hooks* *exit-hooks*))
  27
  28 (defvar *save-hooks* nil
  29   #!+sb-doc
  30   "A list of function designators which are called in an unspecified
  31 order before creating a saved core image.
  32
  33 Unused by SBCL itself: reserved for user and applications.")
  34
  35 (defvar *init-hooks* nil
  36   #!+sb-doc
  37   "A list of function designators which are called in an unspecified
  38 order when a saved core image starts up, after the system itself has
  39 been initialized.
  40
  41 Unused by SBCL itself: reserved for user and applications.")
  42
  43 (defvar *exit-hooks* nil
  44   #!+sb-doc
  45   "A list of function designators which are called in an unspecified
  46 order when SBCL process exits.
  47
  48 Unused by SBCL itself: reserved for user and applications.
  49
  50 Using (SB-EXT:EXIT :ABORT T), or calling exit(3) directly circumvents
  51 these hooks.")
  52
  53 \f
  54 ;;; Binary search for simple vectors
  55 (defun binary-search (value seq &key (key #'identity))
  56   (declare (simple-vector seq))
  57   (labels ((recurse (start end)
  58              (when (< start end)
  59                (let* ((i (+ start (truncate (- end start) 2)))
  60                       (elt (svref seq i))
  61                       (key-value (funcall key elt)))
  62                  (cond ((< value key-value)
  63                         (recurse start i))
  64                        ((> value key-value)
  65                         (recurse (1+ i) end))
  66                        (t
  67                         elt))))))
  68     (recurse 0 (length seq))))
  69
  70 (defun double-vector-binary-search (value vector)
  71   (declare (simple-vector vector)
  72            (optimize speed)
  73            (integer value))
  74   (labels ((recurse (start end)
  75              (declare (type index start end))
  76              (when (< start end)
  77                (let* ((i (+ start (truncate (- end start) 2)))
  78                       (elt (svref vector (truly-the index (* 2 i)))))
  79                  (declare (type integer elt)
  80                           (type index i))
  81                  (cond ((< value elt)
  82                         (recurse start i))
  83                        ((> value elt)
  84                         (recurse (1+ i) end))
  85                        (t
  86                         (svref vector (truly-the index (1+ (* 2 i))))))))))
  87     (recurse 0 (truncate (length vector) 2))))
  88
  89 \f
  90 ;;;; helpers for C library calls
  91
  92 ;;; Signal a SIMPLE-CONDITION/ERROR condition associated with an ANSI C
  93 ;;; errno problem, arranging for the condition's print representation
  94 ;;; to be similar to the ANSI C perror(3) style.
  95 (defun simple-perror (prefix-string
  96                       &key
  97                       (errno (get-errno))
  98                       (simple-error 'simple-error)
  99                       other-condition-args)
 100   (declare (type symbol simple-error))
 101   (aver (subtypep simple-error 'simple-condition))
 102   (aver (subtypep simple-error 'error))
 103   (apply #'error
 104          simple-error
 105          :format-control "~@<~A: ~2I~_~A~:>"
 106          :format-arguments (list prefix-string (strerror errno))
 107          other-condition-args))
 108
 109 ;;; Constructing shortish strings one character at a time. More efficient then
 110 ;;; a string-stream, as can directly use simple-base-strings when applicable,
 111 ;;; and if the maximum size is know doesn't need to copy the result at all --
 112 ;;; but if the result is going to be HUGE, string-streams will win.
 113 (defmacro with-push-char ((&key (element-type 'character) (initial-size 28)) &body body)
 114   (with-unique-names (string size pointer)
 115     `(let* ((,size ,initial-size)
 116             (,string (make-array ,size :element-type ',element-type))
 117             (,pointer 0))
 118        (declare (type (integer 0 ,sb!xc:array-dimension-limit) ,size)
 119                 (type (integer 0 ,(1- sb!xc:array-dimension-limit)) ,pointer)
 120                 (type (simple-array ,element-type (*)) ,string))
 121        (flet ((push-char (char)
 122                 (declare (optimize (sb!c::insert-array-bounds-checks 0)))
 123                 (when (= ,pointer ,size)
 124                   (let ((old ,string))
 125                     (setf ,size (* 2 (+ ,size 2))
 126                           ,string (make-array ,size :element-type ',element-type))
 127                     (replace ,string old)))
 128                 (setf (char ,string ,pointer) char)
 129                 (incf ,pointer))
 130               (get-pushed-string ()
 131                 (let ((string ,string)
 132                       (size ,pointer))
 133                   (setf ,size 0
 134                         ,pointer 0
 135                         ,string ,(coerce "" `(simple-array ,element-type (*))))
 136                   ;; This is really local, so we can be destructive!
 137                   (%shrink-vector string size)
 138                   string)))
 139          ,@body))))
 140
 141 ;;; The smallest power of two that is equal to or greater than X.
 142 (defun power-of-two-ceiling (x)
 143   (declare (index x))
 144   (ash 1 (integer-length (1- x))))