src/code/target-pathname.lisp

   1 ;;;; machine/filesystem-independent pathname functions
   2
   3 ;;;; This software is part of the SBCL system. See the README file for
   4 ;;;; more information.
   5 ;;;;
   6 ;;;; This software is derived from the CMU CL system, which was
   7 ;;;; written at Carnegie Mellon University and released into the
   8 ;;;; public domain. The software is in the public domain and is
   9 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  10 ;;;; files for more information.
  11
  12 (in-package "SB!IMPL")
  13
  14 #!-sb-fluid (declaim (freeze-type logical-pathname logical-host))
  15 \f
  16 ;;; To be initialized in unix/win32-pathname.lisp
  17 (defvar *physical-host*)
  18
  19 (defun make-host-load-form (host)
  20   (declare (ignore host))
  21   '*physical-host*)
  22
  23 ;;; Return a value suitable, e.g., for preinitializing
  24 ;;; *DEFAULT-PATHNAME-DEFAULTS* before *DEFAULT-PATHNAME-DEFAULTS* is
  25 ;;; initialized (at which time we can't safely call e.g. #'PATHNAME).
  26 (defun make-trivial-default-pathname ()
  27   (%make-pathname *physical-host* nil nil nil nil :newest))
  28 \f
  29 ;;; pathname methods
  30
  31 (def!method print-object ((pathname pathname) stream)
  32   (let ((namestring (handler-case (namestring pathname)
  33                       (error nil))))
  34     (if namestring
  35         (format stream
  36                 (if (or *print-readably* *print-escape*)
  37                     "#P~S"
  38                     "~A")
  39                 (coerce namestring '(simple-array character (*))))
  40         (print-unreadable-object (pathname stream :type t)
  41           (format stream
  42                   "~@<(with no namestring) ~_:HOST ~S ~_:DEVICE ~S ~_:DIRECTORY ~S ~
  43                   ~_:NAME ~S ~_:TYPE ~S ~_:VERSION ~S~:>"
  44                   (%pathname-host pathname)
  45                   (%pathname-device pathname)
  46                   (%pathname-directory pathname)
  47                   (%pathname-name pathname)
  48                   (%pathname-type pathname)
  49                   (%pathname-version pathname))))))
  50
  51 (def!method make-load-form ((pathname pathname) &optional environment)
  52   (make-load-form-saving-slots pathname :environment environment))
  53 \f
  54 ;;; A pathname is logical if the host component is a logical host.
  55 ;;; This constructor is used to make an instance of the correct type
  56 ;;; from parsed arguments.
  57 (defun %make-maybe-logical-pathname (host device directory name type version)
  58   ;; We canonicalize logical pathname components to uppercase. ANSI
  59   ;; doesn't strictly require this, leaving it up to the implementor;
  60   ;; but the arguments given in the X3J13 cleanup issue
  61   ;; PATHNAME-LOGICAL:ADD seem compelling: we should canonicalize the
  62   ;; case, and uppercase is the ordinary way to do that.
  63   (flet ((upcase-maybe (x) (typecase x (string (logical-word-or-lose x)) (t x))))
  64     (if (typep host 'logical-host)
  65         (%make-logical-pathname host
  66                                 :unspecific
  67                                 (mapcar #'upcase-maybe directory)
  68                                 (upcase-maybe name)
  69                                 (upcase-maybe type)
  70                                 version)
  71         (progn
  72           (aver (eq host *physical-host*))
  73           (%make-pathname host device directory name type version)))))
  74
  75 ;;; Hash table searching maps a logical pathname's host to its
  76 ;;; physical pathname translation.
  77 (defvar *logical-hosts* (make-hash-table :test 'equal :synchronized t))
  78 \f
  79 ;;;; patterns
  80
  81 (def!method make-load-form ((pattern pattern) &optional environment)
  82   (make-load-form-saving-slots pattern :environment environment))
  83
  84 (def!method print-object ((pattern pattern) stream)
  85   (print-unreadable-object (pattern stream :type t)
  86     (if *print-pretty*
  87         (let ((*print-escape* t))
  88           (pprint-fill stream (pattern-pieces pattern) nil))
  89         (prin1 (pattern-pieces pattern) stream))))
  90
  91 (defun pattern= (pattern1 pattern2)
  92   (declare (type pattern pattern1 pattern2))
  93   (let ((pieces1 (pattern-pieces pattern1))
  94         (pieces2 (pattern-pieces pattern2)))
  95     (and (= (length pieces1) (length pieces2))
  96          (every (lambda (piece1 piece2)
  97                   (typecase piece1
  98                     (simple-string
  99                      (and (simple-string-p piece2)
 100                           (string= piece1 piece2)))
 101                     (cons
 102                      (and (consp piece2)
 103                           (eq (car piece1) (car piece2))
 104                           (string= (cdr piece1) (cdr piece2))))
 105                     (t
 106                      (eq piece1 piece2))))
 107                 pieces1
 108                 pieces2))))
 109
 110 ;;; If the string matches the pattern returns the multiple values T
 111 ;;; and a list of the matched strings.
 112 (defun pattern-matches (pattern string)
 113   (declare (type pattern pattern)
 114            (type simple-string string))
 115   (let ((len (length string)))
 116     (labels ((maybe-prepend (subs cur-sub chars)
 117                (if cur-sub
 118                    (let* ((len (length chars))
 119                           (new (make-string len))
 120                           (index len))
 121                      (dolist (char chars)
 122                        (setf (schar new (decf index)) char))
 123                      (cons new subs))
 124                    subs))
 125              (matches (pieces start subs cur-sub chars)
 126                (if (null pieces)
 127                    (if (= start len)
 128                        (values t (maybe-prepend subs cur-sub chars))
 129                        (values nil nil))
 130                    (let ((piece (car pieces)))
 131                      (etypecase piece
 132                        (simple-string
 133                         (let ((end (+ start (length piece))))
 134                           (and (<= end len)
 135                                (string= piece string
 136                                         :start2 start :end2 end)
 137                                (matches (cdr pieces) end
 138                                         (maybe-prepend subs cur-sub chars)
 139                                         nil nil))))
 140                        (list
 141                         (ecase (car piece)
 142                           (:character-set
 143                            (and (< start len)
 144                                 (let ((char (schar string start)))
 145                                   (if (find char (cdr piece) :test #'char=)
 146                                       (matches (cdr pieces) (1+ start) subs t
 147                                                (cons char chars))))))))
 148                        ((member :single-char-wild)
 149                         (and (< start len)
 150                              (matches (cdr pieces) (1+ start) subs t
 151                                       (cons (schar string start) chars))))
 152                        ((member :multi-char-wild)
 153                         (multiple-value-bind (won new-subs)
 154                             (matches (cdr pieces) start subs t chars)
 155                           (if won
 156                               (values t new-subs)
 157                               (and (< start len)
 158                                    (matches pieces (1+ start) subs t
 159                                             (cons (schar string start)
 160                                                   chars)))))))))))
 161       (multiple-value-bind (won subs)
 162           (matches (pattern-pieces pattern) 0 nil nil nil)
 163         (values won (reverse subs))))))
 164
 165 ;;; PATHNAME-MATCH-P for directory components
 166 (defun directory-components-match (thing wild)
 167   (or (eq thing wild)
 168       (eq wild :wild)
 169       ;; If THING has a null directory, assume that it matches
 170       ;; (:ABSOLUTE :WILD-INFERIORS) or (:RELATIVE :WILD-INFERIORS).
 171       (and (consp wild)
 172            (null thing)
 173            (member (first wild) '(:absolute :relative))
 174            (eq (second wild) :wild-inferiors))
 175       (and (consp wild)
 176            (let ((wild1 (first wild)))
 177              (if (eq wild1 :wild-inferiors)
 178                  (let ((wild-subdirs (rest wild)))
 179                    (or (null wild-subdirs)
 180                        (loop
 181                          (when (directory-components-match thing wild-subdirs)
 182                            (return t))
 183                          (pop thing)
 184                          (unless thing (return nil)))))
 185                  (and (consp thing)
 186                       (components-match (first thing) wild1)
 187                       (directory-components-match (rest thing)
 188                                                   (rest wild))))))))
 189
 190 ;;; Return true if pathname component THING is matched by WILD. (not
 191 ;;; commutative)
 192 (defun components-match (thing wild)
 193   (declare (type (or pattern symbol simple-string integer) thing wild))
 194   (or (eq thing wild)
 195       (eq wild :wild)
 196       (typecase thing
 197         (simple-string
 198          ;; String is matched by itself, a matching pattern or :WILD.
 199          (typecase wild
 200            (pattern
 201             (values (pattern-matches wild thing)))
 202            (simple-string
 203             (string= thing wild))))
 204         (pattern
 205          ;; A pattern is only matched by an identical pattern.
 206          (and (pattern-p wild) (pattern= thing wild)))
 207         (integer
 208          ;; An integer (version number) is matched by :WILD or the
 209          ;; same integer. This branch will actually always be NIL as
 210          ;; long as the version is a fixnum.
 211          (eql thing wild)))))
 212
 213 ;;; a predicate for comparing two pathname slot component sub-entries
 214 (defun compare-component (this that)
 215   (or (eql this that)
 216       (typecase this
 217         (simple-string
 218          (and (simple-string-p that)
 219               (string= this that)))
 220         (pattern
 221          (and (pattern-p that)
 222               (pattern= this that)))
 223         (cons
 224          (and (consp that)
 225               (compare-component (car this) (car that))
 226               (compare-component (cdr this) (cdr that)))))))
 227 \f
 228 ;;;; pathname functions
 229
 230 (defun pathname= (pathname1 pathname2)
 231   (declare (type pathname pathname1)
 232            (type pathname pathname2))
 233   (or (eq pathname1 pathname2)
 234       (and (eq (%pathname-host pathname1)
 235                (%pathname-host pathname2))
 236            (compare-component (%pathname-device pathname1)
 237                               (%pathname-device pathname2))
 238            (compare-component (%pathname-directory pathname1)
 239                               (%pathname-directory pathname2))
 240            (compare-component (%pathname-name pathname1)
 241                               (%pathname-name pathname2))
 242            (compare-component (%pathname-type pathname1)
 243                               (%pathname-type pathname2))
 244            (or (eq (%pathname-host pathname1) *physical-host*)
 245                (compare-component (%pathname-version pathname1)
 246                                   (%pathname-version pathname2))))))
 247
 248 ;;; Convert PATHNAME-DESIGNATOR (a pathname, or string, or
 249 ;;; stream), into a pathname in pathname.
 250 ;;;
 251 ;;; FIXME: was rewritten, should be tested (or rewritten again, this
 252 ;;; time using ONCE-ONLY, *then* tested)
 253 (eval-when (:compile-toplevel :execute)
 254 (sb!xc:defmacro with-pathname ((pathname pathname-designator) &body body)
 255   (let ((pd0 (gensym)))
 256     `(let* ((,pd0 ,pathname-designator)
 257             (,pathname (etypecase ,pd0
 258                          (pathname ,pd0)
 259                          (string (parse-namestring ,pd0))
 260                          (file-stream (file-name ,pd0)))))
 261        ,@body)))
 262
 263 (sb!xc:defmacro with-native-pathname ((pathname pathname-designator) &body body)
 264   (let ((pd0 (gensym)))
 265     `(let* ((,pd0 ,pathname-designator)
 266             (,pathname (etypecase ,pd0
 267                          (pathname ,pd0)
 268                          (string (parse-native-namestring ,pd0))
 269                          ;; FIXME
 270                          #+nil
 271                          (file-stream (file-name ,pd0)))))
 272        ,@body)))
 273
 274 (sb!xc:defmacro with-host ((host host-designator) &body body)
 275   ;; Generally, redundant specification of information in software,
 276   ;; whether in code or in comments, is bad. However, the ANSI spec
 277   ;; for this is messy enough that it's hard to hold in short-term
 278   ;; memory, so I've recorded these redundant notes on the
 279   ;; implications of the ANSI spec.
 280   ;;
 281   ;; According to the ANSI spec, HOST can be a valid pathname host, or
 282   ;; a logical host, or NIL.
 283   ;;
 284   ;; A valid pathname host can be a valid physical pathname host or a
 285   ;; valid logical pathname host.
 286   ;;
 287   ;; A valid physical pathname host is "any of a string, a list of
 288   ;; strings, or the symbol :UNSPECIFIC, that is recognized by the
 289   ;; implementation as the name of a host". In SBCL as of 0.6.9.8,
 290   ;; that means :UNSPECIFIC: though someday we might want to
 291   ;; generalize it to allow strings like "RTFM.MIT.EDU" or lists like
 292   ;; '("RTFM" "MIT" "EDU"), that's not supported now.
 293   ;;
 294   ;; A valid logical pathname host is a string which has been defined as
 295   ;; the name of a logical host, as with LOAD-LOGICAL-PATHNAME-TRANSLATIONS.
 296   ;;
 297   ;; A logical host is an object of implementation-dependent nature. In
 298   ;; SBCL, it's a member of the HOST class (a subclass of STRUCTURE-OBJECT).
 299   (let ((hd0 (gensym)))
 300     `(let* ((,hd0 ,host-designator)
 301             (,host (etypecase ,hd0
 302                      ((string 0)
 303                       ;; This is a special host. It's not valid as a
 304                       ;; logical host, so it is a sensible thing to
 305                       ;; designate the physical host object. So we do
 306                       ;; that.
 307                       *physical-host*)
 308                      (string
 309                       ;; In general ANSI-compliant Common Lisps, a
 310                       ;; string might also be a physical pathname
 311                       ;; host, but ANSI leaves this up to the
 312                       ;; implementor, and in SBCL we don't do it, so
 313                       ;; it must be a logical host.
 314                       (find-logical-host ,hd0))
 315                      ((or null (member :unspecific))
 316                       ;; CLHS says that HOST=:UNSPECIFIC has
 317                       ;; implementation-defined behavior. We
 318                       ;; just turn it into NIL.
 319                       nil)
 320                      (list
 321                       ;; ANSI also allows LISTs to designate hosts,
 322                       ;; but leaves its interpretation
 323                       ;; implementation-defined. Our interpretation
 324                       ;; is that it's unsupported.:-|
 325                       (error "A LIST representing a pathname host is not ~
 326                               supported in this implementation:~%  ~S"
 327                              ,hd0))
 328                      (host ,hd0))))
 329       ,@body)))
 330 ) ; EVAL-WHEN
 331
 332 (defun find-host (host-designator &optional (errorp t))
 333   (with-host (host host-designator)
 334     (when (and errorp (not host))
 335       (error "Couldn't find host: ~S" host-designator))
 336     host))
 337
 338 (defun pathname (pathspec)
 339   #!+sb-doc
 340   "Convert PATHSPEC (a pathname designator) into a pathname."
 341   (declare (type pathname-designator pathspec))
 342   (with-pathname (pathname pathspec)
 343     pathname))
 344
 345 (defun native-pathname (pathspec)
 346   #!+sb-doc
 347   "Convert PATHSPEC (a pathname designator) into a pathname, assuming
 348 the operating system native pathname conventions."
 349   (with-native-pathname (pathname pathspec)
 350     pathname))
 351
 352 ;;; Change the case of thing if DIDDLE-P.
 353 (defun maybe-diddle-case (thing diddle-p)
 354   (if (and diddle-p (not (or (symbolp thing) (integerp thing))))
 355       (labels ((check-for (pred in)
 356                  (typecase in
 357                    (pattern
 358                     (dolist (piece (pattern-pieces in))
 359                       (when (typecase piece
 360                               (simple-string
 361                                (check-for pred piece))
 362                               (cons
 363                                (case (car piece)
 364                                  (:character-set
 365                                   (check-for pred (cdr piece))))))
 366                         (return t))))
 367                    (list
 368                     (dolist (x in)
 369                       (when (check-for pred x)
 370                         (return t))))
 371                    (simple-string
 372                     (dotimes (i (length in))
 373                       (when (funcall pred (schar in i))
 374                         (return t))))
 375                    (t nil)))
 376                (diddle-with (fun thing)
 377                  (typecase thing
 378                    (pattern
 379                     (make-pattern
 380                      (mapcar (lambda (piece)
 381                                (typecase piece
 382                                  (simple-string
 383                                   (funcall fun piece))
 384                                  (cons
 385                                   (case (car piece)
 386                                     (:character-set
 387                                      (cons :character-set
 388                                            (funcall fun (cdr piece))))
 389                                     (t
 390                                      piece)))
 391                                  (t
 392                                   piece)))
 393                              (pattern-pieces thing))))
 394                    (list
 395                     (mapcar fun thing))
 396                    (simple-string
 397                     (funcall fun thing))
 398                    (t
 399                     thing))))
 400         (let ((any-uppers (check-for #'upper-case-p thing))
 401               (any-lowers (check-for #'lower-case-p thing)))
 402           (cond ((and any-uppers any-lowers)
 403                  ;; mixed case, stays the same
 404                  thing)
 405                 (any-uppers
 406                  ;; all uppercase, becomes all lower case
 407                  (diddle-with (lambda (x) (if (stringp x)
 408                                               (string-downcase x)
 409                                               x)) thing))
 410                 (any-lowers
 411                  ;; all lowercase, becomes all upper case
 412                  (diddle-with (lambda (x) (if (stringp x)
 413                                               (string-upcase x)
 414                                               x)) thing))
 415                 (t
 416                  ;; no letters?  I guess just leave it.
 417                  thing))))
 418       thing))
 419
 420 (defun merge-directories (dir1 dir2 diddle-case)
 421   (if (or (eq (car dir1) :absolute)
 422           (null dir2))
 423       dir1
 424       (let ((results nil))
 425         (flet ((add (dir)
 426                  (if (and (eq dir :back)
 427                           results
 428                           (typep (car results) '(or string pattern
 429                                                  (member :wild :wild-inferiors))))
 430                      (pop results)
 431                      (push dir results))))
 432           (dolist (dir (maybe-diddle-case dir2 diddle-case))
 433             (add dir))
 434           (dolist (dir (cdr dir1))
 435             (add dir)))
 436         (reverse results))))
 437
 438 (defun merge-pathnames (pathname
 439                         &optional
 440                         (defaults *default-pathname-defaults*)
 441                         (default-version :newest))
 442   #!+sb-doc
 443   "Construct a filled in pathname by completing the unspecified components
 444    from the defaults."
 445   (declare (type pathname-designator pathname)
 446            (type pathname-designator defaults)
 447            (values pathname))
 448   (with-pathname (defaults defaults)
 449     (let ((pathname (let ((*default-pathname-defaults* defaults))
 450                       (pathname pathname))))
 451       (let* ((default-host (%pathname-host defaults))
 452              (pathname-host (%pathname-host pathname))
 453              (diddle-case
 454               (and default-host pathname-host
 455                    (not (eq (host-customary-case default-host)
 456                             (host-customary-case pathname-host)))))
 457              (directory (merge-directories (%pathname-directory pathname)
 458                                            (%pathname-directory defaults)
 459                                            diddle-case)))
 460         (%make-maybe-logical-pathname
 461          (or pathname-host default-host)
 462          (and ;; The device of ~/ shouldn't be merged,
 463               ;; because the expansion may have a different device
 464               (not (and (>= (length directory) 2)
 465                         (eql (car directory) :absolute)
 466                         (eql (cadr directory) :home)))
 467               (or (%pathname-device pathname)
 468                   (maybe-diddle-case (%pathname-device defaults)
 469                                      diddle-case)))
 470          directory
 471          (or (%pathname-name pathname)
 472              (maybe-diddle-case (%pathname-name defaults)
 473                                 diddle-case))
 474          (or (%pathname-type pathname)
 475              (maybe-diddle-case (%pathname-type defaults)
 476                                 diddle-case))
 477          (or (%pathname-version pathname)
 478              (and (not (%pathname-name pathname)) (%pathname-version defaults))
 479              default-version))))))
 480
 481 (defun import-directory (directory diddle-case)
 482   (etypecase directory
 483     (null nil)
 484     ((member :wild) '(:absolute :wild-inferiors))
 485     ((member :unspecific) '(:relative))
 486     (list
 487      (let ((root (pop directory))
 488            results)
 489        (if (member root '(:relative :absolute))
 490            (push root results)
 491            (error "List of directory components must start with ~S or ~S."
 492                   :absolute :relative))
 493        (when directory
 494          (let ((next (car directory)))
 495            (when (or (eq :home next)
 496                      (typep next '(cons (eql :home) (cons string null))))
 497              (push (pop directory) results)))
 498          (dolist (piece directory)
 499            (typecase piece
 500              ((member :wild :wild-inferiors :up)
 501               (push piece results))
 502              ((member :back)
 503               (if (typep (car results) '(or string pattern
 504                                          (member :wild :wild-inferiors)))
 505                   (pop results)
 506                   (push piece results)))
 507              ((or simple-string pattern)
 508               (push (maybe-diddle-case piece diddle-case) results))
 509              (string
 510               (push (maybe-diddle-case (coerce piece 'simple-string)
 511                                        diddle-case) results))
 512
 513              (t
 514               (error "~S is not allowed as a directory component." piece)))))
 515        (nreverse results)))
 516     (simple-string
 517      `(:absolute ,(maybe-diddle-case directory diddle-case)))
 518     (string
 519      `(:absolute
 520        ,(maybe-diddle-case (coerce directory 'simple-string) diddle-case)))))
 521
 522 (defun make-pathname (&key host
 523                            (device nil devp)
 524                            (directory nil dirp)
 525                            (name nil namep)
 526                            (type nil typep)
 527                            (version nil versionp)
 528                            defaults
 529                            (case :local))
 530   #!+sb-doc
 531   "Makes a new pathname from the component arguments. Note that host is
 532 a host-structure or string."
 533   (declare (type (or string host pathname-component-tokens) host)
 534            (type (or string pathname-component-tokens) device)
 535            (type (or list string pattern pathname-component-tokens) directory)
 536            (type (or string pattern pathname-component-tokens) name type)
 537            (type (or integer pathname-component-tokens (member :newest))
 538                  version)
 539            (type (or pathname-designator null) defaults)
 540            (type (member :common :local) case))
 541   (let* ((defaults (when defaults
 542                      (with-pathname (defaults defaults) defaults)))
 543          (default-host (if defaults
 544                            (%pathname-host defaults)
 545                            (pathname-host *default-pathname-defaults*)))
 546          ;; Raymond Toy writes: CLHS says make-pathname can take a
 547          ;; string (as a logical-host) for the host part. We map that
 548          ;; string into the corresponding logical host structure.
 549          ;;
 550          ;; Paul Werkowski writes:
 551          ;; HyperSpec says for the arg to MAKE-PATHNAME;
 552          ;; "host---a valid physical pathname host. ..."
 553          ;; where it probably means -- a valid pathname host.
 554          ;; "valid pathname host n. a valid physical pathname host or
 555          ;; a valid logical pathname host."
 556          ;; and defines
 557          ;; "valid physical pathname host n. any of a string,
 558          ;; a list of strings, or the symbol :unspecific,
 559          ;; that is recognized by the implementation as the name of a host."
 560          ;; "valid logical pathname host n. a string that has been defined
 561          ;; as the name of a logical host. ..."
 562          ;; HS is silent on what happens if the :HOST arg is NOT one of these.
 563          ;; It seems an error message is appropriate.
 564          (host (or (find-host host nil) default-host))
 565          (diddle-args (and (eq (host-customary-case host) :lower)
 566                            (eq case :common)))
 567          (diddle-defaults
 568           (not (eq (host-customary-case host)
 569                    (host-customary-case default-host))))
 570          (dev (if devp device (if defaults (%pathname-device defaults))))
 571          (dir (import-directory directory diddle-args))
 572          (ver (cond
 573                (versionp version)
 574                (defaults (%pathname-version defaults))
 575                (t nil))))
 576     (when (and defaults (not dirp))
 577       (setf dir
 578             (merge-directories dir
 579                                (%pathname-directory defaults)
 580                                diddle-defaults)))
 581
 582     (macrolet ((pick (var varp field)
 583                  `(cond ((or (simple-string-p ,var)
 584                              (pattern-p ,var))
 585                          (maybe-diddle-case ,var diddle-args))
 586                         ((stringp ,var)
 587                          (maybe-diddle-case (coerce ,var 'simple-string)
 588                                             diddle-args))
 589                         (,varp
 590                          (maybe-diddle-case ,var diddle-args))
 591                         (defaults
 592                          (maybe-diddle-case (,field defaults)
 593                                             diddle-defaults))
 594                         (t
 595                          nil))))
 596       (%make-maybe-logical-pathname host
 597                                     dev ; forced to :UNSPECIFIC when logical
 598                                     dir
 599                                     (pick name namep %pathname-name)
 600                                     (pick type typep %pathname-type)
 601                                     ver))))
 602
 603 (defun pathname-host (pathname &key (case :local))
 604   #!+sb-doc
 605   "Return PATHNAME's host."
 606   (declare (type pathname-designator pathname)
 607            (type (member :local :common) case)
 608            (values host)
 609            (ignore case))
 610   (with-pathname (pathname pathname)
 611     (%pathname-host pathname)))
 612
 613 (defun pathname-device (pathname &key (case :local))
 614   #!+sb-doc
 615   "Return PATHNAME's device."
 616   (declare (type pathname-designator pathname)
 617            (type (member :local :common) case))
 618   (with-pathname (pathname pathname)
 619     (maybe-diddle-case (%pathname-device pathname)
 620                        (and (eq case :common)
 621                             (eq (host-customary-case
 622                                  (%pathname-host pathname))
 623                                 :lower)))))
 624
 625 (defun pathname-directory (pathname &key (case :local))
 626   #!+sb-doc
 627   "Return PATHNAME's directory."
 628   (declare (type pathname-designator pathname)
 629            (type (member :local :common) case))
 630   (with-pathname (pathname pathname)
 631     (maybe-diddle-case (%pathname-directory pathname)
 632                        (and (eq case :common)
 633                             (eq (host-customary-case
 634                                  (%pathname-host pathname))
 635                                 :lower)))))
 636 (defun pathname-name (pathname &key (case :local))
 637   #!+sb-doc
 638   "Return PATHNAME's name."
 639   (declare (type pathname-designator pathname)
 640            (type (member :local :common) case))
 641   (with-pathname (pathname pathname)
 642     (maybe-diddle-case (%pathname-name pathname)
 643                        (and (eq case :common)
 644                             (eq (host-customary-case
 645                                  (%pathname-host pathname))
 646                                 :lower)))))
 647
 648 (defun pathname-type (pathname &key (case :local))
 649   #!+sb-doc
 650   "Return PATHNAME's type."
 651   (declare (type pathname-designator pathname)
 652            (type (member :local :common) case))
 653   (with-pathname (pathname pathname)
 654     (maybe-diddle-case (%pathname-type pathname)
 655                        (and (eq case :common)
 656                             (eq (host-customary-case
 657                                  (%pathname-host pathname))
 658                                 :lower)))))
 659
 660 (defun pathname-version (pathname)
 661   #!+sb-doc
 662   "Return PATHNAME's version."
 663   (declare (type pathname-designator pathname))
 664   (with-pathname (pathname pathname)
 665     (%pathname-version pathname)))
 666 \f
 667 ;;;; namestrings
 668
 669 ;;; Handle the case for PARSE-NAMESTRING parsing a potentially
 670 ;;; syntactically valid logical namestring with an explicit host.
 671 ;;;
 672 ;;; This then isn't fully general -- we are relying on the fact that
 673 ;;; we will only pass to parse-namestring namestring with an explicit
 674 ;;; logical host, so that we can pass the host return from
 675 ;;; parse-logical-namestring through to %PARSE-NAMESTRING as a truth
 676 ;;; value. Yeah, this is probably a KLUDGE - CSR, 2002-04-18
 677 (defun parseable-logical-namestring-p (namestr start end)
 678   (catch 'exit
 679     (handler-bind
 680         ((namestring-parse-error (lambda (c)
 681                                    (declare (ignore c))
 682                                    (throw 'exit nil))))
 683       (let ((colon (position #\: namestr :start start :end end)))
 684         (when colon
 685           (let ((potential-host
 686                  (logical-word-or-lose (subseq namestr start colon))))
 687             ;; depending on the outcome of CSR comp.lang.lisp post
 688             ;; "can PARSE-NAMESTRING create logical hosts", we may need
 689             ;; to do things with potential-host (create it
 690             ;; temporarily, parse the namestring and unintern the
 691             ;; logical host potential-host on failure.
 692             (declare (ignore potential-host))
 693             (let ((result
 694                    (handler-bind
 695                        ((simple-type-error (lambda (c)
 696                                              (declare (ignore c))
 697                                              (throw 'exit nil))))
 698                      (parse-logical-namestring namestr start end))))
 699               ;; if we got this far, we should have an explicit host
 700               ;; (first return value of parse-logical-namestring)
 701               (aver result)
 702               result)))))))
 703
 704 ;;; Handle the case where PARSE-NAMESTRING is actually parsing a
 705 ;;; namestring. We pick off the :JUNK-ALLOWED case then find a host to
 706 ;;; use for parsing, call the parser, then check whether the host matches.
 707 (defun %parse-namestring (namestr host defaults start end junk-allowed)
 708   (declare (type (or host null) host)
 709            (type string namestr)
 710            (type index start)
 711            (type (or index null) end))
 712   (cond
 713     (junk-allowed
 714      (handler-case
 715          (%parse-namestring namestr host defaults start end nil)
 716        (namestring-parse-error (condition)
 717          (values nil (namestring-parse-error-offset condition)))))
 718     (t
 719      (let* ((end (%check-vector-sequence-bounds namestr start end)))
 720        (multiple-value-bind (new-host device directory file type version)
 721            ;; Comments below are quotes from the HyperSpec
 722            ;; PARSE-NAMESTRING entry, reproduced here to demonstrate
 723            ;; that we actually have to do things this way rather than
 724            ;; some possibly more logical way. - CSR, 2002-04-18
 725            (cond
 726              ;; "If host is a logical host then thing is parsed as a
 727              ;; logical pathname namestring on the host."
 728              (host (funcall (host-parse host) namestr start end))
 729              ;; "If host is nil and thing is a syntactically valid
 730              ;; logical pathname namestring containing an explicit
 731              ;; host, then it is parsed as a logical pathname
 732              ;; namestring."
 733              ((parseable-logical-namestring-p namestr start end)
 734               (parse-logical-namestring namestr start end))
 735              ;; "If host is nil, default-pathname is a logical
 736              ;; pathname, and thing is a syntactically valid logical
 737              ;; pathname namestring without an explicit host, then it
 738              ;; is parsed as a logical pathname namestring on the
 739              ;; host that is the host component of default-pathname."
 740              ;;
 741              ;; "Otherwise, the parsing of thing is
 742              ;; implementation-defined."
 743              ;;
 744              ;; Both clauses are handled here, as the default
 745              ;; *DEFAULT-PATHNAME-DEFAULTS* has a SB-IMPL::UNIX-HOST
 746              ;; for a host.
 747              ((pathname-host defaults)
 748               (funcall (host-parse (pathname-host defaults))
 749                        namestr
 750                        start
 751                        end))
 752              ;; I don't think we should ever get here, as the default
 753              ;; host will always have a non-null HOST, given that we
 754              ;; can't create a new pathname without going through
 755              ;; *DEFAULT-PATHNAME-DEFAULTS*, which has a non-null
 756              ;; host...
 757              (t (bug "Fallen through COND in %PARSE-NAMESTRING")))
 758          (when (and host new-host (not (eq new-host host)))
 759            (error 'simple-type-error
 760                   :datum new-host
 761                   ;; Note: ANSI requires that this be a TYPE-ERROR,
 762                   ;; but there seems to be no completely correct
 763                   ;; value to use for TYPE-ERROR-EXPECTED-TYPE.
 764                   ;; Instead, we return a sort of "type error allowed
 765                   ;; type", trying to say "it would be OK if you
 766                   ;; passed NIL as the host value" but not mentioning
 767                   ;; that a matching string would be OK too.
 768                   :expected-type 'null
 769                   :format-control
 770                   "The host in the namestring, ~S,~@
 771                    does not match the explicit HOST argument, ~S."
 772                   :format-arguments (list new-host host)))
 773          (let ((pn-host (or new-host host (pathname-host defaults))))
 774            (values (%make-maybe-logical-pathname
 775                     pn-host device directory file type version)
 776                    end)))))))
 777
 778 ;;; If NAMESTR begins with a colon-terminated, defined, logical host,
 779 ;;; then return that host, otherwise return NIL.
 780 (defun extract-logical-host-prefix (namestr start end)
 781   (declare (type simple-string namestr)
 782            (type index start end)
 783            (values (or logical-host null)))
 784   (let ((colon-pos (position #\: namestr :start start :end end)))
 785     (if colon-pos
 786         (values (gethash (nstring-upcase (subseq namestr start colon-pos))
 787                          *logical-hosts*))
 788         nil)))
 789
 790 (defun parse-namestring (thing
 791                          &optional
 792                          host
 793                          (defaults *default-pathname-defaults*)
 794                          &key (start 0) end junk-allowed)
 795   (declare (type pathname-designator thing defaults)
 796            (type (or list host string (member :unspecific)) host)
 797            (type index start)
 798            (type (or index null) end)
 799            (type (or t null) junk-allowed)
 800            (values (or null pathname) (or null index)))
 801   (with-host (found-host host)
 802     (let (;; According to ANSI defaults may be any valid pathname designator
 803           (defaults (etypecase defaults
 804                       (pathname
 805                        defaults)
 806                       (string
 807                        (aver (pathnamep *default-pathname-defaults*))
 808                        (parse-namestring defaults))
 809                       (stream
 810                        (truename defaults)))))
 811       (declare (type pathname defaults))
 812       (etypecase thing
 813         (simple-string
 814          (%parse-namestring thing found-host defaults start end junk-allowed))
 815         (string
 816          (%parse-namestring (coerce thing 'simple-string)
 817                             found-host defaults start end junk-allowed))
 818         (pathname
 819          (let ((defaulted-host (or found-host (%pathname-host defaults))))
 820            (declare (type host defaulted-host))
 821            (unless (eq defaulted-host (%pathname-host thing))
 822              (error "The HOST argument doesn't match the pathname host:~%  ~
 823                     ~S and ~S."
 824                     defaulted-host (%pathname-host thing))))
 825          (values thing start))
 826         (stream
 827          (let ((name (file-name thing)))
 828            (unless name
 829              (error "can't figure out the file associated with stream:~%  ~S"
 830                     thing))
 831            (values name nil)))))))
 832
 833 (defun %parse-native-namestring (namestr host defaults start end junk-allowed
 834                                  as-directory)
 835   (declare (type (or host null) host)
 836            (type string namestr)
 837            (type index start)
 838            (type (or index null) end))
 839   (cond
 840     (junk-allowed
 841      (handler-case
 842          (%parse-native-namestring namestr host defaults start end nil as-directory)
 843        (namestring-parse-error (condition)
 844          (values nil (namestring-parse-error-offset condition)))))
 845     (t
 846      (let* ((end (%check-vector-sequence-bounds namestr start end)))
 847        (multiple-value-bind (new-host device directory file type version)
 848            (cond
 849              (host
 850               (funcall (host-parse-native host) namestr start end as-directory))
 851              ((pathname-host defaults)
 852               (funcall (host-parse-native (pathname-host defaults))
 853                        namestr
 854                        start
 855                        end
 856                        as-directory))
 857              ;; I don't think we should ever get here, as the default
 858              ;; host will always have a non-null HOST, given that we
 859              ;; can't create a new pathname without going through
 860              ;; *DEFAULT-PATHNAME-DEFAULTS*, which has a non-null
 861              ;; host...
 862              (t (bug "Fallen through COND in %PARSE-NAMESTRING")))
 863          (when (and host new-host (not (eq new-host host)))
 864            (error 'simple-type-error
 865                   :datum new-host
 866                   :expected-type `(or null (eql ,host))
 867                   :format-control
 868                   "The host in the namestring, ~S,~@
 869                    does not match the explicit HOST argument, ~S."
 870                   :format-arguments (list new-host host)))
 871          (let ((pn-host (or new-host host (pathname-host defaults))))
 872            (values (%make-pathname
 873                     pn-host device directory file type version)
 874                    end)))))))
 875
 876 (defun parse-native-namestring (thing
 877                                 &optional
 878                                 host
 879                                 (defaults *default-pathname-defaults*)
 880                                 &key (start 0) end junk-allowed
 881                                 as-directory)
 882   #!+sb-doc
 883   "Convert THING into a pathname, using the native conventions
 884 appropriate for the pathname host HOST, or if not specified the
 885 host of DEFAULTS.  If THING is a string, the parse is bounded by
 886 START and END, and error behaviour is controlled by JUNK-ALLOWED,
 887 as with PARSE-NAMESTRING.  For file systems whose native
 888 conventions allow directories to be indicated as files, if
 889 AS-DIRECTORY is true, return a pathname denoting THING as a
 890 directory."
 891   (declare (type pathname-designator thing defaults)
 892            (type (or list host string (member :unspecific)) host)
 893            (type index start)
 894            (type (or index null) end)
 895            (type (or t null) junk-allowed)
 896            (values (or null pathname) (or null index)))
 897   (with-host (found-host host)
 898     (let ((defaults (etypecase defaults
 899                       (pathname
 900                        defaults)
 901                       (string
 902                        (aver (pathnamep *default-pathname-defaults*))
 903                        (parse-native-namestring defaults))
 904                       (stream
 905                        (truename defaults)))))
 906       (declare (type pathname defaults))
 907       (etypecase thing
 908         (simple-string
 909          (%parse-native-namestring
 910           thing found-host defaults start end junk-allowed as-directory))
 911         (string
 912          (%parse-native-namestring (coerce thing 'simple-string)
 913                                    found-host defaults start end junk-allowed
 914                                    as-directory))
 915         (pathname
 916          (let ((defaulted-host (or found-host (%pathname-host defaults))))
 917            (declare (type host defaulted-host))
 918            (unless (eq defaulted-host (%pathname-host thing))
 919              (error "The HOST argument doesn't match the pathname host:~%  ~
 920                      ~S and ~S."
 921                     defaulted-host (%pathname-host thing))))
 922          (values thing start))
 923         (stream
 924          ;; FIXME
 925          (let ((name (file-name thing)))
 926            (unless name
 927              (error "can't figure out the file associated with stream:~%  ~S"
 928                     thing))
 929            (values name nil)))))))
 930
 931 (defun namestring (pathname)
 932   #!+sb-doc
 933   "Construct the full (name)string form of the pathname."
 934   (declare (type pathname-designator pathname))
 935   (with-pathname (pathname pathname)
 936     (when pathname
 937       (let ((host (%pathname-host pathname)))
 938         (unless host
 939           (error "can't determine the namestring for pathnames with no ~
 940                   host:~%  ~S" pathname))
 941         (funcall (host-unparse host) pathname)))))
 942
 943 (defun native-namestring (pathname &key as-file)
 944   #!+sb-doc
 945   "Construct the full native (name)string form of PATHNAME.  For
 946 file systems whose native conventions allow directories to be
 947 indicated as files, if AS-FILE is true and the name, type, and
 948 version components of PATHNAME are all NIL or :UNSPECIFIC,
 949 construct a string that names the directory according to the file
 950 system's syntax for files."
 951   (declare (type pathname-designator pathname))
 952   (with-native-pathname (pathname pathname)
 953     (when pathname
 954       (let ((host (%pathname-host pathname)))
 955         (unless host
 956           (error "can't determine the native namestring for pathnames with no ~
 957                   host:~%  ~S" pathname))
 958         (funcall (host-unparse-native host) pathname as-file)))))
 959
 960 (defun host-namestring (pathname)
 961   #!+sb-doc
 962   "Return a string representation of the name of the host in the pathname."
 963   (declare (type pathname-designator pathname))
 964   (with-pathname (pathname pathname)
 965     (let ((host (%pathname-host pathname)))
 966       (if host
 967           (funcall (host-unparse-host host) pathname)
 968           (error
 969            "can't determine the namestring for pathnames with no host:~%  ~S"
 970            pathname)))))
 971
 972 (defun directory-namestring (pathname)
 973   #!+sb-doc
 974   "Return a string representation of the directories used in the pathname."
 975   (declare (type pathname-designator pathname))
 976   (with-pathname (pathname pathname)
 977     (let ((host (%pathname-host pathname)))
 978       (if host
 979           (funcall (host-unparse-directory host) pathname)
 980           (error
 981            "can't determine the namestring for pathnames with no host:~%  ~S"
 982            pathname)))))
 983
 984 (defun file-namestring (pathname)
 985   #!+sb-doc
 986   "Return a string representation of the name used in the pathname."
 987   (declare (type pathname-designator pathname))
 988   (with-pathname (pathname pathname)
 989     (let ((host (%pathname-host pathname)))
 990       (if host
 991           (funcall (host-unparse-file host) pathname)
 992           (error
 993            "can't determine the namestring for pathnames with no host:~%  ~S"
 994            pathname)))))
 995
 996 (defun enough-namestring (pathname
 997                           &optional
 998                           (defaults *default-pathname-defaults*))
 999   #!+sb-doc
1000   "Return an abbreviated pathname sufficient to identify the pathname relative
1001    to the defaults."
1002   (declare (type pathname-designator pathname))
1003   (with-pathname (pathname pathname)
1004     (let ((host (%pathname-host pathname)))
1005       (if host
1006           (with-pathname (defaults defaults)
1007             (funcall (host-unparse-enough host) pathname defaults))
1008           (error
1009            "can't determine the namestring for pathnames with no host:~%  ~S"
1010            pathname)))))
1011 \f
1012 ;;;; wild pathnames
1013
1014 (defun wild-pathname-p (pathname &optional field-key)
1015   #!+sb-doc
1016   "Predicate for determining whether pathname contains any wildcards."
1017   (declare (type pathname-designator pathname)
1018            (type (member nil :host :device :directory :name :type :version)
1019                  field-key))
1020   (with-pathname (pathname pathname)
1021     (flet ((frob (x)
1022              (or (pattern-p x) (member x '(:wild :wild-inferiors)))))
1023       (ecase field-key
1024         ((nil)
1025          (or (wild-pathname-p pathname :host)
1026              (wild-pathname-p pathname :device)
1027              (wild-pathname-p pathname :directory)
1028              (wild-pathname-p pathname :name)
1029              (wild-pathname-p pathname :type)
1030              (wild-pathname-p pathname :version)))
1031         (:host (frob (%pathname-host pathname)))
1032         (:device (frob (%pathname-host pathname)))
1033         (:directory (some #'frob (%pathname-directory pathname)))
1034         (:name (frob (%pathname-name pathname)))
1035         (:type (frob (%pathname-type pathname)))
1036         (:version (frob (%pathname-version pathname)))))))
1037
1038 (defun pathname-match-p (in-pathname in-wildname)
1039   #!+sb-doc
1040   "Pathname matches the wildname template?"
1041   (declare (type pathname-designator in-pathname))
1042   (with-pathname (pathname in-pathname)
1043     (with-pathname (wildname in-wildname)
1044       (macrolet ((frob (field &optional (op 'components-match))
1045                    `(or (null (,field wildname))
1046                         (,op (,field pathname) (,field wildname)))))
1047         (and (or (null (%pathname-host wildname))
1048                  (eq (%pathname-host wildname) (%pathname-host pathname)))
1049              (frob %pathname-device)
1050              (frob %pathname-directory directory-components-match)
1051              (frob %pathname-name)
1052              (frob %pathname-type)
1053              (or (eq (%pathname-host wildname) *physical-host*)
1054                  (frob %pathname-version)))))))
1055
1056 ;;; Place the substitutions into the pattern and return the string or pattern
1057 ;;; that results. If DIDDLE-CASE is true, we diddle the result case as well,
1058 ;;; in case we are translating between hosts with difference conventional case.
1059 ;;; The second value is the tail of subs with all of the values that we used up
1060 ;;; stripped off. Note that PATTERN-MATCHES matches all consecutive wildcards
1061 ;;; as a single string, so we ignore subsequent contiguous wildcards.
1062 (defun substitute-into (pattern subs diddle-case)
1063   (declare (type pattern pattern)
1064            (type list subs)
1065            (values (or simple-string pattern) list))
1066   (let ((in-wildcard nil)
1067         (pieces nil)
1068         (strings nil))
1069     (dolist (piece (pattern-pieces pattern))
1070       (cond ((simple-string-p piece)
1071              (push piece strings)
1072              (setf in-wildcard nil))
1073             (in-wildcard)
1074             (t
1075              (setf in-wildcard t)
1076              (unless subs
1077                (error "not enough wildcards in FROM pattern to match ~
1078                        TO pattern:~%  ~S"
1079                       pattern))
1080              (let ((sub (pop subs)))
1081                (typecase sub
1082                  (pattern
1083                   (when strings
1084                     (push (apply #'concatenate 'simple-string
1085                                  (nreverse strings))
1086                           pieces))
1087                   (dolist (piece (pattern-pieces sub))
1088                     (push piece pieces)))
1089                  (simple-string
1090                   (push sub strings))
1091                  (t
1092                   (error "can't substitute this into the middle of a word:~
1093                           ~%  ~S"
1094                          sub)))))))
1095
1096     (when strings
1097       (push (apply #'concatenate 'simple-string (nreverse strings))
1098             pieces))
1099     (values
1100      (maybe-diddle-case
1101       (if (and pieces (simple-string-p (car pieces)) (null (cdr pieces)))
1102           (car pieces)
1103           (make-pattern (nreverse pieces)))
1104       diddle-case)
1105      subs)))
1106
1107 ;;; Called when we can't see how source and from matched.
1108 (defun didnt-match-error (source from)
1109   (error "Pathname components from SOURCE and FROM args to TRANSLATE-PATHNAME~@
1110           did not match:~%  ~S ~S"
1111          source from))
1112
1113 ;;; Do TRANSLATE-COMPONENT for all components except host, directory
1114 ;;; and version.
1115 (defun translate-component (source from to diddle-case)
1116   (typecase to
1117     (pattern
1118      (typecase from
1119        (pattern
1120         (typecase source
1121           (pattern
1122            (if (pattern= from source)
1123                source
1124                (didnt-match-error source from)))
1125           (simple-string
1126            (multiple-value-bind (won subs) (pattern-matches from source)
1127              (if won
1128                  (values (substitute-into to subs diddle-case))
1129                  (didnt-match-error source from))))
1130           (t
1131            (maybe-diddle-case source diddle-case))))
1132        ((member :wild)
1133         (values (substitute-into to (list source) diddle-case)))
1134        (t
1135         (if (components-match source from)
1136             (maybe-diddle-case source diddle-case)
1137             (didnt-match-error source from)))))
1138     ((member nil :wild)
1139      (maybe-diddle-case source diddle-case))
1140     (t
1141      (if (components-match source from)
1142          to
1143          (didnt-match-error source from)))))
1144
1145 ;;; Return a list of all the things that we want to substitute into the TO
1146 ;;; pattern (the things matched by from on source.)  When From contains
1147 ;;; :WILD-INFERIORS, the result contains a sublist of the matched source
1148 ;;; subdirectories.
1149 (defun compute-directory-substitutions (orig-source orig-from)
1150   (let ((source orig-source)
1151         (from orig-from))
1152     (collect ((subs))
1153       (loop
1154         (unless source
1155           (unless (every (lambda (x) (eq x :wild-inferiors)) from)
1156             (didnt-match-error orig-source orig-from))
1157           (subs ())
1158           (return))
1159         (unless from (didnt-match-error orig-source orig-from))
1160         (let ((from-part (pop from))
1161               (source-part (pop source)))
1162           (typecase from-part
1163             (pattern
1164              (typecase source-part
1165                (pattern
1166                 (if (pattern= from-part source-part)
1167                     (subs source-part)
1168                     (didnt-match-error orig-source orig-from)))
1169                (simple-string
1170                 (multiple-value-bind (won new-subs)
1171                     (pattern-matches from-part source-part)
1172                   (if won
1173                       (dolist (sub new-subs)
1174                         (subs sub))
1175                       (didnt-match-error orig-source orig-from))))
1176                (t
1177                 (didnt-match-error orig-source orig-from))))
1178             ((member :wild)
1179              (subs source-part))
1180             ((member :wild-inferiors)
1181              (let ((remaining-source (cons source-part source)))
1182                (collect ((res))
1183                  (loop
1184                    (when (directory-components-match remaining-source from)
1185                      (return))
1186                    (unless remaining-source
1187                      (didnt-match-error orig-source orig-from))
1188                    (res (pop remaining-source)))
1189                  (subs (res))
1190                  (setq source remaining-source))))
1191             (simple-string
1192              (unless (and (simple-string-p source-part)
1193                           (string= from-part source-part))
1194                (didnt-match-error orig-source orig-from)))
1195             (t
1196              (didnt-match-error orig-source orig-from)))))
1197       (subs))))
1198
1199 ;;; This is called by TRANSLATE-PATHNAME on the directory components
1200 ;;; of its argument pathnames to produce the result directory
1201 ;;; component. If this leaves the directory NIL, we return the source
1202 ;;; directory. The :RELATIVE or :ABSOLUTE is taken from the source
1203 ;;; directory, except if TO is :ABSOLUTE, in which case the result
1204 ;;; will be :ABSOLUTE.
1205 (defun translate-directories (source from to diddle-case)
1206   (if (not (and source to from))
1207       (or (and to (null source) (remove :wild-inferiors to))
1208           (mapcar (lambda (x) (maybe-diddle-case x diddle-case)) source))
1209       (collect ((res))
1210                ;; If TO is :ABSOLUTE, the result should still be :ABSOLUTE.
1211                (res (if (eq (first to) :absolute)
1212                  :absolute
1213                  (first source)))
1214         (let ((subs-left (compute-directory-substitutions (rest source)
1215                                                           (rest from))))
1216           (dolist (to-part (rest to))
1217             (typecase to-part
1218               ((member :wild)
1219                (aver subs-left)
1220                (let ((match (pop subs-left)))
1221                  (when (listp match)
1222                    (error ":WILD-INFERIORS is not paired in from and to ~
1223                            patterns:~%  ~S ~S" from to))
1224                  (res (maybe-diddle-case match diddle-case))))
1225               ((member :wild-inferiors)
1226                (aver subs-left)
1227                (let ((match (pop subs-left)))
1228                  (unless (listp match)
1229                    (error ":WILD-INFERIORS not paired in from and to ~
1230                            patterns:~%  ~S ~S" from to))
1231                  (dolist (x match)
1232                    (res (maybe-diddle-case x diddle-case)))))
1233               (pattern
1234                (multiple-value-bind
1235                    (new new-subs-left)
1236                    (substitute-into to-part subs-left diddle-case)
1237                  (setf subs-left new-subs-left)
1238                  (res new)))
1239               (t (res to-part)))))
1240         (res))))
1241
1242 (defun translate-pathname (source from-wildname to-wildname &key)
1243   #!+sb-doc
1244   "Use the source pathname to translate the from-wildname's wild and
1245 unspecified elements into a completed to-pathname based on the to-wildname."
1246   (declare (type pathname-designator source from-wildname to-wildname))
1247   (with-pathname (source source)
1248     (with-pathname (from from-wildname)
1249       (with-pathname (to to-wildname)
1250           (let* ((source-host (%pathname-host source))
1251                  (from-host (%pathname-host from))
1252                  (to-host (%pathname-host to))
1253                  (diddle-case
1254                   (and source-host to-host
1255                        (not (eq (host-customary-case source-host)
1256                                 (host-customary-case to-host))))))
1257             (macrolet ((frob (field &optional (op 'translate-component))
1258                          `(let ((result (,op (,field source)
1259                                              (,field from)
1260                                              (,field to)
1261                                              diddle-case)))
1262                             (if (eq result :error)
1263                                 (error "~S doesn't match ~S." source from)
1264                                 result))))
1265               (%make-maybe-logical-pathname
1266                (or to-host source-host)
1267                (frob %pathname-device)
1268                (frob %pathname-directory translate-directories)
1269                (frob %pathname-name)
1270                (frob %pathname-type)
1271                (if (eq from-host *physical-host*)
1272                    (if (or (eq (%pathname-version to) :wild)
1273                            (eq (%pathname-version to) nil))
1274                        (%pathname-version source)
1275                        (%pathname-version to))
1276                    (frob %pathname-version)))))))))
1277 \f
1278 ;;;;  logical pathname support. ANSI 92-102 specification.
1279 ;;;;
1280 ;;;;  As logical-pathname translations are loaded they are
1281 ;;;;  canonicalized as patterns to enable rapid efficient translation
1282 ;;;;  into physical pathnames.
1283
1284 ;;;; utilities
1285
1286 (defun simplify-namestring (namestring &optional host)
1287   (funcall (host-simplify-namestring
1288             (or host
1289                 (pathname-host (sane-default-pathname-defaults))))
1290            namestring))
1291
1292 ;;; Canonicalize a logical pathname word by uppercasing it checking that it
1293 ;;; contains only legal characters.
1294 (defun logical-word-or-lose (word)
1295   (declare (string word))
1296   (when (string= word "")
1297     (error 'namestring-parse-error
1298            :complaint "Attempted to treat invalid logical hostname ~
1299                        as a logical host:~%  ~S"
1300            :args (list word)
1301            :namestring word :offset 0))
1302   (let ((word (string-upcase word)))
1303     (dotimes (i (length word))
1304       (let ((ch (schar word i)))
1305         (unless (and (typep ch 'standard-char)
1306                      (or (alpha-char-p ch) (digit-char-p ch) (char= ch #\-)))
1307           (error 'namestring-parse-error
1308                  :complaint "logical namestring character which ~
1309                              is not alphanumeric or hyphen:~%  ~S"
1310                  :args (list ch)
1311                  :namestring word :offset i))))
1312     (coerce word 'string))) ; why not simple-string?
1313
1314 ;;; Given a logical host or string, return a logical host. If ERROR-P
1315 ;;; is NIL, then return NIL when no such host exists.
1316 (defun find-logical-host (thing &optional (errorp t))
1317   (etypecase thing
1318     (string
1319      (let ((found (gethash (logical-word-or-lose thing)
1320                            *logical-hosts*)))
1321        (if (or found (not errorp))
1322            found
1323            ;; This is the error signalled from e.g.
1324            ;; LOGICAL-PATHNAME-TRANSLATIONS when host is not a defined
1325            ;; host, and ANSI specifies that that's a TYPE-ERROR.
1326            (error 'simple-type-error
1327                   :datum thing
1328                   ;; God only knows what ANSI expects us to use for
1329                   ;; the EXPECTED-TYPE here. Maybe this will be OK..
1330                   :expected-type
1331                   '(and string (satisfies logical-pathname-translations))
1332                   :format-control "logical host not yet defined: ~S"
1333                   :format-arguments (list thing)))))
1334     (logical-host thing)))
1335
1336 ;;; Given a logical host name or host, return a logical host, creating
1337 ;;; a new one if necessary.
1338 (defun intern-logical-host (thing)
1339   (declare (values logical-host))
1340   (with-locked-system-table (*logical-hosts*)
1341     (or (find-logical-host thing nil)
1342         (let* ((name (logical-word-or-lose thing))
1343                (new (make-logical-host :name name)))
1344           (setf (gethash name *logical-hosts*) new)
1345           new))))
1346 \f
1347 ;;;; logical pathname parsing
1348
1349 ;;; Deal with multi-char wildcards in a logical pathname token.
1350 (defun maybe-make-logical-pattern (namestring chunks)
1351   (let ((chunk (caar chunks)))
1352     (collect ((pattern))
1353       (let ((last-pos 0)
1354             (len (length chunk)))
1355         (declare (fixnum last-pos))
1356         (loop
1357           (when (= last-pos len) (return))
1358           (let ((pos (or (position #\* chunk :start last-pos) len)))
1359             (if (= pos last-pos)
1360                 (when (pattern)
1361                   (error 'namestring-parse-error
1362                          :complaint "double asterisk inside of logical ~
1363                                      word: ~S"
1364                          :args (list chunk)
1365                          :namestring namestring
1366                          :offset (+ (cdar chunks) pos)))
1367                 (pattern (subseq chunk last-pos pos)))
1368             (if (= pos len)
1369                 (return)
1370                 (pattern :multi-char-wild))
1371             (setq last-pos (1+ pos)))))
1372         (aver (pattern))
1373         (if (cdr (pattern))
1374             (make-pattern (pattern))
1375             (let ((x (car (pattern))))
1376               (if (eq x :multi-char-wild)
1377                   :wild
1378                   x))))))
1379
1380 ;;; Return a list of conses where the CDR is the start position and
1381 ;;; the CAR is a string (token) or character (punctuation.)
1382 (defun logical-chunkify (namestr start end)
1383   (collect ((chunks))
1384     (do ((i start (1+ i))
1385          (prev 0))
1386         ((= i end)
1387          (when (> end prev)
1388             (chunks (cons (nstring-upcase (subseq namestr prev end)) prev))))
1389       (let ((ch (schar namestr i)))
1390         (unless (or (alpha-char-p ch) (digit-char-p ch)
1391                     (member ch '(#\- #\*)))
1392           (when (> i prev)
1393             (chunks (cons (nstring-upcase (subseq namestr prev i)) prev)))
1394           (setq prev (1+ i))
1395           (unless (member ch '(#\; #\: #\.))
1396             (error 'namestring-parse-error
1397                    :complaint "illegal character for logical pathname:~%  ~S"
1398                    :args (list ch)
1399                    :namestring namestr
1400                    :offset i))
1401           (chunks (cons ch i)))))
1402     (chunks)))
1403
1404 ;;; Break up a logical-namestring, always a string, into its
1405 ;;; constituent parts.
1406 (defun parse-logical-namestring (namestr start end)
1407   (declare (type simple-string namestr)
1408            (type index start end))
1409   (collect ((directory))
1410     (let ((host nil)
1411           (name nil)
1412           (type nil)
1413           (version nil))
1414       (labels ((expecting (what chunks)
1415                  (unless (and chunks (simple-string-p (caar chunks)))
1416                    (error 'namestring-parse-error
1417                           :complaint "expecting ~A, got ~:[nothing~;~S~]."
1418                           :args (list what (caar chunks) (caar chunks))
1419                           :namestring namestr
1420                           :offset (if chunks (cdar chunks) end)))
1421                  (caar chunks))
1422                (parse-host (chunks)
1423                  (case (caadr chunks)
1424                    (#\:
1425                     (setq host
1426                           (find-logical-host (expecting "a host name" chunks)))
1427                     (parse-relative (cddr chunks)))
1428                    (t
1429                     (parse-relative chunks))))
1430                (parse-relative (chunks)
1431                  (case (caar chunks)
1432                    (#\;
1433                     (directory :relative)
1434                     (parse-directory (cdr chunks)))
1435                    (t
1436                     (directory :absolute) ; Assumption! Maybe revoked later.
1437                     (parse-directory chunks))))
1438                (parse-directory (chunks)
1439                  (case (caadr chunks)
1440                    (#\;
1441                     (directory
1442                      (let ((res (expecting "a directory name" chunks)))
1443                        (cond ((string= res "..") :up)
1444                              ((string= res "**") :wild-inferiors)
1445                              (t
1446                               (maybe-make-logical-pattern namestr chunks)))))
1447                     (parse-directory (cddr chunks)))
1448                    (t
1449                     (parse-name chunks))))
1450                (parse-name (chunks)
1451                  (when chunks
1452                    (expecting "a file name" chunks)
1453                    (setq name (maybe-make-logical-pattern namestr chunks))
1454                    (expecting-dot (cdr chunks))))
1455                (expecting-dot (chunks)
1456                  (when chunks
1457                    (unless (eql (caar chunks) #\.)
1458                      (error 'namestring-parse-error
1459                             :complaint "expecting a dot, got ~S."
1460                             :args (list (caar chunks))
1461                             :namestring namestr
1462                             :offset (cdar chunks)))
1463                    (if type
1464                        (parse-version (cdr chunks))
1465                        (parse-type (cdr chunks)))))
1466                (parse-type (chunks)
1467                  (expecting "a file type" chunks)
1468                  (setq type (maybe-make-logical-pattern namestr chunks))
1469                  (expecting-dot (cdr chunks)))
1470                (parse-version (chunks)
1471                  (let ((str (expecting "a positive integer, * or NEWEST"
1472                                        chunks)))
1473                    (cond
1474                     ((string= str "*") (setq version :wild))
1475                     ((string= str "NEWEST") (setq version :newest))
1476                     (t
1477                      (multiple-value-bind (res pos)
1478                          (parse-integer str :junk-allowed t)
1479                        (unless (and res (plusp res))
1480                          (error 'namestring-parse-error
1481                                 :complaint "expected a positive integer, ~
1482                                             got ~S"
1483                                 :args (list str)
1484                                 :namestring namestr
1485                                 :offset (+ pos (cdar chunks))))
1486                        (setq version res)))))
1487                  (when (cdr chunks)
1488                    (error 'namestring-parse-error
1489                           :complaint "extra stuff after end of file name"
1490                           :namestring namestr
1491                           :offset (cdadr chunks)))))
1492         (parse-host (logical-chunkify namestr start end)))
1493       (values host :unspecific (directory) name type version))))
1494
1495 ;;; We can't initialize this yet because not all host methods are
1496 ;;; loaded yet.
1497 (defvar *logical-pathname-defaults*)
1498
1499 (defun logical-namestring-p (x)
1500   (and (stringp x)
1501        (ignore-errors
1502          (typep (pathname x) 'logical-pathname))))
1503
1504 (deftype logical-namestring ()
1505   `(satisfies logical-namestring-p))
1506
1507 (defun logical-pathname (pathspec)
1508   #!+sb-doc
1509   "Converts the pathspec argument to a logical-pathname and returns it."
1510   (declare (type (or logical-pathname string stream) pathspec)
1511            (values logical-pathname))
1512   (if (typep pathspec 'logical-pathname)
1513       pathspec
1514       (flet ((oops (problem)
1515                (error 'simple-type-error
1516                       :datum pathspec
1517                       :expected-type 'logical-namestring
1518                       :format-control "~S is not a valid logical namestring:~%  ~A"
1519                       :format-arguments (list pathspec problem))))
1520         (let ((res (handler-case
1521                        (parse-namestring pathspec nil *logical-pathname-defaults*)
1522                      (error (e) (oops e)))))
1523           (when (eq (%pathname-host res)
1524                     (%pathname-host *logical-pathname-defaults*))
1525             (oops "no host specified"))
1526           res))))
1527 \f
1528 ;;;; logical pathname unparsing
1529
1530 (defun unparse-logical-directory (pathname)
1531   (declare (type pathname pathname))
1532   (collect ((pieces))
1533     (let ((directory (%pathname-directory pathname)))
1534       (when directory
1535         (ecase (pop directory)
1536           (:absolute) ; nothing special
1537           (:relative (pieces ";")))
1538         (dolist (dir directory)
1539           (cond ((or (stringp dir) (pattern-p dir))
1540                  (pieces (unparse-logical-piece dir))
1541                  (pieces ";"))
1542                 ((eq dir :wild)
1543                  (pieces "*;"))
1544                 ((eq dir :wild-inferiors)
1545                  (pieces "**;"))
1546                 (t
1547                  (error "invalid directory component: ~S" dir))))))
1548     (apply #'concatenate 'simple-string (pieces))))
1549
1550 (defun unparse-logical-piece (thing)
1551   (etypecase thing
1552     ((member :wild) "*")
1553     (simple-string thing)
1554     (pattern
1555      (collect ((strings))
1556        (dolist (piece (pattern-pieces thing))
1557          (etypecase piece
1558            (simple-string (strings piece))
1559            (keyword
1560             (cond ((eq piece :wild-inferiors)
1561                    (strings "**"))
1562                   ((eq piece :multi-char-wild)
1563                    (strings "*"))
1564                   (t (error "invalid keyword: ~S" piece))))))
1565        (apply #'concatenate 'simple-string (strings))))))
1566
1567 (defun unparse-logical-file (pathname)
1568   (declare (type pathname pathname))
1569     (collect ((strings))
1570     (let* ((name (%pathname-name pathname))
1571            (type (%pathname-type pathname))
1572            (version (%pathname-version pathname))
1573            (type-supplied (not (or (null type) (eq type :unspecific))))
1574            (version-supplied (not (or (null version)
1575                                       (eq version :unspecific)))))
1576       (when name
1577         (when (and (null type)
1578                    (typep name 'string)
1579                    (position #\. name :start 1))
1580           (error "too many dots in the name: ~S" pathname))
1581         (strings (unparse-logical-piece name)))
1582       (when type-supplied
1583         (unless name
1584           (error "cannot specify the type without a file: ~S" pathname))
1585         (when (typep type 'string)
1586           (when (position #\. type)
1587             (error "type component can't have a #\. inside: ~S" pathname)))
1588         (strings ".")
1589         (strings (unparse-logical-piece type)))
1590       (when version-supplied
1591         (unless type-supplied
1592           (error "cannot specify the version without a type: ~S" pathname))
1593         (etypecase version
1594           ((member :newest) (strings ".NEWEST"))
1595           ((member :wild) (strings ".*"))
1596           (fixnum (strings ".") (strings (format nil "~D" version))))))
1597     (apply #'concatenate 'simple-string (strings))))
1598
1599 ;;; Unparse a logical pathname string.
1600 (defun unparse-enough-namestring (pathname defaults)
1601   (let* ((path-directory (pathname-directory pathname))
1602          (def-directory (pathname-directory defaults))
1603          (enough-directory
1604            ;; Go down the directory lists to see what matches.  What's
1605            ;; left is what we want, more or less.
1606            (cond ((and (eq (first path-directory) (first def-directory))
1607                        (eq (first path-directory) :absolute))
1608                    ;; Both paths are :ABSOLUTE, so find where the
1609                    ;; common parts end and return what's left
1610                    (do* ((p (rest path-directory) (rest p))
1611                          (d (rest def-directory) (rest d)))
1612                         ((or (endp p) (endp d)
1613                              (not (equal (first p) (first d))))
1614                          `(:relative ,@p))))
1615                  (t
1616                    ;; At least one path is :RELATIVE, so just return the
1617                    ;; original path.  If the original path is :RELATIVE,
1618                    ;; then that's the right one.  If PATH-DIRECTORY is
1619                    ;; :ABSOLUTE, we want to return that except when
1620                    ;; DEF-DIRECTORY is :ABSOLUTE, as handled above. so return
1621                    ;; the original directory.
1622                    path-directory))))
1623     (unparse-logical-namestring
1624      (make-pathname :host (pathname-host pathname)
1625                     :directory enough-directory
1626                     :name (pathname-name pathname)
1627                     :type (pathname-type pathname)
1628                     :version (pathname-version pathname)))))
1629
1630 (defun unparse-logical-namestring (pathname)
1631   (declare (type logical-pathname pathname))
1632   (concatenate 'simple-string
1633                (logical-host-name (%pathname-host pathname)) ":"
1634                (unparse-logical-directory pathname)
1635                (unparse-logical-file pathname)))
1636 \f
1637 ;;;; logical pathname translations
1638
1639 ;;; Verify that the list of translations consists of lists and prepare
1640 ;;; canonical translations. (Parse pathnames and expand out wildcards
1641 ;;; into patterns.)
1642 (defun canonicalize-logical-pathname-translations (translation-list host)
1643   (declare (type list translation-list) (type host host)
1644            (values list))
1645   (mapcar (lambda (translation)
1646             (destructuring-bind (from to) translation
1647               (list (if (typep from 'logical-pathname)
1648                         from
1649                         (parse-namestring from host))
1650                     (pathname to))))
1651           translation-list))
1652
1653 (defun logical-pathname-translations (host)
1654   #!+sb-doc
1655   "Return the (logical) host object argument's list of translations."
1656   (declare (type (or string logical-host) host)
1657            (values list))
1658   (logical-host-translations (find-logical-host host)))
1659
1660 (defun (setf logical-pathname-translations) (translations host)
1661   #!+sb-doc
1662   "Set the translations list for the logical host argument."
1663   (declare (type (or string logical-host) host)
1664            (type list translations)
1665            (values list))
1666   (let ((host (intern-logical-host host)))
1667     (setf (logical-host-canon-transls host)
1668           (canonicalize-logical-pathname-translations translations host))
1669     (setf (logical-host-translations host) translations)))
1670
1671 (defun translate-logical-pathname (pathname &key)
1672   #!+sb-doc
1673   "Translate PATHNAME to a physical pathname, which is returned."
1674   (declare (type pathname-designator pathname)
1675            (values (or null pathname)))
1676   (typecase pathname
1677     (logical-pathname
1678      (dolist (x (logical-host-canon-transls (%pathname-host pathname))
1679                 (error 'simple-file-error
1680                        :pathname pathname
1681                        :format-control "no translation for ~S"
1682                        :format-arguments (list pathname)))
1683        (destructuring-bind (from to) x
1684          (when (pathname-match-p pathname from)
1685            (return (translate-logical-pathname
1686                     (translate-pathname pathname from to)))))))
1687     (pathname pathname)
1688     (t (translate-logical-pathname (pathname pathname)))))
1689
1690 (defvar *logical-pathname-defaults*
1691   (%make-logical-pathname
1692    (make-logical-host :name (logical-word-or-lose "BOGUS"))
1693    :unspecific nil nil nil nil))
1694
1695 (defun load-logical-pathname-translations (host)
1696   #!+sb-doc
1697   "Reads logical pathname translations from SYS:SITE;HOST.TRANSLATIONS.NEWEST,
1698 with HOST replaced by the supplied parameter. Returns T on success.
1699
1700 If HOST is already defined as logical pathname host, no file is loaded and NIL
1701 is returned.
1702
1703 The file should contain a single form, suitable for use with
1704 \(SETF LOGICAL-PATHNAME-TRANSLATIONS).
1705
1706 Note: behaviour of this function is highly implementation dependent, and
1707 historically it used to be a no-op in SBCL -- the current approach is somewhat
1708 experimental and subject to change."
1709   (declare (type string host)
1710            (values (member t nil)))
1711   (if (find-logical-host host nil)
1712       ;; This host is already defined, all is well and good.
1713       nil
1714       ;; ANSI: "The specific nature of the search is
1715       ;; implementation-defined."
1716       (prog1 t
1717         (setf (logical-pathname-translations host)
1718               (with-open-file (lpt (make-pathname :host "SYS"
1719                                                   :directory '(:absolute "SITE")
1720                                                   :name host
1721                                                   :type "TRANSLATIONS"
1722                                                   :version :newest))
1723                 (read lpt))))))
1724
1725 (defun !pathname-cold-init ()
1726   (let* ((sys *default-pathname-defaults*)
1727          (src
1728           (merge-pathnames
1729            (make-pathname :directory '(:relative "src" :wild-inferiors)
1730                           :name :wild :type :wild)
1731            sys))
1732          (contrib
1733           (merge-pathnames
1734            (make-pathname :directory '(:relative "contrib" :wild-inferiors)
1735                           :name :wild :type :wild)
1736            sys))
1737          (output
1738           (merge-pathnames
1739            (make-pathname :directory '(:relative "output" :wild-inferiors)
1740                           :name :wild :type :wild)
1741            sys)))
1742     (setf (logical-pathname-translations "SYS")
1743           `(("SYS:SRC;**;*.*.*" ,src)
1744             ("SYS:CONTRIB;**;*.*.*" ,contrib)
1745             ("SYS:OUTPUT;**;*.*.*" ,output)))))
1746
1747 (defun set-sbcl-source-location (pathname)
1748   #!+sb-doc
1749   "Initialize the SYS logical host based on PATHNAME, which should be
1750 the top-level directory of the SBCL sources. This will replace any
1751 existing translations for \"SYS:SRC;\", \"SYS:CONTRIB;\", and
1752 \"SYS:OUTPUT;\". Other \"SYS:\" translations are preserved."
1753   (let ((truename (truename pathname))
1754         (current-translations
1755          (remove-if (lambda (translation)
1756                       (or (pathname-match-p "SYS:SRC;" translation)
1757                           (pathname-match-p "SYS:CONTRIB;" translation)
1758                           (pathname-match-p "SYS:OUTPUT;" translation)))
1759                     (logical-pathname-translations "SYS")
1760                     :key #'first)))
1761     (flet ((physical-target (component)
1762              (merge-pathnames
1763               (make-pathname :directory (list :relative component
1764                                               :wild-inferiors)
1765                              :name :wild
1766                              :type :wild)
1767               truename)))
1768       (setf (logical-pathname-translations "SYS")
1769             `(("SYS:SRC;**;*.*.*" ,(physical-target "src"))
1770               ("SYS:CONTRIB;**;*.*.*" ,(physical-target "contrib"))
1771               ("SYS:OUTPUT;**;*.*.*" ,(physical-target "output"))
1772               ,@current-translations)))))