src/qworkbenchplugin.pri

   1 isEmpty(IDE_BUILD_TREE) {
   2   IDE_BUILD_TREE = $$OUT_PWD/../../../
   3 }
   4 include(qworkbench.pri)
   5
   6 isEmpty(PROVIDER) {
   7     PROVIDER = Nokia
   8 }
   9
  10 DESTDIR = $$IDE_LIBRARY_PATH/$$PROVIDER/
  11 LIBS += -L$$DESTDIR
  12 INCLUDEPATH += $$IDE_SOURCE_TREE/src/plugins
  13 DEPENDPATH += $$IDE_SOURCE_TREE/src/plugins
  14
  15 # copy the plugin spec
  16 isEmpty(TARGET) {
  17     error("qworkbenchplugin.pri: You must provide a TARGET")
  18 }
  19
  20 # Copy the pluginspec file to the liberary directyory.
  21 # Note: On Windows/MinGW with some sh.exe in the path,
  22 # QMAKE_COPY is some cp command that does not understand
  23 # "\". Force the standard windows copy.
  24 COPYDEST = $${DESTDIR}
  25 COPYSRC = $${_PRO_FILE_PWD_}/$${TARGET}.pluginspec
  26
  27 TARGET = $$qtLibraryTarget($$TARGET)
  28
  29 win32 {
  30     COPYDEST ~= s|/+|\|
  31     COPYSRC ~= s|/+|\|
  32     COPY_CMD=xcopy /y
  33 } else {
  34     COPY_CMD=$${QMAKE_COPY}
  35 }
  36
  37 QMAKE_POST_LINK += $${COPY_CMD} $${COPYSRC} $${COPYDEST}
  38
  39 macx {
  40         QMAKE_LFLAGS_SONAME = -Wl,-install_name,@executable_path/../PlugIns/$${PROVIDER}/
  41 } else:linux-* {
  42     #do the rpath by hand since it's not possible to use ORIGIN in QMAKE_RPATHDIR
  43     QMAKE_RPATHDIR += \$\$ORIGIN/..
  44     IDE_PLUGIN_RPATH = $$join(QMAKE_RPATHDIR, ":")
  45     QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,$${IDE_PLUGIN_RPATH}\'
  46     QMAKE_RPATHDIR =
  47 }
  48
  49
  50 contains(QT_CONFIG, reduce_exports):CONFIG += hide_symbols