demos/demos.pro

   1 TEMPLATE    = subdirs
   2 SUBDIRS     = \
   3             demos_shared \
   4             demos_deform \
   5             demos_gradients \
   6             demos_pathstroke \
   7             demos_affine \
   8             demos_composition \
   9             demos_books \
  10             demos_interview \
  11             demos_mainwindow \
  12             demos_spreadsheet \
  13             demos_textedit \
  14             demos_chip \
  15             demos_embeddeddialogs \
  16             demos_undo \
  17             demos_sub-attaq
  18
  19 symbian: SUBDIRS = \
  20             demos_shared \
  21             demos_deform \
  22             demos_pathstroke
  23
  24 contains(QT_CONFIG, opengl):!contains(QT_CONFIG, opengles1):!contains(QT_CONFIG, opengles1cl):!contains(QT_CONFIG, opengles2):{
  25 SUBDIRS += demos_boxes
  26 }
  27
  28 mac*: SUBDIRS += demos_macmainwindow
  29 wince*|symbian|embedded|x11: SUBDIRS += embedded
  30
  31 !contains(QT_EDITION, Console):!cross_compile:!embedded:!wince*:SUBDIRS += demos_arthurplugin
  32
  33 !cross_compile:{
  34 contains(QT_BUILD_PARTS, tools):{
  35 !wince*:SUBDIRS += demos_sqlbrowser demos_qtdemo
  36 wince*: SUBDIRS += demos_sqlbrowser
  37 }
  38 }
  39 contains(QT_CONFIG, phonon):!static:SUBDIRS += demos_mediaplayer
  40 contains(QT_CONFIG, webkit):contains(QT_CONFIG, svg):SUBDIRS += demos_browser
  41
  42 # install
  43 sources.files = README *.pro
  44 sources.path = $$[QT_INSTALL_DEMOS]
  45 INSTALLS += sources
  46
  47 symbian: include($$QT_SOURCE_TREE/demos/symbianpkgrules.pri)
  48
  49 demos_chip.subdir = chip
  50 demos_embeddeddialogs.subdir = embeddeddialogs
  51 demos_shared.subdir = shared
  52 demos_deform.subdir = deform
  53 demos_gradients.subdir = gradients
  54 demos_pathstroke.subdir = pathstroke
  55 demos_affine.subdir = affine
  56 demos_composition.subdir = composition
  57 demos_books.subdir = books
  58 demos_interview.subdir = interview
  59 demos_macmainwindow.subdir = macmainwindow
  60 demos_mainwindow.subdir = mainwindow
  61 demos_spreadsheet.subdir = spreadsheet
  62 demos_textedit.subdir = textedit
  63 demos_arthurplugin.subdir = arthurplugin
  64 demos_sqlbrowser.subdir = sqlbrowser
  65 demos_undo.subdir = undo
  66 demos_qtdemo.subdir = qtdemo
  67 demos_mediaplayer.subdir = qmediaplayer
  68
  69 demos_browser.subdir = browser
  70
  71 demos_boxes.subdir = boxes
  72 demos_sub-attaq.subdir = sub-attaq
  73
  74 #CONFIG += ordered
  75 !ordered {
  76      demos_affine.depends = demos_shared
  77      demos_deform.depends = demos_shared
  78      demos_gradients.depends = demos_shared
  79      demos_composition.depends = demos_shared
  80      demos_arthurplugin.depends = demos_shared
  81      demos_pathstroke.depends = demos_shared
  82 }