tools/tools.pro

   1 TEMPLATE        = subdirs
   2
   3 no-png {
   4     message("Some graphics-related tools are unavailable without PNG support")
   5 } else {
   6      SUBDIRS += assistant \
   7                 pixeltool \
   8                 porting \
   9                 qtestlib \
  10                 qttracereplay
  11      contains(QT_EDITION, Console) {
  12          SUBDIRS += designer/src/uitools     # Linguist depends on this
  13      } else {
  14          SUBDIRS += designer
  15      }
  16      SUBDIRS     += linguist
  17      symbian: SUBDIRS = designer
  18      wince*: SUBDIRS = qtestlib designer
  19      unix:!mac:!embedded:contains(QT_CONFIG, qt3support):SUBDIRS += qtconfig
  20      win32:!wince*:SUBDIRS += activeqt
  21 }
  22
  23 mac {
  24     SUBDIRS += macdeployqt
  25 }
  26
  27 embedded:SUBDIRS += kmap2qmap
  28
  29 contains(QT_CONFIG, declarative):SUBDIRS += qmlviewer qmldebugger
  30 contains(QT_CONFIG, dbus):SUBDIRS += qdbus
  31 !wince*:contains(QT_CONFIG, xmlpatterns): SUBDIRS += xmlpatterns xmlpatternsvalidator
  32 embedded: SUBDIRS += makeqpf
  33
  34 !wince*:!cross_compile:SUBDIRS += qdoc3
  35
  36 CONFIG+=ordered
  37 QTDIR_build:REQUIRES = "contains(QT_CONFIG, full-config)"