src/code/target-alieneval.lisp

   1 ;;;; This file contains parts of the ALIEN implementation that
   2 ;;;; are not part of the compiler.
   3
   4 ;;;; This software is part of the SBCL system. See the README file for
   5 ;;;; more information.
   6 ;;;;
   7 ;;;; This software is derived from the CMU CL system, which was
   8 ;;;; written at Carnegie Mellon University and released into the
   9 ;;;; public domain. The software is in the public domain and is
  10 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  11 ;;;; files for more information.
  12
  13 (in-package "SB!ALIEN")
  14
  15 (/show0 "target-alieneval.lisp 15")
  16 \f
  17 ;;;; alien variables
  18
  19 ;;; Make a string out of the symbol, converting all uppercase letters to
  20 ;;; lower case and hyphens into underscores.
  21 (eval-when (:compile-toplevel :load-toplevel :execute)
  22   (defun guess-alien-name-from-lisp-name (lisp-name)
  23     (declare (type symbol lisp-name))
  24     (nsubstitute #\_ #\- (string-downcase (symbol-name lisp-name)))))
  25
  26 ;;; The opposite of GUESS-ALIEN-NAME-FROM-LISP-NAME. Make a symbol out
  27 ;;; of the string, converting all lowercase letters to uppercase and
  28 ;;; underscores into hyphens.
  29 (eval-when (:compile-toplevel :load-toplevel :execute)
  30   (defun guess-lisp-name-from-alien-name (alien-name)
  31     (declare (type simple-string alien-name))
  32     (intern (nsubstitute #\- #\_ (string-upcase alien-name)))))
  33
  34 ;;; Extract the Lisp and alien names from NAME. If only one is given,
  35 ;;; guess the other.
  36 (eval-when (:compile-toplevel :load-toplevel :execute)
  37   (defun pick-lisp-and-alien-names (name)
  38     (etypecase name
  39       (string
  40        (values (guess-lisp-name-from-alien-name name) name))
  41       (symbol
  42        (values name (guess-alien-name-from-lisp-name name)))
  43       (list
  44        (unless (proper-list-of-length-p name 2)
  45          (error "badly formed alien name"))
  46        (values (cadr name) (car name))))))
  47
  48 (defmacro define-alien-variable (name type &environment env)
  49   #!+sb-doc
  50   "Define NAME as an external alien variable of type TYPE. NAME should be
  51    a list of a string holding the alien name and a symbol to use as the Lisp
  52    name. If NAME is just a symbol or string, then the other name is guessed
  53    from the one supplied."
  54   (multiple-value-bind (lisp-name alien-name) (pick-lisp-and-alien-names name)
  55     (with-auxiliary-alien-types env
  56       (let ((alien-type (parse-alien-type type env)))
  57         `(eval-when (:compile-toplevel :load-toplevel :execute)
  58            ,@(when *new-auxiliary-types*
  59                `((%def-auxiliary-alien-types ',*new-auxiliary-types*)))
  60            (%define-alien-variable ',lisp-name
  61                                    ',alien-name
  62                                    ',alien-type))))))
  63
  64 (defmacro def-alien-variable (&rest rest)
  65   (deprecation-warning 'def-alien-variable 'define-alien-variable)
  66   `(define-alien-variable ,@rest))
  67
  68 ;;; Do the actual work of DEFINE-ALIEN-VARIABLE.
  69 (eval-when (:compile-toplevel :load-toplevel :execute)
  70   (defun %define-alien-variable (lisp-name alien-name type)
  71     (setf (info :variable :kind lisp-name) :alien)
  72     (setf (info :variable :where-from lisp-name) :defined)
  73     (clear-info :variable :constant-value lisp-name)
  74     (setf (info :variable :alien-info lisp-name)
  75           (make-heap-alien-info :type type
  76                                 :sap-form `(foreign-symbol-sap ',alien-name t)))))
  77
  78 (defmacro extern-alien (name type &environment env)
  79   #!+sb-doc
  80   "Access the alien variable named NAME, assuming it is of type TYPE. This
  81    is SETFable."
  82   (let* ((alien-name (etypecase name
  83                        (symbol (guess-alien-name-from-lisp-name name))
  84                        (string name)))
  85          (alien-type (parse-alien-type type env))
  86          (datap (not (alien-fun-type-p alien-type))))
  87     `(%heap-alien ',(make-heap-alien-info
  88                      :type alien-type
  89                      :sap-form `(foreign-symbol-sap ',alien-name ,datap)))))
  90
  91 (defmacro with-alien (bindings &body body &environment env)
  92   #!+sb-doc
  93   "Establish some local alien variables. Each BINDING is of the form:
  94      VAR TYPE [ ALLOCATION ] [ INITIAL-VALUE | EXTERNAL-NAME ]
  95    ALLOCATION should be one of:
  96      :LOCAL (the default)
  97        The alien is allocated on the stack, and has dynamic extent.
  98      :STATIC
  99        The alien is allocated on the heap, and has infinite extent. The alien
 100        is allocated at load time, so the same piece of memory is used each time
 101        this form executes.
 102      :EXTERN
 103        No alien is allocated, but VAR is established as a local name for
 104        the external alien given by EXTERNAL-NAME."
 105   (/show "entering WITH-ALIEN" bindings)
 106   (with-auxiliary-alien-types env
 107     (dolist (binding (reverse bindings))
 108       (/show binding)
 109       (destructuring-bind
 110           (symbol type &optional (opt1 nil opt1p) (opt2 nil opt2p))
 111           binding
 112         (/show symbol type opt1 opt2)
 113         (let* ((alien-type (parse-alien-type type env))
 114                (datap (not (alien-fun-type-p alien-type))))
 115           (/show alien-type)
 116           (multiple-value-bind (allocation initial-value)
 117               (if opt2p
 118                   (values opt1 opt2)
 119                   (case opt1
 120                     (:extern
 121                      (values opt1 (guess-alien-name-from-lisp-name symbol)))
 122                     (:static
 123                      (values opt1 nil))
 124                     (t
 125                      (values :local opt1))))
 126             (/show allocation initial-value)
 127             (setf body
 128                   (ecase allocation
 129                     #+nil
 130                     (:static
 131                      (let ((sap
 132                             (make-symbol (concatenate 'string "SAP-FOR-"
 133                                                       (symbol-name symbol)))))
 134                        `((let ((,sap (load-time-value (%make-alien ...))))
 135                            (declare (type system-area-pointer ,sap))
 136                            (symbol-macrolet
 137                             ((,symbol (sap-alien ,sap ,type)))
 138                             ,@(when initial-value
 139                                 `((setq ,symbol ,initial-value)))
 140                             ,@body)))))
 141                     (:extern
 142                      (/show0 ":EXTERN case")
 143                      (let ((info (make-heap-alien-info
 144                                   :type alien-type
 145                                   :sap-form `(foreign-symbol-sap ',initial-value
 146                                                                  ,datap))))
 147                        `((symbol-macrolet
 148                           ((,symbol (%heap-alien ',info)))
 149                           ,@body))))
 150                     (:local
 151                      (/show0 ":LOCAL case")
 152                      (let ((var (gensym))
 153                            (initval (if initial-value (gensym)))
 154                            (info (make-local-alien-info :type alien-type)))
 155                        (/show var initval info)
 156                        `((let ((,var (make-local-alien ',info))
 157                                ,@(when initial-value
 158                                    `((,initval ,initial-value))))
 159                            (note-local-alien-type ',info ,var)
 160                            (multiple-value-prog1
 161                                (symbol-macrolet
 162                                 ((,symbol (local-alien ',info ,var)))
 163                                 ,@(when initial-value
 164                                     `((setq ,symbol ,initval)))
 165                                 ,@body)
 166                                (dispose-local-alien ',info ,var))))))))))))
 167     (/show "revised" body)
 168     (verify-local-auxiliaries-okay)
 169     (/show0 "back from VERIFY-LOCAL-AUXILIARIES-OK, returning")
 170     `(symbol-macrolet ((&auxiliary-type-definitions&
 171                         ,(append *new-auxiliary-types*
 172                                  (auxiliary-type-definitions env))))
 173        ,@body)))
 174 \f
 175 ;;;; runtime C values that don't correspond directly to Lisp types
 176
 177 ;;; Note: The DEFSTRUCT for ALIEN-VALUE lives in a separate file
 178 ;;; 'cause it has to be real early in the cold-load order.
 179 #!-sb-fluid (declaim (freeze-type alien-value))
 180 (def!method print-object ((value alien-value) stream)
 181   (print-unreadable-object (value stream)
 182     (format stream
 183             "~S ~S #X~8,'0X ~S ~S"
 184             'alien-value
 185             :sap (sap-int (alien-value-sap value))
 186             :type (unparse-alien-type (alien-value-type value)))))
 187
 188 #!-sb-fluid (declaim (inline null-alien))
 189 (defun null-alien (x)
 190   #!+sb-doc
 191   "Return true if X (which must be an ALIEN pointer) is null, false otherwise."
 192   (zerop (sap-int (alien-sap x))))
 193
 194 (defmacro sap-alien (sap type &environment env)
 195   #!+sb-doc
 196   "Convert the system area pointer SAP to an ALIEN of the specified TYPE (not
 197    evaluated.) TYPE must be pointer-like."
 198   (let ((alien-type (parse-alien-type type env)))
 199     (if (eq (compute-alien-rep-type alien-type) 'system-area-pointer)
 200         `(%sap-alien ,sap ',alien-type)
 201         (error "cannot make an alien of type ~S out of a SAP" type))))
 202
 203 (defun %sap-alien (sap type)
 204   (declare (type system-area-pointer sap)
 205            (type alien-type type))
 206   (make-alien-value :sap sap :type type))
 207
 208 (defun alien-sap (alien)
 209   #!+sb-doc
 210   "Return a System-Area-Pointer pointing to Alien's data."
 211   (declare (type alien-value alien))
 212   (alien-value-sap alien))
 213 \f
 214 ;;;; allocation/deallocation of heap aliens
 215
 216 (defmacro make-alien (type &optional size &environment env)
 217   #!+sb-doc
 218   "Allocate an alien of type TYPE and return an alien pointer to it. If SIZE
 219 is supplied, how it is interpreted depends on TYPE. If TYPE is an array type,
 220 SIZE is used as the first dimension for the allocated array. If TYPE is not an
 221 array, then SIZE is the number of elements to allocate. The memory is
 222 allocated using ``malloc'', so it can be passed to foreign functions which use
 223 ``free''."
 224   (let ((alien-type (if (alien-type-p type)
 225                         type
 226                         (parse-alien-type type env))))
 227     (multiple-value-bind (size-expr element-type)
 228         (if (alien-array-type-p alien-type)
 229             (let ((dims (alien-array-type-dimensions alien-type)))
 230               (cond
 231                 (size
 232                  (unless dims
 233                    (error
 234                     "cannot override the size of zero-dimensional arrays"))
 235                  (when (constantp size)
 236                    (setf alien-type (copy-alien-array-type alien-type))
 237                    (setf (alien-array-type-dimensions alien-type)
 238                          (cons (constant-form-value size) (cdr dims)))))
 239                 (dims
 240                  (setf size (car dims)))
 241                 (t
 242                  (setf size 1)))
 243               (values `(* ,size ,@(cdr dims))
 244                       (alien-array-type-element-type alien-type)))
 245             (values (or size 1) alien-type))
 246       (let ((bits (alien-type-bits element-type))
 247             (alignment (alien-type-alignment element-type)))
 248         (unless bits
 249           (error "The size of ~S is unknown."
 250                  (unparse-alien-type element-type)))
 251         (unless alignment
 252           (error "The alignment of ~S is unknown."
 253                  (unparse-alien-type element-type)))
 254         ;; This is the one place where the %SAP-ALIEN note is quite
 255         ;; undesirable, in most uses of MAKE-ALIEN the %SAP-ALIEN
 256         ;; cannot be optimized away.
 257         `(locally (declare (muffle-conditions compiler-note))
 258            (%sap-alien (%make-alien (* ,(align-offset bits alignment)
 259                                        ,size-expr))
 260                        ',(make-alien-pointer-type :to alien-type)))))))
 261
 262 ;;; Allocate a block of memory at least BITS bits long and return a
 263 ;;; system area pointer to it.
 264 #!-sb-fluid (declaim (inline %make-alien))
 265 (defun %make-alien (bits)
 266   (declare (type index bits))
 267   (alien-funcall (extern-alien "malloc"
 268                                (function system-area-pointer unsigned))
 269                  (ash (the index (+ bits 7)) -3)))
 270
 271 #!-sb-fluid (declaim (inline free-alien))
 272 (defun free-alien (alien)
 273   #!+sb-doc
 274   "Dispose of the storage pointed to by ALIEN. ALIEN must have been allocated
 275    by MAKE-ALIEN or malloc(3)."
 276   (alien-funcall (extern-alien "free" (function (values) system-area-pointer))
 277                  (alien-sap alien))
 278   nil)
 279 \f
 280 ;;;; the SLOT operator
 281
 282 ;;; Find the field named SLOT, or die trying.
 283 (defun slot-or-lose (type slot)
 284   (declare (type alien-record-type type)
 285            (type symbol slot))
 286   (or (find slot (alien-record-type-fields type)
 287             :key #'alien-record-field-name)
 288       (error "There is no slot named ~S in ~S." slot type)))
 289
 290 ;;; Extract the value from the named slot from the record ALIEN. If
 291 ;;; ALIEN is actually a pointer, then DEREF it first.
 292 (defun slot (alien slot)
 293   #!+sb-doc
 294   "Extract SLOT from the Alien STRUCT or UNION ALIEN. May be set with SETF."
 295   (declare (type alien-value alien)
 296            (type symbol slot)
 297            (optimize (inhibit-warnings 3)))
 298   (let ((type (alien-value-type alien)))
 299     (etypecase type
 300       (alien-pointer-type
 301        (slot (deref alien) slot))
 302       (alien-record-type
 303        (let ((field (slot-or-lose type slot)))
 304          (extract-alien-value (alien-value-sap alien)
 305                               (alien-record-field-offset field)
 306                               (alien-record-field-type field)))))))
 307
 308 ;;; Deposit the value in the specified slot of the record ALIEN. If
 309 ;;; the ALIEN is really a pointer, DEREF it first. The compiler uses
 310 ;;; this when it can't figure out anything better.
 311 (defun %set-slot (alien slot value)
 312   (declare (type alien-value alien)
 313            (type symbol slot)
 314            (optimize (inhibit-warnings 3)))
 315   (let ((type (alien-value-type alien)))
 316     (etypecase type
 317       (alien-pointer-type
 318        (%set-slot (deref alien) slot value))
 319       (alien-record-type
 320        (let ((field (slot-or-lose type slot)))
 321          (deposit-alien-value (alien-value-sap alien)
 322                               (alien-record-field-offset field)
 323                               (alien-record-field-type field)
 324                               value))))))
 325
 326 ;;; Compute the address of the specified slot and return a pointer to it.
 327 (defun %slot-addr (alien slot)
 328   (declare (type alien-value alien)
 329            (type symbol slot)
 330            (optimize (inhibit-warnings 3)))
 331   (let ((type (alien-value-type alien)))
 332     (etypecase type
 333       (alien-pointer-type
 334        (%slot-addr (deref alien) slot))
 335       (alien-record-type
 336        (let* ((field (slot-or-lose type slot))
 337               (offset (alien-record-field-offset field))
 338               (field-type (alien-record-field-type field)))
 339          (%sap-alien (sap+ (alien-sap alien) (/ offset sb!vm:n-byte-bits))
 340                      (make-alien-pointer-type :to field-type)))))))
 341 \f
 342 ;;;; the DEREF operator
 343
 344 ;;; This function does most of the work of the different DEREF
 345 ;;; methods. It returns two values: the type and the offset (in bits)
 346 ;;; of the referred-to alien.
 347 (defun deref-guts (alien indices)
 348   (declare (type alien-value alien)
 349            (type list indices)
 350            (values alien-type integer))
 351   (let ((type (alien-value-type alien)))
 352     (etypecase type
 353       (alien-pointer-type
 354        (when (cdr indices)
 355          (error "too many indices when DEREF'ing ~S: ~W"
 356                 type
 357                 (length indices)))
 358        (let ((element-type (alien-pointer-type-to type)))
 359          (values element-type
 360                  (if indices
 361                      (* (align-offset (alien-type-bits element-type)
 362                                       (alien-type-alignment element-type))
 363                         (car indices))
 364                      0))))
 365       (alien-array-type
 366        (unless (= (length indices) (length (alien-array-type-dimensions type)))
 367          (error "incorrect number of indices when DEREF'ing ~S: ~W"
 368                 type (length indices)))
 369        (labels ((frob (dims indices offset)
 370                   (if (null dims)
 371                       offset
 372                       (frob (cdr dims) (cdr indices)
 373                         (+ (if (zerop offset)
 374                                0
 375                                (* offset (car dims)))
 376                            (car indices))))))
 377          (let ((element-type (alien-array-type-element-type type)))
 378            (values element-type
 379                    (* (align-offset (alien-type-bits element-type)
 380                                     (alien-type-alignment element-type))
 381                       (frob (alien-array-type-dimensions type)
 382                         indices 0)))))))))
 383
 384 ;;; Dereference the alien and return the results.
 385 (defun deref (alien &rest indices)
 386   #!+sb-doc
 387   "De-reference an Alien pointer or array. If an array, the indices are used
 388    as the indices of the array element to access. If a pointer, one index can
 389    optionally be specified, giving the equivalent of C pointer arithmetic."
 390   (declare (type alien-value alien)
 391            (type list indices)
 392            (optimize (inhibit-warnings 3)))
 393   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 394     (extract-alien-value (alien-value-sap alien)
 395                          offset
 396                          target-type)))
 397
 398 (defun %set-deref (alien value &rest indices)
 399   (declare (type alien-value alien)
 400            (type list indices)
 401            (optimize (inhibit-warnings 3)))
 402   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 403     (deposit-alien-value (alien-value-sap alien)
 404                          offset
 405                          target-type
 406                          value)))
 407
 408 (defun %deref-addr (alien &rest indices)
 409   (declare (type alien-value alien)
 410            (type list indices)
 411            (optimize (inhibit-warnings 3)))
 412   (multiple-value-bind (target-type offset) (deref-guts alien indices)
 413     (%sap-alien (sap+ (alien-value-sap alien) (/ offset sb!vm:n-byte-bits))
 414                 (make-alien-pointer-type :to target-type))))
 415 \f
 416 ;;;; accessing heap alien variables
 417
 418 (defun %heap-alien (info)
 419   (declare (type heap-alien-info info)
 420            (optimize (inhibit-warnings 3)))
 421   (extract-alien-value (eval (heap-alien-info-sap-form info))
 422                        0
 423                        (heap-alien-info-type info)))
 424
 425 (defun %set-heap-alien (info value)
 426   (declare (type heap-alien-info info)
 427            (optimize (inhibit-warnings 3)))
 428   (deposit-alien-value (eval (heap-alien-info-sap-form info))
 429                        0
 430                        (heap-alien-info-type info)
 431                        value))
 432
 433 (defun %heap-alien-addr (info)
 434   (declare (type heap-alien-info info)
 435            (optimize (inhibit-warnings 3)))
 436   (%sap-alien (eval (heap-alien-info-sap-form info))
 437               (make-alien-pointer-type :to (heap-alien-info-type info))))
 438 \f
 439 ;;;; accessing local aliens
 440
 441 (defun make-local-alien (info)
 442   (let* ((alien (eval `(make-alien ,(local-alien-info-type info))))
 443          (alien-sap (alien-sap alien)))
 444     (finalize
 445      alien
 446      (lambda ()
 447        (alien-funcall
 448         (extern-alien "free" (function (values) system-area-pointer))
 449         alien-sap)))
 450     alien))
 451
 452 (defun note-local-alien-type (info alien)
 453   (declare (ignore info alien))
 454   nil)
 455
 456 (defun local-alien (info alien)
 457   (declare (ignore info))
 458   (deref alien))
 459
 460 (defun %set-local-alien (info alien value)
 461   (declare (ignore info))
 462   (setf (deref alien) value))
 463
 464 (define-setf-expander local-alien (&whole whole info alien)
 465   (let ((value (gensym))
 466         (info-var (gensym))
 467         (alloc-tmp (gensym))
 468         (info (if (and (consp info)
 469                        (eq (car info) 'quote))
 470                   (second info)
 471                   (error "Something is wrong; local-alien-info not found: ~S"
 472                          whole))))
 473     (values nil
 474             nil
 475             (list value)
 476             `(if (%local-alien-forced-to-memory-p ',info)
 477                  (%set-local-alien ',info ,alien ,value)
 478                    (let* ((,info-var ',(local-alien-info-type info))
 479                           (,alloc-tmp (deport-alloc ,value ,info-var)))
 480                      (maybe-with-pinned-objects (,alloc-tmp) (,(local-alien-info-type info))
 481                        (setf ,alien (deport ,alloc-tmp ,info-var)))))
 482             whole)))
 483
 484 (defun %local-alien-forced-to-memory-p (info)
 485   (local-alien-info-force-to-memory-p info))
 486
 487 (defun %local-alien-addr (info alien)
 488   (declare (type local-alien-info info))
 489   (unless (local-alien-info-force-to-memory-p info)
 490     (error "~S isn't forced to memory. Something went wrong." alien))
 491   alien)
 492
 493 (defun dispose-local-alien (info alien)
 494   (declare (ignore info))
 495   (cancel-finalization alien)
 496   (free-alien alien))
 497 \f
 498 ;;;; the CAST macro
 499
 500 (defmacro cast (alien type &environment env)
 501   #!+sb-doc
 502   "Convert ALIEN to an Alien of the specified TYPE (not evaluated.)  Both types
 503    must be Alien array, pointer or function types."
 504   `(%cast ,alien ',(parse-alien-type type env)))
 505
 506 (defun %cast (alien target-type)
 507   (declare (type alien-value alien)
 508            (type alien-type target-type)
 509            (optimize (safety 2))
 510            (optimize (inhibit-warnings 3)))
 511   (if (or (alien-pointer-type-p target-type)
 512           (alien-array-type-p target-type)
 513           (alien-fun-type-p target-type))
 514       (let ((alien-type (alien-value-type alien)))
 515         (if (or (alien-pointer-type-p alien-type)
 516                 (alien-array-type-p alien-type)
 517                 (alien-fun-type-p alien-type))
 518             (naturalize (alien-value-sap alien) target-type)
 519             (error "~S cannot be casted." alien)))
 520       (error "cannot cast to alien type ~S" (unparse-alien-type target-type))))
 521 \f
 522 ;;;; the ALIEN-SIZE macro
 523
 524 (defmacro alien-size (type &optional (units :bits) &environment env)
 525   #!+sb-doc
 526   "Return the size of the alien type TYPE. UNITS specifies the units to
 527    use and can be either :BITS, :BYTES, or :WORDS."
 528   (let* ((alien-type (parse-alien-type type env))
 529          (bits (alien-type-bits alien-type)))
 530     (if bits
 531         (values (ceiling bits
 532                          (ecase units
 533                            (:bits 1)
 534                            (:bytes sb!vm:n-byte-bits)
 535                            (:words sb!vm:n-word-bits))))
 536         (error "unknown size for alien type ~S"
 537                (unparse-alien-type alien-type)))))
 538 \f
 539 ;;;; NATURALIZE, DEPORT, EXTRACT-ALIEN-VALUE, DEPOSIT-ALIEN-VALUE
 540
 541 (defun naturalize (alien type)
 542   (declare (type alien-type type))
 543   (funcall (coerce (compute-naturalize-lambda type) 'function)
 544            alien type))
 545
 546 (defun deport (value type)
 547   (declare (type alien-type type))
 548   (funcall (coerce (compute-deport-lambda type) 'function)
 549            value type))
 550
 551 (defun deport-alloc (value type)
 552   (declare (type alien-type type))
 553   (funcall (coerce (compute-deport-alloc-lambda type) 'function)
 554            value type))
 555
 556 (defun extract-alien-value (sap offset type)
 557   (declare (type system-area-pointer sap)
 558            (type unsigned-byte offset)
 559            (type alien-type type))
 560   (funcall (coerce (compute-extract-lambda type) 'function)
 561            sap offset type))
 562
 563 (defun deposit-alien-value (sap offset type value)
 564   (declare (type system-area-pointer sap)
 565            (type unsigned-byte offset)
 566            (type alien-type type))
 567   (funcall (coerce (compute-deposit-lambda type) 'function)
 568            sap offset type value))
 569 \f
 570 ;;;; ALIEN-FUNCALL, DEFINE-ALIEN-ROUTINE
 571
 572 (defun alien-funcall (alien &rest args)
 573   #!+sb-doc
 574   "Call the foreign function ALIEN with the specified arguments. ALIEN's
 575    type specifies the argument and result types."
 576   (declare (type alien-value alien))
 577   (let ((type (alien-value-type alien)))
 578     (typecase type
 579       (alien-pointer-type
 580        (apply #'alien-funcall (deref alien) args))
 581       (alien-fun-type
 582        (unless (= (length (alien-fun-type-arg-types type))
 583                   (length args))
 584          (error "wrong number of arguments for ~S~%expected ~W, got ~W"
 585                 type
 586                 (length (alien-fun-type-arg-types type))
 587                 (length args)))
 588        (let ((stub (alien-fun-type-stub type)))
 589          (unless stub
 590            (setf stub
 591                  (let ((fun (gensym))
 592                        (parms (make-gensym-list (length args))))
 593                    (compile nil
 594                             `(lambda (,fun ,@parms)
 595                                (declare (optimize (sb!c::insert-step-conditions 0)))
 596                                (declare (type (alien ,type) ,fun))
 597                                (alien-funcall ,fun ,@parms)))))
 598            (setf (alien-fun-type-stub type) stub))
 599          (apply stub alien args)))
 600       (t
 601        (error "~S is not an alien function." alien)))))
 602
 603 (defmacro define-alien-routine (name result-type
 604                                      &rest args
 605                                      &environment lexenv)
 606   #!+sb-doc
 607   "DEFINE-ALIEN-ROUTINE Name Result-Type {(Arg-Name Arg-Type [Style])}*
 608
 609   Define a foreign interface function for the routine with the specified NAME.
 610   Also automatically DECLAIM the FTYPE of the defined function.
 611
 612   NAME may be either a string, a symbol, or a list of the form (string symbol).
 613
 614   RETURN-TYPE is the alien type for the function return value. VOID may be
 615   used to specify a function with no result.
 616
 617   The remaining forms specify individual arguments that are passed to the
 618   routine. ARG-NAME is a symbol that names the argument, primarily for
 619   documentation. ARG-TYPE is the C type of the argument. STYLE specifies the
 620   way that the argument is passed.
 621
 622   :IN
 623         An :IN argument is simply passed by value. The value to be passed is
 624         obtained from argument(s) to the interface function. No values are
 625         returned for :In arguments. This is the default mode.
 626
 627   :OUT
 628         The specified argument type must be a pointer to a fixed sized object.
 629         A pointer to a preallocated object is passed to the routine, and the
 630         the object is accessed on return, with the value being returned from
 631         the interface function. :OUT and :IN-OUT cannot be used with pointers
 632         to arrays, records or functions.
 633
 634   :COPY
 635         This is similar to :IN, except that the argument values are stored
 636         on the stack, and a pointer to the object is passed instead of
 637         the value itself.
 638
 639   :IN-OUT
 640         This is a combination of :OUT and :COPY. A pointer to the argument is
 641         passed, with the object being initialized from the supplied argument
 642         and the return value being determined by accessing the object on
 643         return."
 644   (multiple-value-bind (lisp-name alien-name)
 645       (pick-lisp-and-alien-names name)
 646     (collect ((docs) (lisp-args) (lisp-arg-types)
 647               (lisp-result-types
 648                (cond ((eql result-type 'void)
 649                       ;; What values does a function return, if it
 650                       ;; returns no values? Exactly one - NIL. -- APD,
 651                       ;; 2003-03-02
 652                       (list 'null))
 653                      (t
 654                       ;; FIXME: Check for VALUES.
 655                       (list `(alien ,result-type)))))
 656               (arg-types) (alien-vars)
 657               (alien-args) (results))
 658       (dolist (arg args)
 659         (if (stringp arg)
 660             (docs arg)
 661             (destructuring-bind (name type &optional (style :in)) arg
 662               (unless (member style '(:in :copy :out :in-out))
 663                 (error "bogus argument style ~S in ~S" style arg))
 664               (when (and (member style '(:out :in-out))
 665                          (typep (parse-alien-type type lexenv)
 666                                 'alien-pointer-type))
 667                 (error "can't use :OUT or :IN-OUT on pointer-like type:~%  ~S"
 668                        type))
 669               (let (arg-type)
 670                 (cond ((eq style :in)
 671                        (setq arg-type type)
 672                        (alien-args name))
 673                       (t
 674                        (setq arg-type `(* ,type))
 675                        (if (eq style :out)
 676                            (alien-vars `(,name ,type))
 677                            (alien-vars `(,name ,type ,name)))
 678                        (alien-args `(addr ,name))))
 679                 (arg-types arg-type)
 680                 (unless (eq style :out)
 681                   (lisp-args name)
 682                   (lisp-arg-types t
 683                                   ;; FIXME: It should be something
 684                                   ;; like `(ALIEN ,ARG-TYPE), except
 685                                   ;; for we also accept SAPs where
 686                                   ;; pointers are required.
 687                                   )))
 688               (when (or (eq style :out) (eq style :in-out))
 689                 (results name)
 690                 (lisp-result-types `(alien ,type))))))
 691       `(progn
 692          ;; The theory behind this automatic DECLAIM is that (1) if
 693          ;; you're calling C, static typing is what you're doing
 694          ;; anyway, and (2) such a declamation can be (especially for
 695          ;; alien values) both messy to do by hand and very important
 696          ;; for performance of later code which uses the return value.
 697          (declaim (ftype (function ,(lisp-arg-types)
 698                                    (values ,@(lisp-result-types) &optional))
 699                          ,lisp-name))
 700          (defun ,lisp-name ,(lisp-args)
 701            ,@(docs)
 702            (with-alien
 703             ((,lisp-name (function ,result-type ,@(arg-types))
 704                          :extern ,alien-name)
 705              ,@(alien-vars))
 706              #-nil
 707              (values (alien-funcall ,lisp-name ,@(alien-args))
 708                      ,@(results))
 709              #+nil
 710              (if (alien-values-type-p result-type)
 711                  ;; FIXME: RESULT-TYPE is a type specifier, so it
 712                  ;; cannot be of type ALIEN-VALUES-TYPE. Also note,
 713                  ;; that if RESULT-TYPE is VOID, then this code
 714                  ;; disagrees with the computation of the return type
 715                  ;; and with all usages of this macro. -- APD,
 716                  ;; 2002-03-02
 717                  (let ((temps (make-gensym-list
 718                                (length
 719                                 (alien-values-type-values result-type)))))
 720                    `(multiple-value-bind ,temps
 721                         (alien-funcall ,lisp-name ,@(alien-args))
 722                       (values ,@temps ,@(results))))
 723                  (values (alien-funcall ,lisp-name ,@(alien-args))
 724                          ,@(results)))))))))
 725
 726 (defmacro def-alien-routine (&rest rest)
 727   (deprecation-warning 'def-alien-routine 'define-alien-routine)
 728   `(define-alien-routine ,@rest))
 729 \f
 730 (defun alien-typep (object type)
 731   #!+sb-doc
 732   "Return T iff OBJECT is an alien of type TYPE."
 733   (let ((lisp-rep-type (compute-lisp-rep-type type)))
 734     (if lisp-rep-type
 735         (typep object lisp-rep-type)
 736         (and (alien-value-p object)
 737              (alien-subtype-p (alien-value-type object) type)))))
 738
 739 ;;;; ALIEN CALLBACKS
 740 ;;;;
 741 ;;;; See "Foreign Linkage / Callbacks" in the SBCL Internals manual.
 742
 743 (defvar *alien-callback-info* nil
 744   "Maps SAPs to corresponding CALLBACK-INFO structures: contains all the
 745 information we need to manipulate callbacks after their creation. Used for
 746 changing the lisp-side function they point to, invalidation, etc.")
 747
 748 (defstruct callback-info
 749   specifier
 750   function ; NULL if invalid
 751   wrapper
 752   index)
 753
 754 (defun callback-info-key (info)
 755   (cons (callback-info-specifier info) (callback-info-function info)))
 756
 757 (defun alien-callback-info (alien)
 758   (cdr (assoc (alien-sap alien) *alien-callback-info* :test #'sap=)))
 759
 760 (defvar *alien-callbacks* (make-hash-table :test #'equal)
 761   "Cache of existing callback SAPs, indexed with (SPECIFER . FUNCTION). Used for
 762 memoization: we don't create new callbacks if one pointing to the correct
 763 function with the same specifier already exists.")
 764
 765 (defvar *alien-callback-wrappers* (make-hash-table :test #'equal)
 766   "Cache of existing lisp weappers, indexed with SPECIFER. Used for memoization:
 767 we don't create new wrappers if one for the same specifier already exists.")
 768
 769 (defvar *alien-callback-trampolines* (make-array 32 :fill-pointer 0 :adjustable t)
 770   "Lisp trampoline store: assembler wrappers contain indexes to this, and
 771 ENTER-ALIEN-CALLBACK pulls the corresponsing trampoline out and calls it.")
 772
 773 (defun %alien-callback-sap (specifier result-type argument-types function wrapper)
 774   (let ((key (cons specifier function)))
 775     (or (gethash key *alien-callbacks*)
 776         (setf (gethash key *alien-callbacks*)
 777               (let* ((index (fill-pointer *alien-callback-trampolines*))
 778                      ;; Aside from the INDEX this is known at
 779                      ;; compile-time, which could be utilized by
 780                      ;; having the two-stage assembler tramp &
 781                      ;; wrapper mentioned in [1] above: only the
 782                      ;; per-function tramp would need assembler at
 783                      ;; runtime. Possibly we could even pregenerate
 784                      ;; the code and just patch the index in later.
 785                      (assembler-wrapper (alien-callback-assembler-wrapper
 786                                          index result-type argument-types)))
 787                 (vector-push-extend
 788                  (alien-callback-lisp-trampoline wrapper function)
 789                  *alien-callback-trampolines*)
 790                 (let ((sap (vector-sap assembler-wrapper)))
 791                   (push (cons sap (make-callback-info :specifier specifier
 792                                                       :function function
 793                                                       :wrapper wrapper
 794                                                       :index index))
 795                         *alien-callback-info*)
 796                   sap))))))
 797
 798 (defun alien-callback-lisp-trampoline (wrapper function)
 799   (declare (function wrapper) (optimize speed))
 800   (lambda (args-pointer result-pointer)
 801     (funcall wrapper args-pointer result-pointer function)))
 802
 803 (defun alien-callback-lisp-wrapper-lambda (specifier result-type argument-types env)
 804   (let* ((arguments (make-gensym-list (length argument-types)))
 805          (argument-names arguments)
 806          (argument-specs (cddr specifier)))
 807     `(lambda (args-pointer result-pointer function)
 808        ;; FIXME: the saps are not gc safe
 809        (let ((args-sap (int-sap
 810                         (sb!kernel:get-lisp-obj-address args-pointer)))
 811              (res-sap (int-sap
 812                        (sb!kernel:get-lisp-obj-address result-pointer))))
 813          (declare (ignorable args-sap res-sap))
 814          (with-alien
 815              ,(loop
 816                  with offset = 0
 817                  for spec in argument-specs
 818                  collect `(,(pop argument-names) ,spec
 819                             :local ,(alien-callback-accessor-form
 820                                      spec 'args-sap offset))
 821                  do (incf offset (alien-callback-argument-bytes spec env)))
 822            ,(flet ((store (spec)
 823                           (if spec
 824                               `(setf (deref (sap-alien res-sap (* ,spec)))
 825                                      (funcall function ,@arguments))
 826                               `(funcall function ,@arguments))))
 827                   (cond ((alien-void-type-p result-type)
 828                          (store nil))
 829                         ((alien-integer-type-p result-type)
 830                          (if (alien-integer-type-signed result-type)
 831                              (store `(signed
 832                                       ,(alien-type-word-aligned-bits result-type)))
 833                              (store
 834                               `(unsigned
 835                                 ,(alien-type-word-aligned-bits result-type)))))
 836                         (t
 837                          (store (unparse-alien-type result-type)))))))
 838        (values))))
 839
 840 (defun invalid-alien-callback (&rest arguments)
 841   (declare (ignore arguments))
 842   (error "Invalid alien callback called."))
 843
 844
 845 (defun parse-callback-specification (result-type lambda-list)
 846   (values
 847    `(function ,result-type ,@(mapcar #'second lambda-list))
 848    (mapcar #'first lambda-list)))
 849
 850
 851 (defun parse-alien-ftype (specifier env)
 852   (destructuring-bind (function result-type &rest argument-types)
 853       specifier
 854     (aver (eq 'function function))
 855     (values (let ((*values-type-okay* t))
 856               (parse-alien-type result-type env))
 857             (mapcar (lambda (spec)
 858                       (parse-alien-type spec env))
 859                     argument-types))))
 860
 861 (defun alien-void-type-p (type)
 862   (and (alien-values-type-p type) (not (alien-values-type-values type))))
 863
 864 (defun alien-type-word-aligned-bits (type)
 865   (align-offset (alien-type-bits type) sb!vm:n-word-bits))
 866
 867 (defun alien-callback-argument-bytes (spec env)
 868   (let ((type (parse-alien-type spec env)))
 869     (if (or (alien-integer-type-p type)
 870             (alien-float-type-p type)
 871             (alien-pointer-type-p type)
 872             (alien-system-area-pointer-type-p type))
 873         (ceiling (alien-type-word-aligned-bits type) sb!vm:n-byte-bits)
 874         (error "Unsupported callback argument type: ~A" type))))
 875
 876 (defun enter-alien-callback (index return arguments)
 877   (funcall (aref *alien-callback-trampolines* index)
 878            return
 879            arguments))
 880
 881 ;;; To ensure that callback wrapper functions continue working even
 882 ;;; if #'ENTER-ALIEN-CALLBACK moves in memory, access to it is indirected
 883 ;;; through the *ENTER-ALIEN-CALLBACK* static symbol. -- JES, 2006-01-01
 884 (defvar *enter-alien-callback* #'enter-alien-callback)
 885
 886 ;;;; interface (not public, yet) for alien callbacks
 887
 888 (defmacro alien-callback (specifier function &environment env)
 889   "Returns an alien-value with of alien ftype SPECIFIER, that can be passed to
 890 an alien function as a pointer to the FUNCTION. If a callback for the given
 891 SPECIFIER and FUNCTION already exists, it is returned instead of consing a new
 892 one."
 893   ;; Pull out as much work as is convenient to macro-expansion time, specifically
 894   ;; everything that can be done given just the SPECIFIER and ENV.
 895   (multiple-value-bind (result-type argument-types) (parse-alien-ftype specifier env)
 896     `(%sap-alien
 897       (%alien-callback-sap ',specifier ',result-type ',argument-types
 898                            ,function
 899                            (or (gethash ',specifier *alien-callback-wrappers*)
 900                                (setf (gethash ',specifier *alien-callback-wrappers*)
 901                                      (compile nil
 902                                               ',(alien-callback-lisp-wrapper-lambda
 903                                                  specifier result-type argument-types env)))))
 904       ',(parse-alien-type specifier env))))
 905
 906 (defun alien-callback-p (alien)
 907   "Returns true if the alien is associated with a lisp-side callback,
 908 and a secondary return value of true if the callback is still valid."
 909   (let ((info (alien-callback-info alien)))
 910     (when info
 911       (values t (and (callback-info-function info) t)))))
 912
 913 (defun alien-callback-function (alien)
 914   "Returns the lisp function designator associated with the callback."
 915   (let ((info (alien-callback-info alien)))
 916     (when info
 917       (callback-info-function info))))
 918
 919 (defun (setf alien-callback-function) (function alien)
 920   "Changes the lisp function designated by the callback."
 921   (let ((info (alien-callback-info alien)))
 922     (unless info
 923       (error "Not an alien callback: ~S" alien))
 924     ;; sap cache
 925     (let ((key (callback-info-key info)))
 926       (remhash key *alien-callbacks*)
 927       (setf (gethash key *alien-callbacks*) (alien-sap alien)))
 928     ;; trampoline
 929     (setf (aref *alien-callback-trampolines* (callback-info-index info))
 930           (alien-callback-lisp-trampoline (callback-info-wrapper info) function))
 931     ;; metadata
 932     (setf (callback-info-function info) function)
 933     function))
 934
 935 (defun invalidate-alien-callback (alien)
 936   "Invalidates the callback designated by the alien, if any, allowing the
 937 associated lisp function to be GC'd, and causing further calls to the same
 938 callback signal an error."
 939   (let ((info (alien-callback-info alien)))
 940     (when (and info (callback-info-function info))
 941       ;; sap cache
 942       (remhash (callback-info-key info) *alien-callbacks*)
 943       ;; trampoline
 944       (setf (aref *alien-callback-trampolines* (callback-info-index info))
 945             #'invalid-alien-callback)
 946       ;; metadata
 947       (setf (callback-info-function info) nil)
 948       t)))
 949
 950 ;;; FIXME: This call assembles a new callback for every closure,
 951 ;;; which sucks hugely. ...not that I can think of an obvious
 952 ;;; solution. Possibly maybe we could write a generalized closure
 953 ;;; callback analogous to closure_tramp, and share the actual wrapper?
 954 ;;;
 955 ;;; For lambdas that result in simple-funs we get the callback from
 956 ;;; the cache on subsequent calls.
 957 (defmacro alien-lambda (result-type typed-lambda-list &body forms)
 958   (multiple-value-bind (specifier lambda-list)
 959       (parse-callback-specification result-type typed-lambda-list)
 960     `(alien-callback ,specifier (lambda ,lambda-list ,@forms))))
 961
 962 ;;; FIXME: Should subsequent (SETF FDEFINITION) affect the callback or not?
 963 ;;; What about subsequent DEFINE-ALIEN-CALLBACKs? My guess is that changing
 964 ;;; the FDEFINITION should invalidate the callback, and redefining the
 965 ;;; callback should change existing callbacks to point to the new defintion.
 966 (defmacro define-alien-callback (name result-type typed-lambda-list &body forms)
 967   "Defines #'NAME as a function with the given body and lambda-list, and NAME as
 968 the alien callback for that function with the given alien type."
 969   (declare (symbol name))
 970   (multiple-value-bind (specifier lambda-list)
 971       (parse-callback-specification result-type typed-lambda-list)
 972     `(progn
 973        (defun ,name ,lambda-list ,@forms)
 974        (defparameter ,name (alien-callback ,specifier #',name)))))