bin/rrr-aggregate

   1 #!/usr/bin/perl -- -*- mode: cperl -*-
   2
   3 =head1 NAME
   4
   5 rrr-aggregate - merge a set of recentfiles
   6
   7 =head1 SYNOPSIS
   8
   9   rrr-aggregate [options] file
  10
  11 =head1 OPTIONS
  12
  13 =over 8
  14
  15 =cut
  16
  17 my $optpod = <<'=back';
  18
  19 =item B<--dry-run!>
  20
  21 (TBD) Do not really run the command, ...
  22
  23 =item B<--help|h>
  24
  25 Prints a brief message and exists.
  26
  27 =item B<--locktimeout=s>
  28
  29 Sets the locktimeout. See L<File::Rsync::Mirror::Recentfile>.
  30
  31 =item B<--verbose|v+>
  32
  33 More feedback.
  34
  35 =back
  36
  37 =head1 DESCRIPTION
  38
  39 rersyncrecent is a project to get speedy rsync operation on large
  40 trees over multiple hosts. It maintains a collection of files with
  41 metadata (so called recentfiles) that represent adjacent or
  42 overlapping timespans of file change events.
  43
  44 rrr-aggregate merges the recentfiles that describe a tree. The file
  45 argument is the path to the principal (the shortest) in a collection
  46 of recentfiles.
  47
  48 =cut
  49
  50
  51 use strict;
  52 use warnings;
  53
  54 use File::Rsync::Mirror::Recentfile;
  55 use Getopt::Long;
  56 use Pod::Usage qw(pod2usage);
  57
  58 our %Opt;
  59 my @opt = $optpod =~ /B<--(\S+)>/g;
  60
  61 GetOptions(\%Opt,
  62            @opt,
  63           ) or pod2usage(2);
  64
  65 if ($Opt{help}) {
  66     pod2usage(0);
  67 }
  68
  69 if (! @ARGV) {
  70     pod2usage(2);
  71 }
  72
  73 if ($Opt{'dry-run'}) {
  74     die "FIXME: not yet implemented";
  75 }
  76
  77 my $rf = File::Rsync::Mirror::Recentfile->new_from_file($ARGV[0]);
  78 if (my $tout = $Opt{locktimeout}) {
  79     $rf->locktimeout($tout);
  80 }
  81 $rf->aggregate();
  82
  83 __END__
  84
  85
  86 # Local Variables:
  87 # mode: cperl
  88 # coding: utf-8
  89 # cperl-indent-level: 4
  90 # End: