tests/qtest/meson.build

   1 slow_qtests = {
   2   'bios-tables-test' : 120,
   3   'migration-test' : 480,
   4   'npcm7xx_pwm-test': 300,
   5   'qom-test' : 900,
   6   'test-hmp' : 240,
   7   'pxe-test': 600,
   8   'prom-env-test': 360,
   9   'boot-serial-test': 180,
  10 }
  11
  12 qtests_generic = [
  13   'cdrom-test',
  14   'device-introspect-test',
  15   'machine-none-test',
  16   'qmp-test',
  17   'qmp-cmd-test',
  18   'qom-test',
  19   'test-hmp',
  20   'qos-test',
  21   'readconfig-test',
  22   'netdev-socket',
  23 ]
  24 if enable_modules
  25   qtests_generic += [ 'modules-test' ]
  26 endif
  27
  28 qtests_pci = \
  29   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : []) +                  \
  30   (config_all_devices.has_key('CONFIG_IVSHMEM_DEVICE') ? ['ivshmem-test'] : [])
  31
  32 qtests_cxl = \
  33   (config_all_devices.has_key('CONFIG_CXL') ? ['cxl-test'] : [])
  34
  35 # FIXME: Get rid of get_option('default_devices') here and check
  36 #        for the availability of the default NICs in the tests
  37 qtests_filter = \
  38   (get_option('default_devices') and slirp.found() ? ['test-netfilter'] : []) + \
  39   (get_option('default_devices') and host_os != 'windows' ? ['test-filter-mirror'] : []) + \
  40   (get_option('default_devices') and host_os != 'windows' ? ['test-filter-redirector'] : [])
  41
  42 qtests_i386 = \
  43   (slirp.found() ? ['pxe-test'] : []) + \
  44   qtests_filter + \
  45   (have_tools ? ['ahci-test'] : []) +                                                       \
  46   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +           \
  47   (config_all_devices.has_key('CONFIG_SGA') ? ['boot-serial-test'] : []) +                  \
  48   (config_all_devices.has_key('CONFIG_ISA_IPMI_KCS') ? ['ipmi-kcs-test'] : []) +            \
  49   (host_os == 'linux' and                                                                  \
  50    config_all_devices.has_key('CONFIG_ISA_IPMI_BT') and
  51    config_all_devices.has_key('CONFIG_IPMI_EXTERN') ? ['ipmi-bt-test'] : []) +              \
  52   (config_all_devices.has_key('CONFIG_WDT_IB700') ? ['wdt_ib700-test'] : []) +              \
  53   (config_all_devices.has_key('CONFIG_PVPANIC_ISA') ? ['pvpanic-test'] : []) +              \
  54   (config_all_devices.has_key('CONFIG_PVPANIC_PCI') ? ['pvpanic-pci-test'] : []) +          \
  55   (config_all_devices.has_key('CONFIG_HDA') ? ['intel-hda-test'] : []) +                    \
  56   (config_all_devices.has_key('CONFIG_I82801B11') ? ['i82801b11-test'] : []) +             \
  57   (config_all_devices.has_key('CONFIG_IOH3420') ? ['ioh3420-test'] : []) +                  \
  58   (config_all_devices.has_key('CONFIG_LPC_ICH9') ? ['lpc-ich9-test'] : []) +              \
  59   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +            \
  60   (config_all_devices.has_key('CONFIG_USB_UHCI') and                                        \
  61    config_all_devices.has_key('CONFIG_USB_EHCI') ? ['usb-hcd-ehci-test'] : []) +            \
  62   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +        \
  63   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-test'] : []) +                  \
  64   (config_all_devices.has_key('CONFIG_TPM_CRB') ? ['tpm-crb-swtpm-test'] : []) +            \
  65   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-test'] : []) +              \
  66   (config_all_devices.has_key('CONFIG_TPM_TIS_ISA') ? ['tpm-tis-swtpm-test'] : []) +        \
  67   (config_all_devices.has_key('CONFIG_RTL8139_PCI') ? ['rtl8139-test'] : []) +              \
  68   (config_all_devices.has_key('CONFIG_E1000E_PCI_EXPRESS') ? ['fuzz-e1000e-test'] : []) +   \
  69   (config_all_devices.has_key('CONFIG_MEGASAS_SCSI_PCI') ? ['fuzz-megasas-test'] : []) +    \
  70   (config_all_devices.has_key('CONFIG_LSI_SCSI_PCI') ? ['fuzz-lsi53c895a-test'] : []) +     \
  71   (config_all_devices.has_key('CONFIG_VIRTIO_SCSI') ? ['fuzz-virtio-scsi-test'] : []) +     \
  72   (config_all_devices.has_key('CONFIG_SB16') ? ['fuzz-sb16-test'] : []) +                   \
  73   (config_all_devices.has_key('CONFIG_SDHCI_PCI') ? ['fuzz-sdcard-test'] : []) +            \
  74   (config_all_devices.has_key('CONFIG_ESP_PCI') ? ['am53c974-test'] : []) +                 \
  75   (host_os != 'windows' and                                                                \
  76    config_all_devices.has_key('CONFIG_ACPI_ERST') ? ['erst-test'] : []) +                   \
  77   (config_all_devices.has_key('CONFIG_PCIE_PORT') and                                       \
  78    config_all_devices.has_key('CONFIG_VIRTIO_NET') and                                      \
  79    config_all_devices.has_key('CONFIG_Q35') and                                             \
  80    config_all_devices.has_key('CONFIG_VIRTIO_PCI') and                                      \
  81    slirp.found() ? ['virtio-net-failover'] : []) +                                          \
  82   (unpack_edk2_blobs and                                                                    \
  83    config_all_devices.has_key('CONFIG_HPET') and                                            \
  84    config_all_devices.has_key('CONFIG_PARALLEL') ? ['bios-tables-test'] : []) +             \
  85   qtests_pci +                                                                              \
  86   qtests_cxl +                                                                              \
  87   ['fdc-test',
  88    'ide-test',
  89    'hd-geo-test',
  90    'boot-order-test',
  91    'rtc-test',
  92    'i440fx-test',
  93    'fw_cfg-test',
  94    'device-plug-test',
  95    'drive_del-test',
  96    'tco-test',
  97    'cpu-plug-test',
  98    'q35-test',
  99    'vmgenid-test',
 100    'migration-test',
 101    'test-x86-cpuid-compat',
 102    'numa-test'
 103   ]
 104
 105 if dbus_display
 106   qtests_i386 += ['dbus-display-test']
 107 endif
 108
 109 dbus_daemon = find_program('dbus-daemon', required: false)
 110 if dbus_daemon.found() and gdbus_codegen.found()
 111   # Temporarily disabled due to Patchew failures:
 112   #qtests_i386 += ['dbus-vmstate-test']
 113   dbus_vmstate1 = custom_target('dbus-vmstate description',
 114                                 output: ['dbus-vmstate1.h', 'dbus-vmstate1.c'],
 115                                 input: meson.project_source_root() / 'backends/dbus-vmstate1.xml',
 116                                 command: [gdbus_codegen, '@INPUT@',
 117                                           '--interface-prefix', 'org.qemu',
 118                                           '--generate-c-code', '@BASENAME@']).to_list()
 119 else
 120   dbus_vmstate1 = []
 121 endif
 122
 123 qtests_x86_64 = qtests_i386
 124
 125 qtests_alpha = ['boot-serial-test'] + \
 126   qtests_filter + \
 127   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 128
 129 qtests_avr = [ 'boot-serial-test' ]
 130
 131 qtests_hppa = ['boot-serial-test'] + \
 132   qtests_filter + \
 133   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 134
 135 qtests_m68k = ['boot-serial-test'] + \
 136   qtests_filter
 137
 138 qtests_microblaze = ['boot-serial-test'] + \
 139   qtests_filter
 140
 141 qtests_microblazeel = qtests_microblaze
 142
 143 qtests_mips = \
 144   qtests_filter + \
 145   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 146   (config_all_devices.has_key('CONFIG_VGA') ? ['display-vga-test'] : [])
 147
 148 qtests_mipsel = qtests_mips
 149 qtests_mips64 = qtests_mips
 150 qtests_mips64el = qtests_mips
 151
 152 qtests_ppc = \
 153   qtests_filter + \
 154   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 155   (config_all_devices.has_key('CONFIG_M48T59') ? ['m48t59-test'] : []) +                     \
 156   (config_all_accel.has_key('CONFIG_TCG') ? ['prom-env-test'] : []) +                              \
 157   (config_all_accel.has_key('CONFIG_TCG') ? ['boot-serial-test'] : []) +                           \
 158   ['boot-order-test']
 159
 160 qtests_ppc64 = \
 161   qtests_ppc + \
 162   (config_all_devices.has_key('CONFIG_PSERIES') ? ['device-plug-test'] : []) +               \
 163   (config_all_devices.has_key('CONFIG_POWERNV') ? ['pnv-xscom-test'] : []) +                 \
 164   (config_all_devices.has_key('CONFIG_PSERIES') ? ['rtas-test'] : []) +                      \
 165   (slirp.found() ? ['pxe-test'] : []) +              \
 166   (config_all_devices.has_key('CONFIG_USB_UHCI') ? ['usb-hcd-uhci-test'] : []) +             \
 167   (config_all_devices.has_key('CONFIG_USB_XHCI_NEC') ? ['usb-hcd-xhci-test'] : []) +         \
 168   qtests_pci + ['migration-test', 'numa-test', 'cpu-plug-test', 'drive_del-test']
 169
 170 qtests_sh4 = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 171 qtests_sh4eb = (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : [])
 172
 173 qtests_sparc = ['prom-env-test', 'm48t59-test', 'boot-serial-test'] + \
 174   qtests_filter
 175
 176 qtests_sparc64 = \
 177   (config_all_devices.has_key('CONFIG_ISA_TESTDEV') ? ['endianness-test'] : []) +            \
 178   qtests_filter + \
 179   ['prom-env-test', 'boot-serial-test']
 180
 181 qtests_npcm7xx = \
 182   ['npcm7xx_adc-test',
 183    'npcm7xx_gpio-test',
 184    'npcm7xx_pwm-test',
 185    'npcm7xx_rng-test',
 186    'npcm7xx_sdhci-test',
 187    'npcm7xx_smbus-test',
 188    'npcm7xx_timer-test',
 189    'npcm7xx_watchdog_timer-test'] + \
 190    (slirp.found() ? ['npcm7xx_emc-test'] : [])
 191 qtests_aspeed = \
 192   ['aspeed_hace-test',
 193    'aspeed_smc-test',
 194    'aspeed_gpio-test']
 195 qtests_arm = \
 196   (config_all_devices.has_key('CONFIG_MPS2') ? ['sse-timer-test'] : []) + \
 197   (config_all_devices.has_key('CONFIG_CMSDK_APB_DUALTIMER') ? ['cmsdk-apb-dualtimer-test'] : []) + \
 198   (config_all_devices.has_key('CONFIG_CMSDK_APB_TIMER') ? ['cmsdk-apb-timer-test'] : []) + \
 199   (config_all_devices.has_key('CONFIG_CMSDK_APB_WATCHDOG') ? ['cmsdk-apb-watchdog-test'] : []) + \
 200   (config_all_devices.has_key('CONFIG_PFLASH_CFI02') and
 201    config_all_devices.has_key('CONFIG_MUSICPAL') ? ['pflash-cfi02-test'] : []) + \
 202   (config_all_devices.has_key('CONFIG_ASPEED_SOC') ? qtests_aspeed : []) + \
 203   (config_all_devices.has_key('CONFIG_NPCM7XX') ? qtests_npcm7xx : []) + \
 204   (config_all_devices.has_key('CONFIG_GENERIC_LOADER') ? ['hexloader-test'] : []) + \
 205   (config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
 206   (config_all_devices.has_key('CONFIG_VEXPRESS') ? ['test-arm-mptimer'] : []) + \
 207   (config_all_devices.has_key('CONFIG_MICROBIT') ? ['microbit-test'] : []) + \
 208   ['arm-cpu-features',
 209    'boot-serial-test']
 210
 211 # TODO: once aarch64 TCG is fixed on ARM 32 bit host, make bios-tables-test unconditional
 212 qtests_aarch64 = \
 213   (cpu != 'arm' and unpack_edk2_blobs ? ['bios-tables-test'] : []) +                            \
 214   (config_all_accel.has_key('CONFIG_TCG') and config_all_devices.has_key('CONFIG_TPM_TIS_SYSBUS') ?            \
 215     ['tpm-tis-device-test', 'tpm-tis-device-swtpm-test'] : []) +                                         \
 216   (config_all_devices.has_key('CONFIG_XLNX_ZYNQMP_ARM') ? ['xlnx-can-test', 'fuzz-xlnx-dp-test'] : []) + \
 217   (config_all_devices.has_key('CONFIG_XLNX_VERSAL') ? ['xlnx-canfd-test', 'xlnx-versal-trng-test'] : []) + \
 218   (config_all_devices.has_key('CONFIG_RASPI') ? ['bcm2835-dma-test'] : []) +  \
 219   (config_all_accel.has_key('CONFIG_TCG') and                                            \
 220    config_all_devices.has_key('CONFIG_TPM_TIS_I2C') ? ['tpm-tis-i2c-test'] : []) + \
 221   ['arm-cpu-features',
 222    'numa-test',
 223    'boot-serial-test',
 224    'migration-test']
 225
 226 qtests_s390x = \
 227   qtests_filter + \
 228   ['boot-serial-test',
 229    'drive_del-test',
 230    'device-plug-test',
 231    'virtio-ccw-test',
 232    'cpu-plug-test',
 233    'migration-test']
 234
 235 qtests_riscv32 = \
 236   (config_all_devices.has_key('CONFIG_SIFIVE_E_AON') ? ['sifive-e-aon-watchdog-test'] : [])
 237
 238 qos_test_ss = ss.source_set()
 239 qos_test_ss.add(
 240   'ac97-test.c',
 241   'adm1272-test.c',
 242   'adm1266-test.c',
 243   'ds1338-test.c',
 244   'e1000-test.c',
 245   'eepro100-test.c',
 246   'es1370-test.c',
 247   'ipoctal232-test.c',
 248   'lsm303dlhc-mag-test.c',
 249   'isl_pmbus_vr-test.c',
 250   'max34451-test.c',
 251   'megasas-test.c',
 252   'ne2000-test.c',
 253   'tulip-test.c',
 254   'nvme-test.c',
 255   'pca9552-test.c',
 256   'pci-test.c',
 257   'pcnet-test.c',
 258   'sdhci-test.c',
 259   'spapr-phb-test.c',
 260   'tmp105-test.c',
 261   'emc141x-test.c',
 262   'usb-hcd-ohci-test.c',
 263   'virtio-test.c',
 264   'virtio-blk-test.c',
 265   'virtio-net-test.c',
 266   'virtio-rng-test.c',
 267   'virtio-scsi-test.c',
 268   'virtio-iommu-test.c',
 269   'vmxnet3-test.c',
 270   'igb-test.c',
 271   'ufs-test.c',
 272 )
 273
 274 if config_all_devices.has_key('CONFIG_VIRTIO_SERIAL')
 275   qos_test_ss.add(files('virtio-serial-test.c'))
 276 endif
 277
 278 if host_os != 'windows'
 279   qos_test_ss.add(files('e1000e-test.c'))
 280 endif
 281 if have_virtfs
 282   qos_test_ss.add(files('virtio-9p-test.c'))
 283 endif
 284 if have_vhost_user
 285   qos_test_ss.add(files('vhost-user-test.c'))
 286 endif
 287 if have_tools and have_vhost_user_blk_server
 288   qos_test_ss.add(files('vhost-user-blk-test.c'))
 289 endif
 290
 291 tpmemu_files = ['tpm-emu.c', 'tpm-util.c', 'tpm-tests.c']
 292
 293 migration_files = [files('migration-helpers.c')]
 294 if gnutls.found()
 295   migration_files += [files('../unit/crypto-tls-psk-helpers.c'), gnutls]
 296
 297   if tasn1.found()
 298     migration_files += [files('../unit/crypto-tls-x509-helpers.c',
 299                               '../unit/pkix_asn1_tab.c'), tasn1]
 300   endif
 301 endif
 302
 303 qtests = {
 304   'bios-tables-test': [io, 'boot-sector.c', 'acpi-utils.c', 'tpm-emu.c'],
 305   'cdrom-test': files('boot-sector.c'),
 306   'dbus-vmstate-test': files('migration-helpers.c') + dbus_vmstate1,
 307   'erst-test': files('erst-test.c'),
 308   'ivshmem-test': [rt, '../../contrib/ivshmem-server/ivshmem-server.c'],
 309   'migration-test': migration_files,
 310   'pxe-test': files('boot-sector.c'),
 311   'qos-test': [chardev, io, qos_test_ss.apply({}).sources()],
 312   'tpm-crb-swtpm-test': [io, tpmemu_files],
 313   'tpm-crb-test': [io, tpmemu_files],
 314   'tpm-tis-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 315   'tpm-tis-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 316   'tpm-tis-i2c-test': [io, tpmemu_files, 'qtest_aspeed.c'],
 317   'tpm-tis-device-swtpm-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 318   'tpm-tis-device-test': [io, tpmemu_files, 'tpm-tis-util.c'],
 319   'virtio-net-failover': files('migration-helpers.c'),
 320   'vmgenid-test': files('boot-sector.c', 'acpi-utils.c'),
 321   'netdev-socket': files('netdev-socket.c', '../unit/socket-helpers.c'),
 322 }
 323
 324 if vnc.found()
 325   gvnc = dependency('gvnc-1.0', method: 'pkg-config', required: false)
 326   if gvnc.found()
 327     qtests += {'vnc-display-test': [gvnc]}
 328     qtests_generic += [ 'vnc-display-test' ]
 329   endif
 330 endif
 331
 332 if dbus_display
 333   qtests += {'dbus-display-test': [dbus_display1, gio]}
 334 endif
 335
 336 qtest_executables = {}
 337 foreach dir : target_dirs
 338   if not dir.endswith('-softmmu')
 339     continue
 340   endif
 341
 342   target_base = dir.split('-')[0]
 343   qtest_emulator = emulators['qemu-system-' + target_base]
 344   target_qtests = get_variable('qtests_' + target_base, []) + qtests_generic
 345
 346   test_deps = roms
 347   qtest_env = environment()
 348   if have_tools
 349     qtest_env.set('QTEST_QEMU_IMG', './qemu-img')
 350     test_deps += [qemu_img]
 351   endif
 352   qtest_env.set('G_TEST_DBUS_DAEMON', meson.project_source_root() / 'tests/dbus-vmstate-daemon.sh')
 353   qtest_env.set('QTEST_QEMU_BINARY', './qemu-system-' + target_base)
 354   if have_tools and have_vhost_user_blk_server
 355     qtest_env.set('QTEST_QEMU_STORAGE_DAEMON_BINARY', './storage-daemon/qemu-storage-daemon')
 356     test_deps += [qsd]
 357   endif
 358
 359   qtest_env.set('PYTHON', python.full_path())
 360
 361   foreach test : target_qtests
 362     # Executables are shared across targets, declare them only the first time we
 363     # encounter them
 364     if not qtest_executables.has_key(test)
 365       src = [test + '.c']
 366       deps = [qemuutil, qos]
 367       if test in qtests
 368         # use a sourceset to quickly separate sources and deps
 369         test_ss = ss.source_set()
 370         test_ss.add(qtests[test])
 371         src += test_ss.all_sources()
 372         deps += test_ss.all_dependencies()
 373       endif
 374       qtest_executables += {
 375         test: executable(test, src, dependencies: deps)
 376       }
 377     endif
 378     test('qtest-@0@/@1@'.format(target_base, test),
 379          qtest_executables[test],
 380          depends: [test_deps, qtest_emulator, emulator_modules],
 381          env: qtest_env,
 382          args: ['--tap', '-k'],
 383          protocol: 'tap',
 384          timeout: slow_qtests.get(test, 60),
 385          priority: slow_qtests.get(test, 60),
 386          suite: ['qtest', 'qtest-' + target_base])
 387   endforeach
 388 endforeach