examples/examples.pro

   1 TEMPLATE      = subdirs
   2 SUBDIRS       = \
   3                 animation \
   4                 desktop \
   5                 dialogs \
   6                 draganddrop \
   7                 effects \
   8                 graphicsview \
   9                 ipc \
  10                 itemviews \
  11                 layouts \
  12                 linguist \
  13                 mainwindows \
  14                 network \
  15                 painting \
  16                 qtconcurrent \
  17                 richtext \
  18                 sql \
  19                 statemachine \
  20                 threads \
  21                 tools \
  22                 tutorials \
  23                 widgets \
  24                 uitools \
  25                 xml \
  26                 multitouch \
  27                 gestures
  28
  29 symbian: SUBDIRS = \
  30                 graphicsview \
  31                 itemviews \
  32                 network \
  33                 painting \
  34                 widgets \
  35                 draganddrop \
  36                 mainwindows \
  37                 sql \
  38                 uitools \
  39                 xml
  40
  41 contains(QT_CONFIG, multimedia) {
  42     SUBDIRS += video
  43     !static: SUBDIRS += multimedia
  44 }
  45
  46 contains(QT_CONFIG, script): SUBDIRS += script
  47
  48 contains(QT_CONFIG, phonon):!static: SUBDIRS += phonon
  49 contains(QT_CONFIG, webkit): SUBDIRS += webkit
  50 embedded:SUBDIRS += qws
  51 !wince*:!symbian: {
  52         !contains(QT_EDITION, Console):contains(QT_BUILD_PARTS, tools):SUBDIRS += designer
  53         contains(QT_BUILD_PARTS, tools):SUBDIRS += assistant qtestlib help
  54 } else {
  55         contains(QT_BUILD_PARTS, tools):SUBDIRS += qtestlib
  56 }
  57 contains(QT_CONFIG, opengl): SUBDIRS += opengl
  58 contains(QT_CONFIG, openvg): SUBDIRS += openvg
  59 contains(QT_CONFIG, dbus): SUBDIRS += dbus
  60 win32: SUBDIRS += activeqt
  61 contains(QT_CONFIG, xmlpatterns): SUBDIRS += xmlpatterns
  62 contains(DEFINES, QT_NO_CURSOR): SUBDIRS -= mainwindows
  63
  64 # install
  65 sources.files = README *.pro
  66 sources.path = $$[QT_INSTALL_EXAMPLES]
  67 INSTALLS += sources
  68
  69 symbian: include($$QT_SOURCE_TREE/examples/symbianpkgrules.pri)