audio/meson.build

   1 system_ss.add([spice_headers, files('audio.c')])
   2 system_ss.add(files(
   3   'audio-hmp-cmds.c',
   4   'mixeng.c',
   5   'noaudio.c',
   6   'wavaudio.c',
   7   'wavcapture.c',
   8 ))
   9
  10 system_ss.add(when: coreaudio, if_true: files('coreaudio.m'))
  11 system_ss.add(when: dsound, if_true: files('dsoundaudio.c', 'audio_win_int.c'))
  12
  13 audio_modules = {}
  14 foreach m : [
  15   ['alsa', alsa, files('alsaaudio.c')],
  16   ['oss', oss, files('ossaudio.c')],
  17   ['pa', pulse, files('paaudio.c')],
  18   ['sdl', sdl, files('sdlaudio.c')],
  19   ['jack', jack, files('jackaudio.c')],
  20   ['sndio', sndio, files('sndioaudio.c')],
  21   ['pipewire', pipewire, files('pwaudio.c')],
  22   ['spice', spice, files('spiceaudio.c')]
  23 ]
  24   if m[1].found()
  25     module_ss = ss.source_set()
  26     module_ss.add(m[1], m[2])
  27     audio_modules += {m[0] : module_ss}
  28   endif
  29 endforeach
  30
  31 if dbus_display
  32     module_ss = ss.source_set()
  33     module_ss.add(when: [gio, pixman], if_true: files('dbusaudio.c'))
  34     audio_modules += {'dbus': module_ss}
  35 endif
  36
  37 modules += {'audio': audio_modules}