tests/foreign-stack-alignment.impure.lisp

   1 ;;;; Testing the stack alignment of foreign calls. Uses stack-alignment-offset.c.
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; While most of SBCL is derived from the CMU CL system, the test
   7 ;;;; files (like this one) were written from scratch after the fork
   8 ;;;; from CMU CL.
   9 ;;;;
  10 ;;;; This software is in the public domain and is provided with
  11 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  12 ;;;; more information.
  13
  14 (use-package :sb-alien)
  15
  16 ;;; Callbacks are not part of the exported interface yet -- when they are this can
  17 ;;; go away.
  18 (import 'sb-alien::alien-lambda)
  19
  20 (defun run (program &rest arguments)
  21   (let* ((proc nil)
  22          (output
  23           (with-output-to-string (s)
  24             (setf proc (run-program program arguments
  25                                     :output s)))))
  26     (unless (zerop (process-exit-code proc))
  27       (error "Bad exit code: ~S~%Output:~% ~S"
  28              (process-exit-code proc)
  29              output))
  30     output))
  31
  32 (defvar *required-alignment*
  33   #+arm 8
  34   #+mips 8
  35   #+(and ppc darwin) 16
  36   #+(and ppc (not darwin)) 8
  37   #+(or arm64 x86-64) 16
  38   #+(and x86 (not darwin)) 4
  39   #+(and x86 darwin) 16
  40   #+sparc 8
  41   #+alpha 16
  42   #+hppa 64
  43   #-(or arm arm64 x86 x86-64 mips ppc sparc alpha hppa)
  44   (error "Unknown platform"))
  45
  46 ;;;; Build the offset-tool as regular excutable, and run it with
  47 ;;;; fork/exec, so that no lisp is on the stack. This is our known-good
  48 ;;;; number.
  49
  50 #-win32
  51 (progn
  52   (run "/bin/sh" "run-compiler.sh" "-sbcl-pic"
  53        "stack-alignment-offset.c" "-o" "stack-alignment-offset")
  54
  55   (defparameter *good-offset*
  56     (parse-integer (run "./stack-alignment-offset"
  57                         (princ-to-string *required-alignment*))))
  58
  59   ;; Build the tool again, this time as a shared object, and load it
  60
  61   (run "/bin/sh" "run-compiler.sh" "-sbcl-pic" "-sbcl-shared"
  62        "stack-alignment-offset.c" "-o" "stack-alignment-offset.so")
  63
  64   (load-shared-object (truename "stack-alignment-offset.so"))
  65
  66   (define-alien-routine stack-alignment-offset int (alignment int))
  67   #+alien-callbacks
  68   (define-alien-routine trampoline int (callback (function int))))
  69
  70 ;;;; Now get the offset by calling from lisp, first with a regular foreign function
  71 ;;;; call, then with an intervening callback.
  72
  73 (with-test (:name :regular :fails-on :win32)
  74   (assert (= *good-offset* (stack-alignment-offset *required-alignment*))))
  75
  76 #+alien-callbacks
  77 (with-test (:name :callback :fails-on :win32)
  78   (assert (= *good-offset*
  79              (trampoline (alien-lambda int ()
  80                            (stack-alignment-offset *required-alignment*))))))
  81
  82 (when (probe-file "stack-alignment-offset.so")
  83   (delete-file "stack-alignment-offset")
  84   (delete-file "stack-alignment-offset.so"))
  85
  86 ;;;; success!