zipl/boot/fba2dump.S

   1 /*
   2  *  Dump boot loader for FBA DASDs
   3  *    Copyright IBM Corp. 2004, 2006.
   4  *    Author(s): Michael Holzheu  <holzheu@de.ibm.com>
   5  *
   6  * Uses extern functions:
   7  *  - _panik
   8  *  - _enable_device
   9  *  - _take_dump
  10  *
  11  * Functions:
  12  *  - _dump_mem
  13  */
  14
  15 #include "dumpcommon.S"
  16 #if defined(__s390x__)
  17 #define USE_64BIT_SCLP
  18 #endif
  19 #include "sclp.S"
  20
  21 /* General defines */
  22
  23 #define IPL_BS 0x1000
  24 #define BLOCKS_PER_WRITE 64
  25 #define FBA_BLK_SIZE 0x200
  26 #define STAGE2_DESC 0x218
  27
  28 ################################################################################
  29 # Function entry point at 0x2000 (not used for dump) is called with C linkage
  30 #   %r2-%r3: load descriptor
  31 #   %r3    : device subchannel id
  32 #   %r4    : load address
  33 ################################################################################
  34
  35 #if defined(__s390x__)
  36 dump_magic:  .long 0x5a444642, 0x41363401 # ZDFBA64, version 1
  37 #else
  38 dump_magic:  .long 0x5a444642, 0x41333101 # ZDFBA31, version 1
  39 #endif
  40
  41 #if defined(__s390x__)
  42
  43
  44 /******************************** 64 BIT **************************************/
  45
  46
  47 ################################################################################
  48 # Program execution of the second stage boot loader starts at 0x2008
  49 ################################################################################
  50
  51         .globl _start
  52 _start:
  53         basr  %r13,0
  54 .Linit_base:
  55         la    %r9,0
  56         st    %r9,.Ldh_arch-.Linit_base(%r13) # init arch
  57         l     %r15,1f-.Linit_base(%r13)       # load end of stack address
  58         la    %r7,0
  59         tm    __LC_ARCH_MODE_ID(%r9),0x01     # check arch mode
  60         bnz   .Larch_64-.Linit_base(%r13)
  61
  62         /* 32 bit store status */
  63
  64         l     %r14,.Lstore_status_32-.Linit_base(%r13)
  65         basr  %r14,%r14
  66         la    %r10,ARCH_S390_ID
  67         st    %r10,.Ldh_arch-.Linit_base(%r13)
  68
  69 .Larch_64:
  70         la    %r7,2                             # first try code 2:
  71         la    %r6,0                             # 64 bit psws are restored
  72         sigp  %r7,%r6,0x12                      # switch to 64 bit
  73         bc    8,.Lswitched_64-.Linit_base(%r13) # order accepted ?
  74         la    %r7,1                             # code 2 failed - try code 1
  75         sigp  %r7,%r6,0x12                      # switch to 64 bit
  76 .Lswitched_64:
  77         sam64                                   # switch to 64 bit addr mode
  78         basr   %r13,0
  79 0:      llgf   %r15,1f-0b(%r13)                 # load end of stack address
  80
  81         llgf   %r10,.Ldh_arch-0b(%r13)
  82         cghi   %r10,ARCH_S390_ID
  83         be     .Larch_32-0b(%r13)
  84
  85         /* 64 bit store status */
  86
  87         llgf   %r14,.Lstore_status_64-0b(%r13)
  88         basr   %r14,%r14
  89         lghi   %r10,ARCH_S390X_ID
  90         st     %r10,.Ldh_arch-0b(%r13)
  91
  92 .Larch_32:
  93         llgf   %r2,IPL_SC                   # load ipl device subchannel id
  94         llgf   %r14,.Lenable_device_64-0b(%r13)
  95         basr   %r14,%r14
  96         llgf   %r14,.Ltake_dump_64-0b(%r13)
  97         basr   %r14,%r14
  98 1:      .long  0x10000-128                  # end of stack
  99
 100 ################################################################################
 101 # Dump memory
 102 #  -no parameters
 103 ################################################################################
 104
 105 _dump_mem_64:
 106         stmg   %r6,%r15,48(%r15)
 107         basr   %r13,0                         # base register
 108 0:      aghi   %r15,-200                      # create stack frame
 109
 110         # init progress bar
 111
 112         bras %r14,_init_print_progress_64
 113
 114         # get start and end block
 115
 116         mvc    .Ldev_start_blk-0b(4,%r13),STAGE2_DESC+4
 117         mvc    .Ldev_end_blk-0b(4,%r13),STAGE2_DESC+8+4
 118
 119         # setup define extend
 120
 121         l         %r7,.Ldev_end_blk-0b(%r13)
 122         st        %r7,12+.Ldedata-0b(%r13)
 123
 124         # calculate bytes per write (blksize * blwr)
 125
 126         llgf    %r11,.Ldev_blk_size-0b(%r13)
 127         mh      %r11,.Lblocks_per_write-0b(%r13)
 128         st      %r11,.Lbytes_per_write-0b(%r13)
 129
 130 # write header
 131
 132         stck    .Ldh_time-0b(%r13)            # store time
 133         stidp   .Ldh_cpuid-0b(%r13)           # store cpu id
 134
 135         llgf    %r11,.Ldev_start_blk-0b(%r13) # start block
 136
 137         lgr     %r2,%r11
 138         lghi    %r3, TMP_PAGE_START
 139         mvc     0(256,%r3),.Ldh_dumpheader-0b(%r13) # move to 4k boundary
 140         llgf    %r4,.Lheader_size-0b(%r13)
 141         srda    %r4,32                        # shift ==> 64 bit number
 142         llgf    %r6,.Ldev_blk_size-0b(%r13)   # get blocksize
 143
 144         dr      %r4,%r6                       # nr of blocks for header =
 145                                               # HEADER_SIZE / BLOCKSIZE = r5
 146         lgr     %r4,%r5
 147         lgr     %r12,%r5                      # save nr of blocks
 148         bas     %r14,_writeblock_64-0b(%r13)  # write block to disk
 149         ar      %r11,%r12                     # update block counter
 150
 151 # write memory
 152
 153         lghi    %r10,0                        # start at address 0
 154
 155 .Lmloop:
 156         lghi    %r4,BLOCKS_PER_WRITE          # write so many blocks at a time
 157         lgr     %r2,%r11                      # restore r2
 158         lgr     %r3,%r10                      # restore r3
 159         bas     %r14,_writeblock_64-0b(%r13)  # write block to disk
 160         llgf    %r2,.Lbytes_per_write-0b(%r13)
 161         agr     %r10,%r2                      # update data address
 162         aghi    %r11,BLOCKS_PER_WRITE         # skip to next block
 163
 164         lgr     %r2,%r10                      # print progress to console
 165         bras    %r14,_print_progress_64
 166
 167         lg      %r3,.Ldh_mem_size-0b(%r13)    # get memsize
 168         clgr    %r10,%r3                      # enough ?
 169         bl      .Lmloop-0b(%r13)              # branch if r10 < r3
 170
 171 # write end marker
 172
 173 .lendmarker:                                  # terminate dump file
 174         stck    .Ld_end_time-0b(%r13)         # store end time
 175         lgr     %r2,%r11                      # restore r2
 176         lghi     %r3, TMP_PAGE_START
 177         mvc     0(256,%r3),.Ld_endmarker-0b(%r13) # move to 4k boundary
 178         lghi    %r4,1                         # write one block
 179         bas     %r14,_writeblock_64-0b(%r13)  # write block to disk
 180
 181         lmg     %r6,%r15,248(%r15)
 182         br      %r14                          # return to caller
 183 .Lbytes_per_write:  .long 0x00000000
 184 .Lheader_size:      .long HEADER_SIZE
 185 .Lblocks_per_write: .word BLOCKS_PER_WRITE
 186
 187 ################################################################################
 188 # This function writes a block number given in r2 to disk
 189 #  -r2:  number of first block to write ( input by caller )
 190 #        We start counting with Block Nr 0 !!!
 191 #  -r3:  address to write data from ( input by caller )
 192 #  -r4:  number of blocks to write ( input by caller )
 193 ################################################################################
 194
 195 _writeblock_64:
 196         stmg    %r6,%r15,48(%r15)
 197         basr    %r13,0                        # base register
 198 0:      aghi    %r15,-200                     # create stack frame
 199
 200         # check if blocks are within range:
 201
 202         lgr     %r11,%r2
 203         agr     %r11,%r4                      # End block
 204         llgf    %r12,.Ldev_end_blk-0b(%r13)
 205         clr     %r11,%r12                     # End block < dev_end_blk ?
 206         bl      1f-0b(%r13)                   # no
 207         la      %r2,EMEM                      # if yes panik
 208         llgf    %r14,.Lpanik_64-0b(%r13)
 209         basr    %r14,%r14
 210
 211 1:      la      %r12,.Ldeccw-0b(%r13)
 212         st      %r12,8+.Lorb-0b(%r13)         # store cpaddr to orb
 213         la      %r12,.Lwrccw-0b(%r13)
 214         oi      1(%r12),0x04                  # enable indirect data addressing
 215
 216         #setup locate ccw
 217         sth     %r4,2+.Llodata-0b(%r13)       # store number of blocks
 218         st      %r2,4+.Llodata-0b(%r13)       # store first block
 219
 220         # setup write ccw
 221         la      %r12,.Lwrccw-0b(%r13)
 222         la      %r10,.Lida_list-0b(%r13)      # pointer to ida list
 223         st      %r10,4+.Lwrccw-0b(%r13)       # store idal data address
 224         lgr     %r7,%r4
 225         mh      %r7,2+.Ldev_blk_size-0b(%r13)
 226         sth     %r7,2+.Lwrccw-0b(%r13)        # store byte count
 227
 228         # setup idas
 229
 230         lgr     %r2,%r3                       # start address
 231         lgr     %r3,%r7                       # byte count
 232         lgr     %r4,%r10                      # address of ida list
 233         bas     %r14,_create_ida_list_64-0b(%r13) # create ida list
 234
 235         # CCWs are setup now, arent they?
 236
 237         llgf    %r2,IPL_SC                    # subchannel id
 238         la      %r3,.Lorb-0b(%r13)
 239         la      %r4,.Lirb-0b(%r13)
 240         la      %r5,10                        # initialize retries
 241
 242         bas     %r14,_ssch_64-0b(%r13)        # start I/O
 243
 244         lmg     %r6,%r15,248(%r15)
 245         br      %r14                          # return to caller
 246 .align 8
 247 .Lorb:
 248         .long 0x0049504c,0x0082ff00
 249         .long 0x00000000,0x00000000
 250 .Lirb:
 251         .long 0x00000000,0x00000000
 252         .long 0x00000000,0x00000000
 253         .long 0x00000000,0x00000000
 254         .long 0x00000000,0x00000000
 255         .long 0x00000000,0x00000000
 256         .long 0x00000000,0x00000000
 257         .long 0x00000000,0x00000000
 258         .long 0x00000000,0x00000000
 259 .Ldedata:
 260         .long 0xc0000200,0x00000000
 261         .long 0x00000000,0x00001000
 262 .Llodata:
 263         .long 0x01000000,0x00000000
 264 .align 8
 265 .Lida_list: # enough for 128 blocks a 512 byte
 266         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 267         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 268         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 269         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 270
 271 ################################################################################
 272 # expand Macros
 273 ################################################################################
 274
 275         hex_to_ebcdic
 276         print_progress_64
 277         dump_common_store_status_32
 278         dump_common_fn_64
 279         dump_io_subroutines_64
 280         dump_idal_64
 281         dump_messages
 282         dump_header
 283         tmp_data
 284         sclp_base
 285         sclp_print
 286         sclp_read_info
 287
 288 # extern functions
 289
 290 .Lpanik_64:
 291         .long      _panik_64
 292 .Lenable_device_64:
 293         .long      _enable_device_64
 294 .Ltake_dump_64:
 295         .long      _take_dump_64
 296 .Lstore_status_32:
 297         .long      _store_status_32
 298 .Lstore_status_64:
 299         .long      _store_status_64
 300
 301
 302
 303
 304
 305 #else /* __s390x__ */
 306
 307
 308
 309 /******************************** 32 BIT **************************************/
 310
 311
 312 ################################################################################
 313 # Program execution of the second stage boot loader starts at 0x2008
 314 ################################################################################
 315
 316         .globl _start
 317 _start: basr   %r13,0
 318 0:      l      %r15,1f-0b(%r13)             # load end of stack address
 319
 320         tm    __LC_ARCH_MODE_ID,0x01        # check arch mode
 321         bz   .Larch_31-0b(%r13)
 322         la    %r10,ARCH_S390X_ID
 323         st    %r10,.Ldh_arch-0b(%r13)
 324
 325 .Larch_31:
 326         l      %r11,IPL_SC                  # load ipl device subchannel id
 327         lr     %r2,%r11
 328         l      %r14,.Lenable_device_32-0b(%r13)
 329         basr   %r14,%r14
 330         l      %r14,.Ltake_dump_32-0b(%r13)
 331         basr   %r14,%r14
 332 1:      .long  0x10000-96                   # end of stack
 333
 334
 335 ################################################################################
 336 # Dump memory
 337 #  - no parameters
 338 ################################################################################
 339
 340 _dump_mem_32:
 341         stm    %r6,%r15,24(%r15)
 342         basr   %r13,0                         # base register
 343 0:      s      %r15,.Lc96-0b(%r13)            # create stack frame
 344
 345         # init progress bar
 346
 347         bras %r14,_init_print_progress_32
 348
 349         # get start and end block
 350
 351         mvc    .Ldev_start_blk-0b(4,%r13),STAGE2_DESC+4
 352         mvc    .Ldev_end_blk-0b(4,%r13),STAGE2_DESC+8+4
 353
 354         # setup define extend
 355
 356         l         %r7,.Ldev_end_blk-0b(%r13)
 357         st        %r7,12+.Ldedata-0b(%r13)
 358
 359         # calculate bytes per write (blksize * blwr)
 360
 361         l       %r11,.Ldev_blk_size-0b(%r13)
 362         mh      %r11,.Lblocks_per_write-0b(%r13)
 363         st      %r11,.Lbytes_per_write-0b(%r13)
 364
 365 # write header
 366
 367         stck    .Ldh_time-0b(%r13)            # store time
 368         stidp   .Ldh_cpuid-0b(%r13)           # store cpu id
 369
 370         l       %r11,.Ldev_start_blk-0b(%r13) # start block
 371
 372         lr      %r2,%r11
 373         lhi     %r3, TMP_PAGE_START
 374         mvc     0(256,%r3),.Ldh_dumpheader-0b(%r13) # move to 4k boundary
 375
 376         l       %r4,.Lheader_size-0b(%r13)
 377         srda    %r4,32                        # shift ==> 64 bit number
 378         l       %r6,.Ldev_blk_size-0b(%r13)   # get blocksize
 379
 380         dr      %r4,%r6                       # nr of blocks for header =
 381                                               # HEADER_SIZE / BLOCKSIZE = r5
 382         lr      %r4,%r5
 383         lr      %r12,%r5                      # save nr of blocks
 384         bas     %r14,_writeblock_32-0b(%r13)  # write block to disk
 385         ar      %r11,%r12                     # update block counter
 386
 387 # write memory
 388
 389         la      %r10,0                        # start at address 0
 390
 391 .Lmloop:
 392         la      %r4,BLOCKS_PER_WRITE          # write so many blocks at a time
 393         lr      %r2,%r11                      # restore r2
 394         lr      %r3,%r10                      # restore r3
 395         bas     %r14,_writeblock_32-0b(%r13)  # write block to disk
 396         l       %r2,.Lbytes_per_write-0b(%r13)
 397         ar      %r10,%r2                      # update data address
 398         ah      %r11,.Lblocks_per_write-0b(%r13) # skip to next block
 399
 400         lr      %r2,%r10                      # print progress to console
 401         bras    %r14,_print_progress_32
 402
 403         l       %r3,.Ldh_mem_size+4-0b(%r13)  # get memsize
 404         clr     %r10,%r3                      # enough ?
 405         bl      .Lmloop-0b(%r13)              # branch if r10 < r3
 406
 407 # write end marker
 408
 409 .lendmarker:                                  # terminate dump file
 410         la      %r4,1                         # write endmaker with one block
 411         stck    .Ld_end_time-0b(%r13)         # store end time
 412         lr      %r2,%r11                      # restore r2
 413         lhi     %r3, TMP_PAGE_START
 414         mvc     0(256,%r3),.Ld_endmarker-0b(%r13) # move to 4k boundary
 415         la      %r4,1                         # write 4k at a time
 416         bas     %r14,_writeblock_32-0b(%r13)  # write block to disk
 417
 418         lm      %r6,%r15,120(%r15)
 419         br      %r14                          # return to caller
 420 .Lbytes_per_write:  .long 0x00000000
 421 .Lheader_size:      .long HEADER_SIZE
 422 .Lblocks_per_write: .word BLOCKS_PER_WRITE
 423
 424 ################################################################################
 425 # This function writes a block number given in r2 to disk
 426 #  -r2:   number of first block to write ( input by caller )
 427 #         We start counting with Block Nr 0 !!!
 428 #  -r3:   address to write data from ( input by caller )
 429 #  -r4:   number of blocks to write ( input by caller )
 430 ################################################################################
 431
 432 _writeblock_32:
 433         stm     %r6,%r15,24(%r15)
 434         basr    %r13,0                        # base register
 435 0:      s       %r15,.Lc96-0b(%r13)           # create stack frame
 436
 437         # check if blocks are within range:
 438
 439         lr      %r11,%r2
 440         ar      %r11,%r4                      # End block
 441         l       %r12,.Ldev_end_blk-0b(%r13)
 442         clr     %r11,%r12                     # End block < dev_end_blk ?
 443         bl      1f-0b(%r13)                   # no
 444         la      %r2,EMEM                      # if yes panik
 445         l       %r14,.Lpanik_32-0b(%r13)
 446         basr    %r14,%r14
 447
 448 1:      la      %r12,.Ldeccw-0b(%r13)
 449         st      %r12,8+.Lorb-0b(%r13)         # store cpaddr to orb
 450
 451         #setup locate ccw
 452         sth     %r4,2+.Llodata-0b(%r13)       # store number of blocks
 453         st      %r2,4+.Llodata-0b(%r13)       # store first block
 454
 455         # setup write ccw
 456         la      %r12,.Lwrccw-0b(%r13)
 457         oi      1(%r12),0x04                  # enable ida
 458         la      %r10,.Lida_list-0b(%r13)      # pointer to ida list
 459         st      %r10,4+.Lwrccw-0b(%r13)       # store data address
 460         lr      %r7,%r4
 461         mh      %r7,2+.Ldev_blk_size-0b(%r13)
 462         sth     %r7,2+.Lwrccw-0b(%r13)        # store byte count
 463
 464         # setup idas
 465         lr      %r2,%r3                       # start address
 466         lr      %r3,%r7                       # byte count
 467         lr      %r4,%r10                      # address of ida list
 468         bas     %r14,_create_ida_list_32-0b(%r13)  # create the list
 469
 470         # CCWs are setup now, arent they?
 471
 472         l       %r2,IPL_SC                    # subchannel id
 473         la      %r3,.Lorb-0b(%r13)
 474         la      %r4,.Lirb-0b(%r13)
 475         la      %r5,10                        # initialize retries
 476
 477         bas     %r14,_ssch_32-0b(%r13)        # start I/O
 478
 479         lm      %r6,%r15,120(%r15)
 480         br      %r14                          # return to caller
 481 .Lccw_size:
 482         .word 0x8
 483 .align 8
 484 .Lorb:
 485         .long 0x0049504c,0x0080ff00           # intparm is " IPL"
 486         .long 0x00000000,0x00000000
 487 .Lirb:
 488         .long 0x00000000,0x00000000
 489         .long 0x00000000,0x00000000
 490         .long 0x00000000,0x00000000
 491         .long 0x00000000,0x00000000
 492         .long 0x00000000,0x00000000
 493         .long 0x00000000,0x00000000
 494         .long 0x00000000,0x00000000
 495         .long 0x00000000,0x00000000
 496 .Ldedata:
 497         .long 0xc0000200,0x00000000
 498         .long 0x00000000,0x00001000
 499 .Llodata:
 500         .long 0x01000000,0x00000000
 501 .align 8
 502 .Lida_list: # enough for 128 blocks a 512 byte
 503         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 504         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 505         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 506         .long 0x0,0x0,0x0,0x0,0x0,0x0,0x0,0x0
 507
 508 ################################################################################
 509 # expand Macros
 510 ################################################################################
 511
 512         hex_to_ebcdic
 513         print_progress_32
 514         dump_common_fn_32
 515         dump_io_subroutines_32
 516         dump_idal_32
 517         dump_messages
 518         dump_header
 519         tmp_data
 520         sclp_base
 521         sclp_print
 522         sclp_read_info
 523
 524 # extern functions
 525
 526 .Lpanik_32:
 527         .long      _panik_32
 528 .Lenable_device_32:
 529         .long      _enable_device_32
 530 .Ltake_dump_32:
 531         .long      _take_dump_32
 532
 533 #endif /* __s390x__ */
 534
 535
 536 ################################################################################
 537 # DATA
 538 ################################################################################
 539
 540 .Lc96:  .long  96 # for creating stackframes
 541
 542 # device characteristics
 543 .align 8
 544 .Ldev_start_blk:
 545         .long  0x00000000
 546 .Ldev_end_blk:
 547         .long  0x00000000
 548 .Ldev_blk_size:
 549         .long  FBA_BLK_SIZE
 550
 551 #
 552 # CCWs
 553 #
 554
 555 .align 8
 556
 557 # channel program for one write
 558
 559 .Ldeccw:
 560         .long 0x63400010,0x00000000+.Ldedata     # define extent
 561 .Lloccw:
 562         .long 0x43400008,0x00000000+.Llodata     # locate
 563 .Lwrccw:
 564         .long 0x41200000,0x00000000              # write blocks
 565
 566 .org (IPL_BS - 8)
 567 .Lmem_upper_limit:
 568         .long 0xffffffff,0xffffffff              # can be used for memsize=xxx