src/qt_install.pri

   1 #always install the library
   2 win32 {
   3    dlltarget.path=$$[QT_INSTALL_BINS]
   4    INSTALLS += dlltarget
   5 }
   6 target.path=$$[QT_INSTALL_LIBS]
   7 INSTALLS += target
   8
   9 #headers
  10 qt_install_headers {
  11     INSTALL_HEADERS = $$SYNCQT.HEADER_FILES
  12     equals(TARGET, QtCore) {
  13        #headers generated by configure
  14        INSTALL_HEADERS *= $$QT_BUILD_TREE/src/corelib/global/qconfig.h \
  15                           $$QT_SOURCE_TREE/src/corelib/arch/$$QT_ARCH/arch
  16     }
  17
  18     equals(TARGET, phonon) {
  19         class_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET/Phonon
  20     } else {
  21         flat_headers.files = $$INSTALL_HEADERS
  22         flat_headers.path = $$[QT_INSTALL_HEADERS]/Qt
  23         INSTALLS += flat_headers
  24
  25         class_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
  26     }
  27     class_headers.files = $$SYNCQT.HEADER_CLASSES
  28     INSTALLS += class_headers
  29
  30     targ_headers.files = $$INSTALL_HEADERS
  31     targ_headers.path = $$[QT_INSTALL_HEADERS]/$$TARGET
  32     INSTALLS += targ_headers
  33 }
  34
  35 embedded:equals(TARGET, QtGui) {
  36     # install fonts for embedded
  37     INSTALLS += fonts
  38     fonts.path = $$[QT_INSTALL_LIBS]/fonts
  39     fonts.files = $$QT_SOURCE_TREE/lib/fonts/*
  40 }