translations/translations.pri

   1 defineReplace(prependAll) {
   2     prepend = $$1
   3     arglist = $$2
   4     append  = $$3
   5     for(a,arglist) {
   6       result += $${prepend}$${a}$${append}
   7     }
   8     return ($$result)
   9 }
  10
  11 defineReplace(fixPath) {
  12 WIN {
  13     return ($$replace($$1, /, \))
  14 } ELSE {
  15     return ($$1)
  16 }
  17 }
  18
  19 LUPDATE = $$fixPath($$QT_BUILD_TREE/bin/lupdate) -locations relative -no-ui-lines
  20 LRELEASE = $$fixPath($$QT_BUILD_TREE/bin/lrelease)
  21
  22 ###### Qt Libraries
  23
  24 QT_TS        = de fr zh_CN untranslated ar es iw ja_JP pl pt ru sk sv uk zh_TW da
  25
  26 ts-qt.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
  27                                     3rdparty/phonon \
  28                                     3rdparty/webkit \
  29                                     activeqt \
  30                                     corelib \
  31                                     gui \
  32                                     network \
  33                                     opengl \
  34                                     plugins \
  35                                     qt3support \
  36                                     script \
  37                                     sql \
  38                                     svg \
  39                                     xml \
  40                                     xmlpatterns \
  41                                 -ts $$prependAll($$[QT_INSTALL_TRANSLATIONS]/qt_,$$QT_TS,.ts))
  42 ts-qt.depends = sub-tools
  43
  44 qm-qt.commands = $$LRELEASE $$prependAll($$[QT_INSTALL_TRANSLATIONS]/qt_,$$QT_TS,.ts)
  45 qm-qt.depends = sub-tools
  46
  47 ###### Designer
  48
  49 ts-designer.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
  50                                     ../tools/designer/translations/translations.pro)
  51 ts-designer.depends = sub-tools
  52
  53 qm-designer.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/designer/translations/translations.pro
  54 qm-designer.depends = sub-tools
  55
  56 ###### Linguist
  57
  58 ts-linguist.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
  59                                     ../tools/linguist/linguist/linguist.pro)
  60 ts-linguist.depends = sub-tools
  61
  62 qm-linguist.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/linguist/linguist/linguist.pro
  63 qm-linguist.depends = sub-tools
  64
  65 ###### Assistant
  66
  67 ts-assistant.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
  68                                     ../tools/assistant/translations/translations.pro \
  69                                     && $$LUPDATE \
  70                                     ../tools/assistant/translations/qt_help.pro \
  71                                     && $$LUPDATE \
  72                                     ../tools/assistant/translations/translations_adp.pro)
  73 ts-assistant.depends = sub-tools
  74
  75 qm-assistant.commands = ($$LRELEASE $$QT_SOURCE_TREE/tools/assistant/translations/translations.pro \
  76                          && $$LRELEASE \
  77                             $$QT_SOURCE_TREE/tools/assistant/translations/qt_help.pro \
  78                          && $$LRELEASE \
  79                             $$QT_SOURCE_TREE/tools/assistant/translations/translations_adp.pro)
  80 qm-assistant.depends = sub-tools
  81
  82 ###### Qtconfig
  83
  84 ts-qtconfig.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
  85                                     ../tools/qtconfig/translations/translations.pro)
  86 ts-qtconfig.depends = sub-tools
  87
  88 qm-qtconfig.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/qtconfig/translations/translations.pro
  89 qm-qtconfig.depends = sub-tools
  90
  91 ###### Qvfp
  92
  93 ts-qvfb.commands = (cd $$QT_SOURCE_TREE/src && $$LUPDATE \
  94                                     ../tools/qvfb/translations/translations.pro)
  95 ts-qvfb.depends = sub-tools
  96
  97 qm-qvfb.commands = $$LRELEASE $$QT_SOURCE_TREE/tools/qvfb/translations/translations.pro
  98 qm-qvfb.depends = sub-tools
  99
 100 ###### Overall Rules
 101
 102 ts.depends = ts-qt ts-designer ts-linguist ts-assistant ts-qtconfig ts-qvfb
 103 qm.depends = qm-qt qm-designer qm-linguist qm-assistant qm-qtconfig qm-qvfb
 104
 105 QMAKE_EXTRA_TARGETS += ts-qt ts-designer ts-linguist ts-assistant ts-qtconfig ts-qvfb \
 106                        qm-qt qm-designer qm-linguist qm-assistant qm-qtconfig qm-qvfb \
 107                        ts qm