qemu.nsi

   1 ;!/usr/bin/makensis
   2
   3 ; This NSIS script creates an installer for QEMU on Windows.
   4
   5 ; Copyright (C) 2006-2012 Stefan Weil
   6 ;
   7 ; This program is free software: you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 2 of the License, or
  10 ; (at your option) version 3 or any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ; NSIS_WIN32_MAKENSIS
  21
  22 !define PRODUCT "QEMU"
  23 !define URL     "https://www.qemu.org/"
  24
  25 !define UNINST_EXE "$INSTDIR\qemu-uninstall.exe"
  26 !define UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT}"
  27
  28 !ifndef BINDIR
  29 !define BINDIR nsis.tmp
  30 !endif
  31 !ifndef SRCDIR
  32 !define SRCDIR .
  33 !endif
  34 !ifndef OUTFILE
  35 !define OUTFILE "qemu-setup.exe"
  36 !endif
  37
  38 ; Optionally install documentation.
  39 !ifndef CONFIG_DOCUMENTATION
  40 !define CONFIG_DOCUMENTATION
  41 !endif
  42
  43 ; Use maximum compression.
  44 SetCompressor /SOLID lzma
  45
  46 !include "MUI2.nsh"
  47
  48 ; The name of the installer.
  49 Name "QEMU"
  50
  51 ; The file to write
  52 OutFile "${OUTFILE}"
  53
  54 ; The default installation directory.
  55 !ifdef W64
  56 InstallDir $PROGRAMFILES64\qemu
  57 !else
  58 InstallDir $PROGRAMFILES\qemu
  59 !endif
  60
  61 ; Registry key to check for directory (so if you install again, it will
  62 ; overwrite the old one automatically)
  63 !ifdef W64
  64 InstallDirRegKey HKLM "Software\qemu64" "Install_Dir"
  65 !else
  66 InstallDirRegKey HKLM "Software\qemu32" "Install_Dir"
  67 !endif
  68
  69 ; Request administrator privileges for Windows Vista.
  70 RequestExecutionLevel admin
  71
  72 ;--------------------------------
  73 ; Interface Settings.
  74 ;!define MUI_HEADERIMAGE "qemu-nsis.bmp"
  75 ; !define MUI_SPECIALBITMAP "qemu.bmp"
  76 !define MUI_ICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  77 !define MUI_UNICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  78 !define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}\pc-bios\qemu-nsis.bmp"
  79 ; !define MUI_HEADERIMAGE_BITMAP "qemu-install.bmp"
  80 ; !define MUI_HEADERIMAGE_UNBITMAP "qemu-uninstall.bmp"
  81 ; !define MUI_COMPONENTSPAGE_SMALLDESC
  82 ; !define MUI_WELCOMEPAGE_TEXT "Insert text here.$\r$\n$\r$\n$\r$\n$_CLICK"
  83
  84 ;--------------------------------
  85 ; Pages.
  86
  87 !insertmacro MUI_PAGE_WELCOME
  88 !insertmacro MUI_PAGE_LICENSE "${SRCDIR}\COPYING"
  89 !insertmacro MUI_PAGE_COMPONENTS
  90 !insertmacro MUI_PAGE_DIRECTORY
  91 !insertmacro MUI_PAGE_INSTFILES
  92 !define MUI_FINISHPAGE_LINK "Visit the QEMU Wiki online!"
  93 !define MUI_FINISHPAGE_LINK_LOCATION "${URL}"
  94 !insertmacro MUI_PAGE_FINISH
  95
  96 !insertmacro MUI_UNPAGE_CONFIRM
  97 !insertmacro MUI_UNPAGE_INSTFILES
  98
  99 ;--------------------------------
 100 ; Languages.
 101
 102 !insertmacro MUI_LANGUAGE "English"
 103 !insertmacro MUI_LANGUAGE "French"
 104 !insertmacro MUI_LANGUAGE "German"
 105
 106 ;--------------------------------
 107
 108 ; The stuff to install.
 109 ;
 110 ; Remember to keep the "Uninstall" section in sync.
 111
 112 Section "${PRODUCT} (required)"
 113
 114     SectionIn RO
 115
 116     ; Set output path to the installation directory.
 117     SetOutPath "$INSTDIR"
 118
 119     File "${SRCDIR}\Changelog"
 120     File "${SRCDIR}\COPYING"
 121     File "${SRCDIR}\COPYING.LIB"
 122     File "${SRCDIR}\README.rst"
 123     File "${SRCDIR}\VERSION"
 124
 125     File "${BINDIR}\*.bmp"
 126     File "${BINDIR}\*.bin"
 127     File "${BINDIR}\*.dtb"
 128     File "${BINDIR}\*.fd"
 129     File "${BINDIR}\*.img"
 130     File "${BINDIR}\*.lid"
 131     File "${BINDIR}\*.ndrv"
 132     File "${BINDIR}\*.rom"
 133     File "${BINDIR}\openbios-*"
 134
 135     File /r "${BINDIR}\keymaps"
 136 !ifdef CONFIG_GTK
 137     File /r "${BINDIR}\share"
 138 !endif
 139
 140 !ifdef W64
 141     SetRegView 64
 142 !endif
 143
 144     ; Write the installation path into the registry
 145     WriteRegStr HKLM SOFTWARE\${PRODUCT} "Install_Dir" "$INSTDIR"
 146
 147     ; Write the uninstall keys for Windows
 148     WriteRegStr HKLM "${UNINST_KEY}" "DisplayName" "QEMU"
 149 !ifdef DISPLAYVERSION
 150     WriteRegStr HKLM "${UNINST_KEY}" "DisplayVersion" "${DISPLAYVERSION}"
 151 !endif
 152     WriteRegStr HKLM "${UNINST_KEY}" "UninstallString" '"${UNINST_EXE}"'
 153     WriteRegDWORD HKLM "${UNINST_KEY}" "NoModify" 1
 154     WriteRegDWORD HKLM "${UNINST_KEY}" "NoRepair" 1
 155     WriteUninstaller "qemu-uninstall.exe"
 156 SectionEnd
 157
 158 Section "Tools" SectionTools
 159     SetOutPath "$INSTDIR"
 160     File "${BINDIR}\qemu-img.exe"
 161     File "${BINDIR}\qemu-io.exe"
 162 SectionEnd
 163
 164 SectionGroup "System Emulations" SectionSystem
 165
 166 !include "${BINDIR}\system-emulations.nsh"
 167
 168 SectionGroupEnd
 169
 170 !ifdef DLLDIR
 171 Section "Libraries (DLL)" SectionDll
 172     SetOutPath "$INSTDIR"
 173     File "${DLLDIR}\*.dll"
 174 SectionEnd
 175 !endif
 176
 177 !ifdef CONFIG_DOCUMENTATION
 178 Section "Documentation" SectionDoc
 179     SetOutPath "$INSTDIR"
 180     File "${BINDIR}\qemu-doc.html"
 181     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 182     CreateShortCut "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk" "$INSTDIR\qemu-doc.html" "" "$INSTDIR\qemu-doc.html" 0
 183 SectionEnd
 184 !endif
 185
 186 ; Optional section (can be disabled by the user)
 187 Section "Start Menu Shortcuts" SectionMenu
 188     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 189     CreateShortCut "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk" "${UNINST_EXE}" "" "${UNINST_EXE}" 0
 190 SectionEnd
 191
 192 ;--------------------------------
 193
 194 ; Uninstaller
 195
 196 Section "Uninstall"
 197     ; Remove registry keys
 198 !ifdef W64
 199     SetRegView 64
 200 !endif
 201     DeleteRegKey HKLM "${UNINST_KEY}"
 202     DeleteRegKey HKLM SOFTWARE\${PRODUCT}
 203
 204     ; Remove shortcuts, if any
 205     Delete "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk"
 206     Delete "$SMPROGRAMS\${PRODUCT}\Technical Documentation.lnk"
 207     Delete "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk"
 208     RMDir "$SMPROGRAMS\${PRODUCT}"
 209
 210     ; Remove files and directories used
 211     Delete "$INSTDIR\Changelog"
 212     Delete "$INSTDIR\COPYING"
 213     Delete "$INSTDIR\COPYING.LIB"
 214     Delete "$INSTDIR\README.rst"
 215     Delete "$INSTDIR\VERSION"
 216     Delete "$INSTDIR\*.bmp"
 217     Delete "$INSTDIR\*.bin"
 218     Delete "$INSTDIR\*.dll"
 219     Delete "$INSTDIR\*.dtb"
 220     Delete "$INSTDIR\*.fd"
 221     Delete "$INSTDIR\*.img"
 222     Delete "$INSTDIR\*.lid"
 223     Delete "$INSTDIR\*.ndrv"
 224     Delete "$INSTDIR\*.rom"
 225     Delete "$INSTDIR\openbios-*"
 226     Delete "$INSTDIR\qemu-img.exe"
 227     Delete "$INSTDIR\qemu-io.exe"
 228     Delete "$INSTDIR\qemu.exe"
 229     Delete "$INSTDIR\qemu-system-*.exe"
 230     Delete "$INSTDIR\qemu-doc.html"
 231     RMDir /r "$INSTDIR\keymaps"
 232     RMDir /r "$INSTDIR\share"
 233     ; Remove generated files
 234     Delete "$INSTDIR\stderr.txt"
 235     Delete "$INSTDIR\stdout.txt"
 236     ; Remove uninstaller
 237     Delete "${UNINST_EXE}"
 238     RMDir "$INSTDIR"
 239 SectionEnd
 240
 241 ;--------------------------------
 242
 243 ; Descriptions (mouse-over).
 244 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 245     !insertmacro MUI_DESCRIPTION_TEXT ${SectionSystem}  "System emulation."
 246     !insertmacro MUI_DESCRIPTION_TEXT ${Section_alpha}  "Alpha system emulation."
 247     !insertmacro MUI_DESCRIPTION_TEXT ${Section_alphaw} "Alpha system emulation (GUI)."
 248     !insertmacro MUI_DESCRIPTION_TEXT ${Section_i386}   "PC i386 system emulation."
 249     !insertmacro MUI_DESCRIPTION_TEXT ${Section_i386w}  "PC i386 system emulation (GUI)."
 250     !insertmacro MUI_DESCRIPTION_TEXT ${SectionTools} "Tools."
 251 !ifdef DLLDIR
 252     !insertmacro MUI_DESCRIPTION_TEXT ${SectionDll}   "Runtime Libraries (DLL)."
 253 !endif
 254 !ifdef CONFIG_DOCUMENTATION
 255     !insertmacro MUI_DESCRIPTION_TEXT ${SectionDoc}   "Documentation."
 256 !endif
 257     !insertmacro MUI_DESCRIPTION_TEXT ${SectionMenu}  "Menu entries."
 258 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 259
 260 ;--------------------------------
 261 ; Functions.
 262
 263 Function .onInit
 264     !insertmacro MUI_LANGDLL_DISPLAY
 265 FunctionEnd