src/src.pro

   1 TEMPLATE = subdirs
   2
   3 # this order is important
   4 unset(SRC_SUBDIRS)
   5 win32:SRC_SUBDIRS += src_winmain
   6 wince*:{
   7   SRC_SUBDIRS += src_corelib src_xml src_gui src_sql src_network src_testlib
   8 } else:symbian {
   9   SRC_SUBDIRS += src_s60main src_corelib src_xml src_gui src_network src_sql src_testlib src_s60installs
  10 } else {
  11     SRC_SUBDIRS += src_tools_bootstrap src_tools_moc src_tools_rcc src_tools_uic src_corelib src_xml src_network src_gui src_sql src_testlib
  12     !vxworks:contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_qt3support
  13     contains(QT_CONFIG, dbus):SRC_SUBDIRS += src_dbus
  14     !cross_compile {
  15         contains(QT_CONFIG, qt3support): SRC_SUBDIRS += src_tools_uic3
  16     }
  17 }
  18 win32:{
  19     SRC_SUBDIRS += src_activeqt
  20     !wince*: SRC_SUBDIRS += src_tools_idc
  21 }
  22
  23 contains(QT_CONFIG, opengl)|contains(QT_CONFIG, opengles1)|contains(QT_CONFIG, opengles2): SRC_SUBDIRS += src_opengl
  24 contains(QT_CONFIG, openvg): SRC_SUBDIRS += src_openvg
  25 contains(QT_CONFIG, xmlpatterns): SRC_SUBDIRS += src_xmlpatterns
  26 contains(QT_CONFIG, phonon): SRC_SUBDIRS += src_phonon
  27 contains(QT_CONFIG, multimedia): SRC_SUBDIRS += src_multimedia
  28 contains(QT_CONFIG, svg): SRC_SUBDIRS += src_svg
  29 contains(QT_CONFIG, webkit)  {
  30     #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): SRC_SUBDIRS += src_javascriptcore
  31     SRC_SUBDIRS += src_webkit
  32 }
  33 contains(QT_CONFIG, script): SRC_SUBDIRS += src_script
  34 contains(QT_CONFIG, scripttools): SRC_SUBDIRS += src_scripttools
  35 SRC_SUBDIRS += src_plugins
  36
  37 src_s60main.subdir = $$QT_SOURCE_TREE/src/s60main
  38 src_s60main.target = sub-s60main
  39 src_s60installs.subdir = $$QT_SOURCE_TREE/src/s60installs
  40 src_s60installs.target = sub-s60installs
  41 src_winmain.subdir = $$QT_SOURCE_TREE/src/winmain
  42 src_winmain.target = sub-winmain
  43 src_tools_bootstrap.subdir = $$QT_SOURCE_TREE/src/tools/bootstrap
  44 src_tools_bootstrap.target = sub-tools-bootstrap
  45 src_tools_moc.subdir = $$QT_SOURCE_TREE/src/tools/moc
  46 src_tools_moc.target = sub-moc
  47 src_tools_rcc.subdir = $$QT_SOURCE_TREE/src/tools/rcc
  48 src_tools_rcc.target = sub-rcc
  49 src_tools_uic.subdir = $$QT_SOURCE_TREE/src/tools/uic
  50 src_tools_uic.target = sub-uic
  51 src_corelib.subdir = $$QT_SOURCE_TREE/src/corelib
  52 src_corelib.target = sub-corelib
  53 src_xml.subdir = $$QT_SOURCE_TREE/src/xml
  54 src_xml.target = sub-xml
  55 src_xmlpatterns.subdir = $$QT_SOURCE_TREE/src/xmlpatterns
  56 src_xmlpatterns.target = sub-xmlpatterns
  57 src_dbus.subdir = $$QT_SOURCE_TREE/src/dbus
  58 src_dbus.target = sub-dbus
  59 src_gui.subdir = $$QT_SOURCE_TREE/src/gui
  60 src_gui.target = sub-gui
  61 src_sql.subdir = $$QT_SOURCE_TREE/src/sql
  62 src_sql.target = sub-sql
  63 src_network.subdir = $$QT_SOURCE_TREE/src/network
  64 src_network.target = sub-network
  65 src_svg.subdir = $$QT_SOURCE_TREE/src/svg
  66 src_svg.target = sub-svg
  67 src_script.subdir = $$QT_SOURCE_TREE/src/script
  68 src_script.target = sub-script
  69 src_scripttools.subdir = $$QT_SOURCE_TREE/src/scripttools
  70 src_scripttools.target = sub-scripttools
  71 src_opengl.subdir = $$QT_SOURCE_TREE/src/opengl
  72 src_opengl.target = sub-opengl
  73 src_openvg.subdir = $$QT_SOURCE_TREE/src/openvg
  74 src_openvg.target = sub-openvg
  75 src_qt3support.subdir = $$QT_SOURCE_TREE/src/qt3support
  76 src_qt3support.target = sub-qt3support
  77 src_phonon.subdir = $$QT_SOURCE_TREE/src/phonon
  78 src_phonon.target = sub-phonon
  79 src_multimedia.subdir = $$QT_SOURCE_TREE/src/multimedia
  80 src_multimedia.target = sub-multimedia
  81 src_tools_uic3.subdir = $$QT_SOURCE_TREE/src/tools/uic3
  82 src_tools_uic3.target = sub-uic3
  83 src_activeqt.subdir = $$QT_SOURCE_TREE/src/activeqt
  84 src_activeqt.target = sub-activeqt
  85 src_tools_idc.subdir = $$QT_SOURCE_TREE/src/tools/idc
  86 src_tools_idc.target = sub-idc
  87 src_plugins.subdir = $$QT_SOURCE_TREE/src/plugins
  88 src_plugins.target = sub-plugins
  89 src_testlib.subdir = $$QT_SOURCE_TREE/src/testlib
  90 src_testlib.target = sub-testlib
  91 src_javascriptcore.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore
  92 src_javascriptcore.target = sub-javascriptcore
  93 src_webkit.subdir = $$QT_SOURCE_TREE/src/3rdparty/webkit/WebCore
  94 src_webkit.target = sub-webkit
  95
  96 #CONFIG += ordered
  97 !wince*:!symbian:!ordered {
  98    src_tools_moc.depends = src_tools_bootstrap
  99    src_tools_rcc.depends = src_tools_bootstrap
 100    src_tools_uic.depends = src_tools_bootstrap
 101    src_corelib.depends = src_tools_moc src_tools_rcc
 102    src_gui.depends = src_corelib src_tools_uic
 103    embedded: src_gui.depends += src_network
 104    src_xml.depends = src_corelib
 105    src_xmlpatterns.depends = src_corelib src_network
 106    src_dbus.depends = src_corelib src_xml
 107    src_svg.depends = src_xml src_gui
 108    src_script.depends = src_corelib
 109    src_scripttools.depends = src_script src_gui src_network
 110    src_network.depends = src_corelib
 111    src_opengl.depends = src_gui
 112    src_openvg.depends = src_gui
 113    src_sql.depends = src_corelib
 114    src_testlib.depends = src_corelib
 115    src_qt3support.depends = src_gui src_xml src_network src_sql
 116    src_phonon.depends = src_gui
 117    src_multimedia.depends = src_gui
 118    src_tools_uic3.depends = src_qt3support src_xml
 119    src_tools_idc.depends = src_corelib
 120    src_tools_activeqt.depends = src_tools_idc src_gui
 121    src_plugins.depends = src_gui src_sql src_svg
 122    contains(QT_CONFIG, webkit)  {
 123       src_webkit.depends = src_gui src_sql src_network src_xml
 124       contains(QT_CONFIG, phonon):src_webkit.depends += src_phonon
 125       #exists($$QT_SOURCE_TREE/src/3rdparty/webkit/JavaScriptCore/JavaScriptCore.pro): src_webkit.depends += src_javascriptcore
 126    }
 127    contains(QT_CONFIG, qt3support): src_plugins.depends += src_qt3support
 128    contains(QT_CONFIG, dbus):{
 129       src_plugins.depends += src_dbus
 130       src_phonon.depends +=  src_dbus
 131    }
 132 }
 133
 134 !symbian {
 135 # This creates a sub-src rule
 136 sub_src_target.CONFIG = recursive
 137 sub_src_target.recurse = $$SRC_SUBDIRS
 138 sub_src_target.target = sub-src
 139 sub_src_target.recurse_target =
 140 QMAKE_EXTRA_TARGETS += sub_src_target
 141
 142 # This gives us a top level debug/release
 143 EXTRA_DEBUG_TARGETS =
 144 EXTRA_RELEASE_TARGETS =
 145 for(subname, SRC_SUBDIRS) {
 146    subdir = $$subname
 147    !isEmpty($${subname}.subdir):subdir = $$eval($${subname}.subdir)
 148    subpro = $$subdir/$${basename(subdir)}.pro
 149    !exists($$subpro):next()
 150    subtarget = $$replace(subdir, [^A-Za-z0-9], _)
 151    reg_src = $$replace(QT_SOURCE_TREE, \\\\, \\\\)
 152    subdir = $$replace(subdir, $$reg_src, $$QT_BUILD_TREE)
 153    subdir = $$replace(subdir, /, $$QMAKE_DIR_SEP)
 154    subdir = $$replace(subdir, \\\\, $$QMAKE_DIR_SEP)
 155    SUB_TEMPLATE = $$list($$fromfile($$subpro, TEMPLATE))
 156    !isEqual(subname, src_tools_bootstrap):if(isEqual($$SUB_TEMPLATE, lib) | isEqual($$SUB_TEMPLATE, subdirs) | isEqual(subname, src_tools_idc) | isEqual(subname, src_tools_uic3)):!separate_debug_info {
 157        #debug
 158        eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
 159        eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) debug))
 160        EXTRA_DEBUG_TARGETS += debug-$${subtarget}
 161        QMAKE_EXTRA_TARGETS += debug-$${subtarget}
 162        #release
 163        eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
 164        eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) release))
 165        EXTRA_RELEASE_TARGETS += release-$${subtarget}
 166        QMAKE_EXTRA_TARGETS += release-$${subtarget}
 167     } else { #do not have a real debug target/release
 168        #debug
 169        eval(debug-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_DEBUG_TARGETS)
 170        eval(debug-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
 171        EXTRA_DEBUG_TARGETS += debug-$${subtarget}
 172        QMAKE_EXTRA_TARGETS += debug-$${subtarget}
 173        #release
 174        eval(release-$${subtarget}.depends = $${subdir}\$${QMAKE_DIR_SEP}$(MAKEFILE) $$EXTRA_RELEASE_TARGETS)
 175        eval(release-$${subtarget}.commands = (cd $$subdir && $(MAKE) -f $(MAKEFILE) first))
 176        EXTRA_RELEASE_TARGETS += release-$${subtarget}
 177        QMAKE_EXTRA_TARGETS += release-$${subtarget}
 178    }
 179 }
 180 debug.depends = $$EXTRA_DEBUG_TARGETS
 181 release.depends = $$EXTRA_RELEASE_TARGETS
 182 QMAKE_EXTRA_TARGETS += debug release
 183 }
 184
 185 SUBDIRS += $$SRC_SUBDIRS
 186