bin/rrr-news

   1 #!/usr/bin/perl -- -*- mode: cperl -*-
   2
   3 =head1 NAME
   4
   5 rrr-news - list files added to the dataset
   6
   7 =head1 SYNOPSIS
   8
   9   rrr-news [options]
  10
  11 =head1 OPTIONS
  12
  13 =over 8
  14
  15 =cut
  16
  17 my $optpod = <<'=back';
  18
  19 =item B<--after=s>
  20
  21 List all new files after this point in time. The format of the
  22 timestamp is the unix epoch in floating point notation as used by
  23 recentfiles in general.
  24
  25 =item B<--before=s>
  26
  27 List all new files before this point in time. The format of the
  28 timestamp is the unix epoch in floating point notation as used by
  29 recentfiles in general.
  30
  31 =item B<--dry-run!>
  32
  33 (TBD) Do not really run the command, ...
  34
  35 =item B<--help|h>
  36
  37 Prints a brief message and exists.
  38
  39 =item B<--local=s>
  40
  41 Specifies a local principal file. Nothing is mirrored, the list is
  42 constructed from local resources. Cannot be combined with the
  43 C<--remote> option.
  44
  45 =item B<--localroot=s>
  46
  47 Specifies the local root directory. C<--remote> must also be specified
  48 and mirroring is happening implicitly. If missing, a temporary
  49 directory is created to hold the data before constructing the list
  50 (but this is inefficient in case the program is called again later
  51 because the temporary directory is not persistent).
  52
  53 =item B<--max=i>
  54
  55 Limit the list to at max this many items.
  56
  57 =item B<--remote=s>
  58
  59 Specifies the remote principal file in rsync notation. This implies
  60 that the necessary remote files will be mirrored before constructing
  61 the list.
  62
  63 =item B<--rsync_options|rsync=s@>
  64
  65 Multiple options in the form of key=value pairs. E.g.
  66
  67   --rsync=compress=1 --rsync=links=1
  68
  69 The options are passed to the underlying L<File::Rsync> objects.
  70
  71 =item B<--skip-deletes!>
  72
  73 Boolean. If true then delete events are skipped.
  74
  75 =item B<--verbose|v+>
  76
  77 More feedback.
  78
  79 =back
  80
  81 =head1 DESCRIPTION
  82
  83 rersyncrecent is a project to get speedy rsync operation on large
  84 trees over multiple hosts. It maintains a collection of files with
  85 metadata (so called recentfiles) that represent adjacent overlapping
  86 timespans of file change events.
  87
  88 rrr-news extracts from the recentfiles the new files added or
  89 modified. The remote-principal-file is the rsync-notation for the
  90 remote recentfile. The second argument is the path to the local mirror
  91 directory. If you omit the second argument, a temporary directory is
  92 taken instead.
  93
  94 =cut
  95
  96
  97 use strict;
  98 use warnings;
  99
 100 use File::Rsync::Mirror::Recent;
 101 use Getopt::Long;
 102 use Pod::Usage qw(pod2usage);
 103
 104 our %Opt;
 105 my @opt = $optpod =~ /B<--(\S+)>/g;
 106
 107 GetOptions(\%Opt,
 108            @opt,
 109           ) or pod2usage(2);
 110
 111 if ($Opt{help}) {
 112     pod2usage(0);
 113 }
 114
 115 if (@ARGV) {
 116     pod2usage(2);
 117 }
 118
 119 if ($Opt{'dry-run'}) {
 120     die "FIXME: not yet implemented";
 121 }
 122
 123 my @constr;
 124 for my $opt (qw(local remote localroot)) {
 125     if (defined $Opt{$opt}) {
 126         push @constr, $opt => $Opt{$opt};
 127     }
 128 }
 129 my $rf = File::Rsync::Mirror::Recent->new
 130     (
 131      @constr,
 132      # stupid, need no rsync options when running wiht -local!
 133      rsync_options => {
 134                        compress => 1,
 135                        links => 1,
 136                        times => 1,
 137                        checksum => 1,
 138                       },
 139     );
 140 if ($rf->remote) {
 141     unless ($rf->localroot) {
 142         require File::Temp;
 143         my $ldir = File::Temp::tempdir(
 144                                        "rrr-news-XXXXXX",
 145                                        TMPDIR => 1,
 146                                       );
 147         $rf->localroot($ldir);
 148     }
 149 } elsif ($rf->local) {
 150 } else {
 151     die "need either --local option or both of --remote and --localroot";
 152 }
 153 for my $passthrough (
 154                      "locktimeout",
 155                      "verbose",
 156                     ) {
 157     if (my $x = $Opt{$passthrough}) {
 158         $rf->$passthrough($x);
 159     }
 160 }
 161 {
 162     my %rsopt;
 163     for my $rsopt (@{$Opt{rsync_options}||[]}) {
 164         my($key,$value) = $rsopt =~ /([^=]+)=(.+)/s;
 165         $rsopt{$key} = $value;
 166     }
 167     $rf->rsync_options(\%rsopt);
 168 }
 169 my @nopt;
 170 for my $opt (qw(after before max skip-deletes)) {
 171     if (defined $Opt{$opt}) {
 172         push @nopt, $opt => $Opt{$opt}
 173     }
 174 }
 175 print map { sprintf "%-20s %s\n", scalar localtime($_->{epoch}), substr($_->{path},8) } @{ $rf->news(@nopt) };
 176
 177 __END__
 178
 179
 180 # Local Variables:
 181 # mode: cperl
 182 # coding: utf-8
 183 # cperl-indent-level: 4
 184 # End: