tests/qtest/meson.build

   1 # All QTests for now are POSIX-only, but the dependencies are
   2 # really in libqtest, not in the testcases themselves.
   3 if not config_host.has_key('CONFIG_POSIX')
   4   subdir_done()
   5 endif
   6
   7 slow_qtests = {
   8   'ahci-test' : 60,
   9   'bios-tables-test' : 120,
  10   'boot-serial-test' : 60,
  11   'migration-test' : 150,
  12   'npcm7xx_pwm-test': 150,
  13   'prom-env-test' : 60,
  14   'pxe-test' : 60,
  15   'qos-test' : 60,
  16   'qom-test' : 300,
  17   'test-hmp' : 120,
  18 }
  19
  20 qtests_generic = \
  21   (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) + \
  22   (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) + \
  23   [
  24   'cdrom-test',
  25   'device-introspect-test',
  26   'machine-none-test',
  27   'qmp-test',
  28   'qmp-cmd-test',
  29   'qom-test',
  30   'test-hmp',
  31   'qos-test',
  32 ]
  33 if config_host.has_key('CONFIG_MODULES')
  34   qtests_generic += [ 'modules-test' ]
  35 endif
  36 if slirp.found()
  37   qtests_generic += [ 'test-query-netdev' ]
  38 endif
  39
  40 qtests_pci = \
  41   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  42   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  43
  44 qtests_i386 = \
  45   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +             \
  46   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                     \
  47   (have_tools ? ['ahci-test'] : []) +                                                       \
  48   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  49   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  50   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['test-filter-redirector'] : []) +    \
  51   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  52   (config_host.has_key('CONFIG_LINUX') and                                                  \
  53    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') ? ['ipmi-bt-test'] : []) +              \
  54   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  55   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  56   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  57   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  58   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  59   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  60   (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
  61   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  62   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  63    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  64   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  65   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  66   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  67   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  68   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  69   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  70   (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
  71   qtests_pci +                                                                              \
  72   ['fdc-test',
  73    'ide-test',
  74    'hd-geo-test',
  75    'boot-order-test',
  76    'bios-tables-test',
  77    'rtc-test',
  78    'i440fx-test',
  79    'fw_cfg-test',
  80    'device-plug-test',
  81    'drive_del-test',
  82    'tco-test',
  83    'cpu-plug-test',
  84    'q35-test',
  85    'vmgenid-test',
  86    'migration-test',
  87    'test-x86-cpuid-compat',
  88    'numa-test']
  89
  90 dbus_daemon = find_program('dbus-daemon', required: false)
  91 if dbus_daemon.found() and config_host.has_key('GDBUS_CODEGEN')
  92   # Temporarily disabled due to Patchew failures:
  93   #qtests_i386 += ['dbus-vmstate-test']
  94   dbus_vmstate1 = custom_target('dbus-vmstate description',
  95                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
  96                                 input: files('dbus-vmstate1.xml'),
  97                                 command: [config_host['GDBUS_CODEGEN'],
  98                                           '@INPUT@',
  99                                           '--interface-prefix', 'org.qemu',
 100                                           '--generate-c-code', '@BASENAME@']).to_list()
 101 else
 102   dbus_vmstate1 = []
 103 endif
 104
 105 qtests_x86_64 = qtests_i386
 106
 107 qtests_alpha = [ 'boot-serial-test' ] +                                                      \
 108   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 109
 110 qtests_avr = [ 'boot-serial-test' ]
 111
 112 qtests_hppa = [ 'boot-serial-test' ] +                                                       \
 113   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 114
 115 qtests_m68k = [ 'boot-serial-test' ]
 116 qtests_microblaze = [ 'boot-serial-test' ]
 117 qtests_microblazeel = qtests_microblaze
 118
 119 qtests_mips = \
 120   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 121   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 122
 123 qtests_mips64 = \
 124   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 125   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 126
 127 qtests_mips64el = \
 128   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 129   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 130
 131 qtests_moxie = [ 'boot-serial-test' ]
 132
 133 qtests_ppc = \
 134   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 135   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 136   ['boot-order-test', 'prom-env-test', 'boot-serial-test']                 \
 137
 138 qtests_ppc64 = \
 139   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 140   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 141   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 142   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +              \
 143   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 144   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 145   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                      \
 146   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 147
 148 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 149 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 150
 151 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test']
 152
 153 qtests_sparc64 = \
 154   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 155   ['prom-env-test', 'boot-serial-test']
 156
 157 qtests_npcm7xx = \
 158   ['npcm7xx_adc-test',
 159    'npcm7xx_gpio-test',
 160    'npcm7xx_pwm-test',
 161    'npcm7xx_rng-test',
 162    'npcm7xx_smbus-test',
 163    'npcm7xx_timer-test',
 164    'npcm7xx_watchdog_timer-test'] + \
 165    (slirp.found() ? ['npcm7xx_emc-test'] : [])
 166 qtests_arm = \
 167   (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
 168   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 169   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 170   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 171   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') ? ['pflash-cfi02-test'] : []) +         \
 172   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 173   ['arm-cpu-features',
 174    'microbit-test',
 175    'm25p80-test',
 176    'test-arm-mptimer',
 177    'boot-serial-test',
 178    'hexloader-test']
 179
 180 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 181 qtests_aarch64 = \
 182   (cpu != 'arm' ? ['bios-tables-test'] : []) +                                                  \
 183   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-test'] : []) +        \
 184   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-swtpm-test'] : []) +  \
 185   ['arm-cpu-features',
 186    'numa-test',
 187    'boot-serial-test',
 188    'xlnx-can-test',
 189    'migration-test']
 190
 191 qtests_s390x = \
 192   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +                 \
 193   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                         \
 194   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : []) +                     \
 195   ['boot-serial-test',
 196    'drive_del-test',
 197    'device-plug-test',
 198    'virtio-ccw-test',
 199    'cpu-plug-test',
 200    'migration-test']
 201
 202 qos_test_ss = ss.source_set()
 203 qos_test_ss.add(
 204   'ac97-test.c',
 205   'ds1338-test.c',
 206   'e1000-test.c',
 207   'e1000e-test.c',
 208   'eepro100-test.c',
 209   'es1370-test.c',
 210   'ipoctal232-test.c',
 211   'megasas-test.c',
 212   'ne2000-test.c',
 213   'tulip-test.c',
 214   'nvme-test.c',
 215   'pca9552-test.c',
 216   'pci-test.c',
 217   'pcnet-test.c',
 218   'sdhci-test.c',
 219   'spapr-phb-test.c',
 220   'tmp105-test.c',
 221   'emc141x-test.c',
 222   'usb-hcd-ohci-test.c',
 223   'virtio-test.c',
 224   'virtio-blk-test.c',
 225   'virtio-net-test.c',
 226   'virtio-rng-test.c',
 227   'virtio-scsi-test.c',
 228   'virtio-serial-test.c',
 229   'vmxnet3-test.c',
 230 )
 231 if have_virtfs
 232   qos_test_ss.add(files('virtio-9p-test.c'))
 233 endif
 234 qos_test_ss.add(when: 'CONFIG_VHOST_USER', if_true: files('vhost-user-test.c'))
 235
 236 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 237
 238 qtests = {
 239   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 240   'cdrom-test': files('boot-sector.c'),
 241   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 242   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 243   'migration-test': files('migration-helpers.c'),
 244   'pxe-test': files('boot-sector.c'),
 245   'qos-test': [chardev, io, qos_test_ss.apply(config_host, strict: false).sources()],
 246   'tpm-crb-swtpm-test': [io, tpmemu_files],
 247   'tpm-crb-test': [io, tpmemu_files],
 248   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 249   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 250   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 251   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 252   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 253 }
 254
 255 qtest_executables = {}
 256 foreach dir : target_dirs
 257   if not dir.endswith('-softmmu')
 258     continue
 259   endif
 260
 261   target_base = dir.split('-')[0]
 262   qtest_emulator = emulators['qemu-system-' + target_base]
 263   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 264
 265   test_deps = []
 266   qtest_env = environment()
 267   if have_tools
 268     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 269     test_deps += [qemu_img]
 270   endif
 271   qtest_env.set('G_TEST_DBUS_DAEMON', meson.source_root() / 'tests/dbus-vmstate-daemon.sh')
 272   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 273
 274   foreach test : target_qtests
 275     # Executables are shared across targets, declare them only the first time we
 276     # encounter them
 277     if not qtest_executables.has_key(test)
 278       src = [test + '.c']
 279       deps = [qemuutil, qos]
 280       if test in qtests
 281         # use a sourceset to quickly separate sources and deps
 282         test_ss = ss.source_set()
 283         test_ss.add(qtests[test])
 284         src += test_ss.all_sources()
 285         deps += test_ss.all_dependencies()
 286       endif
 287       qtest_executables += {
 288         test: executable(test, src, dependencies: deps)
 289       }
 290     endif
 291     # FIXME: missing dependency on the emulator binary and qemu-img
 292     test('qtest-@0@/@1@'.format(target_base, test),
 293          qtest_executables[test],
 294          depends: [test_deps, qtest_emulator],
 295          env: qtest_env,
 296          args: ['--tap', '-k'],
 297          protocol: 'tap',
 298          timeout: slow_qtests.get(test, 30),
 299          priority: slow_qtests.get(test, 30),
 300          suite: ['qtest', 'qtest-' + target_base])
 301   endforeach
 302 endforeach