audio/meson.build

   1 softmmu_ss.add(files(
   2   'audio.c',
   3   'audio_legacy.c',
   4   'mixeng.c',
   5   'noaudio.c',
   6   'wavaudio.c',
   7   'wavcapture.c',
   8 ))
   9
  10 softmmu_ss.add(when: [coreaudio, 'CONFIG_AUDIO_COREAUDIO'], if_true: files('coreaudio.c'))
  11 softmmu_ss.add(when: [dsound, 'CONFIG_AUDIO_DSOUND'], if_true: files('dsoundaudio.c'))
  12 softmmu_ss.add(when: ['CONFIG_AUDIO_WIN_INT'], if_true: files('audio_win_int.c'))
  13
  14 audio_modules = {}
  15 foreach m : [
  16   ['CONFIG_AUDIO_ALSA', 'alsa', alsa, 'alsaaudio.c'],
  17   ['CONFIG_AUDIO_OSS', 'oss', oss, 'ossaudio.c'],
  18   ['CONFIG_AUDIO_PA', 'pa', pulse, 'paaudio.c'],
  19   ['CONFIG_AUDIO_SDL', 'sdl', sdl, 'sdlaudio.c'],
  20   ['CONFIG_AUDIO_JACK', 'jack', jack, 'jackaudio.c'],
  21   ['CONFIG_SPICE', 'spice', spice, 'spiceaudio.c']
  22 ]
  23   if config_host.has_key(m[0])
  24     module_ss = ss.source_set()
  25     module_ss.add(when: m[2], if_true: files(m[3]))
  26     audio_modules += {m[1] : module_ss}
  27   endif
  28 endforeach
  29
  30 modules += {'audio': audio_modules}