tests/float.pure.lisp

   1 ;;;; floating-point-related tests with no side effects
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; While most of SBCL is derived from the CMU CL system, the test
   7 ;;;; files (like this one) were written from scratch after the fork
   8 ;;;; from CMU CL.
   9 ;;;;
  10 ;;;; This software is in the public domain and is provided with
  11 ;;;; absolutely no warranty. See the COPYING and CREDITS files for
  12 ;;;; more information.
  13
  14 (cl:in-package :cl-user)
  15
  16 (dolist (ifnis (list (cons single-float-positive-infinity
  17                            single-float-negative-infinity)
  18                      (cons double-float-positive-infinity
  19                            double-float-negative-infinity)))
  20   (destructuring-bind (+ifni . -ifni) ifnis
  21     (assert (= (* +ifni 1) +ifni))
  22     (assert (= (* +ifni -0.1) -ifni))
  23     (assert (= (+ +ifni -0.1) +ifni))
  24     (assert (= (- +ifni -0.1) +ifni))
  25     (assert (= (sqrt +ifni) +ifni))
  26     (assert (= (* -ifni -14) +ifni))
  27     (assert (= (/ -ifni 0.1) -ifni))
  28     (assert (= (/ -ifni 100/3) -ifni))
  29     (assert (not (= +ifni -ifni)))
  30     (assert (= -ifni -ifni))
  31     (assert (not (= +ifni 100/3)))
  32     (assert (not (= -ifni -1.0 -ifni)))
  33     (assert (not (= -ifni -17/02 -ifni)))
  34     (assert (< -ifni +ifni))
  35     (assert (not (< +ifni 100)))
  36     (assert (not (< +ifni 100.0)))
  37     (assert (not (< +ifni -ifni)))
  38     (assert (< 100 +ifni))
  39     (assert (< 100.0 +ifni))
  40     (assert (>= 100 -ifni))
  41     (assert (not (<= 6/7 (* 3 -ifni))))
  42     (assert (not (> +ifni +ifni)))))
  43
  44 ;;; ANSI: FLOAT-RADIX should signal an error if its argument is not a
  45 ;;; float.
  46 ;;;
  47 ;;; (Peter Van Eynde's ansi-test suite caught this, and Eric Marsden
  48 ;;; reported a fix for CMU CL, which was ported to sbcl-0.6.12.35.)
  49 (assert (typep (nth-value 1 (ignore-errors (float-radix "notfloat")))
  50                'type-error))
  51
  52 (assert (typep (nth-value 1 (ignore-errors
  53                               (funcall (fdefinition 'float-radix) "notfloat")))
  54                'type-error))
  55
  56 ;;; Before 0.8.2.14 the cross compiler failed to work with
  57 ;;; denormalized numbers
  58 (when (subtypep 'single-float 'short-float)
  59   (assert (eql least-positive-single-float least-positive-short-float)))
  60
  61 ;;; bug found by Paul Dietz: FFLOOR and similar did not work for integers
  62 (let ((tests '(((ffloor -8 3) (-3.0 1))
  63                ((fround -8 3) (-3.0 1))
  64                ((ftruncate -8 3) (-2.0 -2))
  65                ((fceiling -8 3) (-2.0 -2)))))
  66   (loop for (exp res) in tests
  67         for real-res = (multiple-value-list (eval exp))
  68         do (assert (equal real-res res))))
  69
  70 ;;; bug 45b reported by PVE
  71 (dolist (type '(short single double long))
  72   (dolist (sign '(positive negative))
  73     (let* ((name (find-symbol (format nil "LEAST-~A-~A-FLOAT"
  74                                       sign type)
  75                               :cl))
  76            (value (symbol-value name)))
  77       (assert (zerop (/ value 2))))))
  78
  79 ;;; bug found by Paul Dietz: bad rounding on small floats
  80 (assert (= (fround least-positive-short-float least-positive-short-float) 1.0))
  81
  82 ;;; bug found by Peter Seibel: scale-float was only accepting float
  83 ;;; exponents, when it should accept all integers.  (also bug #269)
  84 (assert (= (multiple-value-bind (significand expt sign)
  85                (integer-decode-float least-positive-double-float)
  86              (* (scale-float (float significand 0.0d0) expt) sign))
  87            least-positive-double-float))
  88 (assert (= (multiple-value-bind (significand expt sign)
  89                (decode-float least-positive-double-float)
  90              (* (scale-float significand expt) sign))
  91            least-positive-double-float))
  92 (assert (= 0.0 (scale-float 1.0 most-negative-fixnum)))
  93 (assert (= 0.0d0 (scale-float 1.0d0 (1- most-negative-fixnum))))
  94
  95 (with-test (:name (:scale-float-overflow :bug-372)
  96             :fails-on '(and :darwin :ppc)) ;; bug 372
  97   (assert-error (scale-float 1.0 most-positive-fixnum)
  98                 floating-point-overflow)
  99   (assert-error (scale-float 1.0d0 (1+ most-positive-fixnum))
 100                 floating-point-overflow))
 101
 102 ;;; bug found by jsnell when nfroyd tried to implement better LOGAND
 103 ;;; type derivation.
 104 (assert (= (integer-decode-float (coerce -1756510900000000000
 105                                          'single-float))
 106            12780299))
 107
 108 ;;; MISC.564: no out-of-line %ATAN2 for constant folding
 109 (assert (typep
 110   (funcall
 111    (compile
 112     nil
 113     '(lambda (p1)
 114       (declare (optimize (speed 3) (safety 2) (debug 3) (space 0))
 115        (type complex p1))
 116       (phase (the (eql #c(1.0d0 2.0d0)) p1))))
 117    #c(1.0d0 2.0d0))
 118     'double-float))
 119
 120 ;;; More out of line functions (%COS, %SIN, %TAN) for constant folding,
 121 ;;; reported by Mika Pihlajamäki
 122 (funcall (compile nil '(lambda () (cos (tan (round 0))))))
 123 (funcall (compile nil '(lambda () (sin (tan (round 0))))))
 124 (funcall (compile nil '(lambda () (tan (tan (round 0))))))
 125
 126 (with-test (:name (:addition-overflow :bug-372)
 127             :fails-on '(or (and :ppc :openbsd)
 128                            (and :ppc :darwin)
 129                            (and :x86 :netbsd)))
 130   (assert (typep (nth-value
 131                   1
 132                   (ignore-errors
 133                     (sb-sys:without-interrupts
 134                      (sb-int:set-floating-point-modes :current-exceptions nil
 135                                                       :accrued-exceptions nil)
 136                      (loop repeat 2 summing most-positive-double-float)
 137                      (sleep 2))))
 138                  'floating-point-overflow)))
 139
 140 ;; This is the same test as above.  Even if the above copy passes,
 141 ;; this copy will fail if SIGFPE handling ends up clearing the FPU
 142 ;; control word, which can happen if the kernel clears the FPU control
 143 ;; (a reasonable thing for it to do) and the runtime fails to
 144 ;; compensate for this (see RESTORE_FP_CONTROL_WORD in interrupt.c).
 145 ;; Note that this only works when running float.pure.lisp alone, as
 146 ;; the preceeding "pure" test files aren't as free of side effects as
 147 ;; we might like.
 148 (with-test (:name (:addition-overflow :bug-372 :take-2)
 149             :fails-on '(or (and :ppc :openbsd)
 150                            (and :ppc :darwin)
 151                            (and :x86 :netbsd)))
 152   (assert (typep (nth-value
 153                   1
 154                   (ignore-errors
 155                     (sb-sys:without-interrupts
 156                      (sb-int:set-floating-point-modes :current-exceptions nil
 157                                                       :accrued-exceptions nil)
 158                      (loop repeat 2 summing most-positive-double-float)
 159                      (sleep 2))))
 160                  'floating-point-overflow)))
 161
 162 ;;; On x86-64 generating complex floats on the stack failed an aver in
 163 ;;; the compiler if the stack slot was the same as the one containing
 164 ;;; the real part of the complex. The following expression was able to
 165 ;;; trigger this in 0.9.5.62.
 166 (with-test (:name :complex-float-stack)
 167   (dolist (type '((complex double-float)
 168                   (complex single-float)))
 169     (compile nil
 170              `(lambda (x0 x1 x2 x3 x4 x5 x6 x7)
 171                 (declare (type ,type x0 x1 x2 x3 x4 x5 x6 x7))
 172                 (let ((x0 (+ x0 x0))
 173                       (x1 (+ x1 x1))
 174                       (x2 (+ x2 x2))
 175                       (x3 (+ x3 x3))
 176                       (x4 (+ x4 x4))
 177                       (x5 (+ x5 x5))
 178                       (x6 (+ x6 x6))
 179                       (x7 (+ x7 x7)))
 180                   (* (+ x0 x1 x2 x3) (+ x4 x5 x6 x7)
 181                      (+ x0 x2 x4 x6) (+ x1 x3 x5 x7)
 182                      (+ x0 x3 x4 x7) (+ x1 x2 x5 x6)
 183                      (+ x0 x1 x6 x7) (+ x2 x3 x4 x5)))))))
 184
 185
 186 (with-test (:name :nan-comparisons
 187             :fails-on '(or :sparc :mips))
 188   (sb-int:with-float-traps-masked (:invalid)
 189     (macrolet ((test (form)
 190                  (let ((nform (subst '(/ 0.0 0.0) 'nan form)))
 191                    `(progn
 192                       (assert (eval ',nform))
 193                       (assert (eval `(let ((nan (/ 0.0 0.0)))
 194                                        ,',form)))
 195                       (assert (funcall
 196                                (compile nil `(lambda () ,',nform))))
 197                       (assert (funcall
 198                                (compile nil `(lambda (nan) ,',form))
 199                                (/ 0.0 0.0)))))))
 200       (test (/= nan nan))
 201       (test (/= nan nan nan))
 202       (test (/= 1.0 nan 2.0 nan))
 203       (test (/= nan 1.0 2.0 nan))
 204       (test (not (= nan 1.0)))
 205       (test (not (= nan nan)))
 206       (test (not (= nan nan nan)))
 207       (test (not (= 1.0 nan)))
 208       (test (not (= nan 1.0)))
 209       (test (not (= 1.0 1.0 nan)))
 210       (test (not (= 1.0 nan 1.0)))
 211       (test (not (= nan 1.0 1.0)))
 212       (test (not (>= nan nan)))
 213       (test (not (>= nan 1.0)))
 214       (test (not (>= 1.0 nan)))
 215       (test (not (>= 1.0 nan 0.0)))
 216       (test (not (>= 1.0 0.0 nan)))
 217       (test (not (>= nan 1.0 0.0)))
 218       (test (not (<= nan nan)))
 219       (test (not (<= nan 1.0)))
 220       (test (not (<= 1.0 nan)))
 221       (test (not (<= 1.0 nan 2.0)))
 222       (test (not (<= 1.0 2.0 nan)))
 223       (test (not (<= nan 1.0 2.0)))
 224       (test (not (< nan nan)))
 225       (test (not (< -1.0 nan)))
 226       (test (not (< nan 1.0)))
 227       (test (not (> nan nan)))
 228       (test (not (> -1.0 nan)))
 229       (test (not (> nan 1.0))))))
 230
 231 (with-test (:name :log-int/double-accuracy)
 232   ;; we used to use single precision for intermediate results
 233   (assert (eql 2567.6046442221327d0
 234                (log (loop for n from 1 to 1000 for f = 1 then (* f n)
 235                           finally (return f))
 236                     10d0)))
 237   ;; both ways
 238   (assert (eql (log 123123123.0d0 10) (log 123123123 10.0d0))))
 239
 240 (with-test (:name :log-base-zero-return-type)
 241   (assert (eql 0.0f0 (log 123 (eval 0))))
 242   (assert (eql 0.0d0 (log 123.0d0 (eval 0))))
 243   (assert (eql 0.0d0 (log 123 (eval 0.0d0))))
 244   (let ((f (compile nil '(lambda (x y)
 245                           (declare (optimize speed))
 246                           (etypecase x
 247                             (single-float
 248                              (etypecase y
 249                                (single-float (log x y))
 250                                (double-float (log x y))))
 251                             (double-float
 252                              (etypecase y
 253                                (single-float (log x y))
 254                                (double-float (log x y)))))))))
 255     (assert (eql 0.0f0 (funcall f 123.0 0.0)))
 256     (assert (eql 0.0d0 (funcall f 123.0d0 0.0)))
 257     (assert (eql 0.0d0 (funcall f 123.0d0 0.0d0)))
 258     (assert (eql 0.0d0 (funcall f 123.0 0.0d0)))))
 259
 260 ;; Bug reported by Eric Marsden on July 15 2009. The compiler
 261 ;; used not to constant fold calls with arguments of type
 262 ;; (EQL foo).
 263 (with-test (:name :eql-type-constant-fold)
 264   (assert (equal '(FUNCTION (T) (VALUES (MEMBER T) &OPTIONAL))
 265                  (sb-kernel:%simple-fun-type
 266                   (compile nil `(lambda (x)
 267                                   (eql #c(1.0 2.0)
 268                                        (the (eql #c(1.0 2.0))
 269                                          x))))))))
 270
 271 ;; Leakage from the host could result in wrong values for truncation.
 272 (with-test (:name :truncate)
 273   (assert (plusp (sb-kernel:%unary-truncate/single-float (expt 2f0 33))))
 274   (assert (plusp (sb-kernel:%unary-truncate/double-float (expt 2d0 33))))
 275   ;; That'd be one strange host, but just in case
 276   (assert (plusp (sb-kernel:%unary-truncate/single-float (expt 2f0 65))))
 277   (assert (plusp (sb-kernel:%unary-truncate/double-float (expt 2d0 65)))))
 278
 279 ;; On x86-64, we sometimes forgot to clear the higher order bits of the
 280 ;; destination register before using it with an instruction that doesn't
 281 ;; clear the (unused) high order bits. Suspect instructions are operations
 282 ;; with only one operand: for everything else, the destination has already
 283 ;; been loaded with a value, making it safe (by induction).
 284 ;;
 285 ;; The tests are extremely brittle and could be broken by any number of
 286 ;; back- or front-end optimisations. We should just keep the issue above
 287 ;; in mind at all times when working with SSE or similar instruction sets.
 288 ;;
 289 ;; Run only on x86/x86-64m as no other platforms have SB-VM::TOUCH-OBJECT.
 290 (macrolet ((with-pinned-floats ((count type &rest names) &body body)
 291              "Force COUNT float values to be kept live (and hopefully in registers),
 292               fill a temporary register with noise, and execute BODY."
 293              ;; KLUDGE: SB-VM is locked, and non-x86oids don't have
 294              ;; SB-VM::TOUCH-OBJECT.  Don't even READ this body on
 295              ;; other platforms.
 296              #-(or x86 x86-64)
 297              (declare (ignore count type names body))
 298              #+(or x86 x86-64)
 299              (let ((dummy (loop repeat count
 300                                 collect (or (pop names)
 301                                             (gensym "TEMP")))))
 302                `(let ,(loop for i downfrom -1
 303                             for var in dummy
 304                             for j = (coerce i type)
 305                             collect
 306                             `(,var ,(complex j j))) ; we don't actually need that, but
 307                   (declare (type (complex ,type) ,@dummy)) ; future-proofing can't hurt
 308                   ,@(loop for var in dummy
 309                           for i upfrom 0
 310                           collect `(setf ,var ,(complex i (coerce i type))))
 311                   (multiple-value-prog1
 312                       (progn
 313                         (let ((x ,(complex 1d0 1d0)))
 314                           (declare (type (complex double-float) x))
 315                           (setf x ,(complex most-positive-fixnum (float most-positive-fixnum 1d0)))
 316                           (sb-vm::touch-object x))
 317                         (locally ,@body))
 318                     ,@(loop for var in dummy
 319                             collect `(sb-vm::touch-object ,var)))))))
 320   (with-test (:name :clear-sqrtsd :skipped-on '(not (or :x86 :x86-64)))
 321     (flet ((test-sqrtsd (float)
 322              (declare (optimize speed (safety 1))
 323                       (type (double-float (0d0)) float))
 324              (with-pinned-floats (14 double-float x0)
 325                (let ((x (sqrt float)))
 326                  (values (+ x x0) float)))))
 327       (declare (notinline test-sqrtsd))
 328       (assert (zerop (imagpart (test-sqrtsd 4d0))))))
 329
 330   (with-test (:name :clear-sqrtsd-single :skipped-on '(not (or :x86 :x86-64)))
 331     (flet ((test-sqrtsd-float (float)
 332              (declare (optimize speed (safety 1))
 333                       (type (single-float (0f0)) float))
 334              (with-pinned-floats (14 single-float x0)
 335                (let ((x (sqrt float)))
 336                  (values (+ x x0) float)))))
 337       (declare (notinline test-sqrtsd-float))
 338       (assert (zerop (imagpart (test-sqrtsd-float 4f0))))))
 339
 340   (with-test (:name :clear-cvtss2sd :skipped-on '(not (or :x86 :x86-64)))
 341     (flet ((test-cvtss2sd (float)
 342              (declare (optimize speed (safety 1))
 343                       (type single-float float))
 344              (with-pinned-floats (14 double-float x0)
 345                (let ((x (float float 0d0)))
 346                  (values (+ x x0) (+ 1e0 float))))))
 347       (declare (notinline test-cvtss2sd))
 348       (assert (zerop (imagpart (test-cvtss2sd 1f0))))))
 349
 350   (with-test (:name :clear-cvtsd2ss :skipped-on '(not (or :x86 :x86-64)))
 351     (flet ((test-cvtsd2ss (float)
 352              (declare (optimize speed (safety 1))
 353                       (type double-float float))
 354              (with-pinned-floats (14 single-float x0)
 355                (let ((x (float float 1e0)))
 356                  (values (+ x x0) (+ 1d0 float))))))
 357       (declare (notinline test-cvtsd2ss))
 358       (assert (zerop (imagpart (test-cvtsd2ss 4d0))))))
 359
 360   (with-test (:name :clear-cvtsi2sd :skipped-on '(not (or :x86 :x86-64)))
 361     (flet ((test-cvtsi2sd (int)
 362              (declare (optimize speed (safety 0))
 363                       (type (unsigned-byte 10) int))
 364              (with-pinned-floats (15 double-float x0)
 365                (+ (float int 0d0) x0))))
 366       (declare (notinline test-cvtsi2sd))
 367       (assert (zerop (imagpart (test-cvtsi2sd 4))))))
 368
 369   (with-test (:name :clear-cvtsi2ss :skipped-on '(not (or :x86 :x86-64)))
 370     (flet ((test-cvtsi2ss (int)
 371              (declare (optimize speed (safety 0))
 372                       (type (unsigned-byte 10) int))
 373              (with-pinned-floats (15 single-float x0)
 374                (+ (float int 0e0) x0))))
 375       (declare (notinline test-cvtsi2ss))
 376       (assert (zerop (imagpart (test-cvtsi2ss 4)))))))
 377
 378 (with-test (:name :round-to-bignum)
 379   (assert (= (round 1073741822.3d0) 1073741822))
 380   (assert (= (round 1073741822.5d0) 1073741822))
 381   (assert (= (round 1073741822.7d0) 1073741823))
 382   (assert (= (round 1073741823.3d0) 1073741823))
 383   (assert (= (round 1073741823.5d0) 1073741824))
 384   (assert (= (round 1073741823.7d0) 1073741824)))
 385
 386 (with-test (:name :round-single-to-bignum)
 387   (assert (= (round 1e14) 100000000376832))
 388   (assert (= (round 1e19) 9999999980506447872)))
 389
 390 (with-test (:name :scaled-%hypot)
 391   (assert (<= (abs (complex most-positive-double-float 1d0))
 392               (1+ most-positive-double-float))))
 393
 394 ;; On x86-64, MAKE-SINGLE-FLOAT with a negative argument used to set
 395 ;; bits 32-63 of the XMM register to 1, breaking the invariant that
 396 ;; unused parts of XMM registers are always zero. This could become
 397 ;; visible as a QNaN in the imaginary part when next using the register
 398 ;; in a (COMPLEX SINGLE-FLOAT) operation.
 399 (with-test (:name :make-single-float-clear-imagpart)
 400   (let ((f (compile nil
 401                     '(lambda (x)
 402                        (declare (optimize speed))
 403                        (= #c(1.0f0 2.0f0)
 404                           (+ #c(3.0f0 2.0f0)
 405                              (sb-kernel:make-single-float x))))))
 406         (bits (sb-kernel:single-float-bits -2.0f0)))
 407     (assert (< bits 0))         ; Make sure the test is fit for purpose.
 408     (assert (funcall f bits))))