tests/qtest/meson.build

   1 # All QTests for now are POSIX-only, but the dependencies are
   2 # really in libqtest, not in the testcases themselves.
   3 if not config_host.has_key('CONFIG_POSIX')
   4   subdir_done()
   5 endif
   6
   7 slow_qtests = {
   8   'ahci-test' : 60,
   9   'bios-tables-test' : 120,
  10   'boot-serial-test' : 60,
  11   'migration-test' : 150,
  12   'npcm7xx_pwm-test': 150,
  13   'prom-env-test' : 60,
  14   'pxe-test' : 60,
  15   'qos-test' : 60,
  16   'qom-test' : 300,
  17   'test-hmp' : 120,
  18 }
  19
  20 qtests_generic = \
  21   (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) + \
  22   (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) + \
  23   [
  24   'cdrom-test',
  25   'device-introspect-test',
  26   'machine-none-test',
  27   'qmp-test',
  28   'qmp-cmd-test',
  29   'qom-test',
  30   'test-hmp',
  31   'qos-test',
  32 ]
  33 if config_host.has_key('CONFIG_MODULES')
  34   qtests_generic += [ 'modules-test' ]
  35 endif
  36 if slirp.found()
  37   qtests_generic += [ 'test-query-netdev' ]
  38 endif
  39
  40 qtests_pci = \
  41   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  42   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  43
  44 qtests_i386 = \
  45   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +             \
  46   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                     \
  47   (have_tools ? ['ahci-test'] : []) +                                                       \
  48   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  49   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  50   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['test-filter-redirector'] : []) +    \
  51   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  52   (config_host.has_key('CONFIG_LINUX') and                                                  \
  53    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') ? ['ipmi-bt-test'] : []) +              \
  54   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  55   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  56   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  57   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  58   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  59   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  60   (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
  61   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  62   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  63    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  64   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  65   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  66   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  67   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  68   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  69   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  70   qtests_pci +                                                                              \
  71   ['fdc-test',
  72    'ide-test',
  73    'hd-geo-test',
  74    'boot-order-test',
  75    'bios-tables-test',
  76    'rtc-test',
  77    'i440fx-test',
  78    'fw_cfg-test',
  79    'device-plug-test',
  80    'drive_del-test',
  81    'tco-test',
  82    'cpu-plug-test',
  83    'q35-test',
  84    'vmgenid-test',
  85    'migration-test',
  86    'test-x86-cpuid-compat',
  87    'numa-test']
  88
  89 dbus_daemon = find_program('dbus-daemon', required: false)
  90 if dbus_daemon.found() and config_host.has_key('GDBUS_CODEGEN')
  91   # Temporarily disabled due to Patchew failures:
  92   #qtests_i386 += ['dbus-vmstate-test']
  93   dbus_vmstate1 = custom_target('dbus-vmstate description',
  94                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
  95                                 input: files('dbus-vmstate1.xml'),
  96                                 command: [config_host['GDBUS_CODEGEN'],
  97                                           '@INPUT@',
  98                                           '--interface-prefix', 'org.qemu',
  99                                           '--generate-c-code', '@BASENAME@']).to_list()
 100 else
 101   dbus_vmstate1 = []
 102 endif
 103
 104 qtests_x86_64 = qtests_i386
 105
 106 qtests_alpha = [ 'boot-serial-test' ] +                                                      \
 107   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 108
 109 qtests_avr = [ 'boot-serial-test' ]
 110
 111 qtests_hppa = [ 'boot-serial-test' ] +                                                       \
 112   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 113
 114 qtests_m68k = [ 'boot-serial-test' ]
 115 qtests_microblaze = [ 'boot-serial-test' ]
 116 qtests_microblazeel = qtests_microblaze
 117
 118 qtests_mips = \
 119   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 120   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 121
 122 qtests_mips64 = \
 123   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 124   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 125
 126 qtests_mips64el = \
 127   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 128   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 129
 130 qtests_moxie = [ 'boot-serial-test' ]
 131
 132 qtests_ppc = \
 133   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 134   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 135   ['boot-order-test', 'prom-env-test', 'boot-serial-test']                 \
 136
 137 qtests_ppc64 = \
 138   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 139   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 140   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 141   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +              \
 142   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 143   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 144   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                      \
 145   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 146
 147 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 148 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 149
 150 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test']
 151
 152 qtests_sparc64 = \
 153   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 154   ['prom-env-test', 'boot-serial-test']
 155
 156 qtests_npcm7xx = \
 157   ['npcm7xx_adc-test',
 158    'npcm7xx_gpio-test',
 159    'npcm7xx_pwm-test',
 160    'npcm7xx_rng-test',
 161    'npcm7xx_smbus-test',
 162    'npcm7xx_timer-test',
 163    'npcm7xx_watchdog_timer-test'] + \
 164    (slirp.found() ? ['npcm7xx_emc-test'] : [])
 165 qtests_arm = \
 166   (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
 167   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 168   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 169   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 170   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') ? ['pflash-cfi02-test'] : []) +         \
 171   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 172   ['arm-cpu-features',
 173    'microbit-test',
 174    'm25p80-test',
 175    'test-arm-mptimer',
 176    'boot-serial-test',
 177    'hexloader-test']
 178
 179 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 180 qtests_aarch64 = \
 181   (cpu != 'arm' ? ['bios-tables-test'] : []) +                                                  \
 182   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-test'] : []) +        \
 183   (config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ? ['tpm-tis-device-swtpm-test'] : []) +  \
 184   ['arm-cpu-features',
 185    'numa-test',
 186    'boot-serial-test',
 187    'xlnx-can-test',
 188    'migration-test']
 189
 190 qtests_s390x = \
 191   (slirp.found() ? ['pxe-test', 'test-netfilter'] : []) +                 \
 192   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-mirror'] : []) +                         \
 193   (config_host.has_key('CONFIG_POSIX') ? ['test-filter-redirector'] : []) +                     \
 194   ['boot-serial-test',
 195    'drive_del-test',
 196    'device-plug-test',
 197    'virtio-ccw-test',
 198    'cpu-plug-test',
 199    'migration-test']
 200
 201 qos_test_ss = ss.source_set()
 202 qos_test_ss.add(
 203   'ac97-test.c',
 204   'ds1338-test.c',
 205   'e1000-test.c',
 206   'e1000e-test.c',
 207   'eepro100-test.c',
 208   'es1370-test.c',
 209   'ipoctal232-test.c',
 210   'megasas-test.c',
 211   'ne2000-test.c',
 212   'tulip-test.c',
 213   'nvme-test.c',
 214   'pca9552-test.c',
 215   'pci-test.c',
 216   'pcnet-test.c',
 217   'sdhci-test.c',
 218   'spapr-phb-test.c',
 219   'tmp105-test.c',
 220   'emc141x-test.c',
 221   'usb-hcd-ohci-test.c',
 222   'virtio-test.c',
 223   'virtio-blk-test.c',
 224   'virtio-net-test.c',
 225   'virtio-rng-test.c',
 226   'virtio-scsi-test.c',
 227   'virtio-serial-test.c',
 228   'vmxnet3-test.c',
 229 )
 230 if have_virtfs
 231   qos_test_ss.add(files('virtio-9p-test.c'))
 232 endif
 233 qos_test_ss.add(when: 'CONFIG_VHOST_USER', if_true: files('vhost-user-test.c'))
 234
 235 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 236
 237 qtests = {
 238   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 239   'cdrom-test': files('boot-sector.c'),
 240   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 241   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 242   'migration-test': files('migration-helpers.c'),
 243   'pxe-test': files('boot-sector.c'),
 244   'qos-test': [chardev, io, qos_test_ss.apply(config_host, strict: false).sources()],
 245   'tpm-crb-swtpm-test': [io, tpmemu_files],
 246   'tpm-crb-test': [io, tpmemu_files],
 247   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 248   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 249   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 250   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 251   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 252 }
 253
 254 qtest_executables = {}
 255 foreach dir : target_dirs
 256   if not dir.endswith('-softmmu')
 257     continue
 258   endif
 259
 260   target_base = dir.split('-')[0]
 261   qtest_emulator = emulators['qemu-system-' + target_base]
 262   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 263
 264   test_deps = []
 265   qtest_env = environment()
 266   if have_tools
 267     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 268     test_deps += [qemu_img]
 269   endif
 270   qtest_env.set('G_TEST_DBUS_DAEMON', meson.source_root() / 'tests/dbus-vmstate-daemon.sh')
 271   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 272
 273   foreach test : target_qtests
 274     # Executables are shared across targets, declare them only the first time we
 275     # encounter them
 276     if not qtest_executables.has_key(test)
 277       src = [test + '.c']
 278       deps = [qemuutil, qos]
 279       if test in qtests
 280         # use a sourceset to quickly separate sources and deps
 281         test_ss = ss.source_set()
 282         test_ss.add(qtests[test])
 283         src += test_ss.all_sources()
 284         deps += test_ss.all_dependencies()
 285       endif
 286       qtest_executables += {
 287         test: executable(test, src, dependencies: deps)
 288       }
 289     endif
 290     # FIXME: missing dependency on the emulator binary and qemu-img
 291     test('qtest-@0@/@1@'.format(target_base, test),
 292          qtest_executables[test],
 293          depends: [test_deps, qtest_emulator],
 294          env: qtest_env,
 295          args: ['--tap', '-k'],
 296          protocol: 'tap',
 297          timeout: slow_qtests.get(test, 30),
 298          priority: slow_qtests.get(test, 30),
 299          suite: ['qtest', 'qtest-' + target_base])
 300   endforeach
 301 endforeach