hw/usb/meson.build

   1 hw_usb_modules = {}
   2
   3 # usb subsystem core
   4 system_ss.add(when: 'CONFIG_USB', if_true: files(
   5   'bus.c',
   6   'combined-packet.c',
   7   'core.c',
   8   'desc.c',
   9   'desc-msos.c',
  10   'libhw.c',
  11   'pcap.c',
  12 ))
  13
  14 # usb host adapters
  15 system_ss.add(when: 'CONFIG_USB_UHCI', if_true: files('hcd-uhci.c'))
  16 system_ss.add(when: 'CONFIG_USB_OHCI', if_true: files('hcd-ohci.c'))
  17 system_ss.add(when: 'CONFIG_USB_OHCI_PCI', if_true: files('hcd-ohci-pci.c'))
  18 system_ss.add(when: 'CONFIG_USB_EHCI', if_true: files('hcd-ehci.c'))
  19 system_ss.add(when: 'CONFIG_USB_EHCI_PCI', if_true: files('hcd-ehci-pci.c'))
  20 system_ss.add(when: 'CONFIG_USB_EHCI_SYSBUS', if_true: files('hcd-ehci.c', 'hcd-ehci-sysbus.c'))
  21 system_ss.add(when: 'CONFIG_USB_XHCI', if_true: files('hcd-xhci.c'))
  22 system_ss.add(when: 'CONFIG_USB_XHCI_PCI', if_true: files('hcd-xhci-pci.c'))
  23 system_ss.add(when: 'CONFIG_USB_XHCI_SYSBUS', if_true: files('hcd-xhci-sysbus.c'))
  24 system_ss.add(when: 'CONFIG_USB_XHCI_NEC', if_true: files('hcd-xhci-nec.c'))
  25 system_ss.add(when: 'CONFIG_USB_MUSB', if_true: files('hcd-musb.c'))
  26 system_ss.add(when: 'CONFIG_USB_DWC2', if_true: files('hcd-dwc2.c'))
  27 system_ss.add(when: 'CONFIG_USB_DWC3', if_true: files('hcd-dwc3.c'))
  28
  29 system_ss.add(when: 'CONFIG_TUSB6010', if_true: files('tusb6010.c'))
  30 system_ss.add(when: 'CONFIG_IMX', if_true: files('chipidea.c'))
  31 system_ss.add(when: 'CONFIG_IMX_USBPHY', if_true: files('imx-usb-phy.c'))
  32 system_ss.add(when: 'CONFIG_VT82C686', if_true: files('vt82c686-uhci-pci.c'))
  33 system_ss.add(when: 'CONFIG_XLNX_VERSAL', if_true: files('xlnx-versal-usb2-ctrl-regs.c'))
  34 system_ss.add(when: 'CONFIG_XLNX_USB_SUBSYS', if_true: files('xlnx-usb-subsystem.c'))
  35
  36 # emulated usb devices
  37 system_ss.add(when: 'CONFIG_USB', if_true: files('dev-hub.c'))
  38 system_ss.add(when: 'CONFIG_USB', if_true: files('dev-hid.c'))
  39 system_ss.add(when: 'CONFIG_USB_TABLET_WACOM', if_true: files('dev-wacom.c'))
  40 system_ss.add(when: 'CONFIG_USB_STORAGE_CORE', if_true: files('dev-storage.c'))
  41 system_ss.add(when: 'CONFIG_USB_STORAGE_BOT', if_true: files('dev-storage-bot.c'))
  42 system_ss.add(when: 'CONFIG_USB_STORAGE_CLASSIC', if_true: files('dev-storage-classic.c'))
  43 system_ss.add(when: 'CONFIG_USB_STORAGE_UAS', if_true: files('dev-uas.c'))
  44 system_ss.add(when: 'CONFIG_USB_AUDIO', if_true: files('dev-audio.c'))
  45 system_ss.add(when: 'CONFIG_USB_SERIAL', if_true: files('dev-serial.c'))
  46 system_ss.add(when: 'CONFIG_USB_NETWORK', if_true: files('dev-network.c'))
  47 system_ss.add(when: ['CONFIG_POSIX', 'CONFIG_USB_STORAGE_MTP'], if_true: files('dev-mtp.c'))
  48
  49 # smartcard
  50 system_ss.add(when: 'CONFIG_USB_SMARTCARD', if_true: files('dev-smartcard-reader.c'))
  51
  52 if cacard.found()
  53   usbsmartcard_ss = ss.source_set()
  54   usbsmartcard_ss.add(when: 'CONFIG_USB_SMARTCARD',
  55                       if_true: [cacard, files('ccid-card-emulated.c', 'ccid-card-passthru.c')])
  56   hw_usb_modules += {'smartcard': usbsmartcard_ss}
  57 endif
  58
  59 # U2F
  60 system_ss.add(when: 'CONFIG_USB_U2F', if_true: files('u2f.c'))
  61 system_ss.add(when: ['CONFIG_LINUX', 'CONFIG_USB_U2F'], if_true: [libudev, files('u2f-passthru.c')])
  62 if u2f.found()
  63   system_ss.add(when: 'CONFIG_USB_U2F', if_true: [u2f, files('u2f-emulated.c')])
  64 endif
  65
  66 # CanoKey
  67 if canokey.found()
  68   system_ss.add(when: 'CONFIG_USB_CANOKEY', if_true: [canokey, files('canokey.c')])
  69 endif
  70
  71 # usb redirect
  72 if usbredir.found()
  73   usbredir_ss = ss.source_set()
  74   usbredir_ss.add(when: 'CONFIG_USB',
  75                   if_true: [usbredir, files('redirect.c', 'quirks.c')])
  76   hw_usb_modules += {'redirect': usbredir_ss}
  77 endif
  78
  79 # usb pass-through
  80 if libusb.found()
  81   usbhost_ss = ss.source_set()
  82   usbhost_ss.add(when: ['CONFIG_USB', libusb],
  83                  if_true: files('host-libusb.c'))
  84   hw_usb_modules += {'host': usbhost_ss}
  85 endif
  86
  87 system_ss.add(when: ['CONFIG_USB', 'CONFIG_XEN_BUS', libusb], if_true: files('xen-usb.c'))
  88
  89 modules += { 'hw-usb': hw_usb_modules }