tests/qtest/meson.build

   1 # All QTests for now are POSIX-only, but the dependencies are
   2 # really in libqtest, not in the testcases themselves.
   3 if not config_host.has_key('CONFIG_POSIX')
   4   subdir_done()
   5 endif
   6
   7 slow_qtests = {
   8   'ahci-test' : 60,
   9   'bios-tables-test' : 120,
  10   'boot-serial-test' : 60,
  11   'migration-test' : 150,
  12   'npcm7xx_pwm-test': 150,
  13   'prom-env-test' : 60,
  14   'pxe-test' : 60,
  15   'qos-test' : 60,
  16   'qom-test' : 300,
  17   'test-hmp' : 120,
  18 }
  19
  20 qtests_generic = [
  21   'cdrom-test',
  22   'device-introspect-test',
  23   'machine-none-test',
  24   'qmp-test',
  25   'qmp-cmd-test',
  26   'qom-test',
  27   'test-hmp',
  28   'qos-test',
  29 ]
  30 if config_host.has_key('CONFIG_MODULES')
  31   qtests_generic += [ 'modules-test' ]
  32 endif
  33
  34 qtests_pci = \
  35   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  36   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  37
  38 qtests_i386 = \
  39   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +             \
  40   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                     \
  41   (have_tools ? ['ahci-test'] : []) +                                                       \
  42   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  43   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  44   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['test-filter-redirector'] : []) +    \
  45   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  46   (config_host.has_key('CONFIG_LINUX') and                                                  \
  47    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') ? ['ipmi-bt-test'] : []) +              \
  48   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  49   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  50   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  51   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  52   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  53   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  54   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  55   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  56    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  57   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  58   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  59   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  60   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  61   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  62   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  63   qtests_pci +                                                                              \
  64   ['fdc-test',
  65    'ide-test',
  66    'hd-geo-test',
  67    'boot-order-test',
  68    'bios-tables-test',
  69    'rtc-test',
  70    'i440fx-test',
  71    'fuzz-test',
  72    'fw_cfg-test',
  73    'device-plug-test',
  74    'drive_del-test',
  75    'tco-test',
  76    'cpu-plug-test',
  77    'q35-test',
  78    'vmgenid-test',
  79    'migration-test',
  80    'test-x86-cpuid-compat',
  81    'numa-test']
  82
  83 dbus_daemon = find_program('dbus-daemon', required: false)
  84 if dbus_daemon.found() and config_host.has_key('GDBUS_CODEGEN')
  85   # Temporarily disabled due to Patchew failures:
  86   #qtests_i386 += ['dbus-vmstate-test']
  87   dbus_vmstate1 = custom_target('dbus-vmstate description',
  88                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
  89                                 input: files('dbus-vmstate1.xml'),
  90                                 command: [config_host['GDBUS_CODEGEN'],
  91                                           '@INPUT@',
  92                                           '--interface-prefix', 'org.qemu',
  93                                           '--generate-c-code', '@BASENAME@']).to_list()
  94 else
  95   dbus_vmstate1 = []
  96 endif
  97
  98 qtests_x86_64 = qtests_i386
  99
 100 qtests_alpha = [ 'boot-serial-test' ] +                                                      \
 101   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 102
 103 qtests_avr = [ 'boot-serial-test' ]
 104
 105 qtests_hppa = [ 'boot-serial-test' ] +                                                       \
 106   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 107
 108 qtests_m68k = [ 'boot-serial-test' ]
 109 qtests_microblaze = [ 'boot-serial-test' ]
 110 qtests_microblazeel = qtests_microblaze
 111
 112 qtests_mips = \
 113   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 114   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 115
 116 qtests_mips64 = \
 117   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 118   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 119
 120 qtests_mips64el = \
 121   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 122   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 123
 124 qtests_moxie = [ 'boot-serial-test' ]
 125
 126 qtests_ppc = \
 127   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 128   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 129   ['boot-order-test', 'prom-env-test', 'boot-serial-test']                 \
 130
 131 qtests_ppc64 = \
 132   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 133   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 134   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 135   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +              \
 136   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 137   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 138   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                      \
 139   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 140
 141 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 142 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 143
 144 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test']
 145
 146 qtests_sparc64 = \
 147   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 148   ['prom-env-test', 'boot-serial-test']
 149
 150 qtests_npcm7xx = \
 151   ['npcm7xx_adc-test',
 152    'npcm7xx_gpio-test',
 153    'npcm7xx_pwm-test',
 154    'npcm7xx_rng-test',
 155    'npcm7xx_smbus-test',
 156    'npcm7xx_timer-test',
 157    'npcm7xx_watchdog_timer-test']
 158 qtests_arm = \
 159   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 160   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 161   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 162   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') ? ['pflash-cfi02-test'] : []) +         \
 163   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 164   ['arm-cpu-features',
 165    'microbit-test',
 166    'm25p80-test',
 167    'test-arm-mptimer',
 168    'boot-serial-test',
 169    'hexloader-test']
 170
 171 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 172 qtests_aarch64 = \
 173   (cpu != 'arm' ? ['bios-tables-test'] : []) +                                                  \
 174   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-test'] : []) +        \
 175   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-swtpm-test'] : []) +  \
 176   ['arm-cpu-features',
 177    'numa-test',
 178    'boot-serial-test',
 179    'xlnx-can-test',
 180    'migration-test']
 181
 182 qtests_s390x = \
 183   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +                 \
 184   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                         \
 185   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : []) +                     \
 186   ['boot-serial-test',
 187    'drive_del-test',
 188    'device-plug-test',
 189    'virtio-ccw-test',
 190    'cpu-plug-test',
 191    'migration-test']
 192
 193 qos_test_ss = ss.source_set()
 194 qos_test_ss.add(
 195   'ac97-test.c',
 196   'ds1338-test.c',
 197   'e1000-test.c',
 198   'e1000e-test.c',
 199   'eepro100-test.c',
 200   'es1370-test.c',
 201   'ipoctal232-test.c',
 202   'megasas-test.c',
 203   'ne2000-test.c',
 204   'tulip-test.c',
 205   'nvme-test.c',
 206   'pca9552-test.c',
 207   'pci-test.c',
 208   'pcnet-test.c',
 209   'sdhci-test.c',
 210   'spapr-phb-test.c',
 211   'tmp105-test.c',
 212   'emc141x-test.c',
 213   'usb-hcd-ohci-test.c',
 214   'virtio-test.c',
 215   'virtio-blk-test.c',
 216   'virtio-net-test.c',
 217   'virtio-rng-test.c',
 218   'virtio-scsi-test.c',
 219   'virtio-serial-test.c',
 220   'vmxnet3-test.c',
 221 )
 222 if have_virtfs
 223   qos_test_ss.add(files('virtio-9p-test.c'))
 224 endif
 225 qos_test_ss.add(when: 'CONFIG_VHOST_USER', if_true: files('vhost-user-test.c'))
 226
 227 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 228
 229 qtests = {
 230   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 231   'cdrom-test': files('boot-sector.c'),
 232   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 233   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 234   'migration-test': files('migration-helpers.c'),
 235   'pxe-test': files('boot-sector.c'),
 236   'qos-test': [chardev, io, qos_test_ss.apply(config_host, strict: false).sources()],
 237   'tpm-crb-swtpm-test': [io, tpmemu_files],
 238   'tpm-crb-test': [io, tpmemu_files],
 239   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 240   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 241   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 242   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 243   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 244 }
 245
 246 qtest_executables = {}
 247 foreach dir : target_dirs
 248   if not dir.endswith('-softmmu')
 249     continue
 250   endif
 251
 252   target_base = dir.split('-')[0]
 253   qtest_emulator = emulators['qemu-system-' + target_base]
 254   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 255
 256   test_deps = []
 257   qtest_env = environment()
 258   if have_tools
 259     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 260     test_deps += [qemu_img]
 261   endif
 262   qtest_env.set('G_TEST_DBUS_DAEMON', meson.source_root() / 'tests/dbus-vmstate-daemon.sh')
 263   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 264
 265   foreach test : target_qtests
 266     # Executables are shared across targets, declare them only the first time we
 267     # encounter them
 268     if not qtest_executables.has_key(test)
 269       src = [test + '.c']
 270       deps = [qemuutil, qos]
 271       if test in qtests
 272         # use a sourceset to quickly separate sources and deps
 273         test_ss = ss.source_set()
 274         test_ss.add(qtests[test])
 275         src += test_ss.all_sources()
 276         deps += test_ss.all_dependencies()
 277       endif
 278       qtest_executables += {
 279         test: executable(test, src, dependencies: deps)
 280       }
 281     endif
 282     # FIXME: missing dependency on the emulator binary and qemu-img
 283     test('qtest-@0@/@1@'.format(target_base, test),
 284          qtest_executables[test],
 285          depends: [test_deps, qtest_emulator],
 286          env: qtest_env,
 287          args: ['--tap', '-k'],
 288          protocol: 'tap',
 289          timeout: slow_qtests.get(test, 30),
 290          priority: slow_qtests.get(test, 30),
 291          suite: ['qtest', 'qtest-' + target_base])
 292   endforeach
 293 endforeach