meson.build

   1 project('qemu', ['c'], meson_version: '>=0.63.0',
   2         default_options: ['warning_level=2', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto',
   3                           'b_staticpic=false', 'stdsplit=false', 'optimization=2', 'b_pie=true'],
   4         version: files('VERSION'))
   5
   6 add_test_setup('quick', exclude_suites: ['slow', 'thorough'], is_default: true)
   7 add_test_setup('slow', exclude_suites: ['thorough'], env: ['G_TEST_SLOW=1', 'SPEED=slow'])
   8 add_test_setup('thorough', env: ['G_TEST_SLOW=1', 'SPEED=thorough'])
   9
  10 meson.add_postconf_script(find_program('scripts/symlink-install-tree.py'))
  11
  12 ####################
  13 # Global variables #
  14 ####################
  15
  16 not_found = dependency('', required: false)
  17 keyval = import('keyval')
  18 ss = import('sourceset')
  19 fs = import('fs')
  20
  21 host_os = host_machine.system()
  22 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  23
  24 # Temporary directory used for files created while
  25 # configure runs. Since it is in the build directory
  26 # we can safely blow away any previous version of it
  27 # (and we need not jump through hoops to try to delete
  28 # it when configure exits.)
  29 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  30
  31 if get_option('qemu_suffix').startswith('/')
  32   error('qemu_suffix cannot start with a /')
  33 endif
  34
  35 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  36 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  37 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  38 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  39
  40 qemu_desktopdir = get_option('datadir') / 'applications'
  41 qemu_icondir = get_option('datadir') / 'icons'
  42
  43 genh = []
  44 qapi_trace_events = []
  45
  46 bsd_oses = ['gnu/kfreebsd', 'freebsd', 'netbsd', 'openbsd', 'dragonfly', 'darwin']
  47 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  48 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  49   'arm', 'aarch64', 'loongarch64', 'mips', 'mips64', 'sparc64']
  50
  51 cpu = host_machine.cpu_family()
  52
  53 target_dirs = config_host['TARGET_DIRS'].split()
  54
  55 ############
  56 # Programs #
  57 ############
  58
  59 sh = find_program('sh')
  60 python = import('python').find_installation()
  61
  62 cc = meson.get_compiler('c')
  63 all_languages = ['c']
  64 if host_os == 'windows' and add_languages('cpp', required: false, native: false)
  65   all_languages += ['cpp']
  66   cxx = meson.get_compiler('cpp')
  67 endif
  68 if host_os == 'darwin' and \
  69    add_languages('objc', required: true, native: false)
  70   all_languages += ['objc']
  71   objc = meson.get_compiler('objc')
  72 endif
  73
  74 dtrace = not_found
  75 stap = not_found
  76 if 'dtrace' in get_option('trace_backends')
  77   dtrace = find_program('dtrace', required: true)
  78   stap = find_program('stap', required: false)
  79   if stap.found()
  80     # Workaround to avoid dtrace(1) producing a file with 'hidden' symbol
  81     # visibility. Define STAP_SDT_V2 to produce 'default' symbol visibility
  82     # instead. QEMU --enable-modules depends on this because the SystemTap
  83     # semaphores are linked into the main binary and not the module's shared
  84     # object.
  85     add_global_arguments('-DSTAP_SDT_V2',
  86                          native: false, language: all_languages)
  87   endif
  88 endif
  89
  90 if get_option('iasl') == ''
  91   iasl = find_program('iasl', required: false)
  92 else
  93   iasl = find_program(get_option('iasl'), required: true)
  94 endif
  95
  96 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
  97 unpack_edk2_blobs = false
  98 foreach target : edk2_targets
  99   if target in target_dirs
 100     bzip2 = find_program('bzip2', required: get_option('install_blobs'))
 101     unpack_edk2_blobs = bzip2.found()
 102     break
 103   endif
 104 endforeach
 105
 106 #####################
 107 # Option validation #
 108 #####################
 109
 110 # Fuzzing
 111 if get_option('fuzzing') and get_option('fuzzing_engine') == '' and \
 112     not cc.links('''
 113           #include <stdint.h>
 114           #include <sys/types.h>
 115           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size);
 116           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size) { return 0; }
 117         ''',
 118         args: ['-Werror', '-fsanitize=fuzzer'])
 119   error('Your compiler does not support -fsanitize=fuzzer')
 120 endif
 121
 122 # Tracing backends
 123 if 'ftrace' in get_option('trace_backends') and host_os != 'linux'
 124   error('ftrace is supported only on Linux')
 125 endif
 126 if 'syslog' in get_option('trace_backends') and not cc.compiles('''
 127     #include <syslog.h>
 128     int main(void) {
 129         openlog("qemu", LOG_PID, LOG_DAEMON);
 130         syslog(LOG_INFO, "configure");
 131         return 0;
 132     }''')
 133   error('syslog is not supported on this system')
 134 endif
 135
 136 # Miscellaneous Linux-only features
 137 get_option('mpath') \
 138   .require(host_os == 'linux', error_message: 'Multipath is supported only on Linux')
 139
 140 multiprocess_allowed = get_option('multiprocess') \
 141   .require(host_os == 'linux', error_message: 'Multiprocess QEMU is supported only on Linux') \
 142   .allowed()
 143
 144 vfio_user_server_allowed = get_option('vfio_user_server') \
 145   .require(host_os == 'linux', error_message: 'vfio-user server is supported only on Linux') \
 146   .allowed()
 147
 148 have_tpm = get_option('tpm') \
 149   .require(host_os != 'windows', error_message: 'TPM emulation only available on POSIX systems') \
 150   .allowed()
 151
 152 # vhost
 153 have_vhost_user = get_option('vhost_user') \
 154   .disable_auto_if(host_os != 'linux') \
 155   .require(host_os != 'windows',
 156            error_message: 'vhost-user is not available on Windows').allowed()
 157 have_vhost_vdpa = get_option('vhost_vdpa') \
 158   .require(host_os == 'linux',
 159            error_message: 'vhost-vdpa is only available on Linux').allowed()
 160 have_vhost_kernel = get_option('vhost_kernel') \
 161   .require(host_os == 'linux',
 162            error_message: 'vhost-kernel is only available on Linux').allowed()
 163 have_vhost_user_crypto = get_option('vhost_crypto') \
 164   .require(have_vhost_user,
 165            error_message: 'vhost-crypto requires vhost-user to be enabled').allowed()
 166
 167 have_vhost = have_vhost_user or have_vhost_vdpa or have_vhost_kernel
 168
 169 have_vhost_net_user = have_vhost_user and get_option('vhost_net').allowed()
 170 have_vhost_net_vdpa = have_vhost_vdpa and get_option('vhost_net').allowed()
 171 have_vhost_net_kernel = have_vhost_kernel and get_option('vhost_net').allowed()
 172 have_vhost_net = have_vhost_net_kernel or have_vhost_net_user or have_vhost_net_vdpa
 173
 174 # type of binaries to build
 175 have_linux_user = false
 176 have_bsd_user = false
 177 have_system = false
 178 foreach target : target_dirs
 179   have_linux_user = have_linux_user or target.endswith('linux-user')
 180   have_bsd_user = have_bsd_user or target.endswith('bsd-user')
 181   have_system = have_system or target.endswith('-softmmu')
 182 endforeach
 183 have_user = have_linux_user or have_bsd_user
 184
 185 have_tools = get_option('tools') \
 186   .disable_auto_if(not have_system) \
 187   .allowed()
 188 have_ga = get_option('guest_agent') \
 189   .disable_auto_if(not have_system and not have_tools) \
 190   .require(host_os in ['sunos', 'linux', 'windows', 'freebsd', 'netbsd', 'openbsd'],
 191            error_message: 'unsupported OS for QEMU guest agent') \
 192   .allowed()
 193 have_block = have_system or have_tools
 194
 195 enable_modules = get_option('modules') \
 196   .require(host_os != 'windows',
 197            error_message: 'Modules are not available for Windows') \
 198   .require(not get_option('prefer_static'),
 199            error_message: 'Modules are incompatible with static linking') \
 200   .allowed()
 201
 202 #######################################
 203 # Variables for host and accelerators #
 204 #######################################
 205
 206 if cpu not in supported_cpus
 207   host_arch = 'unknown'
 208 elif cpu == 'x86'
 209   host_arch = 'i386'
 210 elif cpu == 'mips64'
 211   host_arch = 'mips'
 212 elif cpu in ['riscv32', 'riscv64']
 213   host_arch = 'riscv'
 214 else
 215   host_arch = cpu
 216 endif
 217
 218 if cpu in ['x86', 'x86_64']
 219   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
 220 elif cpu == 'aarch64'
 221   kvm_targets = ['aarch64-softmmu']
 222 elif cpu == 's390x'
 223   kvm_targets = ['s390x-softmmu']
 224 elif cpu in ['ppc', 'ppc64']
 225   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
 226 elif cpu in ['mips', 'mips64']
 227   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
 228 elif cpu in ['riscv32']
 229   kvm_targets = ['riscv32-softmmu']
 230 elif cpu in ['riscv64']
 231   kvm_targets = ['riscv64-softmmu']
 232 elif cpu in ['loongarch64']
 233   kvm_targets = ['loongarch64-softmmu']
 234 else
 235   kvm_targets = []
 236 endif
 237 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
 238
 239 if cpu in ['x86', 'x86_64']
 240   xen_targets = ['i386-softmmu', 'x86_64-softmmu']
 241 elif cpu in ['arm', 'aarch64']
 242   # i386 emulator provides xenpv machine type for multiple architectures
 243   xen_targets = ['i386-softmmu', 'x86_64-softmmu', 'aarch64-softmmu']
 244 else
 245   xen_targets = []
 246 endif
 247 accelerator_targets += { 'CONFIG_XEN': xen_targets }
 248
 249 if cpu in ['aarch64']
 250   accelerator_targets += {
 251     'CONFIG_HVF': ['aarch64-softmmu']
 252   }
 253 endif
 254
 255 if cpu in ['x86', 'x86_64']
 256   accelerator_targets += {
 257     'CONFIG_HVF': ['x86_64-softmmu'],
 258     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
 259     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
 260   }
 261 endif
 262
 263 modular_tcg = []
 264 # Darwin does not support references to thread-local variables in modules
 265 if host_os != 'darwin'
 266   modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
 267 endif
 268
 269 ##################
 270 # Compiler flags #
 271 ##################
 272
 273 foreach lang : all_languages
 274   compiler = meson.get_compiler(lang)
 275   if compiler.get_id() == 'gcc' and compiler.version().version_compare('>=7.4')
 276     # ok
 277   elif compiler.get_id() == 'clang' and compiler.compiles('''
 278       #ifdef __apple_build_version__
 279       # if __clang_major__ < 12 || (__clang_major__ == 12 && __clang_minor__ < 0)
 280       #  error You need at least XCode Clang v12.0 to compile QEMU
 281       # endif
 282       #else
 283       # if __clang_major__ < 10 || (__clang_major__ == 10 && __clang_minor__ < 0)
 284       #  error You need at least Clang v10.0 to compile QEMU
 285       # endif
 286       #endif''')
 287     # ok
 288   else
 289     error('You either need GCC v7.4 or Clang v10.0 (or XCode Clang v12.0) to compile QEMU')
 290   endif
 291 endforeach
 292
 293 # default flags for all hosts
 294 # We use -fwrapv to tell the compiler that we require a C dialect where
 295 # left shift of signed integers is well defined and has the expected
 296 # 2s-complement style results. (Both clang and gcc agree that it
 297 # provides these semantics.)
 298
 299 qemu_common_flags = [
 300   '-D_GNU_SOURCE', '-D_FILE_OFFSET_BITS=64', '-D_LARGEFILE_SOURCE',
 301   '-fno-strict-aliasing', '-fno-common', '-fwrapv' ]
 302 qemu_cflags = []
 303 qemu_ldflags = []
 304
 305 if host_os == 'darwin'
 306   # Disable attempts to use ObjectiveC features in os/object.h since they
 307   # won't work when we're compiling with gcc as a C compiler.
 308   if compiler.get_id() == 'gcc'
 309     qemu_common_flags += '-DOS_OBJECT_USE_OBJC=0'
 310   endif
 311 elif host_os == 'sunos'
 312   # needed for CMSG_ macros in sys/socket.h
 313   qemu_common_flags += '-D_XOPEN_SOURCE=600'
 314   # needed for TIOCWIN* defines in termios.h
 315   qemu_common_flags += '-D__EXTENSIONS__'
 316 elif host_os == 'haiku'
 317   qemu_common_flags += ['-DB_USE_POSITIVE_POSIX_ERRORS', '-D_BSD_SOURCE', '-fPIC']
 318 endif
 319
 320 # __sync_fetch_and_and requires at least -march=i486. Many toolchains
 321 # use i686 as default anyway, but for those that don't, an explicit
 322 # specification is necessary
 323 if host_arch == 'i386' and not cc.links('''
 324   static int sfaa(int *ptr)
 325   {
 326     return __sync_fetch_and_and(ptr, 0);
 327   }
 328
 329   int main(void)
 330   {
 331     int val = 42;
 332     val = __sync_val_compare_and_swap(&val, 0, 1);
 333     sfaa(&val);
 334     return val;
 335   }''')
 336   qemu_common_flags = ['-march=i486'] + qemu_common_flags
 337 endif
 338
 339 if get_option('prefer_static')
 340   qemu_ldflags += get_option('b_pie') ? '-static-pie' : '-static'
 341 endif
 342
 343 # Meson currently only handles pie as a boolean for now, so if the user
 344 # has explicitly disabled PIE we need to extend our cflags.
 345 #
 346 # -no-pie is supposedly a linker flag that has no effect on the compiler
 347 # command line, but some distros, that didn't quite know what they were
 348 # doing, made local changes to gcc's specs file that turned it into
 349 # a compiler command-line flag.
 350 #
 351 # What about linker flags?  For a static build, no PIE is implied by -static
 352 # which we added above (and if it's not because of the same specs patching,
 353 # there's nothing we can do: compilation will fail, report a bug to your
 354 # distro and do not use --disable-pie in the meanwhile).  For dynamic linking,
 355 # instead, we can't add -no-pie because it overrides -shared: the linker then
 356 # tries to build an executable instead of a shared library and fails.  So
 357 # don't add -no-pie anywhere and cross fingers. :(
 358 if not get_option('b_pie')
 359   qemu_common_flags += cc.get_supported_arguments('-fno-pie', '-no-pie')
 360 endif
 361
 362 if not get_option('stack_protector').disabled()
 363   stack_protector_probe = '''
 364     int main(int argc, char *argv[])
 365     {
 366       char arr[64], *p = arr, *c = argv[argc - 1];
 367       while (*c) {
 368           *p++ = *c++;
 369       }
 370       return 0;
 371     }'''
 372   have_stack_protector = false
 373   foreach arg : ['-fstack-protector-strong', '-fstack-protector-all']
 374     # We need to check both a compile and a link, since some compiler
 375     # setups fail only on a .c->.o compile and some only at link time
 376     if cc.compiles(stack_protector_probe, args: ['-Werror', arg]) and \
 377        cc.links(stack_protector_probe, args: ['-Werror', arg])
 378       have_stack_protector = true
 379       qemu_cflags += arg
 380       qemu_ldflags += arg
 381       break
 382     endif
 383   endforeach
 384   get_option('stack_protector') \
 385     .require(have_stack_protector, error_message: 'Stack protector not supported')
 386 endif
 387
 388 coroutine_backend = get_option('coroutine_backend')
 389 ucontext_probe = '''
 390   #include <ucontext.h>
 391   #ifdef __stub_makecontext
 392   #error Ignoring glibc stub makecontext which will always fail
 393   #endif
 394   int main(void) { makecontext(0, 0, 0); return 0; }'''
 395
 396 # On Windows the only valid backend is the Windows specific one.
 397 # For POSIX prefer ucontext, but it's not always possible. The fallback
 398 # is sigcontext.
 399 supported_backends = []
 400 if host_os == 'windows'
 401   supported_backends += ['windows']
 402 else
 403   if host_os != 'darwin' and cc.links(ucontext_probe)
 404     supported_backends += ['ucontext']
 405   endif
 406   supported_backends += ['sigaltstack']
 407 endif
 408
 409 if coroutine_backend == 'auto'
 410   coroutine_backend = supported_backends[0]
 411 elif coroutine_backend not in supported_backends
 412   error('"@0@" backend requested but not available.  Available backends: @1@' \
 413         .format(coroutine_backend, ', '.join(supported_backends)))
 414 endif
 415
 416 # Compiles if SafeStack *not* enabled
 417 safe_stack_probe = '''
 418   int main(void)
 419   {
 420   #if defined(__has_feature)
 421   #if __has_feature(safe_stack)
 422   #error SafeStack Enabled
 423   #endif
 424   #endif
 425       return 0;
 426   }'''
 427 if get_option('safe_stack') != not cc.compiles(safe_stack_probe)
 428   safe_stack_arg = get_option('safe_stack') ? '-fsanitize=safe-stack' : '-fno-sanitize=safe-stack'
 429   if get_option('safe_stack') != not cc.compiles(safe_stack_probe, args: safe_stack_arg)
 430     error(get_option('safe_stack') \
 431           ? 'SafeStack not supported by your compiler' \
 432           : 'Cannot disable SafeStack')
 433   endif
 434   qemu_cflags += safe_stack_arg
 435   qemu_ldflags += safe_stack_arg
 436 endif
 437 if get_option('safe_stack') and coroutine_backend != 'ucontext'
 438   error('SafeStack is only supported with the ucontext coroutine backend')
 439 endif
 440
 441 if get_option('sanitizers')
 442   if cc.has_argument('-fsanitize=address')
 443     qemu_cflags = ['-fsanitize=address'] + qemu_cflags
 444     qemu_ldflags = ['-fsanitize=address'] + qemu_ldflags
 445   endif
 446
 447   # Detect static linking issue with ubsan - https://gcc.gnu.org/bugzilla/show_bug.cgi?id=84285
 448   if cc.links('int main(int argc, char **argv) { return argc + 1; }',
 449               args: [qemu_ldflags, '-fsanitize=undefined'])
 450     qemu_cflags = ['-fsanitize=undefined'] + qemu_cflags
 451     qemu_ldflags = ['-fsanitize=undefined'] + qemu_ldflags
 452   endif
 453 endif
 454
 455 # Thread sanitizer is, for now, much noisier than the other sanitizers;
 456 # keep it separate until that is not the case.
 457 if get_option('tsan')
 458   if get_option('sanitizers')
 459     error('TSAN is not supported with other sanitizers')
 460   endif
 461   if not cc.has_function('__tsan_create_fiber',
 462                          args: '-fsanitize=thread',
 463                          prefix: '#include <sanitizer/tsan_interface.h>')
 464     error('Cannot enable TSAN due to missing fiber annotation interface')
 465   endif
 466   qemu_cflags = ['-fsanitize=thread'] + qemu_cflags
 467   qemu_ldflags = ['-fsanitize=thread'] + qemu_ldflags
 468 endif
 469
 470 # Detect support for PT_GNU_RELRO + DT_BIND_NOW.
 471 # The combination is known as "full relro", because .got.plt is read-only too.
 472 qemu_ldflags += cc.get_supported_link_arguments('-Wl,-z,relro', '-Wl,-z,now')
 473
 474 if host_os == 'windows'
 475   qemu_ldflags += cc.get_supported_link_arguments('-Wl,--no-seh', '-Wl,--nxcompat')
 476   qemu_ldflags += cc.get_supported_link_arguments('-Wl,--dynamicbase', '-Wl,--high-entropy-va')
 477 endif
 478
 479 if get_option('fuzzing')
 480   # Specify a filter to only instrument code that is directly related to
 481   # virtual-devices.
 482   configure_file(output: 'instrumentation-filter',
 483                  input: 'scripts/oss-fuzz/instrumentation-filter-template',
 484                  copy: true)
 485
 486   if cc.compiles('int main () { return 0; }',
 487                   name: '-fsanitize-coverage-allowlist=/dev/null',
 488                  args: ['-fsanitize-coverage-allowlist=/dev/null',
 489                         '-fsanitize-coverage=trace-pc'] )
 490     qemu_common_flags += ['-fsanitize-coverage-allowlist=instrumentation-filter']
 491   endif
 492
 493   if get_option('fuzzing_engine') == ''
 494     # Add CFLAGS to tell clang to add fuzzer-related instrumentation to all the
 495     # compiled code.  To build non-fuzzer binaries with --enable-fuzzing, link
 496     # everything with fsanitize=fuzzer-no-link. Otherwise, the linker will be
 497     # unable to bind the fuzzer-related callbacks added by instrumentation.
 498     qemu_common_flags += ['-fsanitize=fuzzer-no-link']
 499     qemu_ldflags += ['-fsanitize=fuzzer-no-link']
 500     # For the actual fuzzer binaries, we need to link against the libfuzzer
 501     # library. They need to be configurable, to support OSS-Fuzz
 502     fuzz_exe_ldflags = ['-fsanitize=fuzzer']
 503   else
 504     # LIB_FUZZING_ENGINE was set; assume we are running on OSS-Fuzz, and
 505     # the needed CFLAGS have already been provided
 506     fuzz_exe_ldflags = get_option('fuzzing_engine').split()
 507   endif
 508 endif
 509
 510 if get_option('cfi')
 511   cfi_flags=[]
 512   # Check for dependency on LTO
 513   if not get_option('b_lto')
 514     error('Selected Control-Flow Integrity but LTO is disabled')
 515   endif
 516   if enable_modules
 517     error('Selected Control-Flow Integrity is not compatible with modules')
 518   endif
 519   # Check for cfi flags. CFI requires LTO so we can't use
 520   # get_supported_arguments, but need a more complex "compiles" which allows
 521   # custom arguments
 522   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
 523                  args: ['-flto', '-fsanitize=cfi-icall'] )
 524     cfi_flags += '-fsanitize=cfi-icall'
 525   else
 526     error('-fsanitize=cfi-icall is not supported by the compiler')
 527   endif
 528   if cc.compiles('int main () { return 0; }',
 529                  name: '-fsanitize-cfi-icall-generalize-pointers',
 530                  args: ['-flto', '-fsanitize=cfi-icall',
 531                         '-fsanitize-cfi-icall-generalize-pointers'] )
 532     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
 533   else
 534     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
 535   endif
 536   if get_option('cfi_debug')
 537     if cc.compiles('int main () { return 0; }',
 538                    name: '-fno-sanitize-trap=cfi-icall',
 539                    args: ['-flto', '-fsanitize=cfi-icall',
 540                           '-fno-sanitize-trap=cfi-icall'] )
 541       cfi_flags += '-fno-sanitize-trap=cfi-icall'
 542     else
 543       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
 544     endif
 545   endif
 546   add_global_arguments(cfi_flags, native: false, language: all_languages)
 547   add_global_link_arguments(cfi_flags, native: false, language: all_languages)
 548 endif
 549
 550 # Check further flags that make QEMU more robust against malicious parties
 551
 552 hardening_flags = [
 553     # Initialize all stack variables to zero. This makes
 554     # it harder to take advantage of uninitialized stack
 555     # data to drive exploits
 556     '-ftrivial-auto-var-init=zero',
 557 ]
 558
 559 # Zero out registers used during a function call
 560 # upon its return. This makes it harder to assemble
 561 # ROP gadgets into something usable
 562 #
 563 # NB: Clang 17 is broken and SEGVs
 564 # https://github.com/llvm/llvm-project/issues/75168
 565 if cc.compiles('extern struct { void (*cb)(void); } s; void f(void) { s.cb(); }',
 566                name: '-fzero-call-used-regs=used-gpr',
 567                args: ['-O2', '-fzero-call-used-regs=used-gpr'])
 568     hardening_flags += '-fzero-call-used-regs=used-gpr'
 569 endif
 570
 571 qemu_common_flags += cc.get_supported_arguments(hardening_flags)
 572
 573 add_global_arguments(qemu_common_flags, native: false, language: all_languages)
 574 add_global_link_arguments(qemu_ldflags, native: false, language: all_languages)
 575
 576 # Collect warning flags we want to set, sorted alphabetically
 577 warn_flags = [
 578   # First enable interesting warnings
 579   '-Wempty-body',
 580   '-Wendif-labels',
 581   '-Wexpansion-to-defined',
 582   '-Wformat-security',
 583   '-Wformat-y2k',
 584   '-Wignored-qualifiers',
 585   '-Wimplicit-fallthrough=2',
 586   '-Winit-self',
 587   '-Wmissing-format-attribute',
 588   '-Wmissing-prototypes',
 589   '-Wnested-externs',
 590   '-Wold-style-declaration',
 591   '-Wold-style-definition',
 592   '-Wredundant-decls',
 593   '-Wshadow=local',
 594   '-Wstrict-prototypes',
 595   '-Wtype-limits',
 596   '-Wundef',
 597   '-Wvla',
 598   '-Wwrite-strings',
 599
 600   # Then disable some undesirable warnings
 601   '-Wno-gnu-variable-sized-type-not-at-end',
 602   '-Wno-initializer-overrides',
 603   '-Wno-missing-field-initializers',
 604   '-Wno-missing-include-dirs',
 605   '-Wno-override-init',
 606   '-Wno-psabi',
 607   '-Wno-shift-negative-value',
 608   '-Wno-sign-compare',
 609   '-Wno-string-plus-int',
 610   '-Wno-tautological-type-limit-compare',
 611   '-Wno-unused-parameter',
 612   '-Wno-gnu-variable-sized-type-not-at-end',
 613   '-Wno-error=cast-function-type',
 614   '-Wno-error=format',
 615   '-Wno-error=format-extra-args',
 616   '-Wno-error=implicit-fallthrough',
 617   '-Wno-error=parentheses',
 618   '-Wshadow=local',
 619   '-Wno-typedef-redefinition',
 620 ]
 621
 622 if host_os != 'darwin'
 623   warn_flags += ['-Wthread-safety']
 624 endif
 625
 626 # Set up C++ compiler flags
 627 qemu_cxxflags = []
 628 if 'cpp' in all_languages
 629   qemu_cxxflags = ['-D__STDC_LIMIT_MACROS', '-D__STDC_CONSTANT_MACROS', '-D__STDC_FORMAT_MACROS'] + qemu_cflags
 630 endif
 631
 632 add_project_arguments(qemu_cflags, native: false, language: 'c')
 633 add_project_arguments(cc.get_supported_arguments(warn_flags), native: false, language: 'c')
 634 if 'cpp' in all_languages
 635   add_project_arguments(qemu_cxxflags, native: false, language: 'cpp')
 636   add_project_arguments(cxx.get_supported_arguments(warn_flags), native: false, language: 'cpp')
 637 endif
 638 if 'objc' in all_languages
 639   # Note sanitizer flags are not applied to Objective-C sources!
 640   add_project_arguments(objc.get_supported_arguments(warn_flags), native: false, language: 'objc')
 641 endif
 642 if host_os == 'linux'
 643   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 644                         '-isystem', 'linux-headers',
 645                         language: all_languages)
 646 endif
 647
 648 add_project_arguments('-iquote', '.',
 649                       '-iquote', meson.current_source_dir(),
 650                       '-iquote', meson.current_source_dir() / 'include',
 651                       language: all_languages)
 652
 653 # If a host-specific include directory exists, list that first...
 654 host_include = meson.current_source_dir() / 'host/include/'
 655 if fs.is_dir(host_include / host_arch)
 656   add_project_arguments('-iquote', host_include / host_arch,
 657                         language: all_languages)
 658 endif
 659 # ... followed by the generic fallback.
 660 add_project_arguments('-iquote', host_include / 'generic',
 661                       language: all_languages)
 662
 663 sparse = find_program('cgcc', required: get_option('sparse'))
 664 if sparse.found()
 665   run_target('sparse',
 666              command: [find_program('scripts/check_sparse.py'),
 667                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 668                        '-Wno-transparent-union', '-Wno-old-initializer',
 669                        '-Wno-non-pointer-null'])
 670 endif
 671
 672 #####################################
 673 # Host-specific libraries and flags #
 674 #####################################
 675
 676 libm = cc.find_library('m', required: false)
 677 threads = dependency('threads')
 678 util = cc.find_library('util', required: false)
 679 winmm = []
 680 socket = []
 681 version_res = []
 682 coref = []
 683 iokit = []
 684 emulator_link_args = []
 685 midl = not_found
 686 widl = not_found
 687 pathcch = not_found
 688 host_dsosuf = '.so'
 689 if host_os == 'windows'
 690   midl = find_program('midl', required: false)
 691   widl = find_program('widl', required: false)
 692   pathcch = cc.find_library('pathcch')
 693   socket = cc.find_library('ws2_32')
 694   winmm = cc.find_library('winmm')
 695
 696   win = import('windows')
 697   version_res = win.compile_resources('version.rc',
 698                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 699                                       include_directories: include_directories('.'))
 700   host_dsosuf = '.dll'
 701 elif host_os == 'darwin'
 702   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 703   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 704   host_dsosuf = '.dylib'
 705 elif host_os == 'sunos'
 706   socket = [cc.find_library('socket'),
 707             cc.find_library('nsl'),
 708             cc.find_library('resolv')]
 709 elif host_os == 'haiku'
 710   socket = [cc.find_library('posix_error_mapper'),
 711             cc.find_library('network'),
 712             cc.find_library('bsd')]
 713 elif host_os == 'openbsd'
 714   if get_option('tcg').allowed() and target_dirs.length() > 0
 715     # Disable OpenBSD W^X if available
 716     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 717   endif
 718 endif
 719
 720 ###############################################
 721 # Host-specific configuration of accelerators #
 722 ###############################################
 723
 724 accelerators = []
 725 if get_option('kvm').allowed() and host_os == 'linux'
 726   accelerators += 'CONFIG_KVM'
 727 endif
 728 if get_option('whpx').allowed() and host_os == 'windows'
 729   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 730     error('WHPX requires 64-bit host')
 731   elif cc.has_header('winhvplatform.h', required: get_option('whpx')) and \
 732        cc.has_header('winhvemulation.h', required: get_option('whpx'))
 733     accelerators += 'CONFIG_WHPX'
 734   endif
 735 endif
 736
 737 hvf = not_found
 738 if get_option('hvf').allowed()
 739   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 740                    required: get_option('hvf'))
 741   if hvf.found()
 742     accelerators += 'CONFIG_HVF'
 743   endif
 744 endif
 745
 746 nvmm = not_found
 747 if host_os == 'netbsd'
 748   nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 749   if nvmm.found()
 750     accelerators += 'CONFIG_NVMM'
 751   endif
 752 endif
 753
 754 tcg_arch = host_arch
 755 if get_option('tcg').allowed()
 756   if host_arch == 'unknown'
 757     if not get_option('tcg_interpreter')
 758       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 759     endif
 760   elif get_option('tcg_interpreter')
 761     warning('Use of the TCG interpreter is not recommended on this host')
 762     warning('architecture. There is a native TCG execution backend available')
 763     warning('which provides substantially better performance and reliability.')
 764     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 765     warning('configuration option on this architecture to use the native')
 766     warning('backend.')
 767   endif
 768   if get_option('tcg_interpreter')
 769     tcg_arch = 'tci'
 770   elif host_arch == 'x86_64'
 771     tcg_arch = 'i386'
 772   elif host_arch == 'ppc64'
 773     tcg_arch = 'ppc'
 774   endif
 775   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 776                         language: all_languages)
 777
 778   accelerators += 'CONFIG_TCG'
 779 endif
 780
 781 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 782   error('KVM not available on this platform')
 783 endif
 784 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 785   error('HVF not available on this platform')
 786 endif
 787 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 788   error('NVMM not available on this platform')
 789 endif
 790 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 791   error('WHPX not available on this platform')
 792 endif
 793
 794 xen = not_found
 795 if get_option('xen').enabled() or (get_option('xen').auto() and have_system)
 796   xencontrol = dependency('xencontrol', required: false,
 797                           method: 'pkg-config')
 798   if xencontrol.found()
 799     xen_pc = declare_dependency(version: xencontrol.version(),
 800       dependencies: [
 801         xencontrol,
 802         # disabler: true makes xen_pc.found() return false if any is not found
 803         dependency('xenstore', required: false,
 804                    method: 'pkg-config',
 805                    disabler: true),
 806         dependency('xenforeignmemory', required: false,
 807                    method: 'pkg-config',
 808                    disabler: true),
 809         dependency('xengnttab', required: false,
 810                    method: 'pkg-config',
 811                    disabler: true),
 812         dependency('xenevtchn', required: false,
 813                    method: 'pkg-config',
 814                    disabler: true),
 815         dependency('xendevicemodel', required: false,
 816                    method: 'pkg-config',
 817                    disabler: true),
 818         # optional, no "disabler: true"
 819         dependency('xentoolcore', required: false,
 820                    method: 'pkg-config')])
 821     if xen_pc.found()
 822       xen = xen_pc
 823     endif
 824   endif
 825   if not xen.found()
 826     xen_tests = [ '4.11.0', '4.10.0', '4.9.0', '4.8.0', '4.7.1' ]
 827     xen_libs = {
 828       '4.11.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
 829       '4.10.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
 830       '4.9.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
 831       '4.8.0': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
 832       '4.7.1': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
 833     }
 834     xen_deps = {}
 835     foreach ver: xen_tests
 836       # cache the various library tests to avoid polluting the logs
 837       xen_test_deps = []
 838       foreach l: xen_libs[ver]
 839         if l not in xen_deps
 840           xen_deps += { l: cc.find_library(l, required: false) }
 841         endif
 842         xen_test_deps += xen_deps[l]
 843       endforeach
 844
 845       # Use -D to pick just one of the test programs in scripts/xen-detect.c
 846       xen_version = ver.split('.')
 847       xen_ctrl_version = xen_version[0] + \
 848         ('0' + xen_version[1]).substring(-2) + \
 849         ('0' + xen_version[2]).substring(-2)
 850       if cc.links(files('scripts/xen-detect.c'),
 851                   args: '-DCONFIG_XEN_CTRL_INTERFACE_VERSION=' + xen_ctrl_version,
 852                   dependencies: xen_test_deps)
 853         xen = declare_dependency(version: ver, dependencies: xen_test_deps)
 854         break
 855       endif
 856     endforeach
 857   endif
 858   if xen.found()
 859     accelerators += 'CONFIG_XEN'
 860   elif get_option('xen').enabled()
 861     error('could not compile and link Xen test program')
 862   endif
 863 endif
 864 have_xen_pci_passthrough = get_option('xen_pci_passthrough') \
 865   .require(xen.found(),
 866            error_message: 'Xen PCI passthrough requested but Xen not enabled') \
 867   .require(host_os == 'linux',
 868            error_message: 'Xen PCI passthrough not available on this platform') \
 869   .require(cpu == 'x86'  or cpu == 'x86_64',
 870            error_message: 'Xen PCI passthrough not available on this platform') \
 871   .allowed()
 872
 873 ################
 874 # Dependencies #
 875 ################
 876
 877 # When bumping glib minimum version, please check also whether to increase
 878 # the _WIN32_WINNT setting in osdep.h according to the value from glib
 879 glib_req_ver = '>=2.56.0'
 880 glib_pc = dependency('glib-2.0', version: glib_req_ver, required: true,
 881                     method: 'pkg-config')
 882 glib_cflags = []
 883 if enable_modules
 884   gmodule = dependency('gmodule-export-2.0', version: glib_req_ver, required: true,
 885                        method: 'pkg-config')
 886 elif get_option('plugins')
 887   gmodule = dependency('gmodule-no-export-2.0', version: glib_req_ver, required: true,
 888                        method: 'pkg-config')
 889 else
 890   gmodule = not_found
 891 endif
 892
 893 # This workaround is required due to a bug in pkg-config file for glib as it
 894 # doesn't define GLIB_STATIC_COMPILATION for pkg-config --static
 895 if host_os == 'windows' and get_option('prefer_static')
 896   glib_cflags += ['-DGLIB_STATIC_COMPILATION']
 897 endif
 898
 899 # Sanity check that the current size_t matches the
 900 # size that glib thinks it should be. This catches
 901 # problems on multi-arch where people try to build
 902 # 32-bit QEMU while pointing at 64-bit glib headers
 903
 904 if not cc.compiles('''
 905   #include <glib.h>
 906   #include <unistd.h>
 907
 908   #define QEMU_BUILD_BUG_ON(x) \
 909   typedef char qemu_build_bug_on[(x)?-1:1] __attribute__((unused));
 910
 911   int main(void) {
 912      QEMU_BUILD_BUG_ON(sizeof(size_t) != GLIB_SIZEOF_SIZE_T);
 913      return 0;
 914   }''', dependencies: glib_pc, args: glib_cflags)
 915   error('''sizeof(size_t) doesn't match GLIB_SIZEOF_SIZE_T.
 916         You probably need to set PKG_CONFIG_LIBDIR" to point
 917         to the right pkg-config files for your build target.''')
 918 endif
 919
 920 # Silence clang warnings triggered by glib < 2.57.2
 921 if not cc.compiles('''
 922   #include <glib.h>
 923   typedef struct Foo {
 924     int i;
 925   } Foo;
 926   static void foo_free(Foo *f)
 927   {
 928     g_free(f);
 929   }
 930   G_DEFINE_AUTOPTR_CLEANUP_FUNC(Foo, foo_free)
 931   int main(void) { return 0; }''', dependencies: glib_pc, args: ['-Wunused-function', '-Werror'])
 932   glib_cflags += cc.get_supported_arguments('-Wno-unused-function')
 933 endif
 934 glib = declare_dependency(dependencies: [glib_pc, gmodule],
 935                           compile_args: glib_cflags,
 936                           version: glib_pc.version())
 937
 938 # Check whether glib has gslice, which we have to avoid for correctness.
 939 # TODO: remove this check and the corresponding workaround (qtree) when
 940 # the minimum supported glib is >= 2.75.3
 941 glib_has_gslice = glib.version().version_compare('<2.75.3')
 942
 943 # override glib dep to include the above refinements
 944 meson.override_dependency('glib-2.0', glib)
 945
 946 # The path to glib.h is added to all compilation commands.
 947 add_project_dependencies(glib.partial_dependency(compile_args: true, includes: true),
 948                          native: false, language: all_languages)
 949
 950 gio = not_found
 951 gdbus_codegen = not_found
 952 gdbus_codegen_error = '@0@ requires gdbus-codegen, please install libgio'
 953 if not get_option('gio').auto() or have_system
 954   gio = dependency('gio-2.0', required: get_option('gio'),
 955                    method: 'pkg-config')
 956   if gio.found() and not cc.links('''
 957     #include <gio/gio.h>
 958     int main(void)
 959     {
 960       g_dbus_proxy_new_sync(0, 0, 0, 0, 0, 0, 0, 0);
 961       return 0;
 962     }''', dependencies: [glib, gio])
 963     if get_option('gio').enabled()
 964       error('The installed libgio is broken for static linking')
 965     endif
 966     gio = not_found
 967   endif
 968   if gio.found()
 969     gdbus_codegen = find_program(gio.get_variable('gdbus_codegen'),
 970                                  required: get_option('gio'))
 971     gio_unix = dependency('gio-unix-2.0', required: get_option('gio'),
 972                           method: 'pkg-config')
 973     gio = declare_dependency(dependencies: [gio, gio_unix],
 974                              version: gio.version())
 975   endif
 976 endif
 977 if gdbus_codegen.found() and get_option('cfi')
 978   gdbus_codegen = not_found
 979   gdbus_codegen_error = '@0@ uses gdbus-codegen, which does not support control flow integrity'
 980 endif
 981
 982 xml_pp = find_program('scripts/xml-preprocess.py')
 983
 984 lttng = not_found
 985 if 'ust' in get_option('trace_backends')
 986   lttng = dependency('lttng-ust', required: true, version: '>= 2.1',
 987                      method: 'pkg-config')
 988 endif
 989 pixman = not_found
 990 if not get_option('pixman').auto() or have_system or have_tools
 991   pixman = dependency('pixman-1', required: get_option('pixman'), version:'>=0.21.8',
 992                       method: 'pkg-config')
 993 endif
 994
 995 zlib = dependency('zlib', required: true)
 996
 997 libaio = not_found
 998 if not get_option('linux_aio').auto() or have_block
 999   libaio = cc.find_library('aio', has_headers: ['libaio.h'],
1000                            required: get_option('linux_aio'))
1001 endif
1002
1003 linux_io_uring_test = '''
1004   #include <liburing.h>
1005   #include <linux/errqueue.h>
1006
1007   int main(void) { return 0; }'''
1008
1009 linux_io_uring = not_found
1010 if not get_option('linux_io_uring').auto() or have_block
1011   linux_io_uring = dependency('liburing', version: '>=0.3',
1012                               required: get_option('linux_io_uring'),
1013                               method: 'pkg-config')
1014   if not cc.links(linux_io_uring_test)
1015     linux_io_uring = not_found
1016   endif
1017 endif
1018
1019 libnfs = not_found
1020 if not get_option('libnfs').auto() or have_block
1021   libnfs = dependency('libnfs', version: '>=1.9.3',
1022                       required: get_option('libnfs'),
1023                       method: 'pkg-config')
1024 endif
1025
1026 libattr_test = '''
1027   #include <stddef.h>
1028   #include <sys/types.h>
1029   #ifdef CONFIG_LIBATTR
1030   #include <attr/xattr.h>
1031   #else
1032   #include <sys/xattr.h>
1033   #endif
1034   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
1035
1036 libattr = not_found
1037 have_old_libattr = false
1038 if get_option('attr').allowed()
1039   if cc.links(libattr_test)
1040     libattr = declare_dependency()
1041   else
1042     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
1043                               required: get_option('attr'))
1044     if libattr.found() and not \
1045       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
1046       libattr = not_found
1047       if get_option('attr').enabled()
1048         error('could not link libattr')
1049       else
1050         warning('could not link libattr, disabling')
1051       endif
1052     else
1053       have_old_libattr = libattr.found()
1054     endif
1055   endif
1056 endif
1057
1058 cocoa = dependency('appleframeworks', modules: ['Cocoa', 'CoreVideo'],
1059                    required: get_option('cocoa'))
1060
1061 vmnet = dependency('appleframeworks', modules: 'vmnet', required: get_option('vmnet'))
1062 if vmnet.found() and not cc.has_header_symbol('vmnet/vmnet.h',
1063                                               'VMNET_BRIDGED_MODE',
1064                                               dependencies: vmnet)
1065   vmnet = not_found
1066   if get_option('vmnet').enabled()
1067     error('vmnet.framework API is outdated')
1068   else
1069     warning('vmnet.framework API is outdated, disabling')
1070   endif
1071 endif
1072
1073 seccomp = not_found
1074 seccomp_has_sysrawrc = false
1075 if not get_option('seccomp').auto() or have_system or have_tools
1076   seccomp = dependency('libseccomp', version: '>=2.3.0',
1077                        required: get_option('seccomp'),
1078                        method: 'pkg-config')
1079   if seccomp.found()
1080     seccomp_has_sysrawrc = cc.has_header_symbol('seccomp.h',
1081                                                 'SCMP_FLTATR_API_SYSRAWRC',
1082                                                 dependencies: seccomp)
1083   endif
1084 endif
1085
1086 libcap_ng = not_found
1087 if not get_option('cap_ng').auto() or have_system or have_tools
1088   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
1089                               required: get_option('cap_ng'))
1090 endif
1091 if libcap_ng.found() and not cc.links('''
1092    #include <cap-ng.h>
1093    int main(void)
1094    {
1095      capng_capability_to_name(CAPNG_EFFECTIVE);
1096      return 0;
1097    }''', dependencies: libcap_ng)
1098   libcap_ng = not_found
1099   if get_option('cap_ng').enabled()
1100     error('could not link libcap-ng')
1101   else
1102     warning('could not link libcap-ng, disabling')
1103   endif
1104 endif
1105
1106 if get_option('xkbcommon').auto() and not have_system and not have_tools
1107   xkbcommon = not_found
1108 else
1109   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
1110                          method: 'pkg-config')
1111 endif
1112
1113 slirp = not_found
1114 if not get_option('slirp').auto() or have_system
1115   slirp = dependency('slirp', required: get_option('slirp'),
1116                      method: 'pkg-config')
1117   # slirp < 4.7 is incompatible with CFI support in QEMU.  This is because
1118   # it passes function pointers within libslirp as callbacks for timers.
1119   # When using a system-wide shared libslirp, the type information for the
1120   # callback is missing and the timer call produces a false positive with CFI.
1121   # Do not use the "version" keyword argument to produce a better error.
1122   # with control-flow integrity.
1123   if get_option('cfi') and slirp.found() and slirp.version().version_compare('<4.7')
1124     if get_option('slirp').enabled()
1125       error('Control-Flow Integrity requires libslirp 4.7.')
1126     else
1127       warning('Cannot use libslirp since Control-Flow Integrity requires libslirp >= 4.7.')
1128       slirp = not_found
1129     endif
1130   endif
1131 endif
1132
1133 vde = not_found
1134 if not get_option('vde').auto() or have_system or have_tools
1135   vde = cc.find_library('vdeplug', has_headers: ['libvdeplug.h'],
1136                            required: get_option('vde'))
1137 endif
1138 if vde.found() and not cc.links('''
1139    #include <libvdeplug.h>
1140    int main(void)
1141    {
1142      struct vde_open_args a = {0, 0, 0};
1143      char s[] = "";
1144      vde_open(s, s, &a);
1145      return 0;
1146    }''', dependencies: vde)
1147   vde = not_found
1148   if get_option('cap_ng').enabled()
1149     error('could not link libvdeplug')
1150   else
1151     warning('could not link libvdeplug, disabling')
1152   endif
1153 endif
1154
1155 pulse = not_found
1156 if not get_option('pa').auto() or (host_os == 'linux' and have_system)
1157   pulse = dependency('libpulse', required: get_option('pa'),
1158                      method: 'pkg-config')
1159 endif
1160 alsa = not_found
1161 if not get_option('alsa').auto() or (host_os == 'linux' and have_system)
1162   alsa = dependency('alsa', required: get_option('alsa'),
1163                     method: 'pkg-config')
1164 endif
1165 jack = not_found
1166 if not get_option('jack').auto() or have_system
1167   jack = dependency('jack', required: get_option('jack'),
1168                     method: 'pkg-config')
1169 endif
1170 pipewire = not_found
1171 if not get_option('pipewire').auto() or (host_os == 'linux' and have_system)
1172   pipewire = dependency('libpipewire-0.3', version: '>=0.3.60',
1173                     required: get_option('pipewire'),
1174                     method: 'pkg-config')
1175 endif
1176 sndio = not_found
1177 if not get_option('sndio').auto() or have_system
1178   sndio = dependency('sndio', required: get_option('sndio'),
1179                     method: 'pkg-config')
1180 endif
1181
1182 spice_protocol = not_found
1183 if not get_option('spice_protocol').auto() or have_system
1184   spice_protocol = dependency('spice-protocol', version: '>=0.14.0',
1185                               required: get_option('spice_protocol'),
1186                               method: 'pkg-config')
1187 endif
1188 spice = not_found
1189 if get_option('spice') \
1190              .disable_auto_if(not have_system) \
1191              .require(pixman.found(),
1192                       error_message: 'cannot enable SPICE if pixman is not available') \
1193              .allowed()
1194   spice = dependency('spice-server', version: '>=0.14.0',
1195                      required: get_option('spice'),
1196                      method: 'pkg-config')
1197 endif
1198 spice_headers = spice.partial_dependency(compile_args: true, includes: true)
1199
1200 rt = cc.find_library('rt', required: false)
1201
1202 libiscsi = not_found
1203 if not get_option('libiscsi').auto() or have_block
1204   libiscsi = dependency('libiscsi', version: '>=1.9.0',
1205                          required: get_option('libiscsi'),
1206                          method: 'pkg-config')
1207 endif
1208 zstd = not_found
1209 if not get_option('zstd').auto() or have_block
1210   zstd = dependency('libzstd', version: '>=1.4.0',
1211                     required: get_option('zstd'),
1212                     method: 'pkg-config')
1213 endif
1214 virgl = not_found
1215
1216 have_vhost_user_gpu = have_tools and host_os == 'linux' and pixman.found()
1217 if not get_option('virglrenderer').auto() or have_system or have_vhost_user_gpu
1218   virgl = dependency('virglrenderer',
1219                      method: 'pkg-config',
1220                      required: get_option('virglrenderer'))
1221 endif
1222 rutabaga = not_found
1223 if not get_option('rutabaga_gfx').auto() or have_system or have_vhost_user_gpu
1224   rutabaga = dependency('rutabaga_gfx_ffi',
1225                          method: 'pkg-config',
1226                          required: get_option('rutabaga_gfx'))
1227 endif
1228 blkio = not_found
1229 if not get_option('blkio').auto() or have_block
1230   blkio = dependency('blkio',
1231                      method: 'pkg-config',
1232                      required: get_option('blkio'))
1233 endif
1234 curl = not_found
1235 if not get_option('curl').auto() or have_block
1236   curl = dependency('libcurl', version: '>=7.29.0',
1237                     method: 'pkg-config',
1238                     required: get_option('curl'))
1239 endif
1240 libudev = not_found
1241 if host_os == 'linux' and (have_system or have_tools)
1242   libudev = dependency('libudev',
1243                        method: 'pkg-config',
1244                        required: get_option('libudev'))
1245 endif
1246
1247 mpathlibs = [libudev]
1248 mpathpersist = not_found
1249 if host_os == 'linux' and have_tools and get_option('mpath').allowed()
1250   mpath_test_source = '''
1251     #include <libudev.h>
1252     #include <mpath_persist.h>
1253     unsigned mpath_mx_alloc_len = 1024;
1254     int logsink;
1255     static struct config *multipath_conf;
1256     extern struct udev *udev;
1257     extern struct config *get_multipath_config(void);
1258     extern void put_multipath_config(struct config *conf);
1259     struct udev *udev;
1260     struct config *get_multipath_config(void) { return multipath_conf; }
1261     void put_multipath_config(struct config *conf) { }
1262     int main(void) {
1263         udev = udev_new();
1264         multipath_conf = mpath_lib_init();
1265         return 0;
1266     }'''
1267   libmpathpersist = cc.find_library('mpathpersist',
1268                                     required: get_option('mpath'))
1269   if libmpathpersist.found()
1270     mpathlibs += libmpathpersist
1271     if get_option('prefer_static')
1272       mpathlibs += cc.find_library('devmapper',
1273                                      required: get_option('mpath'))
1274     endif
1275     mpathlibs += cc.find_library('multipath',
1276                                  required: get_option('mpath'))
1277     foreach lib: mpathlibs
1278       if not lib.found()
1279         mpathlibs = []
1280         break
1281       endif
1282     endforeach
1283     if mpathlibs.length() == 0
1284       msg = 'Dependencies missing for libmpathpersist'
1285     elif cc.links(mpath_test_source, dependencies: mpathlibs)
1286       mpathpersist = declare_dependency(dependencies: mpathlibs)
1287     else
1288       msg = 'Cannot detect libmpathpersist API'
1289     endif
1290     if not mpathpersist.found()
1291       if get_option('mpath').enabled()
1292         error(msg)
1293       else
1294         warning(msg + ', disabling')
1295       endif
1296     endif
1297   endif
1298 endif
1299
1300 iconv = not_found
1301 curses = not_found
1302 if have_system and get_option('curses').allowed()
1303   curses_test = '''
1304     #if defined(__APPLE__) || defined(__OpenBSD__)
1305     #define _XOPEN_SOURCE_EXTENDED 1
1306     #endif
1307     #include <locale.h>
1308     #include <curses.h>
1309     #include <wchar.h>
1310     int main(void) {
1311       wchar_t wch = L'w';
1312       setlocale(LC_ALL, "");
1313       resize_term(0, 0);
1314       addwstr(L"wide chars\n");
1315       addnwstr(&wch, 1);
1316       add_wch(WACS_DEGREE);
1317       return 0;
1318     }'''
1319
1320   curses_dep_list = host_os == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
1321   curses = dependency(curses_dep_list,
1322                       required: false,
1323                       method: 'pkg-config')
1324   msg = get_option('curses').enabled() ? 'curses library not found' : ''
1325   curses_compile_args = ['-DNCURSES_WIDECHAR=1']
1326   if curses.found()
1327     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
1328       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses],
1329                                   version: curses.version())
1330     else
1331       msg = 'curses package not usable'
1332       curses = not_found
1333     endif
1334   endif
1335   if not curses.found()
1336     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
1337     if host_os != 'windows' and not has_curses_h
1338       message('Trying with /usr/include/ncursesw')
1339       curses_compile_args += ['-I/usr/include/ncursesw']
1340       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
1341     endif
1342     if has_curses_h
1343       curses_libname_list = (host_os == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
1344       foreach curses_libname : curses_libname_list
1345         libcurses = cc.find_library(curses_libname,
1346                                     required: false)
1347         if libcurses.found()
1348           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
1349             curses = declare_dependency(compile_args: curses_compile_args,
1350                                         dependencies: [libcurses])
1351             break
1352           else
1353             msg = 'curses library not usable'
1354           endif
1355         endif
1356       endforeach
1357     endif
1358   endif
1359   if get_option('iconv').allowed()
1360     foreach link_args : [ ['-liconv'], [] ]
1361       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
1362       # We need to use libiconv if available because mixing libiconv's headers with
1363       # the system libc does not work.
1364       # However, without adding glib to the dependencies -L/usr/local/lib will not be
1365       # included in the command line and libiconv will not be found.
1366       if cc.links('''
1367         #include <iconv.h>
1368         int main(void) {
1369           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
1370           return conv != (iconv_t) -1;
1371         }''', args: link_args, dependencies: glib)
1372         iconv = declare_dependency(link_args: link_args, dependencies: glib)
1373         break
1374       endif
1375     endforeach
1376   endif
1377   if curses.found() and not iconv.found()
1378     if get_option('iconv').enabled()
1379       error('iconv not available')
1380     endif
1381     msg = 'iconv required for curses UI but not available'
1382     curses = not_found
1383   endif
1384   if not curses.found() and msg != ''
1385     if get_option('curses').enabled()
1386       error(msg)
1387     else
1388       warning(msg + ', disabling')
1389     endif
1390   endif
1391 endif
1392
1393 brlapi = not_found
1394 if not get_option('brlapi').auto() or have_system
1395   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
1396                          required: get_option('brlapi'))
1397   if brlapi.found() and not cc.links('''
1398      #include <brlapi.h>
1399      #include <stddef.h>
1400      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
1401     brlapi = not_found
1402     if get_option('brlapi').enabled()
1403       error('could not link brlapi')
1404     else
1405       warning('could not link brlapi, disabling')
1406     endif
1407   endif
1408 endif
1409
1410 sdl = not_found
1411 if not get_option('sdl').auto() or have_system
1412   sdl = dependency('sdl2', required: get_option('sdl'))
1413   sdl_image = not_found
1414 endif
1415 if sdl.found()
1416   # Some versions of SDL have problems with -Wundef
1417   if not cc.compiles('''
1418                      #include <SDL.h>
1419                      #include <SDL_syswm.h>
1420                      int main(int argc, char *argv[]) { return 0; }
1421                      ''', dependencies: sdl, args: '-Werror=undef')
1422     sdl = declare_dependency(compile_args: '-Wno-undef',
1423                              dependencies: sdl,
1424                              version: sdl.version())
1425   endif
1426   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
1427                          method: 'pkg-config')
1428 else
1429   if get_option('sdl_image').enabled()
1430     error('sdl-image required, but SDL was @0@'.format(
1431           get_option('sdl').disabled() ? 'disabled' : 'not found'))
1432   endif
1433   sdl_image = not_found
1434 endif
1435
1436 rbd = not_found
1437 if not get_option('rbd').auto() or have_block
1438   librados = cc.find_library('rados', required: get_option('rbd'))
1439   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
1440                            required: get_option('rbd'))
1441   if librados.found() and librbd.found()
1442     if cc.links('''
1443       #include <stdio.h>
1444       #include <rbd/librbd.h>
1445       int main(void) {
1446         rados_t cluster;
1447         rados_create(&cluster, NULL);
1448         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
1449         #error
1450         #endif
1451         return 0;
1452       }''', dependencies: [librbd, librados])
1453       rbd = declare_dependency(dependencies: [librbd, librados])
1454     elif get_option('rbd').enabled()
1455       error('librbd >= 1.12.0 required')
1456     else
1457       warning('librbd >= 1.12.0 not found, disabling')
1458     endif
1459   endif
1460 endif
1461
1462 glusterfs = not_found
1463 glusterfs_ftruncate_has_stat = false
1464 glusterfs_iocb_has_stat = false
1465 if not get_option('glusterfs').auto() or have_block
1466   glusterfs = dependency('glusterfs-api', version: '>=3',
1467                          required: get_option('glusterfs'),
1468                          method: 'pkg-config')
1469   if glusterfs.found()
1470     glusterfs_ftruncate_has_stat = cc.links('''
1471       #include <glusterfs/api/glfs.h>
1472
1473       int
1474       main(void)
1475       {
1476           /* new glfs_ftruncate() passes two additional args */
1477           return glfs_ftruncate(NULL, 0, NULL, NULL);
1478       }
1479     ''', dependencies: glusterfs)
1480     glusterfs_iocb_has_stat = cc.links('''
1481       #include <glusterfs/api/glfs.h>
1482
1483       /* new glfs_io_cbk() passes two additional glfs_stat structs */
1484       static void
1485       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
1486       {}
1487
1488       int
1489       main(void)
1490       {
1491           glfs_io_cbk iocb = &glusterfs_iocb;
1492           iocb(NULL, 0 , NULL, NULL, NULL);
1493           return 0;
1494       }
1495     ''', dependencies: glusterfs)
1496   endif
1497 endif
1498
1499 hv_balloon = false
1500 if get_option('hv_balloon').allowed() and have_system
1501   if cc.links('''
1502     #include <string.h>
1503     #include <gmodule.h>
1504     int main(void) {
1505         GTree *tree;
1506
1507         tree = g_tree_new((GCompareFunc)strcmp);
1508         (void)g_tree_node_first(tree);
1509         g_tree_destroy(tree);
1510         return 0;
1511     }
1512   ''', dependencies: glib)
1513     hv_balloon = true
1514   else
1515     if get_option('hv_balloon').enabled()
1516       error('could not enable hv-balloon, update your glib')
1517     else
1518       warning('could not find glib support for hv-balloon, disabling')
1519     endif
1520   endif
1521 endif
1522
1523 libssh = not_found
1524 if not get_option('libssh').auto() or have_block
1525   libssh = dependency('libssh', version: '>=0.8.7',
1526                     method: 'pkg-config',
1527                     required: get_option('libssh'))
1528 endif
1529
1530 libbzip2 = not_found
1531 if not get_option('bzip2').auto() or have_block
1532   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
1533                              required: get_option('bzip2'))
1534   if libbzip2.found() and not cc.links('''
1535      #include <bzlib.h>
1536      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
1537     libbzip2 = not_found
1538     if get_option('bzip2').enabled()
1539       error('could not link libbzip2')
1540     else
1541       warning('could not link libbzip2, disabling')
1542     endif
1543   endif
1544 endif
1545
1546 liblzfse = not_found
1547 if not get_option('lzfse').auto() or have_block
1548   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
1549                              required: get_option('lzfse'))
1550 endif
1551 if liblzfse.found() and not cc.links('''
1552    #include <lzfse.h>
1553    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
1554   liblzfse = not_found
1555   if get_option('lzfse').enabled()
1556     error('could not link liblzfse')
1557   else
1558     warning('could not link liblzfse, disabling')
1559   endif
1560 endif
1561
1562 oss = not_found
1563 if get_option('oss').allowed() and have_system
1564   if not cc.has_header('sys/soundcard.h')
1565     # not found
1566   elif host_os == 'netbsd'
1567     oss = cc.find_library('ossaudio', required: get_option('oss'))
1568   else
1569     oss = declare_dependency()
1570   endif
1571
1572   if not oss.found()
1573     if get_option('oss').enabled()
1574       error('OSS not found')
1575     endif
1576   endif
1577 endif
1578 dsound = not_found
1579 if not get_option('dsound').auto() or (host_os == 'windows' and have_system)
1580   if cc.has_header('dsound.h')
1581     dsound = declare_dependency(link_args: ['-lole32', '-ldxguid'])
1582   endif
1583
1584   if not dsound.found()
1585     if get_option('dsound').enabled()
1586       error('DirectSound not found')
1587     endif
1588   endif
1589 endif
1590
1591 coreaudio = not_found
1592 if not get_option('coreaudio').auto() or (host_os == 'darwin' and have_system)
1593   coreaudio = dependency('appleframeworks', modules: 'CoreAudio',
1594                          required: get_option('coreaudio'))
1595 endif
1596
1597 opengl = not_found
1598 if not get_option('opengl').auto() or have_system or have_vhost_user_gpu
1599   epoxy = dependency('epoxy', method: 'pkg-config',
1600                       required: get_option('opengl'))
1601   if cc.has_header('epoxy/egl.h', dependencies: epoxy)
1602     opengl = epoxy
1603   elif get_option('opengl').enabled()
1604     error('epoxy/egl.h not found')
1605   endif
1606 endif
1607 gbm = not_found
1608 if (have_system or have_tools) and (virgl.found() or opengl.found())
1609   gbm = dependency('gbm', method: 'pkg-config', required: false)
1610 endif
1611 have_vhost_user_gpu = have_vhost_user_gpu and virgl.found() and opengl.found() and gbm.found()
1612
1613 gnutls = not_found
1614 gnutls_crypto = not_found
1615 if get_option('gnutls').enabled() or (get_option('gnutls').auto() and have_system)
1616   # For general TLS support our min gnutls matches
1617   # that implied by our platform support matrix
1618   #
1619   # For the crypto backends, we look for a newer
1620   # gnutls:
1621   #
1622   #   Version 3.6.8  is needed to get XTS
1623   #   Version 3.6.13 is needed to get PBKDF
1624   #   Version 3.6.14 is needed to get HW accelerated XTS
1625   #
1626   # If newer enough gnutls isn't available, we can
1627   # still use a different crypto backend to satisfy
1628   # the platform support requirements
1629   gnutls_crypto = dependency('gnutls', version: '>=3.6.14',
1630                              method: 'pkg-config',
1631                              required: false)
1632   if gnutls_crypto.found()
1633     gnutls = gnutls_crypto
1634   else
1635     # Our min version if all we need is TLS
1636     gnutls = dependency('gnutls', version: '>=3.5.18',
1637                         method: 'pkg-config',
1638                         required: get_option('gnutls'))
1639   endif
1640 endif
1641
1642 # We prefer use of gnutls for crypto, unless the options
1643 # explicitly asked for nettle or gcrypt.
1644 #
1645 # If gnutls isn't available for crypto, then we'll prefer
1646 # gcrypt over nettle for performance reasons.
1647 gcrypt = not_found
1648 nettle = not_found
1649 hogweed = not_found
1650 crypto_sm4 = not_found
1651 xts = 'none'
1652
1653 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
1654   error('Only one of gcrypt & nettle can be enabled')
1655 endif
1656
1657 # Explicit nettle/gcrypt request, so ignore gnutls for crypto
1658 if get_option('nettle').enabled() or get_option('gcrypt').enabled()
1659   gnutls_crypto = not_found
1660 endif
1661
1662 if not gnutls_crypto.found()
1663   if (not get_option('gcrypt').auto() or have_system) and not get_option('nettle').enabled()
1664     gcrypt = dependency('libgcrypt', version: '>=1.8',
1665                         method: 'config-tool',
1666                         required: get_option('gcrypt'))
1667     # Debian has removed -lgpg-error from libgcrypt-config
1668     # as it "spreads unnecessary dependencies" which in
1669     # turn breaks static builds...
1670     if gcrypt.found() and get_option('prefer_static')
1671       gcrypt = declare_dependency(dependencies:
1672         [gcrypt,
1673          cc.find_library('gpg-error', required: true)],
1674         version: gcrypt.version())
1675     endif
1676     crypto_sm4 = gcrypt
1677     # SM4 ALG is available in libgcrypt >= 1.9
1678     if gcrypt.found() and not cc.links('''
1679       #include <gcrypt.h>
1680       int main(void) {
1681         gcry_cipher_hd_t handler;
1682         gcry_cipher_open(&handler, GCRY_CIPHER_SM4, GCRY_CIPHER_MODE_ECB, 0);
1683         return 0;
1684       }''', dependencies: gcrypt)
1685       crypto_sm4 = not_found
1686     endif
1687   endif
1688   if (not get_option('nettle').auto() or have_system) and not gcrypt.found()
1689     nettle = dependency('nettle', version: '>=3.4',
1690                         method: 'pkg-config',
1691                         required: get_option('nettle'))
1692     if nettle.found() and not cc.has_header('nettle/xts.h', dependencies: nettle)
1693       xts = 'private'
1694     endif
1695     crypto_sm4 = nettle
1696     # SM4 ALG is available in nettle >= 3.9
1697     if nettle.found() and not cc.links('''
1698       #include <nettle/sm4.h>
1699       int main(void) {
1700         struct sm4_ctx ctx;
1701         unsigned char key[16] = {0};
1702         sm4_set_encrypt_key(&ctx, key);
1703         return 0;
1704       }''', dependencies: nettle)
1705       crypto_sm4 = not_found
1706     endif
1707   endif
1708 endif
1709
1710 capstone = not_found
1711 if not get_option('capstone').auto() or have_system or have_user
1712   capstone = dependency('capstone', version: '>=3.0.5',
1713                         method: 'pkg-config',
1714                         required: get_option('capstone'))
1715
1716   # Some versions of capstone have broken pkg-config file
1717   # that reports a wrong -I path, causing the #include to
1718   # fail later. If the system has such a broken version
1719   # do not use it.
1720   if capstone.found() and not cc.compiles('#include <capstone.h>',
1721                                           dependencies: [capstone])
1722     capstone = not_found
1723     if get_option('capstone').enabled()
1724       error('capstone requested, but it does not appear to work')
1725     endif
1726   endif
1727 endif
1728
1729 gmp = dependency('gmp', required: false, method: 'pkg-config')
1730 if nettle.found() and gmp.found()
1731   hogweed = dependency('hogweed', version: '>=3.4',
1732                        method: 'pkg-config',
1733                        required: get_option('nettle'))
1734 endif
1735
1736
1737 gtk = not_found
1738 gtkx11 = not_found
1739 vte = not_found
1740 have_gtk_clipboard = get_option('gtk_clipboard').enabled()
1741
1742 if get_option('gtk') \
1743              .disable_auto_if(not have_system) \
1744              .require(pixman.found(),
1745                       error_message: 'cannot enable GTK if pixman is not available') \
1746              .allowed()
1747   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
1748                    method: 'pkg-config',
1749                    required: get_option('gtk'))
1750   if gtk.found()
1751     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
1752                         method: 'pkg-config',
1753                         required: false)
1754     gtk = declare_dependency(dependencies: [gtk, gtkx11],
1755                              version: gtk.version())
1756
1757     if not get_option('vte').auto() or have_system
1758       vte = dependency('vte-2.91',
1759                        method: 'pkg-config',
1760                        required: get_option('vte'))
1761     endif
1762   elif have_gtk_clipboard
1763     error('GTK clipboard requested, but GTK not found')
1764   endif
1765 endif
1766
1767 x11 = not_found
1768 if gtkx11.found()
1769   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found())
1770 endif
1771 png = not_found
1772 if get_option('png').allowed() and have_system
1773    png = dependency('libpng', version: '>=1.6.34', required: get_option('png'),
1774                     method: 'pkg-config')
1775 endif
1776 vnc = not_found
1777 jpeg = not_found
1778 sasl = not_found
1779 if get_option('vnc') \
1780              .disable_auto_if(not have_system) \
1781              .require(pixman.found(),
1782                       error_message: 'cannot enable VNC if pixman is not available') \
1783              .allowed()
1784   vnc = declare_dependency() # dummy dependency
1785   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
1786                     method: 'pkg-config')
1787   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
1788                          required: get_option('vnc_sasl'))
1789   if sasl.found()
1790     sasl = declare_dependency(dependencies: sasl,
1791                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
1792   endif
1793 endif
1794
1795 pam = not_found
1796 if not get_option('auth_pam').auto() or have_system
1797   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
1798                         required: get_option('auth_pam'))
1799 endif
1800 if pam.found() and not cc.links('''
1801    #include <stddef.h>
1802    #include <security/pam_appl.h>
1803    int main(void) {
1804      const char *service_name = "qemu";
1805      const char *user = "frank";
1806      const struct pam_conv pam_conv = { 0 };
1807      pam_handle_t *pamh = NULL;
1808      pam_start(service_name, user, &pam_conv, &pamh);
1809      return 0;
1810    }''', dependencies: pam)
1811   pam = not_found
1812   if get_option('auth_pam').enabled()
1813     error('could not link libpam')
1814   else
1815     warning('could not link libpam, disabling')
1816   endif
1817 endif
1818
1819 snappy = not_found
1820 if not get_option('snappy').auto() or have_system
1821   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
1822                            required: get_option('snappy'))
1823 endif
1824 if snappy.found() and not cc.links('''
1825    #include <snappy-c.h>
1826    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
1827   snappy = not_found
1828   if get_option('snappy').enabled()
1829     error('could not link libsnappy')
1830   else
1831     warning('could not link libsnappy, disabling')
1832   endif
1833 endif
1834
1835 lzo = not_found
1836 if not get_option('lzo').auto() or have_system
1837   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
1838                         required: get_option('lzo'))
1839 endif
1840 if lzo.found() and not cc.links('''
1841    #include <lzo/lzo1x.h>
1842    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
1843   lzo = not_found
1844   if get_option('lzo').enabled()
1845     error('could not link liblzo2')
1846   else
1847     warning('could not link liblzo2, disabling')
1848   endif
1849 endif
1850
1851 numa = not_found
1852 if not get_option('numa').auto() or have_system or have_tools
1853   numa = cc.find_library('numa', has_headers: ['numa.h'],
1854                               required: get_option('numa'))
1855 endif
1856 if numa.found() and not cc.links('''
1857    #include <numa.h>
1858    int main(void) { return numa_available(); }
1859    ''', dependencies: numa)
1860   numa = not_found
1861   if get_option('numa').enabled()
1862     error('could not link numa')
1863   else
1864     warning('could not link numa, disabling')
1865   endif
1866 endif
1867
1868 rdma = not_found
1869 if not get_option('rdma').auto() or have_system
1870   libumad = cc.find_library('ibumad', required: get_option('rdma'))
1871   rdma_libs = [cc.find_library('rdmacm', has_headers: ['rdma/rdma_cma.h'],
1872                                required: get_option('rdma')),
1873                cc.find_library('ibverbs', required: get_option('rdma')),
1874                libumad]
1875   rdma = declare_dependency(dependencies: rdma_libs)
1876   foreach lib: rdma_libs
1877     if not lib.found()
1878       rdma = not_found
1879     endif
1880   endforeach
1881 endif
1882
1883 cacard = not_found
1884 if not get_option('smartcard').auto() or have_system
1885   cacard = dependency('libcacard', required: get_option('smartcard'),
1886                       version: '>=2.5.1', method: 'pkg-config')
1887 endif
1888 u2f = not_found
1889 if not get_option('u2f').auto() or have_system
1890   u2f = dependency('u2f-emu', required: get_option('u2f'),
1891                    method: 'pkg-config')
1892 endif
1893 canokey = not_found
1894 if not get_option('canokey').auto() or have_system
1895   canokey = dependency('canokey-qemu', required: get_option('canokey'),
1896                    method: 'pkg-config')
1897 endif
1898 usbredir = not_found
1899 if not get_option('usb_redir').auto() or have_system
1900   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1901                         version: '>=0.6', method: 'pkg-config')
1902 endif
1903 libusb = not_found
1904 if not get_option('libusb').auto() or have_system
1905   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1906                       version: '>=1.0.13', method: 'pkg-config')
1907 endif
1908
1909 libpmem = not_found
1910 if not get_option('libpmem').auto() or have_system
1911   libpmem = dependency('libpmem', required: get_option('libpmem'),
1912                        method: 'pkg-config')
1913 endif
1914 libdaxctl = not_found
1915 if not get_option('libdaxctl').auto() or have_system
1916   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1917                          version: '>=57', method: 'pkg-config')
1918 endif
1919 tasn1 = not_found
1920 if gnutls.found()
1921   tasn1 = dependency('libtasn1',
1922                      method: 'pkg-config')
1923 endif
1924 keyutils = not_found
1925 if not get_option('libkeyutils').auto() or have_block
1926   keyutils = dependency('libkeyutils', required: get_option('libkeyutils'),
1927                         method: 'pkg-config')
1928 endif
1929
1930 has_gettid = cc.has_function('gettid')
1931
1932 # libselinux
1933 selinux = dependency('libselinux',
1934                      required: get_option('selinux'),
1935                      method: 'pkg-config')
1936
1937 # Malloc tests
1938
1939 malloc = []
1940 if get_option('malloc') == 'system'
1941   has_malloc_trim = \
1942     get_option('malloc_trim').allowed() and \
1943     cc.has_function('malloc_trim', prefix: '#include <malloc.h>')
1944 else
1945   has_malloc_trim = false
1946   malloc = cc.find_library(get_option('malloc'), required: true)
1947 endif
1948 if not has_malloc_trim and get_option('malloc_trim').enabled()
1949   if get_option('malloc') == 'system'
1950     error('malloc_trim not available on this platform.')
1951   else
1952     error('malloc_trim not available with non-libc memory allocator')
1953   endif
1954 endif
1955
1956 gnu_source_prefix = '''
1957   #ifndef _GNU_SOURCE
1958   #define _GNU_SOURCE
1959   #endif
1960 '''
1961
1962 # Check whether the glibc provides STATX_BASIC_STATS
1963
1964 has_statx = cc.has_header_symbol('sys/stat.h', 'STATX_BASIC_STATS', prefix: gnu_source_prefix)
1965
1966 # Check whether statx() provides mount ID information
1967
1968 has_statx_mnt_id = cc.has_header_symbol('sys/stat.h', 'STATX_MNT_ID', prefix: gnu_source_prefix)
1969
1970 have_vhost_user_blk_server = get_option('vhost_user_blk_server') \
1971   .require(host_os == 'linux',
1972            error_message: 'vhost_user_blk_server requires linux') \
1973   .require(have_vhost_user,
1974            error_message: 'vhost_user_blk_server requires vhost-user support') \
1975   .disable_auto_if(not have_tools and not have_system) \
1976   .allowed()
1977
1978 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1979   error('Cannot enable fuse-lseek while fuse is disabled')
1980 endif
1981
1982 fuse = dependency('fuse3', required: get_option('fuse'),
1983                   version: '>=3.1', method: 'pkg-config')
1984
1985 fuse_lseek = not_found
1986 if get_option('fuse_lseek').allowed()
1987   if fuse.version().version_compare('>=3.8')
1988     # Dummy dependency
1989     fuse_lseek = declare_dependency()
1990   elif get_option('fuse_lseek').enabled()
1991     if fuse.found()
1992       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1993     else
1994       error('fuse-lseek requires libfuse, which was not found')
1995     endif
1996   endif
1997 endif
1998
1999 have_libvduse = (host_os == 'linux')
2000 if get_option('libvduse').enabled()
2001     if host_os != 'linux'
2002         error('libvduse requires linux')
2003     endif
2004 elif get_option('libvduse').disabled()
2005     have_libvduse = false
2006 endif
2007
2008 have_vduse_blk_export = (have_libvduse and host_os == 'linux')
2009 if get_option('vduse_blk_export').enabled()
2010     if host_os != 'linux'
2011         error('vduse_blk_export requires linux')
2012     elif not have_libvduse
2013         error('vduse_blk_export requires libvduse support')
2014     endif
2015 elif get_option('vduse_blk_export').disabled()
2016     have_vduse_blk_export = false
2017 endif
2018
2019 # libbpf
2020 bpf_version = '1.1.0'
2021 libbpf = dependency('libbpf', version: '>=' + bpf_version, required: get_option('bpf'), method: 'pkg-config')
2022 if libbpf.found() and not cc.links('''
2023    #include <bpf/libbpf.h>
2024    #include <linux/bpf.h>
2025    int main(void)
2026    {
2027      // check flag availability
2028      int flag = BPF_F_MMAPABLE;
2029      bpf_object__destroy_skeleton(NULL);
2030      return 0;
2031    }''', dependencies: libbpf)
2032   libbpf = not_found
2033   if get_option('bpf').enabled()
2034     error('libbpf skeleton/mmaping test failed')
2035   else
2036     warning('libbpf skeleton/mmaping test failed, disabling')
2037   endif
2038 endif
2039
2040 # libxdp
2041 libxdp = not_found
2042 if not get_option('af_xdp').auto() or have_system
2043     libxdp = dependency('libxdp', required: get_option('af_xdp'),
2044                         version: '>=1.4.0', method: 'pkg-config')
2045 endif
2046
2047 # libdw
2048 libdw = not_found
2049 if not get_option('libdw').auto() or \
2050         (not get_option('prefer_static') and (have_system or have_user))
2051     libdw = dependency('libdw',
2052                        method: 'pkg-config',
2053                        required: get_option('libdw'))
2054 endif
2055
2056 #################
2057 # config-host.h #
2058 #################
2059
2060 config_host_data = configuration_data()
2061
2062 audio_drivers_selected = []
2063 if have_system
2064   audio_drivers_available = {
2065     'alsa': alsa.found(),
2066     'coreaudio': coreaudio.found(),
2067     'dsound': dsound.found(),
2068     'jack': jack.found(),
2069     'oss': oss.found(),
2070     'pa': pulse.found(),
2071     'pipewire': pipewire.found(),
2072     'sdl': sdl.found(),
2073     'sndio': sndio.found(),
2074   }
2075   foreach k, v: audio_drivers_available
2076     config_host_data.set('CONFIG_AUDIO_' + k.to_upper(), v)
2077   endforeach
2078
2079   # Default to native drivers first, OSS second, SDL third
2080   audio_drivers_priority = \
2081     [ 'pa', 'coreaudio', 'dsound', 'sndio', 'oss' ] + \
2082     (host_os == 'linux' ? [] : [ 'sdl' ])
2083   audio_drivers_default = []
2084   foreach k: audio_drivers_priority
2085     if audio_drivers_available[k]
2086       audio_drivers_default += k
2087     endif
2088   endforeach
2089
2090   foreach k: get_option('audio_drv_list')
2091     if k == 'default'
2092       audio_drivers_selected += audio_drivers_default
2093     elif not audio_drivers_available[k]
2094       error('Audio driver "@0@" not available.'.format(k))
2095     else
2096       audio_drivers_selected += k
2097     endif
2098   endforeach
2099 endif
2100 config_host_data.set('CONFIG_AUDIO_DRIVERS',
2101                      '"' + '", "'.join(audio_drivers_selected) + '", ')
2102
2103 have_host_block_device = (host_os != 'darwin' or
2104     cc.has_header('IOKit/storage/IOMedia.h'))
2105
2106 dbus_display = get_option('dbus_display') \
2107   .require(gio.version().version_compare('>=2.64'),
2108            error_message: '-display dbus requires glib>=2.64') \
2109   .require(gdbus_codegen.found(),
2110            error_message: gdbus_codegen_error.format('-display dbus')) \
2111   .allowed()
2112
2113 have_virtfs = get_option('virtfs') \
2114     .require(host_os == 'linux' or host_os == 'darwin',
2115              error_message: 'virtio-9p (virtfs) requires Linux or macOS') \
2116     .require(host_os == 'linux' or cc.has_function('pthread_fchdir_np'),
2117              error_message: 'virtio-9p (virtfs) on macOS requires the presence of pthread_fchdir_np') \
2118     .require(host_os == 'darwin' or libattr.found(),
2119              error_message: 'virtio-9p (virtfs) on Linux requires libattr-devel') \
2120     .disable_auto_if(not have_tools and not have_system) \
2121     .allowed()
2122
2123 have_virtfs_proxy_helper = get_option('virtfs_proxy_helper') \
2124     .require(host_os != 'darwin', error_message: 'the virtfs proxy helper is incompatible with macOS') \
2125     .require(have_virtfs, error_message: 'the virtfs proxy helper requires that virtfs is enabled') \
2126     .disable_auto_if(not have_tools) \
2127     .require(libcap_ng.found(), error_message: 'the virtfs proxy helper requires libcap-ng') \
2128     .allowed()
2129
2130 if get_option('block_drv_ro_whitelist') == ''
2131   config_host_data.set('CONFIG_BDRV_RO_WHITELIST', '')
2132 else
2133   config_host_data.set('CONFIG_BDRV_RO_WHITELIST',
2134         '"' + get_option('block_drv_ro_whitelist').replace(',', '", "') + '", ')
2135 endif
2136 if get_option('block_drv_rw_whitelist') == ''
2137   config_host_data.set('CONFIG_BDRV_RW_WHITELIST', '')
2138 else
2139   config_host_data.set('CONFIG_BDRV_RW_WHITELIST',
2140         '"' + get_option('block_drv_rw_whitelist').replace(',', '", "') + '", ')
2141 endif
2142
2143 foreach k : get_option('trace_backends')
2144   config_host_data.set('CONFIG_TRACE_' + k.to_upper(), true)
2145 endforeach
2146 config_host_data.set_quoted('CONFIG_TRACE_FILE', get_option('trace_file'))
2147 config_host_data.set_quoted('CONFIG_TLS_PRIORITY', get_option('tls_priority'))
2148 if iasl.found()
2149   config_host_data.set_quoted('CONFIG_IASL', iasl.full_path())
2150 endif
2151 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
2152 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
2153 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
2154 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
2155 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
2156
2157 qemu_firmwarepath = ''
2158 foreach k : get_option('qemu_firmwarepath')
2159   qemu_firmwarepath += '"' + get_option('prefix') / k + '", '
2160 endforeach
2161 config_host_data.set('CONFIG_QEMU_FIRMWAREPATH', qemu_firmwarepath)
2162
2163 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
2164 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
2165 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
2166 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
2167 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
2168 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
2169
2170 if enable_modules
2171   config_host_data.set('CONFIG_STAMP', run_command(
2172       meson.current_source_dir() / 'scripts/qemu-stamp.py',
2173       meson.project_version(), get_option('pkgversion'), '--',
2174       meson.current_source_dir() / 'configure',
2175       capture: true, check: true).stdout().strip())
2176 endif
2177
2178 have_slirp_smbd = get_option('slirp_smbd') \
2179   .require(host_os != 'windows', error_message: 'Host smbd not supported on this platform.') \
2180   .allowed()
2181 if have_slirp_smbd
2182   smbd_path = get_option('smbd')
2183   if smbd_path == ''
2184     smbd_path = (host_os == 'sunos' ? '/usr/sfw/sbin/smbd' : '/usr/sbin/smbd')
2185   endif
2186   config_host_data.set_quoted('CONFIG_SMBD_COMMAND', smbd_path)
2187 endif
2188
2189 config_host_data.set('HOST_' + host_arch.to_upper(), 1)
2190
2191 kvm_targets_c = '""'
2192 if get_option('kvm').allowed() and host_os == 'linux'
2193   kvm_targets_c = '"' + '" ,"'.join(kvm_targets) + '"'
2194 endif
2195 config_host_data.set('CONFIG_KVM_TARGETS', kvm_targets_c)
2196
2197 if get_option('module_upgrades') and not enable_modules
2198   error('Cannot enable module-upgrades as modules are not enabled')
2199 endif
2200 config_host_data.set('CONFIG_MODULE_UPGRADES', get_option('module_upgrades'))
2201
2202 config_host_data.set('CONFIG_ATTR', libattr.found())
2203 config_host_data.set('CONFIG_BDRV_WHITELIST_TOOLS', get_option('block_drv_whitelist_in_tools'))
2204 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
2205 config_host_data.set('CONFIG_BSD', host_os in bsd_oses)
2206 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
2207 config_host_data.set('CONFIG_COCOA', cocoa.found())
2208 config_host_data.set('CONFIG_DARWIN', host_os == 'darwin')
2209 config_host_data.set('CONFIG_FUZZ', get_option('fuzzing'))
2210 config_host_data.set('CONFIG_GCOV', get_option('b_coverage'))
2211 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
2212 config_host_data.set('CONFIG_LINUX', host_os == 'linux')
2213 config_host_data.set('CONFIG_POSIX', host_os != 'windows')
2214 config_host_data.set('CONFIG_WIN32', host_os == 'windows')
2215 config_host_data.set('CONFIG_LZO', lzo.found())
2216 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
2217 config_host_data.set('CONFIG_BLKIO', blkio.found())
2218 if blkio.found()
2219   config_host_data.set('CONFIG_BLKIO_VHOST_VDPA_FD',
2220                        blkio.version().version_compare('>=1.3.0'))
2221 endif
2222 config_host_data.set('CONFIG_CURL', curl.found())
2223 config_host_data.set('CONFIG_CURSES', curses.found())
2224 config_host_data.set('CONFIG_GBM', gbm.found())
2225 config_host_data.set('CONFIG_GIO', gio.found())
2226 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
2227 if glusterfs.found()
2228   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
2229   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
2230   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
2231   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
2232   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
2233   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
2234 endif
2235 config_host_data.set('CONFIG_GTK', gtk.found())
2236 config_host_data.set('CONFIG_VTE', vte.found())
2237 config_host_data.set('CONFIG_GTK_CLIPBOARD', have_gtk_clipboard)
2238 config_host_data.set('CONFIG_HEXAGON_IDEF_PARSER', get_option('hexagon_idef_parser'))
2239 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
2240 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
2241 config_host_data.set('CONFIG_EBPF', libbpf.found())
2242 config_host_data.set('CONFIG_AF_XDP', libxdp.found())
2243 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
2244 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
2245 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
2246 config_host_data.set('CONFIG_LIBSSH', libssh.found())
2247 config_host_data.set('CONFIG_LINUX_AIO', libaio.found())
2248 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
2249 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
2250 config_host_data.set('CONFIG_MODULES', enable_modules)
2251 config_host_data.set('CONFIG_NUMA', numa.found())
2252 if numa.found()
2253   config_host_data.set('HAVE_NUMA_HAS_PREFERRED_MANY',
2254                        cc.has_function('numa_has_preferred_many',
2255                                        dependencies: numa))
2256 endif
2257 config_host_data.set('CONFIG_OPENGL', opengl.found())
2258 config_host_data.set('CONFIG_PLUGIN', get_option('plugins'))
2259 config_host_data.set('CONFIG_RBD', rbd.found())
2260 config_host_data.set('CONFIG_RDMA', rdma.found())
2261 config_host_data.set('CONFIG_RELOCATABLE', get_option('relocatable'))
2262 config_host_data.set('CONFIG_SAFESTACK', get_option('safe_stack'))
2263 config_host_data.set('CONFIG_SDL', sdl.found())
2264 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
2265 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
2266 if seccomp.found()
2267   config_host_data.set('CONFIG_SECCOMP_SYSRAWRC', seccomp_has_sysrawrc)
2268 endif
2269 config_host_data.set('CONFIG_PIXMAN', pixman.found())
2270 config_host_data.set('CONFIG_SLIRP', slirp.found())
2271 config_host_data.set('CONFIG_SNAPPY', snappy.found())
2272 config_host_data.set('CONFIG_SOLARIS', host_os == 'sunos')
2273 if get_option('tcg').allowed()
2274   config_host_data.set('CONFIG_TCG', 1)
2275   config_host_data.set('CONFIG_TCG_INTERPRETER', tcg_arch == 'tci')
2276 endif
2277 config_host_data.set('CONFIG_TPM', have_tpm)
2278 config_host_data.set('CONFIG_TSAN', get_option('tsan'))
2279 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
2280 config_host_data.set('CONFIG_VDE', vde.found())
2281 config_host_data.set('CONFIG_VHOST', have_vhost)
2282 config_host_data.set('CONFIG_VHOST_NET', have_vhost_net)
2283 config_host_data.set('CONFIG_VHOST_NET_USER', have_vhost_net_user)
2284 config_host_data.set('CONFIG_VHOST_NET_VDPA', have_vhost_net_vdpa)
2285 config_host_data.set('CONFIG_VHOST_KERNEL', have_vhost_kernel)
2286 config_host_data.set('CONFIG_VHOST_USER', have_vhost_user)
2287 config_host_data.set('CONFIG_VHOST_CRYPTO', have_vhost_user_crypto)
2288 config_host_data.set('CONFIG_VHOST_VDPA', have_vhost_vdpa)
2289 config_host_data.set('CONFIG_VMNET', vmnet.found())
2290 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
2291 config_host_data.set('CONFIG_VDUSE_BLK_EXPORT', have_vduse_blk_export)
2292 config_host_data.set('CONFIG_PNG', png.found())
2293 config_host_data.set('CONFIG_VNC', vnc.found())
2294 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
2295 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
2296 if virgl.found()
2297   config_host_data.set('HAVE_VIRGL_D3D_INFO_EXT',
2298                        cc.has_member('struct virgl_renderer_resource_info_ext', 'd3d_tex2d',
2299                                      prefix: '#include <virglrenderer.h>',
2300                                      dependencies: virgl))
2301 endif
2302 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
2303 config_host_data.set('CONFIG_VTE', vte.found())
2304 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
2305 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
2306 config_host_data.set('CONFIG_GETTID', has_gettid)
2307 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
2308 config_host_data.set('CONFIG_GNUTLS_CRYPTO', gnutls_crypto.found())
2309 config_host_data.set('CONFIG_TASN1', tasn1.found())
2310 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
2311 config_host_data.set('CONFIG_NETTLE', nettle.found())
2312 config_host_data.set('CONFIG_CRYPTO_SM4', crypto_sm4.found())
2313 config_host_data.set('CONFIG_HOGWEED', hogweed.found())
2314 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
2315 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
2316 config_host_data.set('CONFIG_STATX', has_statx)
2317 config_host_data.set('CONFIG_STATX_MNT_ID', has_statx_mnt_id)
2318 config_host_data.set('CONFIG_ZSTD', zstd.found())
2319 config_host_data.set('CONFIG_FUSE', fuse.found())
2320 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
2321 config_host_data.set('CONFIG_SPICE_PROTOCOL', spice_protocol.found())
2322 if spice_protocol.found()
2323 config_host_data.set('CONFIG_SPICE_PROTOCOL_MAJOR', spice_protocol.version().split('.')[0])
2324 config_host_data.set('CONFIG_SPICE_PROTOCOL_MINOR', spice_protocol.version().split('.')[1])
2325 config_host_data.set('CONFIG_SPICE_PROTOCOL_MICRO', spice_protocol.version().split('.')[2])
2326 endif
2327 config_host_data.set('CONFIG_SPICE', spice.found())
2328 config_host_data.set('CONFIG_X11', x11.found())
2329 config_host_data.set('CONFIG_DBUS_DISPLAY', dbus_display)
2330 config_host_data.set('CONFIG_CFI', get_option('cfi'))
2331 config_host_data.set('CONFIG_SELINUX', selinux.found())
2332 config_host_data.set('CONFIG_XEN_BACKEND', xen.found())
2333 config_host_data.set('CONFIG_LIBDW', libdw.found())
2334 if xen.found()
2335   # protect from xen.version() having less than three components
2336   xen_version = xen.version().split('.') + ['0', '0']
2337   xen_ctrl_version = xen_version[0] + \
2338     ('0' + xen_version[1]).substring(-2) + \
2339     ('0' + xen_version[2]).substring(-2)
2340   config_host_data.set('CONFIG_XEN_CTRL_INTERFACE_VERSION', xen_ctrl_version)
2341 endif
2342 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
2343 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
2344 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
2345 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
2346
2347 config_host_data.set_quoted('CONFIG_HOST_DSOSUF', host_dsosuf)
2348 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
2349
2350 have_coroutine_pool = get_option('coroutine_pool')
2351 if get_option('debug_stack_usage') and have_coroutine_pool
2352   message('Disabling coroutine pool to measure stack usage')
2353   have_coroutine_pool = false
2354 endif
2355 config_host_data.set('CONFIG_COROUTINE_POOL', have_coroutine_pool)
2356 config_host_data.set('CONFIG_DEBUG_GRAPH_LOCK', get_option('debug_graph_lock'))
2357 config_host_data.set('CONFIG_DEBUG_MUTEX', get_option('debug_mutex'))
2358 config_host_data.set('CONFIG_DEBUG_STACK_USAGE', get_option('debug_stack_usage'))
2359 config_host_data.set('CONFIG_DEBUG_TCG', get_option('debug_tcg'))
2360 config_host_data.set('CONFIG_LIVE_BLOCK_MIGRATION', get_option('live_block_migration').allowed())
2361 config_host_data.set('CONFIG_QOM_CAST_DEBUG', get_option('qom_cast_debug'))
2362 config_host_data.set('CONFIG_REPLICATION', get_option('replication').allowed())
2363
2364 # has_header
2365 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
2366 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
2367 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
2368 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
2369 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
2370 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
2371 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
2372 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
2373 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
2374 if host_os == 'windows'
2375   config_host_data.set('HAVE_AFUNIX_H', cc.has_header('afunix.h'))
2376 endif
2377
2378 # has_function
2379 config_host_data.set('CONFIG_CLOSE_RANGE', cc.has_function('close_range'))
2380 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
2381 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
2382 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
2383 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
2384 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
2385 config_host_data.set('CONFIG_GETCPU', cc.has_function('getcpu', prefix: gnu_source_prefix))
2386 config_host_data.set('CONFIG_SCHED_GETCPU', cc.has_function('sched_getcpu', prefix: '#include <sched.h>'))
2387 # Note that we need to specify prefix: here to avoid incorrectly
2388 # thinking that Windows has posix_memalign()
2389 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign', prefix: '#include <stdlib.h>'))
2390 config_host_data.set('CONFIG_ALIGNED_MALLOC', cc.has_function('_aligned_malloc'))
2391 config_host_data.set('CONFIG_VALLOC', cc.has_function('valloc'))
2392 config_host_data.set('CONFIG_MEMALIGN', cc.has_function('memalign'))
2393 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
2394 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
2395 config_host_data.set('CONFIG_PTHREAD_FCHDIR_NP', cc.has_function('pthread_fchdir_np'))
2396 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
2397 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
2398 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
2399 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
2400 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
2401 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
2402 config_host_data.set('HAVE_GETIFADDRS', cc.has_function('getifaddrs'))
2403 config_host_data.set('HAVE_GLIB_WITH_SLICE_ALLOCATOR', glib_has_gslice)
2404 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
2405 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
2406 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
2407 if rbd.found()
2408   config_host_data.set('HAVE_RBD_NAMESPACE_EXISTS',
2409                        cc.has_function('rbd_namespace_exists',
2410                                        dependencies: rbd,
2411                                        prefix: '#include <rbd/librbd.h>'))
2412 endif
2413 if rdma.found()
2414   config_host_data.set('HAVE_IBV_ADVISE_MR',
2415                        cc.has_function('ibv_advise_mr',
2416                                        dependencies: rdma,
2417                                        prefix: '#include <infiniband/verbs.h>'))
2418 endif
2419
2420 have_asan_fiber = false
2421 if get_option('sanitizers') and \
2422    not cc.has_function('__sanitizer_start_switch_fiber',
2423                          args: '-fsanitize=address',
2424                          prefix: '#include <sanitizer/asan_interface.h>')
2425   warning('Missing ASAN due to missing fiber annotation interface')
2426   warning('Without code annotation, the report may be inferior.')
2427 else
2428   have_asan_fiber = true
2429 endif
2430 config_host_data.set('CONFIG_ASAN_IFACE_FIBER', have_asan_fiber)
2431
2432 have_inotify_init = cc.has_header_symbol('sys/inotify.h', 'inotify_init')
2433 have_inotify_init1 = cc.has_header_symbol('sys/inotify.h', 'inotify_init1')
2434 inotify = not_found
2435 if (have_inotify_init or have_inotify_init1) and host_os == 'freebsd'
2436   # libinotify-kqueue
2437   inotify = cc.find_library('inotify')
2438   if have_inotify_init
2439     have_inotify_init = inotify.found()
2440   endif
2441   if have_inotify_init1
2442     have_inotify_init1 = inotify.found()
2443   endif
2444 endif
2445 config_host_data.set('CONFIG_INOTIFY', have_inotify_init)
2446 config_host_data.set('CONFIG_INOTIFY1', have_inotify_init1)
2447
2448 # has_header_symbol
2449 config_host_data.set('CONFIG_BLKZONED',
2450                      cc.has_header_symbol('linux/blkzoned.h', 'BLKOPENZONE'))
2451 config_host_data.set('CONFIG_EPOLL_CREATE1',
2452                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
2453 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
2454                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
2455                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
2456 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
2457                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
2458 config_host_data.set('CONFIG_FIEMAP',
2459                      cc.has_header('linux/fiemap.h') and
2460                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
2461 config_host_data.set('CONFIG_GETRANDOM',
2462                      cc.has_function('getrandom') and
2463                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
2464 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
2465                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
2466 config_host_data.set('CONFIG_RTNETLINK',
2467                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
2468 config_host_data.set('CONFIG_SYSMACROS',
2469                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
2470 config_host_data.set('HAVE_OPTRESET',
2471                      cc.has_header_symbol('getopt.h', 'optreset'))
2472 config_host_data.set('HAVE_IPPROTO_MPTCP',
2473                      cc.has_header_symbol('netinet/in.h', 'IPPROTO_MPTCP'))
2474
2475 # has_member
2476 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
2477                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
2478                                    prefix: '#include <signal.h>'))
2479 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
2480                      cc.has_member('struct stat', 'st_atim',
2481                                    prefix: '#include <sys/stat.h>'))
2482 config_host_data.set('HAVE_BLK_ZONE_REP_CAPACITY',
2483                      cc.has_member('struct blk_zone', 'capacity',
2484                                    prefix: '#include <linux/blkzoned.h>'))
2485
2486 # has_type
2487 config_host_data.set('CONFIG_IOVEC',
2488                      cc.has_type('struct iovec',
2489                                  prefix: '#include <sys/uio.h>'))
2490 config_host_data.set('HAVE_UTMPX',
2491                      cc.has_type('struct utmpx',
2492                                  prefix: '#include <utmpx.h>'))
2493
2494 config_host_data.set('CONFIG_EVENTFD', cc.links('''
2495   #include <sys/eventfd.h>
2496   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
2497 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
2498   #include <unistd.h>
2499   int main(void) {
2500   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
2501   return fdatasync(0);
2502   #else
2503   #error Not supported
2504   #endif
2505   }'''))
2506
2507 has_madvise = cc.links(gnu_source_prefix + '''
2508   #include <sys/types.h>
2509   #include <sys/mman.h>
2510   #include <stddef.h>
2511   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }''')
2512 missing_madvise_proto = false
2513 if has_madvise
2514   # Some platforms (illumos and Solaris before Solaris 11) provide madvise()
2515   # but forget to prototype it. In this case, has_madvise will be true (the
2516   # test program links despite a compile warning). To detect the
2517   # missing-prototype case, we try again with a definitely-bogus prototype.
2518   # This will only compile if the system headers don't provide the prototype;
2519   # otherwise the conflicting prototypes will cause a compiler error.
2520   missing_madvise_proto = cc.links(gnu_source_prefix + '''
2521     #include <sys/types.h>
2522     #include <sys/mman.h>
2523     #include <stddef.h>
2524     extern int madvise(int);
2525     int main(void) { return madvise(0); }''')
2526 endif
2527 config_host_data.set('CONFIG_MADVISE', has_madvise)
2528 config_host_data.set('HAVE_MADVISE_WITHOUT_PROTOTYPE', missing_madvise_proto)
2529
2530 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
2531   #include <sys/mman.h>
2532   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
2533 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
2534   #include <fcntl.h>
2535   #if !defined(AT_EMPTY_PATH)
2536   # error missing definition
2537   #else
2538   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
2539   #endif'''))
2540 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
2541   #include <sys/mman.h>
2542   #include <stddef.h>
2543   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
2544
2545 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_W_TID', cc.links(gnu_source_prefix + '''
2546   #include <pthread.h>
2547
2548   static void *f(void *p) { return NULL; }
2549   int main(void)
2550   {
2551     pthread_t thread;
2552     pthread_create(&thread, 0, f, 0);
2553     pthread_setname_np(thread, "QEMU");
2554     return 0;
2555   }''', dependencies: threads))
2556 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_WO_TID', cc.links(gnu_source_prefix + '''
2557   #include <pthread.h>
2558
2559   static void *f(void *p) { pthread_setname_np("QEMU"); return NULL; }
2560   int main(void)
2561   {
2562     pthread_t thread;
2563     pthread_create(&thread, 0, f, 0);
2564     return 0;
2565   }''', dependencies: threads))
2566 config_host_data.set('CONFIG_PTHREAD_SET_NAME_NP', cc.links(gnu_source_prefix + '''
2567   #include <pthread.h>
2568   #include <pthread_np.h>
2569
2570   static void *f(void *p) { return NULL; }
2571   int main(void)
2572   {
2573     pthread_t thread;
2574     pthread_create(&thread, 0, f, 0);
2575     pthread_set_name_np(thread, "QEMU");
2576     return 0;
2577   }''', dependencies: threads))
2578 config_host_data.set('CONFIG_PTHREAD_CONDATTR_SETCLOCK', cc.links(gnu_source_prefix + '''
2579   #include <pthread.h>
2580   #include <time.h>
2581
2582   int main(void)
2583   {
2584     pthread_condattr_t attr
2585     pthread_condattr_init(&attr);
2586     pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);
2587     return 0;
2588   }''', dependencies: threads))
2589 config_host_data.set('CONFIG_PTHREAD_AFFINITY_NP', cc.links(gnu_source_prefix + '''
2590   #include <pthread.h>
2591
2592   static void *f(void *p) { return NULL; }
2593   int main(void)
2594   {
2595     int setsize = CPU_ALLOC_SIZE(64);
2596     pthread_t thread;
2597     cpu_set_t *cpuset;
2598     pthread_create(&thread, 0, f, 0);
2599     cpuset = CPU_ALLOC(64);
2600     CPU_ZERO_S(setsize, cpuset);
2601     pthread_setaffinity_np(thread, setsize, cpuset);
2602     pthread_getaffinity_np(thread, setsize, cpuset);
2603     CPU_FREE(cpuset);
2604     return 0;
2605   }''', dependencies: threads))
2606 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
2607   #include <sys/signalfd.h>
2608   #include <stddef.h>
2609   int main(void) { return signalfd(-1, NULL, SFD_CLOEXEC); }'''))
2610 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
2611   #include <unistd.h>
2612   #include <fcntl.h>
2613   #include <limits.h>
2614
2615   int main(void)
2616   {
2617     int len, fd = 0;
2618     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
2619     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
2620     return 0;
2621   }'''))
2622
2623 config_host_data.set('HAVE_MLOCKALL', cc.links(gnu_source_prefix + '''
2624   #include <sys/mman.h>
2625   int main(void) {
2626     return mlockall(MCL_FUTURE);
2627   }'''))
2628
2629 have_l2tpv3 = false
2630 if get_option('l2tpv3').allowed() and have_system
2631   have_l2tpv3 = cc.has_type('struct mmsghdr',
2632     prefix: gnu_source_prefix + '''
2633       #include <sys/socket.h>
2634       #include <linux/ip.h>''')
2635 endif
2636 config_host_data.set('CONFIG_L2TPV3', have_l2tpv3)
2637
2638 have_netmap = false
2639 if get_option('netmap').allowed() and have_system
2640   have_netmap = cc.compiles('''
2641     #include <inttypes.h>
2642     #include <net/if.h>
2643     #include <net/netmap.h>
2644     #include <net/netmap_user.h>
2645     #if (NETMAP_API < 11) || (NETMAP_API > 15)
2646     #error
2647     #endif
2648     int main(void) { return 0; }''')
2649   if not have_netmap and get_option('netmap').enabled()
2650     error('Netmap headers not available')
2651   endif
2652 endif
2653 config_host_data.set('CONFIG_NETMAP', have_netmap)
2654
2655 # Work around a system header bug with some kernel/XFS header
2656 # versions where they both try to define 'struct fsxattr':
2657 # xfs headers will not try to redefine structs from linux headers
2658 # if this macro is set.
2659 config_host_data.set('HAVE_FSXATTR', cc.links('''
2660   #include <linux/fs.h>
2661   struct fsxattr foo;
2662   int main(void) {
2663     return 0;
2664   }'''))
2665
2666 # Some versions of Mac OS X incorrectly define SIZE_MAX
2667 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
2668     #include <stdint.h>
2669     #include <stdio.h>
2670     int main(void) {
2671         return printf("%zu", SIZE_MAX);
2672     }''', args: ['-Werror']))
2673
2674 # See if 64-bit atomic operations are supported.
2675 # Note that without __atomic builtins, we can only
2676 # assume atomic loads/stores max at pointer size.
2677 config_host_data.set('CONFIG_ATOMIC64', cc.links('''
2678   #include <stdint.h>
2679   int main(void)
2680   {
2681     uint64_t x = 0, y = 0;
2682     y = __atomic_load_n(&x, __ATOMIC_RELAXED);
2683     __atomic_store_n(&x, y, __ATOMIC_RELAXED);
2684     __atomic_compare_exchange_n(&x, &y, x, 0, __ATOMIC_RELAXED, __ATOMIC_RELAXED);
2685     __atomic_exchange_n(&x, y, __ATOMIC_RELAXED);
2686     __atomic_fetch_add(&x, y, __ATOMIC_RELAXED);
2687     return 0;
2688   }'''))
2689
2690 has_int128_type = cc.compiles('''
2691   __int128_t a;
2692   __uint128_t b;
2693   int main(void) { b = a; }''')
2694 config_host_data.set('CONFIG_INT128_TYPE', has_int128_type)
2695
2696 has_int128 = has_int128_type and cc.links('''
2697   __int128_t a;
2698   __uint128_t b;
2699   int main (void) {
2700     a = a + b;
2701     b = a * b;
2702     a = a * a;
2703     return 0;
2704   }''')
2705 config_host_data.set('CONFIG_INT128', has_int128)
2706
2707 if has_int128_type
2708   # "do we have 128-bit atomics which are handled inline and specifically not
2709   # via libatomic". The reason we can't use libatomic is documented in the
2710   # comment starting "GCC is a house divided" in include/qemu/atomic128.h.
2711   # We only care about these operations on 16-byte aligned pointers, so
2712   # force 16-byte alignment of the pointer, which may be greater than
2713   # __alignof(unsigned __int128) for the host.
2714   atomic_test_128 = '''
2715     int main(int ac, char **av) {
2716       __uint128_t *p = __builtin_assume_aligned(av[ac - 1], 16);
2717       p[1] = __atomic_load_n(&p[0], __ATOMIC_RELAXED);
2718       __atomic_store_n(&p[2], p[3], __ATOMIC_RELAXED);
2719       __atomic_compare_exchange_n(&p[4], &p[5], p[6], 0, __ATOMIC_RELAXED, __ATOMIC_RELAXED);
2720       return 0;
2721     }'''
2722   has_atomic128 = cc.links(atomic_test_128)
2723
2724   config_host_data.set('CONFIG_ATOMIC128', has_atomic128)
2725
2726   if not has_atomic128
2727     # Even with __builtin_assume_aligned, the above test may have failed
2728     # without optimization enabled.  Try again with optimizations locally
2729     # enabled for the function.  See
2730     #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=107389
2731     has_atomic128_opt = cc.links('__attribute__((optimize("O1")))' + atomic_test_128)
2732     config_host_data.set('CONFIG_ATOMIC128_OPT', has_atomic128_opt)
2733
2734     if not has_atomic128_opt
2735       config_host_data.set('CONFIG_CMPXCHG128', cc.links('''
2736         int main(void)
2737         {
2738           __uint128_t x = 0, y = 0;
2739           __sync_val_compare_and_swap_16(&x, y, x);
2740           return 0;
2741         }
2742       '''))
2743     endif
2744   endif
2745 endif
2746
2747 config_host_data.set('CONFIG_GETAUXVAL', cc.links(gnu_source_prefix + '''
2748   #include <sys/auxv.h>
2749   int main(void) {
2750     return getauxval(AT_HWCAP) == 0;
2751   }'''))
2752
2753 config_host_data.set('CONFIG_USBFS', have_linux_user and cc.compiles('''
2754   #include <linux/usbdevice_fs.h>
2755
2756   #ifndef USBDEVFS_GET_CAPABILITIES
2757   #error "USBDEVFS_GET_CAPABILITIES undefined"
2758   #endif
2759
2760   #ifndef USBDEVFS_DISCONNECT_CLAIM
2761   #error "USBDEVFS_DISCONNECT_CLAIM undefined"
2762   #endif
2763
2764   int main(void) { return 0; }'''))
2765
2766 have_keyring = get_option('keyring') \
2767   .require(host_os == 'linux', error_message: 'keyring is only available on Linux') \
2768   .require(cc.compiles('''
2769     #include <errno.h>
2770     #include <asm/unistd.h>
2771     #include <linux/keyctl.h>
2772     #include <sys/syscall.h>
2773     #include <unistd.h>
2774     int main(void) {
2775         return syscall(__NR_keyctl, KEYCTL_READ, 0, NULL, NULL, 0);
2776     }'''), error_message: 'keyctl syscall not available on this system').allowed()
2777 config_host_data.set('CONFIG_SECRET_KEYRING', have_keyring)
2778
2779 have_cpuid_h = cc.links('''
2780   #include <cpuid.h>
2781   int main(void) {
2782     unsigned a, b, c, d;
2783     unsigned max = __get_cpuid_max(0, 0);
2784
2785     if (max >= 1) {
2786         __cpuid(1, a, b, c, d);
2787     }
2788
2789     if (max >= 7) {
2790         __cpuid_count(7, 0, a, b, c, d);
2791     }
2792
2793     return 0;
2794   }''')
2795 config_host_data.set('CONFIG_CPUID_H', have_cpuid_h)
2796
2797 config_host_data.set('CONFIG_AVX2_OPT', get_option('avx2') \
2798   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX2') \
2799   .require(cc.links('''
2800     #include <cpuid.h>
2801     #include <immintrin.h>
2802     static int __attribute__((target("avx2"))) bar(void *a) {
2803       __m256i x = *(__m256i *)a;
2804       return _mm256_testz_si256(x, x);
2805     }
2806     int main(int argc, char *argv[]) { return bar(argv[argc - 1]); }
2807   '''), error_message: 'AVX2 not available').allowed())
2808
2809 config_host_data.set('CONFIG_AVX512F_OPT', get_option('avx512f') \
2810   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX512F') \
2811   .require(cc.links('''
2812     #include <cpuid.h>
2813     #include <immintrin.h>
2814     static int __attribute__((target("avx512f"))) bar(void *a) {
2815       __m512i x = *(__m512i *)a;
2816       return _mm512_test_epi64_mask(x, x);
2817     }
2818     int main(int argc, char *argv[]) { return bar(argv[argc - 1]); }
2819   '''), error_message: 'AVX512F not available').allowed())
2820
2821 config_host_data.set('CONFIG_AVX512BW_OPT', get_option('avx512bw') \
2822   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX512BW') \
2823   .require(cc.links('''
2824     #include <cpuid.h>
2825     #include <immintrin.h>
2826     static int __attribute__((target("avx512bw"))) bar(void *a) {
2827       __m512i *x = a;
2828       __m512i res= _mm512_abs_epi8(*x);
2829       return res[1];
2830     }
2831     int main(int argc, char *argv[]) { return bar(argv[0]); }
2832   '''), error_message: 'AVX512BW not available').allowed())
2833
2834 # For both AArch64 and AArch32, detect if builtins are available.
2835 config_host_data.set('CONFIG_ARM_AES_BUILTIN', cc.compiles('''
2836     #include <arm_neon.h>
2837     #ifndef __ARM_FEATURE_AES
2838     __attribute__((target("+crypto")))
2839     #endif
2840     void foo(uint8x16_t *p) { *p = vaesmcq_u8(*p); }
2841   '''))
2842
2843 have_pvrdma = get_option('pvrdma') \
2844   .require(rdma.found(), error_message: 'PVRDMA requires OpenFabrics libraries') \
2845   .require(cc.compiles(gnu_source_prefix + '''
2846     #include <sys/mman.h>
2847     int main(void)
2848     {
2849       char buf = 0;
2850       void *addr = &buf;
2851       addr = mremap(addr, 0, 1, MREMAP_MAYMOVE | MREMAP_FIXED);
2852
2853       return 0;
2854     }'''), error_message: 'PVRDMA requires mremap').allowed()
2855
2856 if have_pvrdma
2857   config_host_data.set('LEGACY_RDMA_REG_MR', not cc.links('''
2858     #include <infiniband/verbs.h>
2859     int main(void)
2860     {
2861       struct ibv_mr *mr;
2862       struct ibv_pd *pd = NULL;
2863       size_t length = 10;
2864       uint64_t iova = 0;
2865       int access = 0;
2866       void *addr = NULL;
2867
2868       mr = ibv_reg_mr_iova(pd, addr, length, iova, access);
2869       ibv_dereg_mr(mr);
2870       return 0;
2871     }'''))
2872 endif
2873
2874 if get_option('membarrier').disabled()
2875   have_membarrier = false
2876 elif host_os == 'windows'
2877   have_membarrier = true
2878 elif host_os == 'linux'
2879   have_membarrier = cc.compiles('''
2880     #include <linux/membarrier.h>
2881     #include <sys/syscall.h>
2882     #include <unistd.h>
2883     #include <stdlib.h>
2884     int main(void) {
2885         syscall(__NR_membarrier, MEMBARRIER_CMD_QUERY, 0);
2886         syscall(__NR_membarrier, MEMBARRIER_CMD_SHARED, 0);
2887         exit(0);
2888     }''')
2889 endif
2890 config_host_data.set('CONFIG_MEMBARRIER', get_option('membarrier') \
2891   .require(have_membarrier, error_message: 'membarrier system call not available') \
2892   .allowed())
2893
2894 have_afalg = get_option('crypto_afalg') \
2895   .require(cc.compiles(gnu_source_prefix + '''
2896     #include <errno.h>
2897     #include <sys/types.h>
2898     #include <sys/socket.h>
2899     #include <linux/if_alg.h>
2900     int main(void) {
2901       int sock;
2902       sock = socket(AF_ALG, SOCK_SEQPACKET, 0);
2903       return sock;
2904     }
2905   '''), error_message: 'AF_ALG requested but could not be detected').allowed()
2906 config_host_data.set('CONFIG_AF_ALG', have_afalg)
2907
2908 config_host_data.set('CONFIG_AF_VSOCK', cc.has_header_symbol(
2909   'linux/vm_sockets.h', 'AF_VSOCK',
2910   prefix: '#include <sys/socket.h>',
2911 ))
2912
2913 have_vss = false
2914 have_vss_sdk = false # old xp/2003 SDK
2915 if host_os == 'windows' and 'cpp' in all_languages
2916   have_vss = cxx.compiles('''
2917     #define __MIDL_user_allocate_free_DEFINED__
2918     #include <vss.h>
2919     int main(void) { return VSS_CTX_BACKUP; }''')
2920   have_vss_sdk = cxx.has_header('vscoordint.h')
2921 endif
2922 config_host_data.set('HAVE_VSS_SDK', have_vss_sdk)
2923
2924 # Older versions of MinGW do not import _lock_file and _unlock_file properly.
2925 # This was fixed for v6.0.0 with commit b48e3ac8969d.
2926 if host_os == 'windows'
2927   config_host_data.set('HAVE__LOCK_FILE', cc.links('''
2928     #include <stdio.h>
2929     int main(void) {
2930       _lock_file(NULL);
2931       _unlock_file(NULL);
2932       return 0;
2933     }''', name: '_lock_file and _unlock_file'))
2934 endif
2935
2936 if host_os == 'windows'
2937   mingw_has_setjmp_longjmp = cc.links('''
2938     #include <setjmp.h>
2939     int main(void) {
2940       /*
2941        * These functions are not available in setjmp header, but may be
2942        * available at link time, from libmingwex.a.
2943        */
2944       extern int __mingw_setjmp(jmp_buf);
2945       extern void __attribute__((noreturn)) __mingw_longjmp(jmp_buf, int);
2946       jmp_buf env;
2947       __mingw_setjmp(env);
2948       __mingw_longjmp(env, 0);
2949     }
2950   ''', name: 'mingw setjmp and longjmp')
2951
2952   if cpu == 'aarch64' and not mingw_has_setjmp_longjmp
2953     error('mingw must provide setjmp/longjmp for windows-arm64')
2954   endif
2955 endif
2956
2957 ########################
2958 # Target configuration #
2959 ########################
2960
2961 minikconf = find_program('scripts/minikconf.py')
2962
2963 config_all_accel = {}
2964 config_all_devices = {}
2965 config_devices_mak_list = []
2966 config_devices_h = {}
2967 config_target_h = {}
2968 config_target_mak = {}
2969
2970 disassemblers = {
2971   'alpha' : ['CONFIG_ALPHA_DIS'],
2972   'avr' : ['CONFIG_AVR_DIS'],
2973   'cris' : ['CONFIG_CRIS_DIS'],
2974   'hexagon' : ['CONFIG_HEXAGON_DIS'],
2975   'hppa' : ['CONFIG_HPPA_DIS'],
2976   'i386' : ['CONFIG_I386_DIS'],
2977   'x86_64' : ['CONFIG_I386_DIS'],
2978   'm68k' : ['CONFIG_M68K_DIS'],
2979   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
2980   'mips' : ['CONFIG_MIPS_DIS'],
2981   'nios2' : ['CONFIG_NIOS2_DIS'],
2982   'or1k' : ['CONFIG_OPENRISC_DIS'],
2983   'ppc' : ['CONFIG_PPC_DIS'],
2984   'riscv' : ['CONFIG_RISCV_DIS'],
2985   'rx' : ['CONFIG_RX_DIS'],
2986   's390' : ['CONFIG_S390_DIS'],
2987   'sh4' : ['CONFIG_SH4_DIS'],
2988   'sparc' : ['CONFIG_SPARC_DIS'],
2989   'xtensa' : ['CONFIG_XTENSA_DIS'],
2990   'loongarch' : ['CONFIG_LOONGARCH_DIS'],
2991 }
2992
2993 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
2994 host_kconfig = \
2995   (get_option('fuzzing') ? ['CONFIG_FUZZ=y'] : []) + \
2996   (have_tpm ? ['CONFIG_TPM=y'] : []) + \
2997   (pixman.found() ? ['CONFIG_PIXMAN=y'] : []) + \
2998   (spice.found() ? ['CONFIG_SPICE=y'] : []) + \
2999   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
3000   (opengl.found() ? ['CONFIG_OPENGL=y'] : []) + \
3001   (x11.found() ? ['CONFIG_X11=y'] : []) + \
3002   (have_vhost_user ? ['CONFIG_VHOST_USER=y'] : []) + \
3003   (have_vhost_vdpa ? ['CONFIG_VHOST_VDPA=y'] : []) + \
3004   (have_vhost_kernel ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
3005   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
3006   (host_os == 'linux' ? ['CONFIG_LINUX=y'] : []) + \
3007   (have_pvrdma ? ['CONFIG_PVRDMA=y'] : []) + \
3008   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : []) + \
3009   (vfio_user_server_allowed ? ['CONFIG_VFIO_USER_SERVER_ALLOWED=y'] : []) + \
3010   (hv_balloon ? ['CONFIG_HV_BALLOON_POSSIBLE=y'] : [])
3011
3012 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
3013
3014 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
3015 actual_target_dirs = []
3016 fdt_required = []
3017 foreach target : target_dirs
3018   config_target = { 'TARGET_NAME': target.split('-')[0] }
3019   if target.endswith('linux-user')
3020     if host_os != 'linux'
3021       if default_targets
3022         continue
3023       endif
3024       error('Target @0@ is only available on a Linux host'.format(target))
3025     endif
3026     config_target += { 'CONFIG_LINUX_USER': 'y' }
3027   elif target.endswith('bsd-user')
3028     if host_os not in bsd_oses
3029       if default_targets
3030         continue
3031       endif
3032       error('Target @0@ is only available on a BSD host'.format(target))
3033     endif
3034     config_target += { 'CONFIG_BSD_USER': 'y' }
3035   elif target.endswith('softmmu')
3036     config_target += { 'CONFIG_SYSTEM_ONLY': 'y' }
3037     config_target += { 'CONFIG_SOFTMMU': 'y' }
3038   endif
3039   if target.endswith('-user')
3040     config_target += {
3041       'CONFIG_USER_ONLY': 'y',
3042       'CONFIG_QEMU_INTERP_PREFIX':
3043         get_option('interp_prefix').replace('%M', config_target['TARGET_NAME'])
3044     }
3045   endif
3046
3047   accel_kconfig = []
3048   foreach sym: accelerators
3049     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
3050       config_target += { sym: 'y' }
3051       config_all_accel += { sym: 'y' }
3052       if target in modular_tcg
3053         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
3054       else
3055         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
3056       endif
3057       accel_kconfig += [ sym + '=y' ]
3058     endif
3059   endforeach
3060   if accel_kconfig.length() == 0
3061     if default_targets
3062       continue
3063     endif
3064     error('No accelerator available for target @0@'.format(target))
3065   endif
3066
3067   actual_target_dirs += target
3068   config_target += keyval.load('configs/targets' / target + '.mak')
3069   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
3070
3071   if 'TARGET_NEED_FDT' in config_target
3072     fdt_required += target
3073   endif
3074
3075   # Add default keys
3076   if 'TARGET_BASE_ARCH' not in config_target
3077     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
3078   endif
3079   if 'TARGET_ABI_DIR' not in config_target
3080     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
3081   endif
3082   if 'TARGET_BIG_ENDIAN' not in config_target
3083     config_target += {'TARGET_BIG_ENDIAN': 'n'}
3084   endif
3085
3086   foreach k, v: disassemblers
3087     if host_arch.startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
3088       foreach sym: v
3089         config_target += { sym: 'y' }
3090       endforeach
3091     endif
3092   endforeach
3093
3094   config_target_data = configuration_data()
3095   foreach k, v: config_target
3096     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
3097       # do nothing
3098     elif ignored.contains(k)
3099       # do nothing
3100     elif k == 'TARGET_BASE_ARCH'
3101       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
3102       # not used to select files from sourcesets.
3103       config_target_data.set('TARGET_' + v.to_upper(), 1)
3104     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
3105       config_target_data.set_quoted(k, v)
3106     elif v == 'y'
3107       config_target_data.set(k, 1)
3108     elif v == 'n'
3109       config_target_data.set(k, 0)
3110     else
3111       config_target_data.set(k, v)
3112     endif
3113   endforeach
3114   config_target_data.set('QEMU_ARCH',
3115                          'QEMU_ARCH_' + config_target['TARGET_BASE_ARCH'].to_upper())
3116   config_target_h += {target: configure_file(output: target + '-config-target.h',
3117                                                configuration: config_target_data)}
3118
3119   if target.endswith('-softmmu')
3120     config_input = meson.get_external_property(target, 'default')
3121     config_devices_mak = target + '-config-devices.mak'
3122     config_devices_mak = configure_file(
3123       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
3124       output: config_devices_mak,
3125       depfile: config_devices_mak + '.d',
3126       capture: true,
3127       command: [minikconf,
3128                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
3129                 config_devices_mak, '@DEPFILE@', '@INPUT@',
3130                 host_kconfig, accel_kconfig,
3131                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
3132
3133     config_devices_data = configuration_data()
3134     config_devices = keyval.load(config_devices_mak)
3135     foreach k, v: config_devices
3136       config_devices_data.set(k, 1)
3137     endforeach
3138     config_devices_mak_list += config_devices_mak
3139     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
3140                                                 configuration: config_devices_data)}
3141     config_target += config_devices
3142     config_all_devices += config_devices
3143   endif
3144   config_target_mak += {target: config_target}
3145 endforeach
3146 target_dirs = actual_target_dirs
3147
3148 target_configs_h = []
3149 foreach target: target_dirs
3150   target_configs_h += config_target_h[target]
3151   target_configs_h += config_devices_h.get(target, [])
3152 endforeach
3153 genh += custom_target('config-poison.h',
3154                       input: [target_configs_h],
3155                       output: 'config-poison.h',
3156                       capture: true,
3157                       command: [find_program('scripts/make-config-poison.sh'),
3158                                 target_configs_h])
3159
3160 ###############
3161 # Subprojects #
3162 ###############
3163
3164 libvfio_user_dep = not_found
3165 if have_system and vfio_user_server_allowed
3166   libvfio_user_proj = subproject('libvfio-user', required: true)
3167   libvfio_user_dep = libvfio_user_proj.get_variable('libvfio_user_dep')
3168 endif
3169
3170 fdt = not_found
3171 fdt_opt = get_option('fdt')
3172 if fdt_required.length() > 0 or fdt_opt == 'enabled'
3173   if fdt_opt == 'disabled'
3174     error('fdt disabled but required by targets ' + ', '.join(fdt_required))
3175   endif
3176
3177   if fdt_opt in ['enabled', 'auto', 'system']
3178     if get_option('wrap_mode') == 'nodownload'
3179       fdt_opt = 'system'
3180     endif
3181     fdt = cc.find_library('fdt', required: fdt_opt == 'system')
3182     if fdt.found() and cc.links('''
3183        #include <libfdt.h>
3184        #include <libfdt_env.h>
3185        int main(void) { fdt_find_max_phandle(NULL, NULL); return 0; }''',
3186          dependencies: fdt)
3187       fdt_opt = 'system'
3188     elif fdt_opt == 'system'
3189        error('system libfdt requested, but it is too old (1.5.1 or newer required)')
3190     else
3191       fdt_opt = 'internal'
3192       fdt = not_found
3193     endif
3194   endif
3195   if not fdt.found()
3196     assert(fdt_opt == 'internal')
3197     libfdt_proj = subproject('dtc', required: true,
3198                              default_options: ['tools=false',  'yaml=disabled',
3199                                                'python=disabled', 'default_library=static'])
3200     fdt = libfdt_proj.get_variable('libfdt_dep')
3201   endif
3202 else
3203   fdt_opt = 'disabled'
3204 endif
3205
3206 config_host_data.set('CONFIG_FDT', fdt.found())
3207
3208 vhost_user = not_found
3209 if host_os == 'linux' and have_vhost_user
3210   libvhost_user = subproject('libvhost-user')
3211   vhost_user = libvhost_user.get_variable('vhost_user_dep')
3212 endif
3213
3214 libvduse = not_found
3215 if have_libvduse
3216   libvduse_proj = subproject('libvduse')
3217   libvduse = libvduse_proj.get_variable('libvduse_dep')
3218 endif
3219
3220 #####################
3221 # Generated sources #
3222 #####################
3223
3224 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
3225
3226 hxtool = find_program('scripts/hxtool')
3227 shaderinclude = find_program('scripts/shaderinclude.py')
3228 qapi_gen = find_program('scripts/qapi-gen.py')
3229 qapi_gen_depends = [ meson.current_source_dir() / 'scripts/qapi/__init__.py',
3230                      meson.current_source_dir() / 'scripts/qapi/commands.py',
3231                      meson.current_source_dir() / 'scripts/qapi/common.py',
3232                      meson.current_source_dir() / 'scripts/qapi/error.py',
3233                      meson.current_source_dir() / 'scripts/qapi/events.py',
3234                      meson.current_source_dir() / 'scripts/qapi/expr.py',
3235                      meson.current_source_dir() / 'scripts/qapi/gen.py',
3236                      meson.current_source_dir() / 'scripts/qapi/introspect.py',
3237                      meson.current_source_dir() / 'scripts/qapi/main.py',
3238                      meson.current_source_dir() / 'scripts/qapi/parser.py',
3239                      meson.current_source_dir() / 'scripts/qapi/schema.py',
3240                      meson.current_source_dir() / 'scripts/qapi/source.py',
3241                      meson.current_source_dir() / 'scripts/qapi/types.py',
3242                      meson.current_source_dir() / 'scripts/qapi/visit.py',
3243                      meson.current_source_dir() / 'scripts/qapi-gen.py'
3244 ]
3245
3246 tracetool = [
3247   python, files('scripts/tracetool.py'),
3248    '--backend=' + ','.join(get_option('trace_backends'))
3249 ]
3250 tracetool_depends = files(
3251   'scripts/tracetool/backend/log.py',
3252   'scripts/tracetool/backend/__init__.py',
3253   'scripts/tracetool/backend/dtrace.py',
3254   'scripts/tracetool/backend/ftrace.py',
3255   'scripts/tracetool/backend/simple.py',
3256   'scripts/tracetool/backend/syslog.py',
3257   'scripts/tracetool/backend/ust.py',
3258   'scripts/tracetool/format/ust_events_c.py',
3259   'scripts/tracetool/format/ust_events_h.py',
3260   'scripts/tracetool/format/__init__.py',
3261   'scripts/tracetool/format/d.py',
3262   'scripts/tracetool/format/simpletrace_stap.py',
3263   'scripts/tracetool/format/c.py',
3264   'scripts/tracetool/format/h.py',
3265   'scripts/tracetool/format/log_stap.py',
3266   'scripts/tracetool/format/stap.py',
3267   'scripts/tracetool/__init__.py',
3268   'scripts/tracetool/vcpu.py'
3269 )
3270
3271 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
3272                     meson.current_source_dir(),
3273                     get_option('pkgversion'), meson.project_version()]
3274 qemu_version = custom_target('qemu-version.h',
3275                              output: 'qemu-version.h',
3276                              command: qemu_version_cmd,
3277                              capture: true,
3278                              build_by_default: true,
3279                              build_always_stale: true)
3280 genh += qemu_version
3281
3282 hxdep = []
3283 hx_headers = [
3284   ['qemu-options.hx', 'qemu-options.def'],
3285   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
3286 ]
3287 if have_system
3288   hx_headers += [
3289     ['hmp-commands.hx', 'hmp-commands.h'],
3290     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
3291   ]
3292 endif
3293 foreach d : hx_headers
3294   hxdep += custom_target(d[1],
3295                 input: files(d[0]),
3296                 output: d[1],
3297                 capture: true,
3298                 command: [hxtool, '-h', '@INPUT0@'])
3299 endforeach
3300 genh += hxdep
3301
3302 ###############
3303 # Trace files #
3304 ###############
3305
3306 # TODO: add each directory to the subdirs from its own meson.build, once
3307 # we have those
3308 trace_events_subdirs = [
3309   'crypto',
3310   'qapi',
3311   'qom',
3312   'monitor',
3313   'util',
3314   'gdbstub',
3315 ]
3316 if have_linux_user
3317   trace_events_subdirs += [ 'linux-user' ]
3318 endif
3319 if have_bsd_user
3320   trace_events_subdirs += [ 'bsd-user' ]
3321 endif
3322 if have_block
3323   trace_events_subdirs += [
3324     'authz',
3325     'block',
3326     'io',
3327     'nbd',
3328     'scsi',
3329   ]
3330 endif
3331 if have_system
3332   trace_events_subdirs += [
3333     'accel/kvm',
3334     'audio',
3335     'backends',
3336     'backends/tpm',
3337     'chardev',
3338     'ebpf',
3339     'hw/9pfs',
3340     'hw/acpi',
3341     'hw/adc',
3342     'hw/alpha',
3343     'hw/arm',
3344     'hw/audio',
3345     'hw/block',
3346     'hw/char',
3347     'hw/display',
3348     'hw/dma',
3349     'hw/fsi',
3350     'hw/hyperv',
3351     'hw/i2c',
3352     'hw/i386',
3353     'hw/i386/xen',
3354     'hw/i386/kvm',
3355     'hw/ide',
3356     'hw/input',
3357     'hw/intc',
3358     'hw/isa',
3359     'hw/mem',
3360     'hw/mips',
3361     'hw/misc',
3362     'hw/misc/macio',
3363     'hw/net',
3364     'hw/net/can',
3365     'hw/nubus',
3366     'hw/nvme',
3367     'hw/nvram',
3368     'hw/pci',
3369     'hw/pci-host',
3370     'hw/ppc',
3371     'hw/rdma',
3372     'hw/rdma/vmw',
3373     'hw/rtc',
3374     'hw/s390x',
3375     'hw/scsi',
3376     'hw/sd',
3377     'hw/sh4',
3378     'hw/sparc',
3379     'hw/sparc64',
3380     'hw/ssi',
3381     'hw/timer',
3382     'hw/tpm',
3383     'hw/ufs',
3384     'hw/usb',
3385     'hw/vfio',
3386     'hw/virtio',
3387     'hw/watchdog',
3388     'hw/xen',
3389     'hw/gpio',
3390     'migration',
3391     'net',
3392     'system',
3393     'ui',
3394     'hw/remote',
3395   ]
3396 endif
3397 if have_system or have_user
3398   trace_events_subdirs += [
3399     'accel/tcg',
3400     'hw/core',
3401     'target/arm',
3402     'target/arm/hvf',
3403     'target/hppa',
3404     'target/i386',
3405     'target/i386/kvm',
3406     'target/loongarch',
3407     'target/mips/tcg',
3408     'target/nios2',
3409     'target/ppc',
3410     'target/riscv',
3411     'target/s390x',
3412     'target/s390x/kvm',
3413     'target/sparc',
3414   ]
3415 endif
3416
3417 ###################
3418 # Collect sources #
3419 ###################
3420
3421 authz_ss = ss.source_set()
3422 blockdev_ss = ss.source_set()
3423 block_ss = ss.source_set()
3424 chardev_ss = ss.source_set()
3425 common_ss = ss.source_set()
3426 crypto_ss = ss.source_set()
3427 hwcore_ss = ss.source_set()
3428 io_ss = ss.source_set()
3429 qmp_ss = ss.source_set()
3430 qom_ss = ss.source_set()
3431 system_ss = ss.source_set()
3432 specific_fuzz_ss = ss.source_set()
3433 specific_ss = ss.source_set()
3434 stub_ss = ss.source_set()
3435 trace_ss = ss.source_set()
3436 user_ss = ss.source_set()
3437 util_ss = ss.source_set()
3438
3439 # accel modules
3440 qtest_module_ss = ss.source_set()
3441 tcg_module_ss = ss.source_set()
3442
3443 modules = {}
3444 target_modules = {}
3445 hw_arch = {}
3446 target_arch = {}
3447 target_system_arch = {}
3448 target_user_arch = {}
3449
3450 # NOTE: the trace/ subdirectory needs the qapi_trace_events variable
3451 # that is filled in by qapi/.
3452 subdir('qapi')
3453 subdir('qobject')
3454 subdir('stubs')
3455 subdir('trace')
3456 subdir('util')
3457 subdir('qom')
3458 subdir('authz')
3459 subdir('crypto')
3460 subdir('ui')
3461 subdir('hw')
3462 subdir('gdbstub')
3463
3464 if enable_modules
3465   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
3466   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
3467 endif
3468
3469 qom_ss = qom_ss.apply({})
3470 libqom = static_library('qom', qom_ss.sources() + genh,
3471                         dependencies: [qom_ss.dependencies()],
3472                         name_suffix: 'fa',
3473                         build_by_default: false)
3474 qom = declare_dependency(link_whole: libqom)
3475
3476 event_loop_base = files('event-loop-base.c')
3477 event_loop_base = static_library('event-loop-base',
3478                                  sources: event_loop_base + genh,
3479                                  name_suffix: 'fa',
3480                                  build_by_default: false)
3481 event_loop_base = declare_dependency(link_whole: event_loop_base,
3482                                      dependencies: [qom])
3483
3484 stub_ss = stub_ss.apply({})
3485
3486 util_ss.add_all(trace_ss)
3487 util_ss = util_ss.apply({})
3488 libqemuutil = static_library('qemuutil',
3489                              build_by_default: false,
3490                              sources: util_ss.sources() + stub_ss.sources() + genh,
3491                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
3492 qemuutil = declare_dependency(link_with: libqemuutil,
3493                               sources: genh + version_res,
3494                               dependencies: [event_loop_base])
3495
3496 if have_system or have_user
3497   decodetree = generator(find_program('scripts/decodetree.py'),
3498                          output: 'decode-@BASENAME@.c.inc',
3499                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
3500   subdir('libdecnumber')
3501   subdir('target')
3502 endif
3503
3504 subdir('audio')
3505 subdir('io')
3506 subdir('chardev')
3507 subdir('fsdev')
3508 subdir('dump')
3509
3510 if have_block
3511   block_ss.add(files(
3512     'block.c',
3513     'blockjob.c',
3514     'job.c',
3515     'qemu-io-cmds.c',
3516   ))
3517   if config_host_data.get('CONFIG_REPLICATION')
3518     block_ss.add(files('replication.c'))
3519   endif
3520
3521   subdir('nbd')
3522   subdir('scsi')
3523   subdir('block')
3524
3525   blockdev_ss.add(files(
3526     'blockdev.c',
3527     'blockdev-nbd.c',
3528     'iothread.c',
3529     'job-qmp.c',
3530   ), gnutls)
3531
3532   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
3533   # os-win32.c does not
3534   if host_os == 'windows'
3535     system_ss.add(files('os-win32.c'))
3536   else
3537     blockdev_ss.add(files('os-posix.c'))
3538   endif
3539 endif
3540
3541 common_ss.add(files('cpu-common.c'))
3542 specific_ss.add(files('cpu-target.c'))
3543
3544 subdir('system')
3545
3546 # Work around a gcc bug/misfeature wherein constant propagation looks
3547 # through an alias:
3548 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
3549 # to guess that a const variable is always zero.  Without lto, this is
3550 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
3551 # without lto, not even the alias is required -- we simply use different
3552 # declarations in different compilation units.
3553 pagevary = files('page-vary-common.c')
3554 if get_option('b_lto')
3555   pagevary_flags = ['-fno-lto']
3556   if get_option('cfi')
3557     pagevary_flags += '-fno-sanitize=cfi-icall'
3558   endif
3559   pagevary = static_library('page-vary-common', sources: pagevary + genh,
3560                             c_args: pagevary_flags)
3561   pagevary = declare_dependency(link_with: pagevary)
3562 endif
3563 common_ss.add(pagevary)
3564 specific_ss.add(files('page-vary-target.c'))
3565
3566 subdir('backends')
3567 subdir('disas')
3568 subdir('migration')
3569 subdir('monitor')
3570 subdir('net')
3571 subdir('replay')
3572 subdir('semihosting')
3573 subdir('stats')
3574 subdir('tcg')
3575 subdir('fpu')
3576 subdir('accel')
3577 subdir('plugins')
3578 subdir('ebpf')
3579
3580 common_user_inc = []
3581
3582 subdir('common-user')
3583 subdir('bsd-user')
3584 subdir('linux-user')
3585
3586 # needed for fuzzing binaries
3587 subdir('tests/qtest/libqos')
3588 subdir('tests/qtest/fuzz')
3589
3590 # accel modules
3591 tcg_real_module_ss = ss.source_set()
3592 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
3593 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
3594 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
3595                                 'tcg': tcg_real_module_ss }}
3596
3597 ##############################################
3598 # Internal static_libraries and dependencies #
3599 ##############################################
3600
3601 modinfo_collect = find_program('scripts/modinfo-collect.py')
3602 modinfo_generate = find_program('scripts/modinfo-generate.py')
3603 modinfo_files = []
3604
3605 block_mods = []
3606 system_mods = []
3607 foreach d, list : modules
3608   if not (d == 'block' ? have_block : have_system)
3609     continue
3610   endif
3611
3612   foreach m, module_ss : list
3613     if enable_modules
3614       module_ss = module_ss.apply(config_all_devices, strict: false)
3615       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
3616                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
3617       if d == 'block'
3618         block_mods += sl
3619       else
3620         system_mods += sl
3621       endif
3622       if module_ss.sources() != []
3623         # FIXME: Should use sl.extract_all_objects(recursive: true) as
3624         # input. Sources can be used multiple times but objects are
3625         # unique when it comes to lookup in compile_commands.json.
3626         # Depnds on a mesion version with
3627         # https://github.com/mesonbuild/meson/pull/8900
3628         modinfo_files += custom_target(d + '-' + m + '.modinfo',
3629                                        output: d + '-' + m + '.modinfo',
3630                                        input: module_ss.sources() + genh,
3631                                        capture: true,
3632                                        command: [modinfo_collect, module_ss.sources()])
3633       endif
3634     else
3635       if d == 'block'
3636         block_ss.add_all(module_ss)
3637       else
3638         system_ss.add_all(module_ss)
3639       endif
3640     endif
3641   endforeach
3642 endforeach
3643
3644 foreach d, list : target_modules
3645   foreach m, module_ss : list
3646     if enable_modules
3647       foreach target : target_dirs
3648         if target.endswith('-softmmu')
3649           config_target = config_target_mak[target]
3650           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3651           c_args = ['-DNEED_CPU_H',
3652                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3653                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3654           target_module_ss = module_ss.apply(config_target, strict: false)
3655           if target_module_ss.sources() != []
3656             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
3657             sl = static_library(module_name,
3658                                 [genh, target_module_ss.sources()],
3659                                 dependencies: [modulecommon, target_module_ss.dependencies()],
3660                                 include_directories: target_inc,
3661                                 c_args: c_args,
3662                                 pic: true)
3663             system_mods += sl
3664             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
3665             modinfo_files += custom_target(module_name + '.modinfo',
3666                                            output: module_name + '.modinfo',
3667                                            input: target_module_ss.sources() + genh,
3668                                            capture: true,
3669                                            command: [modinfo_collect, '--target', target, target_module_ss.sources()])
3670           endif
3671         endif
3672       endforeach
3673     else
3674       specific_ss.add_all(module_ss)
3675     endif
3676   endforeach
3677 endforeach
3678
3679 if enable_modules
3680   foreach target : target_dirs
3681     if target.endswith('-softmmu')
3682       config_target = config_target_mak[target]
3683       config_devices_mak = target + '-config-devices.mak'
3684       modinfo_src = custom_target('modinfo-' + target + '.c',
3685                                   output: 'modinfo-' + target + '.c',
3686                                   input: modinfo_files,
3687                                   command: [modinfo_generate, '--devices', config_devices_mak, '@INPUT@'],
3688                                   capture: true)
3689
3690       modinfo_lib = static_library('modinfo-' + target + '.c', modinfo_src)
3691       modinfo_dep = declare_dependency(link_with: modinfo_lib)
3692
3693       arch = config_target['TARGET_NAME'] == 'sparc64' ? 'sparc64' : config_target['TARGET_BASE_ARCH']
3694       hw_arch[arch].add(modinfo_dep)
3695     endif
3696   endforeach
3697 endif
3698
3699 nm = find_program('nm')
3700 undefsym = find_program('scripts/undefsym.py')
3701 block_syms = custom_target('block.syms', output: 'block.syms',
3702                              input: [libqemuutil, block_mods],
3703                              capture: true,
3704                              command: [undefsym, nm, '@INPUT@'])
3705 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
3706                              input: [libqemuutil, system_mods],
3707                              capture: true,
3708                              command: [undefsym, nm, '@INPUT@'])
3709
3710 authz_ss = authz_ss.apply({})
3711 libauthz = static_library('authz', authz_ss.sources() + genh,
3712                           dependencies: [authz_ss.dependencies()],
3713                           name_suffix: 'fa',
3714                           build_by_default: false)
3715
3716 authz = declare_dependency(link_whole: libauthz,
3717                            dependencies: qom)
3718
3719 crypto_ss = crypto_ss.apply({})
3720 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
3721                            dependencies: [crypto_ss.dependencies()],
3722                            name_suffix: 'fa',
3723                            build_by_default: false)
3724
3725 crypto = declare_dependency(link_whole: libcrypto,
3726                             dependencies: [authz, qom])
3727
3728 io_ss = io_ss.apply({})
3729 libio = static_library('io', io_ss.sources() + genh,
3730                        dependencies: [io_ss.dependencies()],
3731                        link_with: libqemuutil,
3732                        name_suffix: 'fa',
3733                        build_by_default: false)
3734
3735 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
3736
3737 libmigration = static_library('migration', sources: migration_files + genh,
3738                               name_suffix: 'fa',
3739                               build_by_default: false)
3740 migration = declare_dependency(link_with: libmigration,
3741                                dependencies: [zlib, qom, io])
3742 system_ss.add(migration)
3743
3744 block_ss = block_ss.apply({})
3745 libblock = static_library('block', block_ss.sources() + genh,
3746                           dependencies: block_ss.dependencies(),
3747                           link_depends: block_syms,
3748                           name_suffix: 'fa',
3749                           build_by_default: false)
3750
3751 block = declare_dependency(link_whole: [libblock],
3752                            link_args: '@block.syms',
3753                            dependencies: [crypto, io])
3754
3755 blockdev_ss = blockdev_ss.apply({})
3756 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
3757                              dependencies: blockdev_ss.dependencies(),
3758                              name_suffix: 'fa',
3759                              build_by_default: false)
3760
3761 blockdev = declare_dependency(link_whole: [libblockdev],
3762                               dependencies: [block, event_loop_base])
3763
3764 qmp_ss = qmp_ss.apply({})
3765 libqmp = static_library('qmp', qmp_ss.sources() + genh,
3766                         dependencies: qmp_ss.dependencies(),
3767                         name_suffix: 'fa',
3768                         build_by_default: false)
3769
3770 qmp = declare_dependency(link_whole: [libqmp])
3771
3772 libchardev = static_library('chardev', chardev_ss.sources() + genh,
3773                             name_suffix: 'fa',
3774                             dependencies: chardev_ss.dependencies(),
3775                             build_by_default: false)
3776
3777 chardev = declare_dependency(link_whole: libchardev)
3778
3779 hwcore_ss = hwcore_ss.apply({})
3780 libhwcore = static_library('hwcore', sources: hwcore_ss.sources() + genh,
3781                            name_suffix: 'fa',
3782                            build_by_default: false)
3783 hwcore = declare_dependency(link_whole: libhwcore)
3784 common_ss.add(hwcore)
3785
3786 ###########
3787 # Targets #
3788 ###########
3789
3790 emulator_modules = []
3791 foreach m : block_mods + system_mods
3792   emulator_modules += shared_module(m.name(),
3793                 build_by_default: true,
3794                 name_prefix: '',
3795                 link_whole: m,
3796                 install: true,
3797                 install_dir: qemu_moddir)
3798 endforeach
3799 if emulator_modules.length() > 0
3800   alias_target('modules', emulator_modules)
3801 endif
3802
3803 system_ss.add(authz, blockdev, chardev, crypto, io, qmp)
3804 common_ss.add(qom, qemuutil)
3805
3806 common_ss.add_all(when: 'CONFIG_SYSTEM_ONLY', if_true: [system_ss])
3807 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
3808
3809 # Note that this library is never used directly (only through extract_objects)
3810 # and is not built by default; therefore, source files not used by the build
3811 # configuration will be in build.ninja, but are never built by default.
3812 common_all = static_library('common',
3813                             build_by_default: false,
3814                             sources: common_ss.all_sources() + genh,
3815                             include_directories: common_user_inc,
3816                             implicit_include_directories: false,
3817                             dependencies: common_ss.all_dependencies(),
3818                             name_suffix: 'fa')
3819
3820 feature_to_c = find_program('scripts/feature_to_c.py')
3821
3822 if host_os == 'darwin'
3823   entitlement = find_program('scripts/entitlement.sh')
3824 endif
3825
3826 traceable = []
3827 emulators = {}
3828 foreach target : target_dirs
3829   config_target = config_target_mak[target]
3830   target_name = config_target['TARGET_NAME']
3831   target_base_arch = config_target['TARGET_BASE_ARCH']
3832   arch_srcs = [config_target_h[target]]
3833   arch_deps = []
3834   c_args = ['-DNEED_CPU_H',
3835             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3836             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3837   link_args = emulator_link_args
3838
3839   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3840   if host_os == 'linux'
3841     target_inc += include_directories('linux-headers', is_system: true)
3842   endif
3843   if target.endswith('-softmmu')
3844     target_type='system'
3845     t = target_system_arch[target_base_arch].apply(config_target, strict: false)
3846     arch_srcs += t.sources()
3847     arch_deps += t.dependencies()
3848
3849     hw_dir = target_name == 'sparc64' ? 'sparc64' : target_base_arch
3850     if hw_arch.has_key(hw_dir)
3851       hw = hw_arch[hw_dir].apply(config_target, strict: false)
3852       arch_srcs += hw.sources()
3853       arch_deps += hw.dependencies()
3854     endif
3855
3856     arch_srcs += config_devices_h[target]
3857     link_args += ['@block.syms', '@qemu.syms']
3858   else
3859     abi = config_target['TARGET_ABI_DIR']
3860     target_type='user'
3861     target_inc += common_user_inc
3862     if target_base_arch in target_user_arch
3863       t = target_user_arch[target_base_arch].apply(config_target, strict: false)
3864       arch_srcs += t.sources()
3865       arch_deps += t.dependencies()
3866     endif
3867     if 'CONFIG_LINUX_USER' in config_target
3868       base_dir = 'linux-user'
3869     endif
3870     if 'CONFIG_BSD_USER' in config_target
3871       base_dir = 'bsd-user'
3872       target_inc += include_directories('bsd-user/' / host_os)
3873       target_inc += include_directories('bsd-user/host/' / host_arch)
3874       dir = base_dir / abi
3875       arch_srcs += files(dir / 'signal.c', dir / 'target_arch_cpu.c')
3876     endif
3877     target_inc += include_directories(
3878       base_dir,
3879       base_dir / abi,
3880     )
3881     if 'CONFIG_LINUX_USER' in config_target
3882       dir = base_dir / abi
3883       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
3884       if config_target.has_key('TARGET_SYSTBL_ABI')
3885         arch_srcs += \
3886           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
3887                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
3888       endif
3889     endif
3890   endif
3891
3892   if 'TARGET_XML_FILES' in config_target
3893     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
3894                                 output: target + '-gdbstub-xml.c',
3895                                 input: files(config_target['TARGET_XML_FILES'].split()),
3896                                 command: [feature_to_c, '@INPUT@'],
3897                                 capture: true)
3898     arch_srcs += gdbstub_xml
3899   endif
3900
3901   t = target_arch[target_base_arch].apply(config_target, strict: false)
3902   arch_srcs += t.sources()
3903   arch_deps += t.dependencies()
3904
3905   target_common = common_ss.apply(config_target, strict: false)
3906   objects = common_all.extract_objects(target_common.sources())
3907   deps = target_common.dependencies()
3908
3909   target_specific = specific_ss.apply(config_target, strict: false)
3910   arch_srcs += target_specific.sources()
3911   arch_deps += target_specific.dependencies()
3912
3913   lib = static_library('qemu-' + target,
3914                  sources: arch_srcs + genh,
3915                  dependencies: arch_deps,
3916                  objects: objects,
3917                  include_directories: target_inc,
3918                  c_args: c_args,
3919                  build_by_default: false,
3920                  name_suffix: 'fa')
3921
3922   if target.endswith('-softmmu')
3923     execs = [{
3924       'name': 'qemu-system-' + target_name,
3925       'win_subsystem': 'console',
3926       'sources': files('system/main.c'),
3927       'dependencies': []
3928     }]
3929     if host_os == 'windows' and (sdl.found() or gtk.found())
3930       execs += [{
3931         'name': 'qemu-system-' + target_name + 'w',
3932         'win_subsystem': 'windows',
3933         'sources': files('system/main.c'),
3934         'dependencies': []
3935       }]
3936     endif
3937     if get_option('fuzzing')
3938       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
3939       execs += [{
3940         'name': 'qemu-fuzz-' + target_name,
3941         'win_subsystem': 'console',
3942         'sources': specific_fuzz.sources(),
3943         'dependencies': specific_fuzz.dependencies(),
3944       }]
3945     endif
3946   else
3947     execs = [{
3948       'name': 'qemu-' + target_name,
3949       'win_subsystem': 'console',
3950       'sources': [],
3951       'dependencies': []
3952     }]
3953   endif
3954   foreach exe: execs
3955     exe_name = exe['name']
3956     if host_os == 'darwin'
3957       exe_name += '-unsigned'
3958     endif
3959
3960     emulator = executable(exe_name, exe['sources'],
3961                install: true,
3962                c_args: c_args,
3963                dependencies: arch_deps + deps + exe['dependencies'],
3964                objects: lib.extract_all_objects(recursive: true),
3965                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
3966                link_args: link_args,
3967                win_subsystem: exe['win_subsystem'])
3968
3969     if host_os == 'darwin'
3970       icon = 'pc-bios/qemu.rsrc'
3971       build_input = [emulator, files(icon)]
3972       install_input = [
3973         get_option('bindir') / exe_name,
3974         meson.current_source_dir() / icon
3975       ]
3976       if 'CONFIG_HVF' in config_target
3977         entitlements = 'accel/hvf/entitlements.plist'
3978         build_input += files(entitlements)
3979         install_input += meson.current_source_dir() / entitlements
3980       endif
3981
3982       emulators += {exe['name'] : custom_target(exe['name'],
3983                    input: build_input,
3984                    output: exe['name'],
3985                    command: [entitlement, '@OUTPUT@', '@INPUT@'])
3986       }
3987
3988       meson.add_install_script(entitlement, '--install',
3989                                get_option('bindir') / exe['name'],
3990                                install_input)
3991     else
3992       emulators += {exe['name']: emulator}
3993     endif
3994
3995     traceable += [{
3996       'exe': exe['name'],
3997       'probe-prefix': 'qemu.' + target_type + '.' + target_name,
3998     }]
3999
4000   endforeach
4001 endforeach
4002
4003 # Other build targets
4004
4005 if get_option('plugins')
4006   install_headers('include/qemu/qemu-plugin.h')
4007   if host_os == 'windows'
4008     # On windows, we want to deliver the qemu_plugin_api.lib file in the qemu installer,
4009     # so that plugin authors can compile against it.
4010     install_data(win32_qemu_plugin_api_lib, install_dir: 'lib')
4011   endif
4012 endif
4013
4014 subdir('qga')
4015
4016 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
4017 # when we don't build tools or system
4018 if xkbcommon.found()
4019   # used for the update-keymaps target, so include rules even if !have_tools
4020   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
4021                            dependencies: [qemuutil, xkbcommon], install: have_tools)
4022 endif
4023
4024 if have_tools
4025   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
4026              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
4027   qemu_io = executable('qemu-io', files('qemu-io.c'),
4028              dependencies: [block, qemuutil], install: true)
4029   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
4030                dependencies: [blockdev, qemuutil, gnutls, selinux],
4031                install: true)
4032
4033   subdir('storage-daemon')
4034
4035   foreach exe: [ 'qemu-img', 'qemu-io', 'qemu-nbd', 'qemu-storage-daemon']
4036     traceable += [{
4037       'exe': exe,
4038       'probe-prefix': 'qemu.' + exe.substring(5).replace('-', '_')
4039     }]
4040   endforeach
4041
4042   subdir('contrib/rdmacm-mux')
4043   subdir('contrib/elf2dmp')
4044
4045   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
4046              dependencies: qemuutil,
4047              install: true)
4048
4049   if have_vhost_user
4050     subdir('contrib/vhost-user-blk')
4051     subdir('contrib/vhost-user-gpu')
4052     subdir('contrib/vhost-user-input')
4053     subdir('contrib/vhost-user-scsi')
4054   endif
4055
4056   if host_os == 'linux'
4057     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
4058                dependencies: [qemuutil, libcap_ng],
4059                install: true,
4060                install_dir: get_option('libexecdir'))
4061
4062     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
4063                dependencies: [authz, crypto, io, qom, qemuutil,
4064                               libcap_ng, mpathpersist],
4065                install: true)
4066   endif
4067
4068   if have_ivshmem
4069     subdir('contrib/ivshmem-client')
4070     subdir('contrib/ivshmem-server')
4071   endif
4072 endif
4073
4074 if stap.found()
4075   foreach t: traceable
4076     foreach stp: [
4077       {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / t['exe'], 'install': false},
4078       {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / t['exe'], 'install': true},
4079       {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
4080       {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
4081     ]
4082       cmd = [
4083         tracetool, '--group=all', '--format=' + stp['fmt'],
4084         '--binary=' + stp['bin'],
4085         '--probe-prefix=' + t['probe-prefix'],
4086         '@INPUT@', '@OUTPUT@'
4087       ]
4088
4089       custom_target(t['exe'] + stp['ext'],
4090                     input: trace_events_all,
4091                     output: t['exe'] + stp['ext'],
4092                     install: stp['install'],
4093                     install_dir: get_option('datadir') / 'systemtap/tapset',
4094                     command: cmd,
4095                     depend_files: tracetool_depends)
4096     endforeach
4097   endforeach
4098 endif
4099
4100 subdir('scripts')
4101 subdir('tools')
4102 subdir('pc-bios')
4103 subdir('docs')
4104 subdir('tests')
4105 if gtk.found()
4106   subdir('po')
4107 endif
4108
4109 if host_machine.system() == 'windows'
4110   nsis_cmd = [
4111     find_program('scripts/nsis.py'),
4112     '@OUTPUT@',
4113     get_option('prefix'),
4114     meson.current_source_dir(),
4115     glib_pc.get_variable('bindir'),
4116     host_machine.cpu(),
4117     '--',
4118     '-DDISPLAYVERSION=' + meson.project_version(),
4119   ]
4120   if build_docs
4121     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
4122   endif
4123   if gtk.found()
4124     nsis_cmd += '-DCONFIG_GTK=y'
4125   endif
4126
4127   nsis = custom_target('nsis',
4128                        output: 'qemu-setup-' + meson.project_version() + '.exe',
4129                        input: files('qemu.nsi'),
4130                        build_always_stale: true,
4131                        command: nsis_cmd + ['@INPUT@'])
4132   alias_target('installer', nsis)
4133 endif
4134
4135 #########################
4136 # Configuration summary #
4137 #########################
4138
4139 # Build environment
4140 summary_info = {}
4141 summary_info += {'Build directory':   meson.current_build_dir()}
4142 summary_info += {'Source path':       meson.current_source_dir()}
4143 summary_info += {'Download dependencies': get_option('wrap_mode') != 'nodownload'}
4144 summary(summary_info, bool_yn: true, section: 'Build environment')
4145
4146 # Directories
4147 summary_info += {'Install prefix':    get_option('prefix')}
4148 summary_info += {'BIOS directory':    qemu_datadir}
4149 pathsep = host_os == 'windows' ? ';' : ':'
4150 summary_info += {'firmware path':     pathsep.join(get_option('qemu_firmwarepath'))}
4151 summary_info += {'binary directory':  get_option('prefix') / get_option('bindir')}
4152 summary_info += {'library directory': get_option('prefix') / get_option('libdir')}
4153 summary_info += {'module directory':  qemu_moddir}
4154 summary_info += {'libexec directory': get_option('prefix') / get_option('libexecdir')}
4155 summary_info += {'include directory': get_option('prefix') / get_option('includedir')}
4156 summary_info += {'config directory':  get_option('prefix') / get_option('sysconfdir')}
4157 if host_os != 'windows'
4158   summary_info += {'local state directory': get_option('prefix') / get_option('localstatedir')}
4159   summary_info += {'Manual directory':      get_option('prefix') / get_option('mandir')}
4160 else
4161   summary_info += {'local state directory': 'queried at runtime'}
4162 endif
4163 summary_info += {'Doc directory':     get_option('prefix') / get_option('docdir')}
4164 summary(summary_info, bool_yn: true, section: 'Directories')
4165
4166 # Host binaries
4167 summary_info = {}
4168 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
4169 summary_info += {'sphinx-build':      sphinx_build}
4170
4171 # FIXME: the [binaries] section of machine files, which can be probed
4172 # with find_program(), would be great for passing gdb and genisoimage
4173 # paths from configure to Meson.  However, there seems to be no way to
4174 # hide a program (for example if gdb is too old).
4175 if config_host.has_key('GDB')
4176   summary_info += {'gdb':             config_host['GDB']}
4177 endif
4178 summary_info += {'iasl':              iasl}
4179 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
4180 if host_os == 'windows' and have_ga
4181   summary_info += {'wixl':            wixl}
4182 endif
4183 if slirp.found() and have_system
4184   summary_info += {'smbd':            have_slirp_smbd ? smbd_path : false}
4185 endif
4186 summary(summary_info, bool_yn: true, section: 'Host binaries')
4187
4188 # Configurable features
4189 summary_info = {}
4190 summary_info += {'Documentation':     build_docs}
4191 summary_info += {'system-mode emulation': have_system}
4192 summary_info += {'user-mode emulation': have_user}
4193 summary_info += {'block layer':       have_block}
4194 summary_info += {'Install blobs':     get_option('install_blobs')}
4195 summary_info += {'module support':    enable_modules}
4196 if enable_modules
4197   summary_info += {'alternative module path': get_option('module_upgrades')}
4198 endif
4199 summary_info += {'fuzzing support':   get_option('fuzzing')}
4200 if have_system
4201   summary_info += {'Audio drivers':     ' '.join(audio_drivers_selected)}
4202 endif
4203 summary_info += {'Trace backends':    ','.join(get_option('trace_backends'))}
4204 if 'simple' in get_option('trace_backends')
4205   summary_info += {'Trace output file': get_option('trace_file') + '-<pid>'}
4206 endif
4207 summary_info += {'D-Bus display':     dbus_display}
4208 summary_info += {'QOM debugging':     get_option('qom_cast_debug')}
4209 summary_info += {'Relocatable install': get_option('relocatable')}
4210 summary_info += {'vhost-kernel support': have_vhost_kernel}
4211 summary_info += {'vhost-net support': have_vhost_net}
4212 summary_info += {'vhost-user support': have_vhost_user}
4213 summary_info += {'vhost-user-crypto support': have_vhost_user_crypto}
4214 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
4215 summary_info += {'vhost-vdpa support': have_vhost_vdpa}
4216 summary_info += {'build guest agent': have_ga}
4217 summary(summary_info, bool_yn: true, section: 'Configurable features')
4218
4219 # Compilation information
4220 summary_info = {}
4221 summary_info += {'host CPU':          cpu}
4222 summary_info += {'host endianness':   build_machine.endian()}
4223 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
4224 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
4225 if 'cpp' in all_languages
4226   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
4227 else
4228   summary_info += {'C++ compiler':      false}
4229 endif
4230 if 'objc' in all_languages
4231   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
4232 else
4233   summary_info += {'Objective-C compiler': false}
4234 endif
4235 option_cflags = (get_option('debug') ? ['-g'] : [])
4236 if get_option('optimization') != 'plain'
4237   option_cflags += ['-O' + get_option('optimization')]
4238 endif
4239 summary_info += {'CFLAGS':            ' '.join(get_option('c_args') + option_cflags)}
4240 if 'cpp' in all_languages
4241   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args') + option_cflags)}
4242 endif
4243 if 'objc' in all_languages
4244   summary_info += {'OBJCFLAGS':       ' '.join(get_option('objc_args') + option_cflags)}
4245 endif
4246 link_args = get_option('c_link_args')
4247 if link_args.length() > 0
4248   summary_info += {'LDFLAGS':         ' '.join(link_args)}
4249 endif
4250 summary_info += {'QEMU_CFLAGS':       ' '.join(qemu_common_flags + qemu_cflags)}
4251 if 'cpp' in all_languages
4252   summary_info += {'QEMU_CXXFLAGS':     ' '.join(qemu_common_flags + qemu_cxxflags)}
4253 endif
4254 if 'objc' in all_languages
4255   summary_info += {'QEMU_OBJCFLAGS':    ' '.join(qemu_common_flags)}
4256 endif
4257 summary_info += {'QEMU_LDFLAGS':      ' '.join(qemu_ldflags)}
4258 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
4259 summary_info += {'PIE':               get_option('b_pie')}
4260 summary_info += {'static build':      get_option('prefer_static')}
4261 summary_info += {'malloc trim support': has_malloc_trim}
4262 summary_info += {'membarrier':        have_membarrier}
4263 summary_info += {'debug graph lock':  get_option('debug_graph_lock')}
4264 summary_info += {'debug stack usage': get_option('debug_stack_usage')}
4265 summary_info += {'mutex debugging':   get_option('debug_mutex')}
4266 summary_info += {'memory allocator':  get_option('malloc')}
4267 summary_info += {'avx2 optimization': config_host_data.get('CONFIG_AVX2_OPT')}
4268 summary_info += {'avx512bw optimization': config_host_data.get('CONFIG_AVX512BW_OPT')}
4269 summary_info += {'avx512f optimization': config_host_data.get('CONFIG_AVX512F_OPT')}
4270 summary_info += {'gcov':              get_option('b_coverage')}
4271 summary_info += {'thread sanitizer':  get_option('tsan')}
4272 summary_info += {'CFI support':       get_option('cfi')}
4273 if get_option('cfi')
4274   summary_info += {'CFI debug support': get_option('cfi_debug')}
4275 endif
4276 summary_info += {'strip binaries':    get_option('strip')}
4277 summary_info += {'sparse':            sparse}
4278 summary_info += {'mingw32 support':   host_os == 'windows'}
4279 summary(summary_info, bool_yn: true, section: 'Compilation')
4280
4281 # snarf the cross-compilation information for tests
4282 summary_info = {}
4283 have_cross = false
4284 foreach target: target_dirs
4285   tcg_mak = meson.current_build_dir() / 'tests/tcg' / target / 'config-target.mak'
4286   if fs.exists(tcg_mak)
4287     config_cross_tcg = keyval.load(tcg_mak)
4288     if 'CC' in config_cross_tcg
4289       summary_info += {config_cross_tcg['TARGET_NAME']: config_cross_tcg['CC']}
4290       have_cross = true
4291     endif
4292   endif
4293 endforeach
4294 if have_cross
4295   summary(summary_info, bool_yn: true, section: 'Cross compilers')
4296 endif
4297
4298 # Targets and accelerators
4299 summary_info = {}
4300 if have_system
4301   summary_info += {'KVM support':       config_all_accel.has_key('CONFIG_KVM')}
4302   summary_info += {'HVF support':       config_all_accel.has_key('CONFIG_HVF')}
4303   summary_info += {'WHPX support':      config_all_accel.has_key('CONFIG_WHPX')}
4304   summary_info += {'NVMM support':      config_all_accel.has_key('CONFIG_NVMM')}
4305   summary_info += {'Xen support':       xen.found()}
4306   if xen.found()
4307     summary_info += {'xen ctrl version':  xen.version()}
4308   endif
4309   summary_info += {'Xen emulation':     config_all_devices.has_key('CONFIG_XEN_EMU')}
4310 endif
4311 summary_info += {'TCG support':       config_all_accel.has_key('CONFIG_TCG')}
4312 if config_all_accel.has_key('CONFIG_TCG')
4313   if get_option('tcg_interpreter')
4314     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, slow)'}
4315   else
4316     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
4317   endif
4318   summary_info += {'TCG plugins':       get_option('plugins')}
4319   summary_info += {'TCG debug enabled': get_option('debug_tcg')}
4320 endif
4321 summary_info += {'target list':       ' '.join(target_dirs)}
4322 if have_system
4323   summary_info += {'default devices':   get_option('default_devices')}
4324   summary_info += {'out of process emulation': multiprocess_allowed}
4325   summary_info += {'vfio-user server': vfio_user_server_allowed}
4326 endif
4327 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
4328
4329 # Block layer
4330 summary_info = {}
4331 summary_info += {'coroutine backend': coroutine_backend}
4332 summary_info += {'coroutine pool':    have_coroutine_pool}
4333 if have_block
4334   summary_info += {'Block whitelist (rw)': get_option('block_drv_rw_whitelist')}
4335   summary_info += {'Block whitelist (ro)': get_option('block_drv_ro_whitelist')}
4336   summary_info += {'Use block whitelist in tools': get_option('block_drv_whitelist_in_tools')}
4337   summary_info += {'VirtFS (9P) support':    have_virtfs}
4338   summary_info += {'VirtFS (9P) Proxy Helper support (deprecated)': have_virtfs_proxy_helper}
4339   summary_info += {'Live block migration': config_host_data.get('CONFIG_LIVE_BLOCK_MIGRATION')}
4340   summary_info += {'replication support': config_host_data.get('CONFIG_REPLICATION')}
4341   summary_info += {'bochs support':     get_option('bochs').allowed()}
4342   summary_info += {'cloop support':     get_option('cloop').allowed()}
4343   summary_info += {'dmg support':       get_option('dmg').allowed()}
4344   summary_info += {'qcow v1 support':   get_option('qcow1').allowed()}
4345   summary_info += {'vdi support':       get_option('vdi').allowed()}
4346   summary_info += {'vhdx support':      get_option('vhdx').allowed()}
4347   summary_info += {'vmdk support':      get_option('vmdk').allowed()}
4348   summary_info += {'vpc support':       get_option('vpc').allowed()}
4349   summary_info += {'vvfat support':     get_option('vvfat').allowed()}
4350   summary_info += {'qed support':       get_option('qed').allowed()}
4351   summary_info += {'parallels support': get_option('parallels').allowed()}
4352   summary_info += {'FUSE exports':      fuse}
4353   summary_info += {'VDUSE block exports': have_vduse_blk_export}
4354 endif
4355 summary(summary_info, bool_yn: true, section: 'Block layer support')
4356
4357 # Crypto
4358 summary_info = {}
4359 summary_info += {'TLS priority':      get_option('tls_priority')}
4360 summary_info += {'GNUTLS support':    gnutls}
4361 if gnutls.found()
4362   summary_info += {'  GNUTLS crypto':   gnutls_crypto.found()}
4363 endif
4364 summary_info += {'libgcrypt':         gcrypt}
4365 summary_info += {'nettle':            nettle}
4366 if nettle.found()
4367    summary_info += {'  XTS':             xts != 'private'}
4368 endif
4369 summary_info += {'SM4 ALG support':   crypto_sm4}
4370 summary_info += {'AF_ALG support':    have_afalg}
4371 summary_info += {'rng-none':          get_option('rng_none')}
4372 summary_info += {'Linux keyring':     have_keyring}
4373 summary_info += {'Linux keyutils':    keyutils}
4374 summary(summary_info, bool_yn: true, section: 'Crypto')
4375
4376 # UI
4377 summary_info = {}
4378 if host_os == 'darwin'
4379   summary_info += {'Cocoa support':           cocoa}
4380 endif
4381 summary_info += {'SDL support':       sdl}
4382 summary_info += {'SDL image support': sdl_image}
4383 summary_info += {'GTK support':       gtk}
4384 summary_info += {'pixman':            pixman}
4385 summary_info += {'VTE support':       vte}
4386 summary_info += {'PNG support':       png}
4387 summary_info += {'VNC support':       vnc}
4388 if vnc.found()
4389   summary_info += {'VNC SASL support':  sasl}
4390   summary_info += {'VNC JPEG support':  jpeg}
4391 endif
4392 summary_info += {'spice protocol support': spice_protocol}
4393 if spice_protocol.found()
4394   summary_info += {'  spice server support': spice}
4395 endif
4396 summary_info += {'curses support':    curses}
4397 summary_info += {'brlapi support':    brlapi}
4398 summary(summary_info, bool_yn: true, section: 'User interface')
4399
4400 # Graphics backends
4401 summary_info = {}
4402 summary_info += {'VirGL support':     virgl}
4403 summary_info += {'Rutabaga support':  rutabaga}
4404 summary(summary_info, bool_yn: true, section: 'Graphics backends')
4405
4406 # Audio backends
4407 summary_info = {}
4408 if host_os not in ['darwin', 'haiku', 'windows']
4409   summary_info += {'OSS support':     oss}
4410   summary_info += {'sndio support':   sndio}
4411 elif host_os == 'darwin'
4412   summary_info += {'CoreAudio support': coreaudio}
4413 elif host_os == 'windows'
4414   summary_info += {'DirectSound support': dsound}
4415 endif
4416 if host_os == 'linux'
4417   summary_info += {'ALSA support':    alsa}
4418   summary_info += {'PulseAudio support': pulse}
4419 endif
4420 summary_info += {'PipeWire support':  pipewire}
4421 summary_info += {'JACK support':      jack}
4422 summary(summary_info, bool_yn: true, section: 'Audio backends')
4423
4424 # Network backends
4425 summary_info = {}
4426 if host_os == 'darwin'
4427   summary_info += {'vmnet.framework support': vmnet}
4428 endif
4429 summary_info += {'AF_XDP support':    libxdp}
4430 summary_info += {'slirp support':     slirp}
4431 summary_info += {'vde support':       vde}
4432 summary_info += {'netmap support':    have_netmap}
4433 summary_info += {'l2tpv3 support':    have_l2tpv3}
4434 summary(summary_info, bool_yn: true, section: 'Network backends')
4435
4436 # Libraries
4437 summary_info = {}
4438 summary_info += {'libtasn1':          tasn1}
4439 summary_info += {'PAM':               pam}
4440 summary_info += {'iconv support':     iconv}
4441 summary_info += {'blkio support':     blkio}
4442 summary_info += {'curl support':      curl}
4443 summary_info += {'Multipath support': mpathpersist}
4444 summary_info += {'Linux AIO support': libaio}
4445 summary_info += {'Linux io_uring support': linux_io_uring}
4446 summary_info += {'ATTR/XATTR support': libattr}
4447 summary_info += {'RDMA support':      rdma}
4448 summary_info += {'PVRDMA support':    have_pvrdma}
4449 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
4450 summary_info += {'libcap-ng support': libcap_ng}
4451 summary_info += {'bpf support':       libbpf}
4452 summary_info += {'rbd support':       rbd}
4453 summary_info += {'smartcard support': cacard}
4454 summary_info += {'U2F support':       u2f}
4455 summary_info += {'libusb':            libusb}
4456 summary_info += {'usb net redir':     usbredir}
4457 summary_info += {'OpenGL support (epoxy)': opengl}
4458 summary_info += {'GBM':               gbm}
4459 summary_info += {'libiscsi support':  libiscsi}
4460 summary_info += {'libnfs support':    libnfs}
4461 if host_os == 'windows'
4462   if have_ga
4463     summary_info += {'QGA VSS support':   have_qga_vss}
4464   endif
4465 endif
4466 summary_info += {'seccomp support':   seccomp}
4467 summary_info += {'GlusterFS support': glusterfs}
4468 summary_info += {'hv-balloon support': hv_balloon}
4469 summary_info += {'TPM support':       have_tpm}
4470 summary_info += {'libssh support':    libssh}
4471 summary_info += {'lzo support':       lzo}
4472 summary_info += {'snappy support':    snappy}
4473 summary_info += {'bzip2 support':     libbzip2}
4474 summary_info += {'lzfse support':     liblzfse}
4475 summary_info += {'zstd support':      zstd}
4476 summary_info += {'NUMA host support': numa}
4477 summary_info += {'capstone':          capstone}
4478 summary_info += {'libpmem support':   libpmem}
4479 summary_info += {'libdaxctl support': libdaxctl}
4480 summary_info += {'libudev':           libudev}
4481 # Dummy dependency, keep .found()
4482 summary_info += {'FUSE lseek':        fuse_lseek.found()}
4483 summary_info += {'selinux':           selinux}
4484 summary_info += {'libdw':             libdw}
4485 if host_os == 'freebsd'
4486   summary_info += {'libinotify-kqueue': inotify}
4487 endif
4488 summary(summary_info, bool_yn: true, section: 'Dependencies')
4489
4490 if host_arch == 'unknown'
4491   message()
4492   warning('UNSUPPORTED HOST CPU')
4493   message()
4494   message('Support for CPU host architecture ' + cpu + ' is not currently')
4495   message('maintained. The QEMU project does not guarantee that QEMU will')
4496   message('compile or work on this host CPU. You can help by volunteering')
4497   message('to maintain it and providing a build host for our continuous')
4498   message('integration setup.')
4499   if get_option('tcg').allowed() and target_dirs.length() > 0
4500     message()
4501     message('configure has succeeded and you can continue to build, but')
4502     message('QEMU will use a slow interpreter to emulate the target CPU.')
4503   endif
4504 endif
4505
4506 if not supported_oses.contains(host_os)
4507   message()
4508   warning('UNSUPPORTED HOST OS')
4509   message()
4510   message('Support for host OS ' + host_os + 'is not currently maintained.')
4511   message('configure has succeeded and you can continue to build, but')
4512   message('the QEMU project does not guarantee that QEMU will compile or')
4513   message('work on this operating system. You can help by volunteering')
4514   message('to maintain it and providing a build host for our continuous')
4515   message('integration setup. This will ensure that future versions of QEMU')
4516   message('will keep working on ' + host_os + '.')
4517 endif
4518
4519 if host_arch == 'unknown' or not supported_oses.contains(host_os)
4520   message()
4521   message('If you want to help supporting QEMU on this platform, please')
4522   message('contact the developers at qemu-devel@nongnu.org.')
4523 endif
4524
4525 actually_reloc = get_option('relocatable')
4526 # check if get_relocated_path() is actually able to relocate paths
4527 if get_option('relocatable') and \
4528   not (get_option('prefix') / get_option('bindir')).startswith(get_option('prefix') / '')
4529   message()
4530   warning('bindir not included within prefix, the installation will not be relocatable.')
4531   actually_reloc = false
4532 endif
4533 if not actually_reloc and (host_os == 'windows' or get_option('relocatable'))
4534   if host_os == 'windows'
4535     message()
4536     warning('Windows installs should usually be relocatable.')
4537   endif
4538   message()
4539   message('QEMU will have to be installed under ' + get_option('prefix') + '.')
4540   message('Use --disable-relocatable to remove this warning.')
4541 endif