ui/meson.build

   1 system_ss.add(pixman)
   2 specific_ss.add(when: ['CONFIG_SYSTEM_ONLY'], if_true: pixman)   # for the include path
   3 specific_ss.add(when: ['CONFIG_SYSTEM_ONLY'], if_true: opengl)   # for the include path
   4
   5 system_ss.add(png)
   6 system_ss.add(files(
   7   'clipboard.c',
   8   'console.c',
   9   'cursor.c',
  10   'input-keymap.c',
  11   'input-legacy.c',
  12   'input-barrier.c',
  13   'input.c',
  14   'kbd-state.c',
  15   'keymaps.c',
  16   'qemu-pixman.c',
  17   'ui-hmp-cmds.c',
  18   'ui-qmp-cmds.c',
  19   'util.c',
  20 ))
  21 if dbus_display
  22   system_ss.add(files('dbus-module.c'))
  23 endif
  24 system_ss.add([spice_headers, files('spice-module.c')])
  25 system_ss.add(when: spice_protocol, if_true: files('vdagent.c'))
  26
  27 system_ss.add(when: 'CONFIG_LINUX', if_true: files(
  28   'input-linux.c',
  29   'udmabuf.c',
  30 ))
  31 system_ss.add(when: cocoa, if_true: files('cocoa.m'))
  32
  33 vnc_ss = ss.source_set()
  34 vnc_ss.add(files(
  35   'vnc.c',
  36   'vnc-enc-zlib.c',
  37   'vnc-enc-hextile.c',
  38   'vnc-enc-tight.c',
  39   'vnc-palette.c',
  40   'vnc-enc-zrle.c',
  41   'vnc-auth-vencrypt.c',
  42   'vnc-ws.c',
  43   'vnc-jobs.c',
  44   'vnc-clipboard.c',
  45 ))
  46 vnc_ss.add(zlib, jpeg, gnutls)
  47 vnc_ss.add(when: sasl, if_true: files('vnc-auth-sasl.c'))
  48 system_ss.add_all(when: vnc, if_true: vnc_ss)
  49 system_ss.add(when: vnc, if_false: files('vnc-stubs.c'))
  50
  51 ui_modules = {}
  52
  53 if curses.found()
  54   curses_ss = ss.source_set()
  55   curses_ss.add(when: [curses, iconv], if_true: [files('curses.c'), pixman])
  56   ui_modules += {'curses' : curses_ss}
  57 endif
  58
  59 system_ss.add(opengl)
  60 if opengl.found()
  61   opengl_ss = ss.source_set()
  62   opengl_ss.add(gbm)
  63   opengl_ss.add(when: [opengl, pixman],
  64                if_true: files('shader.c', 'console-gl.c', 'egl-helpers.c', 'egl-context.c'))
  65   ui_modules += {'opengl' : opengl_ss}
  66 endif
  67
  68 if opengl.found()
  69   egl_headless_ss = ss.source_set()
  70   egl_headless_ss.add(when: [opengl, pixman],
  71                       if_true: [files('egl-headless.c'), gbm])
  72   ui_modules += {'egl-headless' : egl_headless_ss}
  73 endif
  74
  75 if dbus_display
  76   dbus_ss = ss.source_set()
  77   env = environment()
  78   env.set('TARGETOS', targetos)
  79   xml = custom_target('dbus-display preprocess',
  80                       input: 'dbus-display1.xml',
  81                       output: 'dbus-display1.xml',
  82                       env: env,
  83                       command: [xml_pp, '@INPUT@', '@OUTPUT@'])
  84   dbus_display1 = custom_target('dbus-display gdbus-codegen',
  85                                 output: ['dbus-display1.h', 'dbus-display1.c'],
  86                                 input: xml,
  87                                 command: [gdbus_codegen, '@INPUT@',
  88                                           '--glib-min-required', '2.64',
  89                                           '--output-directory', meson.current_build_dir(),
  90                                           '--interface-prefix', 'org.qemu.',
  91                                           '--c-namespace', 'QemuDBus',
  92                                           '--generate-c-code', '@BASENAME@'])
  93   dbus_display1_lib = static_library('dbus-display1', dbus_display1, dependencies: gio)
  94   dbus_display1_dep = declare_dependency(link_with: dbus_display1_lib, include_directories: include_directories('.'))
  95   dbus_ss.add(when: [gio, pixman, dbus_display1_dep],
  96               if_true: [files(
  97                 'dbus-chardev.c',
  98                 'dbus-clipboard.c',
  99                 'dbus-console.c',
 100                 'dbus-error.c',
 101                 'dbus-listener.c',
 102                 'dbus.c',
 103               ), opengl, gbm])
 104   ui_modules += {'dbus' : dbus_ss}
 105 endif
 106
 107 if gtk.found()
 108   system_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
 109
 110   gtk_ss = ss.source_set()
 111   gtk_ss.add(gtk, vte, pixman, files('gtk.c'))
 112   if have_gtk_clipboard
 113     gtk_ss.add(files('gtk-clipboard.c'))
 114   endif
 115   gtk_ss.add(when: x11, if_true: files('x_keymap.c'))
 116   gtk_ss.add(when: opengl, if_true: files('gtk-gl-area.c'))
 117   gtk_ss.add(when: [x11, opengl], if_true: files('gtk-egl.c'))
 118   ui_modules += {'gtk' : gtk_ss}
 119 endif
 120
 121 if sdl.found()
 122   system_ss.add(when: 'CONFIG_WIN32', if_true: files('win32-kbd-hook.c'))
 123
 124   sdl_ss = ss.source_set()
 125   sdl_ss.add(sdl, sdl_image, pixman, glib, files(
 126     'sdl2-2d.c',
 127     'sdl2-input.c',
 128     'sdl2.c',
 129   ))
 130   sdl_ss.add(when: opengl, if_true: files('sdl2-gl.c'))
 131   sdl_ss.add(when: x11, if_true: files('x_keymap.c'))
 132   ui_modules += {'sdl' : sdl_ss}
 133 endif
 134
 135 if spice.found()
 136   spice_core_ss = ss.source_set()
 137   spice_core_ss.add(spice, pixman, files(
 138     'spice-core.c',
 139     'spice-input.c',
 140     'spice-display.c'
 141   ))
 142   ui_modules += {'spice-core' : spice_core_ss}
 143 endif
 144
 145 if spice.found() and gio.found()
 146   spice_ss = ss.source_set()
 147   spice_ss.add(spice, gio, pixman, files('spice-app.c'))
 148   ui_modules += {'spice-app': spice_ss}
 149 endif
 150
 151 keymaps = [
 152   ['atset1', 'qcode'],
 153   ['linux', 'qcode'],
 154   ['qcode', 'atset1'],
 155   ['qcode', 'atset2'],
 156   ['qcode', 'atset3'],
 157   ['qcode', 'linux'],
 158   ['qcode', 'qnum'],
 159   ['qcode', 'sun'],
 160   ['qnum', 'qcode'],
 161   ['usb', 'qcode'],
 162   ['win32', 'qcode'],
 163   ['x11', 'qcode'],
 164   ['xorgevdev', 'qcode'],
 165   ['xorgkbd', 'qcode'],
 166   ['xorgxquartz', 'qcode'],
 167   ['xorgxwin', 'qcode'],
 168   ['osx', 'qcode'],
 169 ]
 170
 171 if have_system or xkbcommon.found()
 172   keycodemapdb_proj = subproject('keycodemapdb', required: true)
 173   foreach e : keymaps
 174     output = 'input-keymap-@0@-to-@1@.c.inc'.format(e[0], e[1])
 175     genh += custom_target(output,
 176                   output: output,
 177                   capture: true,
 178                   input: keycodemapdb_proj.get_variable('keymaps_csv'),
 179                   command: [python, keycodemapdb_proj.get_variable('keymap_gen').full_path(),
 180                             'code-map', '--lang', 'glib2',
 181                             '--varname', 'qemu_input_map_@0@_to_@1@'.format(e[0], e[1]),
 182                             '@INPUT0@', e[0], e[1]])
 183   endforeach
 184 endif
 185
 186 subdir('shader')
 187
 188 if have_system
 189   subdir('icons')
 190
 191   install_data('qemu.desktop', install_dir: qemu_desktopdir)
 192 endif
 193
 194 modules += {'ui': ui_modules}