src/src.pro

   1 TEMPLATE = subdirs
   2
   3 # this order is important
   4 unset(SRC_SUBDIRS)
   5 win32:SRC_SUBDIRS += src_winmain
   6 wince*:{
   7   SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_script src_testlib
   8 } else {
   9     SRC_SUBDIRS += src_tools_bootstrap src_tools_moc src_tools_rcc src_tools_uic src_corelib src_xml src_network src_gui src_sql src_script src_testlib
  10     contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
  11     contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
  12     !cross_compile {
  13         contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_tools_uic3
  14     }
  15 }
  16 win32:{
  17     SRC_SUBDIRS += src_activeqt
  18     !wince*: SRC_SUBDIRS += src_tools_idc
  19 }
  20
  21 contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
  22 contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
  23 contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
  24 contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
  25 contains(QT_CONFIG, webkit)  {
  26     #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
  27     SRC_SUBDIRS += src_webkit
  28 }
  29 contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
  30 SRC_SUBDIRS += src_plugins
  31
  32 src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
  33 src_winmain.target = sub-winmain
  34 src_tools_bootstrap.subdir = $$QT_SOURCE_TREE/src/tools/bootstrap
  35 src_tools_bootstrap.target = sub-tools-bootstrap
  36 src_tools_moc.subdir = $$QT_SOURCE_TREE/src/tools/moc
  37 src_tools_moc.target = sub-moc
  38 src_tools_rcc.subdir = $$QT_SOURCE_TREE/src/tools/rcc
  39 src_tools_rcc.target = sub-rcc
  40 src_tools_uic.subdir = $$QT_SOURCE_TREE/src/tools/uic
  41 src_tools_uic.target = sub-uic
  42 src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
  43 src_corelib.target = sub-corelib
  44 src_xml.subdir = $$QT_SOURCE_TREE/src/xml
  45 src_xml.target = sub-xml
  46 src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
  47 src_xmlpatterns.target = sub-xmlpatterns
  48 src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
  49 src_dbus.target = sub-dbus
  50 src_gui.subdir = $$QT_SOURCE_TREE/src/gui
  51 src_gui.target = sub-gui
  52 src_sql.subdir = $$QT_SOURCE_TREE/src/sql
  53 src_sql.target = sub-sql
  54 src_network.subdir = $$QT_SOURCE_TREE/src/network
  55 src_network.target = sub-network
  56 src_svg.subdir = $$QT_SOURCE_TREE/src/svg
  57 src_svg.target = sub-svg
  58 src_script.subdir = $$QT_SOURCE_TREE/src/script
  59 src_script.target = sub-script
  60 src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
  61 src_scripttools.target = sub-scripttools
  62 src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
  63 src_opengl.target = sub-opengl
  64 src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
  65 src_qt3support.target = sub-qt3support
  66 src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
  67 src_phonon.target = sub-phonon
  68 src_tools_uic3.subdir = $$QT_SOURCE_TREE/src/tools/uic3
  69 src_tools_uic3.target = sub-uic3
  70 src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
  71 src_activeqt.target = sub-activeqt
  72 src_tools_idc.subdir = $$QT_SOURCE_TREE/src/tools/idc
  73 src_tools_idc.target = sub-idc
  74 src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
  75 src_plugins.target = sub-plugins
  76 src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
  77 src_testlib.target = sub-testlib
  78 src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
  79 src_javascriptcore.target = sub-javascriptcore
  80 src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
  81 src_webkit.target = sub-webkit
  82
  83 #CONFIG += ordered
  84 !wince*:!ordered {
  85    src_tools_moc.depends = src_tools_bootstrap
  86    src_tools_rcc.depends = src_tools_bootstrap
  87    src_tools_uic.depends = src_tools_bootstrap
  88    src_corelib.depends = src_tools_moc src_tools_rcc
  89    src_gui.depends = src_corelib src_tools_uic
  90    embedded: src_gui.depends += src_network
  91    src_xml.depends = src_corelib
  92    src_xmlpatterns.depends = src_corelib src_network
  93    src_dbus.depends = src_corelib src_xml
  94    src_svg.depends = src_xml src_gui
  95    src_script.depends = src_corelib
  96    src_scripttools.depends = src_script src_gui src_network
  97    src_network.depends = src_corelib
  98    src_opengl.depends = src_gui
  99    src_sql.depends = src_corelib
 100    src_testlib.depends = src_corelib
 101    src_qt3support.depends = src_gui src_xml src_network src_sql
 102    src_phonon.depends = src_gui
 103    src_tools_uic3.depends = src_qt3support src_xml
 104    src_tools_idc.depends = src_corelib
 105    src_tools_activeqt.depends = src_tools_idc src_gui
 106    src_plugins.depends = src_gui src_sql src_svg
 107    contains(QT_CONFIG, webkit)  {
 108       src_webkit.depends = src_gui src_sql src_network src_xml
 109       #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
 110    }
 111    contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
 112    contains(QT_CONFIG, dbus):{
 113       src_plugins.depends += src_dbus
 114       src_phonon.depends +=  src_dbus
 115    }
 116 }
 117
 118 # This creates a sub-src rule
 119 sub_src_target.CONFIG = recursive
 120 sub_src_target.recurse = $$SRC_SUBDIRS
 121 sub_src_target.target = sub-src
 122 sub_src_target.recurse_target =
 123 QMAKE_EXTRA_TARGETS += sub_src_target
 124
 125 # This gives us a top level debug/release
 126 EXTRA_DEBUG_TARGETS =
 127 EXTRA_RELEASE_TARGETS =
 128 for(subname, SRC_SUBDIRS) {
 129    subdir = $$subname
 130    !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
 131    subpro = $$subdir/$${basename(subdir)}.pro
 132    !exists($$subpro):next()
 133    subtarget = $$replace(subdir, [^A-Za-z0-9], _)
 134    reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
 135    subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
 136    subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
 137    subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
 138    SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
 139    !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
 140        #debug
 141        eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
 142        eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
 143        EXTRA_DEBUG_TARGETS += debug-$${subtarget}
 144        QMAKE_EXTRA_TARGETS += debug-$${subtarget}
 145        #release
 146        eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
 147        eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
 148        EXTRA_RELEASE_TARGETS += release-$${subtarget}
 149        QMAKE_EXTRA_TARGETS += release-$${subtarget}
 150     } else { #do not have a real debug target/release
 151        #debug
 152        eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
 153        eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
 154        EXTRA_DEBUG_TARGETS += debug-$${subtarget}
 155        QMAKE_EXTRA_TARGETS += debug-$${subtarget}
 156        #release
 157        eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
 158        eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
 159        EXTRA_RELEASE_TARGETS += release-$${subtarget}
 160        QMAKE_EXTRA_TARGETS += release-$${subtarget}
 161    }
 162 }
 163 debug.depends = $$EXTRA_DEBUG_TARGETS
 164 release.depends = $$EXTRA_RELEASE_TARGETS
 165 QMAKE_EXTRA_TARGETS += debug release
 166
 167 SUBDIRS += $$SRC_SUBDIRS
 168