tests/qtest/meson.build

   1 slow_qtests = {
   2   'ahci-test' : 60,
   3   'bios-tables-test' : 120,
   4   'boot-serial-test' : 60,
   5   'migration-test' : 150,
   6   'npcm7xx_pwm-test': 150,
   7   'prom-env-test' : 60,
   8   'pxe-test' : 60,
   9   'qos-test' : 60,
  10   'qom-test' : 300,
  11   'test-hmp' : 120,
  12 }
  13
  14 qtests_generic = [
  15   'cdrom-test',
  16   'device-introspect-test',
  17   'machine-none-test',
  18   'qmp-test',
  19   'qmp-cmd-test',
  20   'qom-test',
  21   'test-hmp',
  22   'qos-test',
  23   'readconfig-test',
  24   'netdev-socket',
  25 ]
  26 if config_host.has_key('CONFIG_MODULES')
  27   qtests_generic += [ 'modules-test' ]
  28 endif
  29
  30 qtests_pci = \
  31   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  32   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  33
  34 qtests_cxl = \
  35   (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
  36
  37 qtests_filter = \
  38   (slirp.found() ? ['test-netfilter'] : []) + \
  39   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) + \
  40   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : [])
  41
  42 qtests_i386 = \
  43   (slirp.found() ? ['pxe-test'] : []) + \
  44   qtests_filter + \
  45   (have_tools ? ['ahci-test'] : []) +                                                       \
  46   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  47   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  48   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  49   (config_host.has_key('CONFIG_LINUX') and                                                  \
  50    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') ? ['ipmi-bt-test'] : []) +              \
  51   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  52   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  53   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  54   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  55   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  56   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  57   (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
  58   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  59   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  60    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  61   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  62   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  63   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  64   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  65   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  66   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  67   (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
  68   (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
  69   (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
  70   (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
  71   (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
  72   (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
  73   (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
  74   (config_host.has_key('CONFIG_POSIX') and                                                  \
  75    config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
  76   (config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
  77    config_all_devices.has_key('CONFIG_Q35') and                                             \
  78    config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
  79    slirp.found() ? ['virtio-net-failover'] : []) +                                          \
  80   (unpack_edk2_blobs ? ['bios-tables-test'] : []) +                                         \
  81   qtests_pci +                                                                              \
  82   qtests_cxl +                                                                              \
  83   ['fdc-test',
  84    'ide-test',
  85    'hd-geo-test',
  86    'boot-order-test',
  87    'rtc-test',
  88    'i440fx-test',
  89    'fw_cfg-test',
  90    'device-plug-test',
  91    'drive_del-test',
  92    'tco-test',
  93    'cpu-plug-test',
  94    'q35-test',
  95    'vmgenid-test',
  96    'migration-test',
  97    'test-x86-cpuid-compat',
  98    'numa-test'
  99   ]
 100
 101 if dbus_display
 102   qtests_i386 += ['dbus-display-test']
 103 endif
 104
 105 dbus_daemon = find_program('dbus-daemon', required: false)
 106 if dbus_daemon.found() and gdbus_codegen.found()
 107   # Temporarily disabled due to Patchew failures:
 108   #qtests_i386 += ['dbus-vmstate-test']
 109   dbus_vmstate1 = custom_target('dbus-vmstate description',
 110                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
 111                                 input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
 112                                 command: [gdbus_codegen, '@INPUT@',
 113                                           '--interface-prefix', 'org.qemu',
 114                                           '--generate-c-code', '@BASENAME@']).to_list()
 115 else
 116   dbus_vmstate1 = []
 117 endif
 118
 119 qtests_x86_64 = qtests_i386
 120
 121 qtests_alpha = ['boot-serial-test'] + \
 122   qtests_filter + \
 123   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 124
 125 qtests_avr = [ 'boot-serial-test' ]
 126
 127 qtests_hppa = ['boot-serial-test'] + \
 128   qtests_filter + \
 129   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 130
 131 qtests_m68k = ['boot-serial-test'] + \
 132   qtests_filter
 133
 134 qtests_microblaze = ['boot-serial-test'] + \
 135   qtests_filter
 136
 137 qtests_microblazeel = qtests_microblaze
 138
 139 qtests_mips = \
 140   qtests_filter + \
 141   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 142   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 143
 144 qtests_mipsel = qtests_mips
 145 qtests_mips64 = qtests_mips
 146 qtests_mips64el = qtests_mips
 147
 148 qtests_ppc = \
 149   qtests_filter + \
 150   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 151   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 152   (config_all_devices.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                      \
 153   (config_all_devices.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                   \
 154   ['boot-order-test']
 155
 156 qtests_ppc64 = \
 157   qtests_ppc + \
 158   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 159   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 160   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 161   (slirp.found() ? ['pxe-test'] : []) +              \
 162   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 163   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 164   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 165
 166 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 167 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 168
 169 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
 170   qtests_filter
 171
 172 qtests_sparc64 = \
 173   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 174   qtests_filter + \
 175   ['prom-env-test', 'boot-serial-test']
 176
 177 qtests_npcm7xx = \
 178   ['npcm7xx_adc-test',
 179    'npcm7xx_gpio-test',
 180    'npcm7xx_pwm-test',
 181    'npcm7xx_rng-test',
 182    'npcm7xx_sdhci-test',
 183    'npcm7xx_smbus-test',
 184    'npcm7xx_timer-test',
 185    'npcm7xx_watchdog_timer-test'] + \
 186    (slirp.found() ? ['npcm7xx_emc-test'] : [])
 187 qtests_aspeed = \
 188   ['aspeed_hace-test',
 189    'aspeed_smc-test',
 190    'aspeed_gpio-test']
 191 qtests_arm = \
 192   (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
 193   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 194   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 195   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 196   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') ? ['pflash-cfi02-test'] : []) +         \
 197   (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
 198   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 199   ['arm-cpu-features',
 200    'microbit-test',
 201    'test-arm-mptimer',
 202    'boot-serial-test',
 203    'hexloader-test']
 204
 205 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 206 qtests_aarch64 = \
 207   (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
 208   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-test'] : []) +        \
 209   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-swtpm-test'] : []) +  \
 210   (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
 211   (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test'] : []) +  \
 212   ['arm-cpu-features',
 213    'numa-test',
 214    'boot-serial-test',
 215    'migration-test']
 216
 217 qtests_s390x = \
 218   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +                 \
 219   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                         \
 220   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : []) +                     \
 221   ['boot-serial-test',
 222    'drive_del-test',
 223    'device-plug-test',
 224    'virtio-ccw-test',
 225    'cpu-plug-test',
 226    'migration-test']
 227
 228 qos_test_ss = ss.source_set()
 229 qos_test_ss.add(
 230   'ac97-test.c',
 231   'adm1272-test.c',
 232   'ds1338-test.c',
 233   'e1000-test.c',
 234   'eepro100-test.c',
 235   'es1370-test.c',
 236   'ipoctal232-test.c',
 237   'lsm303dlhc-mag-test.c',
 238   'isl_pmbus_vr-test.c',
 239   'max34451-test.c',
 240   'megasas-test.c',
 241   'ne2000-test.c',
 242   'tulip-test.c',
 243   'nvme-test.c',
 244   'pca9552-test.c',
 245   'pci-test.c',
 246   'pcnet-test.c',
 247   'sdhci-test.c',
 248   'spapr-phb-test.c',
 249   'tmp105-test.c',
 250   'emc141x-test.c',
 251   'usb-hcd-ohci-test.c',
 252   'virtio-test.c',
 253   'virtio-blk-test.c',
 254   'virtio-net-test.c',
 255   'virtio-rng-test.c',
 256   'virtio-scsi-test.c',
 257   'virtio-serial-test.c',
 258   'virtio-iommu-test.c',
 259   'vmxnet3-test.c',
 260 )
 261 if config_host.has_key('CONFIG_POSIX')
 262   qos_test_ss.add(files('e1000e-test.c'))
 263 endif
 264 if have_virtfs
 265   qos_test_ss.add(files('virtio-9p-test.c'))
 266 endif
 267 if have_vhost_user
 268   qos_test_ss.add(files('vhost-user-test.c'))
 269 endif
 270 if have_tools and have_vhost_user_blk_server
 271   qos_test_ss.add(files('vhost-user-blk-test.c'))
 272 endif
 273
 274 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 275
 276 migration_files = [files('migration-helpers.c')]
 277 if gnutls.found()
 278   migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
 279
 280   if tasn1.found()
 281     migration_files += [files('../unit/crypto-tls-x509-helpers.c',
 282                               '../unit/pkix_asn1_tab.c'), tasn1]
 283   endif
 284 endif
 285
 286 qtests = {
 287   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 288   'cdrom-test': files('boot-sector.c'),
 289   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 290   'erst-test': files('erst-test.c'),
 291   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 292   'migration-test': migration_files,
 293   'pxe-test': files('boot-sector.c'),
 294   'qos-test': [chardev, io, qos_test_ss.apply(config_host, strict: false).sources()],
 295   'tpm-crb-swtpm-test': [io, tpmemu_files],
 296   'tpm-crb-test': [io, tpmemu_files],
 297   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 298   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 299   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 300   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 301   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 302   'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
 303 }
 304
 305 gvnc = dependency('gvnc-1.0', required: false)
 306 if gvnc.found()
 307   qtests += {'vnc-display-test': [gvnc]}
 308   qtests_generic += [ 'vnc-display-test' ]
 309 endif
 310
 311 if dbus_display
 312   qtests += {'dbus-display-test': [dbus_display1, gio]}
 313 endif
 314
 315 qtest_executables = {}
 316 foreach dir : target_dirs
 317   if not dir.endswith('-softmmu')
 318     continue
 319   endif
 320
 321   target_base = dir.split('-')[0]
 322   qtest_emulator = emulators['qemu-system-' + target_base]
 323   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 324
 325   test_deps = roms
 326   qtest_env = environment()
 327   if have_tools
 328     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 329     test_deps += [qemu_img]
 330   endif
 331   qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
 332   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 333   if have_tools and have_vhost_user_blk_server
 334     qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
 335     test_deps += [qsd]
 336   endif
 337
 338   foreach test : target_qtests
 339     # Executables are shared across targets, declare them only the first time we
 340     # encounter them
 341     if not qtest_executables.has_key(test)
 342       src = [test + '.c']
 343       deps = [qemuutil, qos]
 344       if test in qtests
 345         # use a sourceset to quickly separate sources and deps
 346         test_ss = ss.source_set()
 347         test_ss.add(qtests[test])
 348         src += test_ss.all_sources()
 349         deps += test_ss.all_dependencies()
 350       endif
 351       qtest_executables += {
 352         test: executable(test, src, dependencies: deps)
 353       }
 354     endif
 355     test('qtest-@0@/@1@'.format(target_base, test),
 356          qtest_executables[test],
 357          depends: [test_deps, qtest_emulator, emulator_modules],
 358          env: qtest_env,
 359          args: ['--tap', '-k'],
 360          protocol: 'tap',
 361          timeout: slow_qtests.get(test, 30),
 362          priority: slow_qtests.get(test, 30),
 363          suite: ['qtest', 'qtest-' + target_base])
 364   endforeach
 365 endforeach