src/qbase.pri

   1 isEmpty(TARGET):error(You must set TARGET before include()'ing $${_FILE_})
   2 INCLUDEPATH *= $$QMAKE_INCDIR_QT/$$TARGET #just for today to have some compat
   3 !isEmpty(RCC_DIR): INCLUDEPATH += $$RCC_DIR
   4 isEmpty(QT_ARCH):!isEmpty(ARCH):QT_ARCH=$$ARCH #another compat that will rot for change #215700
   5 TEMPLATE        = lib
   6 isEmpty(QT_MAJOR_VERSION) {
   7    VERSION=4.5.3
   8 } else {
   9    VERSION=$${QT_MAJOR_VERSION}.$${QT_MINOR_VERSION}.$${QT_PATCH_VERSION}
  10 }
  11 mac:!contains(QMAKE_EXT_C, .mm):QMAKE_EXT_C += .mm
  12
  13 #load up the headers info
  14 CONFIG += qt_install_headers
  15 HEADERS_PRI = $$QT_BUILD_TREE/include/$$TARGET/headers.pri
  16 include($$HEADERS_PRI)|clear(HEADERS_PRI)
  17
  18 #version overriding
  19 win32 {
  20     #because libnetwork.pro could be qmake'd (qmade?) before libqcore.pro we
  21     #need to override the version of libq* in all other libq*'s just to be
  22     #sure the same version is used
  23         VERSIONS_LIST = $$split(VERSION, ".")
  24     QT_LIBS_OVERRIDE = $$member(VERSIONS_LIST, 0)
  25         for(lib, $$list(qtcore qtgui qtnetwork qtxml qtopengl qtsql qt3support)) {
  26         eval(QMAKE_$${upper($$lib)}_VERSION_OVERRIDE = $$QT_LIBS_OVERRIDE)
  27         eval(QMAKE_$${upper($$lib)}D_VERSION_OVERRIDE = $$QT_LIBS_OVERRIDE)
  28     }
  29 }
  30
  31 #other
  32 DESTDIR          = $$QMAKE_LIBDIR_QT
  33 win32:!wince*:DLLDESTDIR = $$[QT_INSTALL_PREFIX]/bin
  34
  35 CONFIG          += qt warn_on depend_includepath
  36 CONFIG          += qmake_cache target_qt
  37 CONFIG          -= fix_output_dirs
  38 win32|mac:!macx-xcode:CONFIG += debug_and_release
  39 linux-g++*:QMAKE_LFLAGS += $$QMAKE_LFLAGS_NOUNDEF
  40
  41 contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols
  42 unix:contains(QT_CONFIG, reduce_relocations):CONFIG += bsymbolic_functions
  43 contains(QT_CONFIG, largefile):CONFIG += largefile
  44
  45 #mac frameworks
  46 mac:!static:contains(QT_CONFIG, qt_framework) {
  47    #QMAKE_FRAMEWORK_VERSION = 4.0
  48    CONFIG += lib_bundle qt_no_framework_direct_includes qt_framework
  49    CONFIG(debug, debug|release) {
  50       !build_pass:CONFIG += build_all
  51    } else { #release
  52       !debug_and_release|build_pass {
  53           CONFIG -= qt_install_headers #no need to install these as well
  54           FRAMEWORK_HEADERS.version = Versions
  55           FRAMEWORK_HEADERS.files = $$SYNCQT.HEADER_FILES $$SYNCQT.HEADER_CLASSES
  56           FRAMEWORK_HEADERS.path = Headers
  57           equals(TARGET, QtCore) {
  58               #headers generated by configure
  59               !contains(FRAMEWORK_HEADERS.files, .*/qconfig.h) {
  60                   FRAMEWORK_HEADERS.files *= $$QT_BUILD_TREE/src/corelib/global/qconfig.h
  61               }
  62           }
  63       }
  64       QMAKE_BUNDLE_DATA += FRAMEWORK_HEADERS
  65    }
  66 }
  67
  68 mac {
  69    CONFIG += explicitlib
  70    true { #we want to use O2 on Qt itself (Os was used to fix other failures in older GCC)
  71       QMAKE_CFLAGS_RELEASE ~= s,-Os,-O2,
  72       QMAKE_CXXFLAGS_RELEASE ~= s,-Os,-O2,
  73       QMAKE_OBJECTIVE_CFLAGS_RELEASE ~= s,-Os,-O2,
  74    }
  75    macx-g++ {
  76        QMAKE_CFLAGS += -fconstant-cfstrings
  77        QMAKE_CXXFLAGS += -fconstant-cfstrings
  78    }
  79 }
  80
  81 win32:!shared:CONFIG += static
  82
  83 win32-borland {
  84     mng:QMAKE_CFLAGS_WARN_ON    += -w-par
  85     mng:QMAKE_CXXFLAGS_WARN_ON  += -w-par
  86     # Keep the size of the .tds file for the Qt library smaller than
  87     # 34 Mbytes to avoid linking problems
  88     QMAKE_CFLAGS_DEBUG += -vi -y-
  89     QMAKE_CXXFLAGS_DEBUG += -vi -y-
  90 }
  91
  92 win32 {
  93     CONFIG += zlib
  94     INCLUDEPATH += tmp
  95     !static: DEFINES+=QT_MAKEDLL
  96 }
  97 win32-borland:INCLUDEPATH += kernel
  98
  99 aix-g++* {
 100      QMAKE_CFLAGS   += -mminimal-toc
 101      QMAKE_CXXFLAGS += -mminimal-toc
 102 }
 103
 104 embedded {
 105      EMBEDDED_H = $$EMBEDDED_CPP
 106 }
 107
 108 DEPENDPATH += ;$$NETWORK_H;$$KERNEL_H;$$WIDGETS_H;$$SQL_H;$$TABLE_H;$$DIALOGS_H;
 109 DEPENDPATH += $$ICONVIEW_H;$$OPENGL_H;$$THREAD_H;$$TOOLS_H;$$CODECS_H;
 110 DEPENDPATH += $$WORKSPACE_H;$$XML_H;$$STYLES_H;$$COMPAT_H
 111 embedded:DEPENDPATH += ;$$EMBEDDED_H
 112
 113 !static:PRL_EXPORT_DEFINES += QT_SHARED
 114
 115 #install directives
 116 include(qt_install.pri)
 117
 118 unix {
 119    CONFIG     += create_libtool create_pc explicitlib
 120    QMAKE_LIBTOOL_LIBDIR = $$[QT_INSTALL_LIBS]
 121    QMAKE_PRL_LIBDIR = $$[QT_INSTALL_LIBS]
 122    QMAKE_PKGCONFIG_LIBDIR = $$[QT_INSTALL_LIBS]
 123    QMAKE_PKGCONFIG_INCDIR = $$[QT_INSTALL_HEADERS]/$$TARGET
 124    QMAKE_PKGCONFIG_CFLAGS = -I$$[QT_INSTALL_HEADERS]
 125    QMAKE_PKGCONFIG_DESTDIR = pkgconfig
 126    include_replace.match = $$QMAKE_INCDIR_QT
 127    include_replace.replace = $$[QT_INSTALL_HEADERS]
 128    lib_replace.match = $$QMAKE_LIBDIR_QT
 129    lib_replace.replace = $$[QT_INSTALL_LIBS]
 130    prefix_replace.match = $$QT_BUILD_TREE
 131    prefix_replace.replace = $$[QT_INSTALL_PREFIX]
 132    QMAKE_PRL_INSTALL_REPLACE += include_replace lib_replace
 133    QMAKE_LIBTOOL_INSTALL_REPLACE += include_replace lib_replace
 134    QMAKE_PKGCONFIG_INSTALL_REPLACE += include_replace lib_replace prefix_replace
 135 }
 136
 137 contains(QT_PRODUCT, OpenSource.*):DEFINES *= QT_OPENSOURCE
 138 DEFINES += QT_NO_CAST_TO_ASCII QT_ASCII_CAST_WARNINGS
 139 contains(QT_CONFIG, qt3support):DEFINES *= QT3_SUPPORT
 140 DEFINES *= QT_MOC_COMPAT #we don't need warnings from calling moc code in our generated code
 141
 142 TARGET = $$qtLibraryTarget($$TARGET$$QT_LIBINFIX) #do this towards the end
 143
 144 moc_dir.name = moc_location
 145 moc_dir.variable = QMAKE_MOC
 146
 147 uic_dir.name = uic_location
 148 uic_dir.variable = QMAKE_UIC
 149
 150 QMAKE_PKGCONFIG_VARIABLES += moc_dir uic_dir
 151
 152 include(qt_targets.pri)
 153
 154 win32:DEFINES+=_USE_MATH_DEFINES