ROX-Filer/src/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_INIT(main.c)
   3 AC_CONFIG_HEADER(config.h)
   4
   5 AC_ARG_WITH(platform,
   6 [  --with-platform        platform name, as detected by AppRun],
   7 [AC_SUBST(with_platform)],
   8 [
   9 AC_MSG_ERROR([
  10
  11 Please do not run 'configure' manually - instead, run the AppRun script with
  12 the --compile option, like this:
  13         $ ROX-Filer/AppRun --compile
  14
  15 Thank you.
  16 ])
  17 ])
  18
  19 if test -z "$PKG_CONFIG"; then
  20   PKG_CONFIG=pkg-config
  21 fi
  22 AC_SUBST(PKG_CONFIG)
  23
  24 AC_MSG_CHECKING(that pkg-config runs)
  25 if "$PKG_CONFIG" --version > /dev/null 2>&1 ; then
  26   AC_MSG_RESULT(yes)
  27 else
  28   AC_MSG_RESULT(no)
  29   AC_MSG_ERROR([*** $PKG_CONFIG missing ***
  30
  31 \'$PKG_CONFIG --version\' failed to run - make sure it is inside one of the
  32 directories in your PATH environment variable!
  33
  34 pkg-config comes with the developement packages for GTK+-2.0, available at:
  35
  36     http://www.gtk.org])
  37 fi
  38
  39 AC_DEFUN(ROX_REQUIRE, [
  40 AC_MSG_CHECKING(that $1 (version >= $2) is installed)
  41 if "$PKG_CONFIG" --atleast-version=$2 $1 ; then
  42   AC_MSG_RESULT(yes)
  43 else
  44   AC_MSG_RESULT(no)
  45   if "$PKG_CONFIG" --exists $1 ; then
  46     AC_MSG_ERROR(Current version is only `"$PKG_CONFIG" "$1" --modversion`)
  47   else
  48     AC_MSG_ERROR(Package is not installed)
  49   fi
  50 fi
  51 ])
  52
  53 ROX_REQUIRE(gtk+-2.0, 2.0.1)
  54 ROX_REQUIRE(glib-2.0, 2.0.3)
  55 ROX_REQUIRE(libxml-2.0, 2.0.0)
  56
  57 dnl Checks for programs.
  58 AC_PROG_CC
  59
  60 dnl Use -Wall, etc if possible
  61 [
  62 if test "x$GCC" = "xyes"; then
  63   case " $CFLAGS " in
  64   *[\ \ ]-Wall[\ \      ]*) ;;
  65   *) CFLAGS="$CFLAGS -Wall -Wstrict-prototypes -Wmissing-prototypes" ;;
  66   esac
  67 fi
  68 ]
  69
  70 dnl Find the X libraries
  71 AC_PATH_XTRA
  72 if test x$no_x = xyes ; then
  73   AC_MSG_ERROR([X development libraries not found])
  74 fi
  75 LIBS="$LIBS $X_LIBS -lX11 $X_EXTRA_LIBS"
  76 CFLAGS="$CFLAGS $X_CFLAGS"
  77
  78 dnl Does file(1) support '-b' ?
  79 AC_MSG_CHECKING(whether file -b works)
  80 if file -b / > /dev/null 2> /dev/null
  81 then
  82   AC_DEFINE(FILE_B_FLAG)
  83   AC_MSG_RESULT(yes)
  84 else
  85   AC_MSG_RESULT(no)
  86 fi
  87
  88 AC_MSG_CHECKING(for large file support)
  89 if getconf LFS64_CFLAGS > /dev/null 2> /dev/null; then
  90   AC_MSG_RESULT(yes)
  91   LFS_CFLAGS="`getconf LFS_CFLAGS`"
  92   LFS_LDFLAGS="`getconf LFS_LDFLAGS`"
  93   LFS_LIBS="`getconf LFS_LIBS`"
  94   AC_DEFINE(LARGE_FILE_SUPPORT)
  95 else
  96   AC_MSG_RESULT(no)
  97   LFS_CFLAGS=""
  98   LFS_LDFLAGS=""
  99   LFS_LIBS=""
 100 fi
 101 AC_SUBST(LFS_CFLAGS)
 102 AC_SUBST(LFS_LDFLAGS)
 103 AC_SUBST(LFS_LIBS)
 104
 105 dnl Checks for header files.
 106 AC_PATH_X
 107 AC_HEADER_DIRENT
 108 AC_HEADER_STDC
 109 AC_HEADER_SYS_WAIT
 110 AC_CHECK_HEADERS(fcntl.h sys/time.h unistd.h mntent.h sys/ucred.h sys/mntent.h)
 111
 112 dnl Checks for typedefs, structures, and compiler characteristics.
 113 AC_C_CONST
 114 AC_TYPE_UID_T
 115 AC_TYPE_SIZE_T
 116
 117 dnl Checks for library functions.
 118 AC_CHECK_FUNCS(gethostname unsetenv mkdir rmdir strdup strtol getopt_long)
 119
 120 dnl Extract version info from AppInfo.xml
 121 AC_MSG_CHECKING(extracting version information)
 122 [
 123 VERSION=`sed -n 's/^.*<Version>\([.0-9]*\).*<\/Version>.*$/\1/p' ../AppInfo.xml`
 124 ]
 125 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
 126 AC_MSG_RESULT(version $VERSION)
 127
 128 AC_OUTPUT(Makefile)