ui/meson.build

   1 softmmu_ss.add(pixman)
   2 specific_ss.add(when: ['CONFIG_SOFTMMU'], if_true: pixman)   # for the include path
   3
   4 softmmu_ss.add(files(
   5   'clipboard.c',
   6   'console.c',
   7   'cursor.c',
   8   'input-keymap.c',
   9   'input-legacy.c',
  10   'input-barrier.c',
  11   'input.c',
  12   'kbd-state.c',
  13   'keymaps.c',
  14   'qemu-pixman.c',
  15 ))
  16 softmmu_ss.add([spice_headers, files('spice-module.c')])
  17 softmmu_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
  18
  19 softmmu_ss.add(when: 'CONFIG_LINUX', if_true: files('input-linux.c'))
  20 softmmu_ss.add(when: cocoa, if_true: files('cocoa.m'))
  21
  22 vnc_ss = ss.source_set()
  23 vnc_ss.add(files(
  24   'vnc.c',
  25   'vnc-enc-zlib.c',
  26   'vnc-enc-hextile.c',
  27   'vnc-enc-tight.c',
  28   'vnc-palette.c',
  29   'vnc-enc-zrle.c',
  30   'vnc-auth-vencrypt.c',
  31   'vnc-ws.c',
  32   'vnc-jobs.c',
  33 ))
  34 vnc_ss.add(zlib, png, jpeg, gnutls)
  35 vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
  36 softmmu_ss.add_all(when: vnc, if_true: vnc_ss)
  37 softmmu_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
  38 specific_ss.add(when: ['CONFIG_SOFTMMU'], if_true: opengl)
  39
  40 ui_modules = {}
  41
  42 if curses.found()
  43   curses_ss = ss.source_set()
  44   curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
  45   ui_modules += {'curses' : curses_ss}
  46 endif
  47
  48 if config_host.has_key('CONFIG_OPENGL')
  49   opengl_ss = ss.source_set()
  50   opengl_ss.add(gbm)
  51   opengl_ss.add(when: [opengl, pixman, 'CONFIG_OPENGL'],
  52                if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
  53   ui_modules += {'opengl' : opengl_ss}
  54 endif
  55
  56 if config_host.has_key('CONFIG_OPENGL') and gbm.found()
  57   egl_headless_ss = ss.source_set()
  58   egl_headless_ss.add(when: [opengl, gbm, pixman, 'CONFIG_OPENGL'],
  59                       if_true: files('egl-headless.c'))
  60   ui_modules += {'egl-headless' : egl_headless_ss}
  61 endif
  62
  63 if gtk.found()
  64   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
  65
  66   gtk_ss = ss.source_set()
  67   gtk_ss.add(gtk, vte, pixman, files('gtk.c'))
  68   gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
  69   gtk_ss.add(when: [opengl, 'CONFIG_OPENGL'], if_true: files('gtk-gl-area.c'))
  70   gtk_ss.add(when: [x11, opengl, 'CONFIG_OPENGL'], if_true: files('gtk-egl.c'))
  71   ui_modules += {'gtk' : gtk_ss}
  72 endif
  73
  74 if sdl.found()
  75   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
  76
  77   sdl_ss = ss.source_set()
  78   sdl_ss.add(sdl, sdl_image, pixman, glib, files(
  79     'sdl2-2d.c',
  80     'sdl2-input.c',
  81     'sdl2.c',
  82   ))
  83   sdl_ss.add(when: [opengl, 'CONFIG_OPENGL'], if_true: files('sdl2-gl.c'))
  84   sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
  85   ui_modules += {'sdl' : sdl_ss}
  86 endif
  87
  88 if config_host.has_key('CONFIG_SPICE')
  89   spice_core_ss = ss.source_set()
  90   spice_core_ss.add(spice, pixman, files(
  91     'spice-core.c',
  92     'spice-input.c',
  93     'spice-display.c'
  94   ))
  95   ui_modules += {'spice-core' : spice_core_ss}
  96 endif
  97
  98 if config_host.has_key('CONFIG_SPICE') and config_host.has_key('CONFIG_GIO')
  99   spice_ss = ss.source_set()
 100   spice_ss.add(spice, gio, pixman, files('spice-app.c'))
 101   ui_modules += {'spice-app': spice_ss}
 102 endif
 103
 104 keymap_gen = find_program('keycodemapdb/tools/keymap-gen')
 105
 106 keymaps = [
 107   ['atset1', 'qcode'],
 108   ['linux', 'qcode'],
 109   ['qcode', 'atset1'],
 110   ['qcode', 'atset2'],
 111   ['qcode', 'atset3'],
 112   ['qcode', 'linux'],
 113   ['qcode', 'qnum'],
 114   ['qcode', 'sun'],
 115   ['qnum', 'qcode'],
 116   ['usb', 'qcode'],
 117   ['win32', 'qcode'],
 118   ['x11', 'qcode'],
 119   ['xorgevdev', 'qcode'],
 120   ['xorgkbd', 'qcode'],
 121   ['xorgxquartz', 'qcode'],
 122   ['xorgxwin', 'qcode'],
 123   ['osx', 'qcode'],
 124 ]
 125
 126 if have_system or xkbcommon.found()
 127   foreach e : keymaps
 128     output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
 129     genh += custom_target(output,
 130                   output: output,
 131                   capture: true,
 132                   input: files('keycodemapdb/data/keymaps.csv'),
 133                   command: [python.full_path(), files('keycodemapdb/tools/keymap-gen'),
 134                             'code-map',
 135                             '--lang', 'glib2',
 136                             '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
 137                             '@INPUT0@', e[0], e[1]])
 138   endforeach
 139 endif
 140
 141 subdir('shader')
 142
 143 if have_system
 144   subdir('icons')
 145
 146   install_data('qemu.desktop', install_dir: qemu_desktopdir)
 147 endif
 148
 149 modules += {'ui': ui_modules}