tools/qvfb/qvfb.pro

   1 TEMPLATE        = app
   2 CONFIG          += qt warn_on uic
   3 TARGET          = qvfb
   4 DESTDIR         = ../../bin
   5
   6 !win32:!embedded:!mac:CONFIG += x11
   7
   8 target.path=$$[QT_INSTALL_BINS]
   9 INSTALLS += target
  10
  11 DEPENDPATH      = ../../include
  12 INCLUDEPATH     += ../../src/gui/embedded
  13
  14 FORMS           = config.ui
  15 HEADERS         = qvfb.h \
  16                   qvfbview.h \
  17                   qvfbratedlg.h \
  18                   qanimationwriter.h \
  19                   gammaview.h \
  20                   qvfbprotocol.h \
  21                   qvfbshmem.h \
  22                   qvfbmmap.h \
  23                   ../../src/gui/embedded/qvfbhdr.h \
  24                   ../../src/gui/embedded/qlock_p.h \
  25                   ../../src/gui/embedded/qwssignalhandler_p.h
  26
  27 SOURCES         = qvfb.cpp \
  28                   qvfbview.cpp \
  29                   qvfbratedlg.cpp \
  30                   main.cpp \
  31                   qanimationwriter.cpp \
  32                   qvfbprotocol.cpp \
  33                   qvfbshmem.cpp \
  34                   qvfbmmap.cpp \
  35                   ../../src/gui/embedded/qlock.cpp \
  36                   ../../src/gui/embedded/qwssignalhandler.cpp
  37
  38 include($$QT_SOURCE_TREE/tools/shared/deviceskin/deviceskin.pri)
  39
  40 contains(QT_CONFIG, opengl) {
  41         QT += opengl
  42 }
  43
  44 contains(QT_CONFIG, system-png) {
  45         LIBS += -lpng
  46 } else {
  47         INCLUDEPATH     += $$QT_SOURCE_TREE/src/3rdparty/libpng
  48 }
  49 contains(QT_CONFIG, system-zlib) {
  50         LIBS += -lz
  51 } else {
  52         INCLUDEPATH     += $$QT_SOURCE_TREE/src/3rdparty/zlib
  53 }
  54
  55 unix:x11 {
  56     HEADERS     += qvfbx11view.h \
  57                    x11keyfaker.h \
  58                    qtopiakeysym.h
  59     SOURCES     += qvfbx11view.cpp \
  60                    x11keyfaker.cpp
  61     LIBS += -lXtst
  62 }
  63
  64 RESOURCES       += qvfb.qrc