doc/doc.pri

   1 unix {
   2     QDOC = SRCDIR=$$PWD OUTDIR=$$OUT_PWD/doc/html $$(QTDIR)/tools/qdoc3/qdoc3
   3     HELPGENERATOR = $$(QTDIR)/bin/qhelpgenerator
   4 } else {
   5     QDOC = set SRCDIR=$$PWD&& set OUTDIR=$$OUT_PWD/doc/html&& $$(QTDIR)\tools\qdoc3\release\qdoc3.exe
   6     HELPGENERATOR = $$(QTDIR)\bin\qhelpgenerator.exe
   7 }
   8
   9 QHP_FILE = $$OUT_PWD/doc/html/qtcreator.qhp
  10 QCH_FILE = $$OUT_PWD/share/doc/qtcreator/qtcreator.qch
  11
  12 unix {
  13 html_docs.commands = $$QDOC $$PWD/qtcreator.qdocconf
  14 } else {
  15 html_docs.commands = \"$$QDOC $$PWD/qtcreator.qdocconf\"
  16 }
  17 html_docs.depends += $$PWD/qtcreator.qdoc $$PWD/qtcreator.qdocconf
  18 html_docs.files = $$QHP_FILE
  19
  20 qch_docs.commands = $$HELPGENERATOR -o $$QCH_FILE $$QHP_FILE
  21 qch_docs.depends += html_docs
  22 qch_docs.files = $$QCH_FILE
  23
  24 linux-* {
  25     qch_docs.path = /share/doc/qtcreator
  26     INSTALLS += qch_docs
  27 }
  28
  29 macx {
  30     cp_docs.commands = $${QMAKE_COPY_DIR} $${OUT_PWD}/doc $${OUT_PWD}/bin/QtCreator.app/Contents/Resources
  31     cp_docs.depends += qch_docs
  32     docs.depends = cp_docs
  33     QMAKE_EXTRA_TARGETS += html_docs qch_docs cp_docs docs
  34 }
  35 !macx {
  36     docs.depends = qch_docs
  37     QMAKE_EXTRA_TARGETS += html_docs qch_docs docs
  38 }
  39