src/src.pro

   1 # Under Windows launch script start_qgit.bat needs the
   2 # value GIT_EXEC_DIR to be set to the git bin directory
   3 GIT_EXEC_DIR = "$$(ProgramFiles)\\Git\\bin"
   4
   5 # Under Windows uncomment following line to enable console messages
   6 #CONFIG += ENABLE_CONSOLE_MSG
   7
   8 # check for Qt >= 4.3.0
   9 CUR_QT = $$[QT_VERSION]
  10
  11 # WARNING greaterThan is an undocumented function
  12 !greaterThan(CUR_QT, 4.3) {
  13         error("Sorry I need Qt 4.3.0 or later, you seem to have Qt $$CUR_QT instead")
  14 }
  15
  16 # check for g++ compiler
  17 contains(QMAKE_CC,.*g\\+\\+.*) {
  18         CONFIG += HAVE_GCC
  19 }
  20 contains(QMAKE_CC,.*gcc.*) {
  21         CONFIG += HAVE_GCC
  22 }
  23
  24 # General stuff
  25 TEMPLATE = app
  26 CONFIG += qt warn_on exceptions debug_and_release
  27 CONFIG += uic
  28 INCLUDEPATH += ../src
  29 MAKEFILE = qmake
  30 RESOURCES += icons.qrc
  31
  32 # Qt5 needs "widgets"
  33 greaterThan(QT_MAJOR_VERSION, 4): QT += widgets
  34
  35 # Platform dependent stuff
  36 win32 {
  37     TARGET = qgit
  38     target.path = $$GIT_EXEC_DIR
  39     CONFIG += windows embed_manifest_exe
  40     RC_FILE = app_icon.rc
  41 }
  42
  43 unix {
  44     TARGET = qgit
  45     target.path = $$[QT_INSTALL_BINS]
  46     CONFIG += x11
  47 }
  48
  49 macx {
  50     TARGET = qgit
  51     target.path = ~/bin
  52     #CONFIG += x86 ppc
  53     RC_FILE = resources/qgit.icns
  54 }
  55
  56 HAVE_GCC {
  57         QMAKE_CXXFLAGS_RELEASE += -s -O2 -Wno-non-virtual-dtor -Wno-long-long -pedantic -Wconversion
  58         QMAKE_CXXFLAGS_DEBUG += -g3 -ggdb -O0 -Wno-non-virtual-dtor -Wno-long-long -pedantic -Wconversion
  59 }
  60
  61 ENABLE_CONSOLE_MSG {
  62         CONFIG -= windows
  63         CONFIG += console
  64 }
  65
  66 INSTALLS += target
  67
  68 # Directories
  69 DESTDIR = ../bin
  70 UI_DIR = $$BUILD_DIR
  71 MOC_DIR = $$BUILD_DIR
  72 RCC_DIR = $$BUILD_DIR
  73 OBJECTS_DIR = $$BUILD_DIR
  74
  75 # project files
  76 FORMS += commit.ui console.ui customaction.ui fileview.ui help.ui \
  77          mainview.ui patchview.ui rangeselect.ui revsview.ui settings.ui
  78
  79 HEADERS += annotate.h cache.h commitimpl.h common.h config.h consoleimpl.h \
  80            customactionimpl.h dataloader.h domain.h exceptionmanager.h \
  81            filecontent.h filelist.h fileview.h git.h help.h inputdialog.h lanes.h \
  82            listview.h mainimpl.h myprocess.h patchcontent.h patchview.h \
  83            rangeselectimpl.h revdesc.h revsview.h settingsimpl.h \
  84            smartbrowse.h treeview.h \
  85     FileHistory.h
  86
  87 SOURCES += annotate.cpp cache.cpp commitimpl.cpp consoleimpl.cpp \
  88            customactionimpl.cpp dataloader.cpp domain.cpp exceptionmanager.cpp \
  89            filecontent.cpp filelist.cpp fileview.cpp git.cpp inputdialog.cpp \
  90            lanes.cpp listview.cpp mainimpl.cpp myprocess.cpp namespace_def.cpp \
  91            patchcontent.cpp patchview.cpp qgit.cpp rangeselectimpl.cpp \
  92            revdesc.cpp revsview.cpp settingsimpl.cpp smartbrowse.cpp treeview.cpp \
  93     FileHistory.cc \
  94     common.cpp
  95
  96 DISTFILES += app_icon.rc helpgen.sh resources/* Src.vcproj todo.txt
  97 DISTFILES += ../COPYING ../exception_manager.txt ../README ../README_WIN.txt
  98 DISTFILES += ../qgit_inno_setup.iss ../QGit4.sln
  99
 100 # Here we generate a batch called start_qgit.bat used, under Windows only,
 101 # to start qgit with proper PATH set.
 102 #
 103 # NOTE: qgit must be installed in git directory, among git exe files
 104 # for this to work. If you install with 'make install' this is already
 105 # done for you.
 106 #
 107 # Remember to set proper GIT_EXEC_DIR value at the beginning of this file
 108 #
 109 win32 {
 110     !exists($${GIT_EXEC_DIR}/git.exe) {
 111         error("I cannot found git files, please set GIT_EXEC_DIR in 'src.pro' file")
 112     }
 113     QGIT_BAT = ../start_qgit.bat
 114     CUR_PATH = $$system(echo %PATH%)
 115     LINE_1 = $$quote(set PATH=$$CUR_PATH;$$GIT_EXEC_DIR;)
 116     LINE_2 = $$quote(set PATH=$$CUR_PATH;)
 117
 118     qgit_launcher.commands =    @echo @echo OFF > $$QGIT_BAT
 119     qgit_launcher.commands += && @echo $$LINE_1 >> $$QGIT_BAT
 120     qgit_launcher.commands += && @echo bin\\$$TARGET >> $$QGIT_BAT
 121     qgit_launcher.commands += && @echo $$LINE_2 >> $$QGIT_BAT
 122
 123     QMAKE_EXTRA_TARGETS += qgit_launcher
 124     PRE_TARGETDEPS += qgit_launcher
 125 }