src/xmlpatterns/xmlpatterns.pro

   1 TARGET     = QtXmlPatterns
   2 QPRO_PWD   = $$PWD
   3 QT         = core network
   4 DEFINES   += QT_BUILD_XMLPATTERNS_LIB QT_NO_USING_NAMESPACE
   5 win32-msvc*|win32-icc:QMAKE_LFLAGS += /BASE:0x61000000
   6
   7 unix:QMAKE_PKGCONFIG_REQUIRES = QtCore QtNetwork
   8
   9 include(../qbase.pri)
  10
  11 PRECOMPILED_HEADER = ../corelib/global/qt_pch.h
  12
  13 include($$PWD/common.pri)
  14 include($$PWD/acceltree/acceltree.pri)
  15 include($$PWD/api/api.pri)
  16 include($$PWD/data/data.pri)
  17 include($$PWD/environment/environment.pri)
  18 include($$PWD/expr/expr.pri)
  19 include($$PWD/functions/functions.pri)
  20 include($$PWD/iterators/iterators.pri)
  21 include($$PWD/janitors/janitors.pri)
  22 include($$PWD/parser/parser.pri)
  23 include($$PWD/projection/projection.pri)
  24 include($$PWD/type/type.pri)
  25 include($$PWD/utils/utils.pri)
  26 include($$PWD/qobjectmodel/qobjectmodel.pri)
  27
  28 wince*: {
  29    # The Microsoft MIPS compiler crashes if /Og is specified
  30    # -O2/1 expands to /Og plus additional arguments.
  31    contains(DEFINES, MIPS): {
  32       QMAKE_CXXFLAGS_RELEASE ~= s/-O2/-Oi -Ot -Oy -Ob2/
  33       QMAKE_CXXFLAGS_RELEASE ~= s/-O1/-Os -Oy -Ob2/
  34    }
  35 }