src/s60installs/s60installs.pro

   1 # Use subdirs template to suppress generation of unnecessary files
   2 TEMPLATE = subdirs
   3
   4 symbian: {
   5     load(data_caging_paths)
   6
   7     SUBDIRS=
   8     # WARNING: Changing TARGET name will break Symbian SISX upgrade functionality
   9     # DO NOT TOUCH TARGET VARIABLE IF YOU ARE NOT SURE WHAT YOU ARE DOING
  10     TARGET = "Qt"
  11     TARGET.UID3 = 0x2001E61C
  12     VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
  13
  14     qtresources.sources = $${EPOCROOT}$$HW_ZDIR$$APP_RESOURCE_DIR/s60main.rsc
  15     qtresources.path = c:$$APP_RESOURCE_DIR
  16
  17     qtlibraries.sources = \
  18         QtCore.dll \
  19         QtXml.dll \
  20         QtGui.dll \
  21         QtNetwork.dll \
  22         QtTest.dll \
  23         QtSql.dll
  24
  25     qts60plugindeployment = \
  26         "IF package(0x1028315F)" \
  27         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_5_0.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0.dll\"" \
  28         "ELSEIF package(0x102752AE)" \
  29         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_3_2.dll\" - \"c:\\sys\\bin\\qts60plugin_3_2.dll\"" \
  30         "ELSEIF package(0x102032BE)" \
  31         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_3_1.dll\" - \"c:\\sys\\bin\\qts60plugin_3_1.dll\"" \
  32         "ELSE" \
  33         "   \"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/qts60plugin_5_0.dll\" - \"c:\\sys\\bin\\qts60plugin_5_0.dll\"" \
  34         "ENDIF"
  35     qtlibraries.pkg_postrules += qts60plugindeployment
  36
  37     sqlitedeployment = \
  38         "; Deploy sqlite onto phone that does not have it (this should be replaced with embedded sis file when available)" \
  39         "IF NOT package(0x2002533b) " \
  40         "\"$${EPOCROOT}epoc32/release/$(PLATFORM)/$(TARGET)/sqlite3.dll\" - \"c:\\sys\\bin\\sqlite3.dll\"" \
  41         "ENDIF"
  42     qtlibraries.pkg_postrules += sqlitedeployment
  43
  44     qtlibraries.path = c:/sys/bin
  45
  46     vendorinfo = \
  47         "; Localised Vendor name" \
  48         "%{\"Nokia, Qt\"}" \
  49         " " \
  50         "; Unique Vendor name" \
  51         ":\"Nokia, Qt\"" \
  52         " "
  53
  54
  55     qtlibraries.pkg_prerules = vendorinfo
  56     qtlibraries.pkg_prerules += "; Dependencies of Qt libraries"
  57     qtlibraries.pkg_prerules += "(0x20013851), 1, 5, 1, {\"PIPS Installer\"}"
  58     contains(QT_CONFIG, openssl) | contains(QT_CONFIG, openssl-linked) {
  59         qtlibraries.pkg_prerules += "(0x200110CB), 1, 5, 1, {\"Open C LIBSSL Common\"}"
  60     }
  61     contains(CONFIG, stl) {
  62         qtlibraries.pkg_prerules += "(0x2000F866), 1, 0, 0, {\"Standard C++ Library Common\"}"
  63     }
  64
  65     !contains(QT_CONFIG, no-jpeg): imageformats_plugins.sources += qjpeg.dll
  66     !contains(QT_CONFIG, no-gif):  imageformats_plugins.sources += qgif.dll
  67     !contains(QT_CONFIG, no-mng):  imageformats_plugins.sources += qmng.dll
  68     !contains(QT_CONFIG, no-tiff): imageformats_plugins.sources += qtiff.dll
  69     !contains(QT_CONFIG, no-ico):  imageformats_plugins.sources += qico.dll
  70     imageformats_plugins.path = c:$$QT_PLUGINS_BASE_DIR/imageformats
  71
  72     codecs_plugins.sources = qcncodecs.dll qjpcodecs.dll qtwcodecs.dll qkrcodecs.dll
  73     codecs_plugins.path = c:$$QT_PLUGINS_BASE_DIR/codecs
  74
  75     contains(QT_CONFIG, phonon-backend) {
  76         phonon_backend_plugins.sources += phonon_mmf.dll
  77
  78         phonon_backend_plugins.path = c:$$QT_PLUGINS_BASE_DIR/phonon_backend
  79         DEPLOYMENT += phonon_backend_plugins
  80     }
  81
  82     DEPLOYMENT += qtresources qtlibraries imageformats_plugins codecs_plugins graphicssystems_plugins
  83
  84     contains(QT_CONFIG, svg): {
  85        qtlibraries.sources += QtSvg.dll
  86        imageformats_plugins.sources += qsvg.dll
  87        iconengines_plugins.sources = qsvgicon.dll
  88        iconengines_plugins.path = c:$$QT_PLUGINS_BASE_DIR/iconengines
  89        DEPLOYMENT += iconengines_plugins
  90     }
  91
  92     contains(QT_CONFIG, phonon): {
  93        qtlibraries.sources += Phonon.dll
  94     }
  95
  96     contains(QT_CONFIG, script): {
  97         qtlibraries.sources += QtScript.dll
  98     }
  99
 100     contains(QT_CONFIG, xmlpatterns): {
 101        qtlibraries.sources += QtXmlPatterns.dll
 102     }
 103
 104     contains(QT_CONFIG, webkit): {
 105         qtlibraries.sources += QtWebKit.dll
 106     }
 107
 108     graphicssystems_plugins.path = c:$$QT_PLUGINS_BASE_DIR/graphicssystems
 109     contains(QT_CONFIG, openvg) {
 110         qtlibraries.sources += QtOpenVG.dll
 111         graphicssystems_plugins.sources += qvggraphicssystem.dll
 112     }
 113
 114     BLD_INF_RULES.prj_exports += "qt.iby $$CORE_MW_LAYER_IBY_EXPORT_PATH(qt.iby)"
 115     BLD_INF_RULES.prj_exports += "qtdemoapps.iby $$CORE_APP_LAYER_IBY_EXPORT_PATH(qtdemoapps.iby)"
 116 }