src/code/module.lisp

   1 ;;;; REQUIRE, PROVIDE, and friends
   2 ;;;;
   3 ;;;; Officially these are deprecated, but in practice they're probably
   4 ;;;; even less likely to actually go away than there is to ever be
   5 ;;;; another revision of the standard.
   6
   7 ;;;; This software is part of the SBCL system. See the README file for
   8 ;;;; more information.
   9 ;;;;
  10 ;;;; This software is derived from the CMU CL system, which was
  11 ;;;; written at Carnegie Mellon University and released into the
  12 ;;;; public domain. The software is in the public domain and is
  13 ;;;; provided with absolutely no warranty. See the COPYING and CREDITS
  14 ;;;; files for more information.
  15
  16 (in-package "SB!IMPL")
  17 \f
  18 ;;;; exported specials
  19
  20 (defvar *modules* ()
  21   #!+sb-doc
  22   "This is a list of module names that have been loaded into Lisp so far.
  23    It is used by PROVIDE and REQUIRE.")
  24
  25 (defvar *module-provider-functions* (list 'module-provide-contrib)
  26   #!+sb-doc
  27   "See function documentation for REQUIRE.")
  28 \f
  29 ;;;; PROVIDE and REQUIRE
  30
  31 (defun provide (module-name)
  32   #!+sb-doc
  33   "Adds a new module name to *MODULES* indicating that it has been loaded.
  34    Module-name is a string designator"
  35   (pushnew (string module-name) *modules* :test #'string=)
  36   t)
  37
  38 (defvar *requiring* nil)
  39
  40 (defun require-error (control &rest arguments)
  41   (error 'extension-failure
  42          :format-control control
  43          :format-arguments arguments
  44          :references
  45          (list
  46           '(:sbcl :variable *module-provider-functions*)
  47           '(:sbcl :function require))))
  48
  49 (defun require (module-name &optional pathnames)
  50   #!+sb-doc
  51   "Loads a module, unless it already has been loaded. PATHNAMES, if supplied,
  52    is a designator for a list of pathnames to be loaded if the module
  53    needs to be. If PATHNAMES is not supplied, functions from the list
  54    *MODULE-PROVIDER-FUNCTIONS* are called in order with MODULE-NAME
  55    as an argument, until one of them returns non-NIL.  User code is
  56    responsible for calling PROVIDE to indicate a successful load of the
  57    module."
  58   (let ((name (string module-name)))
  59     (when (member name *requiring* :test #'string=)
  60       (require-error "~@<Could not ~S ~A: circularity detected. Please check ~
  61                      your configuration.~:@>" 'require module-name))
  62     (let ((saved-modules (copy-list *modules*))
  63           (*requiring* (cons name *requiring*)))
  64       (unless (member name *modules* :test #'string=)
  65         (cond (pathnames
  66                ;; ambiguity in standard: should we try all pathnames in the
  67                ;; list, or should we stop as soon as one of them calls PROVIDE?
  68                (dolist (ele (ensure-list pathnames) t)
  69                  (load ele)))
  70               (t
  71                (unless (some (lambda (p) (funcall p module-name))
  72                              *module-provider-functions*)
  73                  (require-error "Don't know how to ~S ~A."
  74                                 'require module-name)))))
  75       (set-difference *modules* saved-modules))))
  76
  77 \f
  78 ;;;; miscellany
  79
  80 (defun module-provide-contrib (name)
  81   #!+sb-doc
  82   "Stringify and downcase NAME, then attempt to load the file
  83    $SBCL_HOME/name/name"
  84   (let* ((filesys-name (string-downcase (string name)))
  85          (unadorned-path
  86           (merge-pathnames
  87            (make-pathname :directory (list :relative "contrib")
  88                           :name filesys-name)
  89            (truename (or (sbcl-homedir-pathname)
  90                          (return-from module-provide-contrib nil)))))
  91          (fasl-path (merge-pathnames
  92                      (make-pathname :type *fasl-file-type*)
  93                      unadorned-path))
  94          (lisp-path (merge-pathnames (make-pathname :type "lisp")
  95                                      unadorned-path)))
  96     ;; KLUDGE: there's a race condition here; the file we probe could
  97     ;; be removed by the time we get round to trying to load it.
  98     ;; Maybe factor out the logic in the LOAD guesser as to which file
  99     ;; was meant, so that we can use it here on open streams instead?
 100     (let ((file (or (probe-file fasl-path)
 101                     (probe-file unadorned-path)
 102                     (probe-file lisp-path))))
 103       (when file
 104         (handler-bind
 105             (((or style-warning sb!int:package-at-variance) #'muffle-warning))
 106           (load file))
 107         t))))