src/opengl/opengl.pro

   1 TARGET     = QtOpenGL
   2 QPRO_PWD   = $$PWD
   3 QT         = core gui
   4 DEFINES   += QT_BUILD_OPENGL_LIB
   5 DEFINES   += QT_NO_USING_NAMESPACE
   6 win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x63000000
   7 solaris-cc*:QMAKE_CXXFLAGS_RELEASE -= -O2
   8
   9 unix:QMAKE_PKGCONFIG_REQUIRES = QtCore QtGui
  10
  11 include(../qbase.pri)
  12
  13 !win32:!embedded:!mac:CONFIG       += x11
  14 contains(QT_CONFIG, opengl):CONFIG += opengl
  15 contains(QT_CONFIG, opengles1):CONFIG += opengles1
  16 contains(QT_CONFIG, opengles1cl):CONFIG += opengles1cl
  17 contains(QT_CONFIG, opengles2):CONFIG += opengles2
  18
  19 contains(QT_CONFIG, opengles.*) {
  20         for(p, QMAKE_LIBDIR_EGL) {
  21                 exists($$p):LIBS_PRIVATE += -L$$p
  22         }
  23         !isEmpty(QMAKE_INCDIR_EGL): INCLUDEPATH += $$QMAKE_INCDIR_EGL
  24         !isEmpty(QMAKE_LIBS_EGL): LIBS_PRIVATE += $$QMAKE_LIBS_EGL
  25 }
  26
  27 HEADERS += qgl.h \
  28            qgl_p.h \
  29            qglcolormap.h \
  30            qglpixelbuffer.h \
  31            qglpixelbuffer_p.h \
  32            qglframebufferobject.h  \
  33            qglframebufferobject_p.h  \
  34            qglextensions_p.h \
  35            qglpaintdevice_p.h \
  36
  37
  38 SOURCES += qgl.cpp \
  39            qglcolormap.cpp \
  40            qglpixelbuffer.cpp \
  41            qglframebufferobject.cpp \
  42            qglextensions.cpp \
  43            qglpaintdevice.cpp \
  44
  45
  46 !contains(QT_CONFIG, opengles2) {
  47     HEADERS += qpaintengine_opengl_p.h
  48     SOURCES += qpaintengine_opengl.cpp
  49 }
  50
  51 !contains(QT_CONFIG, opengles1):!contains(QT_CONFIG, opengles1cl) {
  52     HEADERS +=  qglshaderprogram.h \
  53                 qglpixmapfilter_p.h  \
  54                 qgraphicsshadereffect_p.h \
  55                 qgraphicssystem_gl_p.h \
  56                 qwindowsurface_gl_p.h \
  57                 qpixmapdata_gl_p.h \
  58                 gl2paintengineex/qglgradientcache_p.h \
  59                 gl2paintengineex/qglengineshadermanager_p.h \
  60                 gl2paintengineex/qgl2pexvertexarray_p.h \
  61                 gl2paintengineex/qpaintengineex_opengl2_p.h \
  62                 gl2paintengineex/qglengineshadersource_p.h \
  63                 gl2paintengineex/qglcustomshaderstage_p.h
  64
  65     SOURCES +=  qglshaderprogram.cpp \
  66                 qglpixmapfilter.cpp \
  67                 qgraphicsshadereffect.cpp \
  68                 qgraphicssystem_gl.cpp \
  69                 qwindowsurface_gl.cpp \
  70                 qpixmapdata_gl.cpp \
  71                 gl2paintengineex/qglgradientcache.cpp \
  72                 gl2paintengineex/qglengineshadermanager.cpp \
  73                 gl2paintengineex/qgl2pexvertexarray.cpp \
  74                 gl2paintengineex/qpaintengineex_opengl2.cpp \
  75                 gl2paintengineex/qglcustomshaderstage.cpp
  76
  77 }
  78
  79 x11 {
  80     contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles1cl)|contains(QT_CONFIG, opengles2) {
  81         SOURCES +=  qgl_x11egl.cpp \
  82                     qglpixelbuffer_egl.cpp \
  83                     qgl_egl.cpp
  84
  85         HEADERS +=  qgl_egl_p.h
  86
  87     } else {
  88         SOURCES +=  qgl_x11.cpp \
  89                     qglpixelbuffer_x11.cpp
  90     }
  91
  92     contains(QT_CONFIG, fontconfig) {
  93         contains(QT_CONFIG, system-freetype) {
  94             embedded:CONFIG += opentype
  95             # pull in the proper freetype2 include directory
  96             include($$QT_SOURCE_TREE/config.tests/unix/freetype/freetype.pri)
  97             LIBS_PRIVATE += -lfreetype
  98         } else {
  99             ### Note: how does this compile with a non-system freetype?
 100             # This probably doesn't compile
 101         }
 102     } else {
 103         DEFINES *= QT_NO_FREETYPE
 104     }
 105
 106     LIBS_PRIVATE += $$QMAKE_LIBS_DYNLOAD
 107 }
 108
 109 mac {
 110     OBJECTIVE_SOURCES += qgl_mac.mm \
 111                          qglpixelbuffer_mac.mm
 112     LIBS_PRIVATE += -framework AppKit -framework Carbon
 113 }
 114 win32:!wince*: {
 115     SOURCES += qgl_win.cpp \
 116                qglpixelbuffer_win.cpp
 117 }
 118 wince*: {
 119     SOURCES += qgl_wince.cpp \
 120                qglpixelbuffer_egl.cpp \
 121                qgl_egl.cpp
 122
 123     HEADERS += qgl_cl_p.h \
 124                qgl_egl_p.h \
 125 }
 126
 127 embedded {
 128     SOURCES += qgl_qws.cpp \
 129                qglpixelbuffer_egl.cpp \
 130                qglscreen_qws.cpp \
 131                qglwindowsurface_qws.cpp \
 132                qgl_egl.cpp
 133
 134     HEADERS += qglscreen_qws.h \
 135                qglwindowsurface_qws_p.h \
 136                qgl_egl_p.h
 137
 138     contains(QT_CONFIG, fontconfig) {
 139         include($$QT_SOURCE_TREE/config.tests/unix/freetype/freetype.pri)
 140     } else {
 141        DEFINES *= QT_NO_FREETYPE
 142     }
 143 }
 144
 145 INCLUDEPATH += ../3rdparty/harfbuzz/src
 146
 147 wince*: {
 148     contains(QT_CONFIG,opengles1) {
 149         QMAKE_LIBS += "libGLES_CM.lib"
 150     }
 151     contains(QT_CONFIG,opengles1cl) {
 152         QMAKE_LIBS += "libGLES_CL.lib"
 153     }
 154     contains(QT_CONFIG,opengles2) {
 155         QMAKE_LIBS += "libGLESv2.lib"
 156     }
 157
 158 } else {
 159     LIBS_PRIVATE += $$QMAKE_LIBS_OPENGL
 160     LIBS += $$QMAKE_LFLAGS_OPENGL
 161 }