block/meson.build

   1 block_ss.add(genh)
   2 block_ss.add(files(
   3   'accounting.c',
   4   'aio_task.c',
   5   'amend.c',
   6   'backup.c',
   7   'backup-top.c',
   8   'blkdebug.c',
   9   'blklogwrites.c',
  10   'blkreplay.c',
  11   'blkverify.c',
  12   'block-backend.c',
  13   'block-copy.c',
  14   'commit.c',
  15   'copy-on-read.c',
  16   'create.c',
  17   'crypto.c',
  18   'dirty-bitmap.c',
  19   'filter-compress.c',
  20   'io.c',
  21   'mirror.c',
  22   'nbd.c',
  23   'null.c',
  24   'qapi.c',
  25   'qcow2-bitmap.c',
  26   'qcow2-cache.c',
  27   'qcow2-cluster.c',
  28   'qcow2-refcount.c',
  29   'qcow2-snapshot.c',
  30   'qcow2-threads.c',
  31   'qcow2.c',
  32   'quorum.c',
  33   'raw-format.c',
  34   'snapshot.c',
  35   'throttle-groups.c',
  36   'throttle.c',
  37   'vhdx-endian.c',
  38   'vhdx-log.c',
  39   'vhdx.c',
  40   'vmdk.c',
  41   'vpc.c',
  42   'write-threshold.c',
  43 ), zstd, zlib)
  44
  45 block_ss.add(when: 'CONFIG_QCOW1', if_true: files('qcow.c'))
  46 block_ss.add(when: 'CONFIG_VDI', if_true: files('vdi.c'))
  47 block_ss.add(when: 'CONFIG_CLOOP', if_true: files('cloop.c'))
  48 block_ss.add(when: 'CONFIG_BOCHS', if_true: files('bochs.c'))
  49 block_ss.add(when: 'CONFIG_VVFAT', if_true: files('vvfat.c'))
  50 block_ss.add(when: 'CONFIG_DMG', if_true: files('dmg.c'))
  51 block_ss.add(when: 'CONFIG_QED', if_true: files(
  52   'qed-check.c',
  53   'qed-cluster.c',
  54   'qed-l2-cache.c',
  55   'qed-table.c',
  56   'qed.c',
  57 ))
  58 block_ss.add(when: [libxml2, 'CONFIG_PARALLELS'], if_true: files('parallels.c'))
  59 block_ss.add(when: 'CONFIG_WIN32', if_true: files('file-win32.c', 'win32-aio.c'))
  60 block_ss.add(when: 'CONFIG_POSIX', if_true: [files('file-posix.c'), coref, iokit])
  61 block_ss.add(when: 'CONFIG_LIBISCSI', if_true: files('iscsi-opts.c'))
  62 block_ss.add(when: 'CONFIG_LINUX', if_true: files('nvme.c'))
  63 block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
  64 block_ss.add(when: 'CONFIG_SHEEPDOG', if_true: files('sheepdog.c'))
  65 block_ss.add(when: ['CONFIG_LINUX_AIO', libaio], if_true: files('linux-aio.c'))
  66 block_ss.add(when: ['CONFIG_LINUX_IO_URING', linux_io_uring], if_true: files('io_uring.c'))
  67
  68 block_modules = {}
  69
  70 modsrc = []
  71 foreach m : [
  72   ['CONFIG_CURL', 'curl', [curl, glib], 'curl.c'],
  73   ['CONFIG_GLUSTERFS', 'gluster', glusterfs, 'gluster.c'],
  74   ['CONFIG_LIBISCSI', 'iscsi', libiscsi, 'iscsi.c'],
  75   ['CONFIG_LIBNFS', 'nfs', libnfs, 'nfs.c'],
  76   ['CONFIG_LIBSSH', 'ssh', libssh, 'ssh.c'],
  77   ['CONFIG_RBD', 'rbd', rbd, 'rbd.c'],
  78 ]
  79   if config_host.has_key(m[0])
  80     if enable_modules
  81       modsrc += files(m[3])
  82     endif
  83     module_ss = ss.source_set()
  84     module_ss.add(when: m[2], if_true: files(m[3]))
  85     block_modules += {m[1] : module_ss}
  86   endif
  87 endforeach
  88
  89 # those are not exactly regular block modules, so treat them apart
  90 if 'CONFIG_DMG' in config_host
  91   foreach m : [
  92     ['CONFIG_LZFSE', 'dmg-lzfse', liblzfse, 'dmg-lzfse.c'],
  93     ['CONFIG_BZIP2', 'dmg-bz2', [glib, libbzip2], 'dmg-bz2.c']
  94   ]
  95     if config_host.has_key(m[0])
  96       module_ss = ss.source_set()
  97       module_ss.add(when: m[2], if_true: files(m[3]))
  98       block_modules += {m[1] : module_ss}
  99     endif
 100   endforeach
 101 endif
 102
 103 module_block_py = find_program('../scripts/modules/module_block.py')
 104 module_block_h = custom_target('module_block.h',
 105                                output: 'module_block.h',
 106                                input: modsrc,
 107                                command: [module_block_py, '@OUTPUT0@', modsrc])
 108 block_ss.add(module_block_h)
 109
 110 block_ss.add(files('stream.c'))
 111
 112 softmmu_ss.add(files('qapi-sysemu.c'))
 113 subdir('monitor')
 114
 115 modules += {'block': block_modules}