qemu.nsi

   1 ;!/usr/bin/makensis
   2
   3 ; This NSIS script creates an installer for QEMU on Windows.
   4
   5 ; Copyright (C) 2006-2012 Stefan Weil
   6 ;
   7 ; This program is free software: you can redistribute it and/or modify
   8 ; it under the terms of the GNU General Public License as published by
   9 ; the Free Software Foundation, either version 2 of the License, or
  10 ; (at your option) version 3 or any later version.
  11 ;
  12 ; This program is distributed in the hope that it will be useful,
  13 ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ; GNU General Public License for more details.
  16 ;
  17 ; You should have received a copy of the GNU General Public License
  18 ; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ; NSIS_WIN32_MAKENSIS
  21
  22 !define PRODUCT "QEMU"
  23 !define URL     "https://www.qemu.org/"
  24
  25 !define UNINST_EXE "$INSTDIR\qemu-uninstall.exe"
  26 !define UNINST_KEY "Software\Microsoft\Windows\CurrentVersion\Uninstall\${PRODUCT}"
  27
  28 !ifndef BINDIR
  29 !define BINDIR nsis.tmp
  30 !endif
  31 !ifndef SRCDIR
  32 !define SRCDIR .
  33 !endif
  34 !ifndef OUTFILE
  35 !define OUTFILE "qemu-setup.exe"
  36 !endif
  37
  38 ; Optionally install documentation.
  39 !ifndef CONFIG_DOCUMENTATION
  40 !define CONFIG_DOCUMENTATION
  41 !endif
  42
  43 ; Use maximum compression.
  44 SetCompressor /SOLID lzma
  45
  46 !include "MUI2.nsh"
  47
  48 ; The name of the installer.
  49 Name "QEMU"
  50
  51 ; The file to write
  52 OutFile "${OUTFILE}"
  53
  54 ; The default installation directory.
  55 !ifdef W64
  56 InstallDir $PROGRAMFILES64\qemu
  57 !else
  58 InstallDir $PROGRAMFILES\qemu
  59 !endif
  60
  61 ; Registry key to check for directory (so if you install again, it will
  62 ; overwrite the old one automatically)
  63 !ifdef W64
  64 InstallDirRegKey HKLM "Software\qemu64" "Install_Dir"
  65 !else
  66 InstallDirRegKey HKLM "Software\qemu32" "Install_Dir"
  67 !endif
  68
  69 ; Request administrator privileges for Windows Vista.
  70 RequestExecutionLevel admin
  71
  72 ;--------------------------------
  73 ; Interface Settings.
  74 ;!define MUI_HEADERIMAGE "qemu-nsis.bmp"
  75 ; !define MUI_SPECIALBITMAP "qemu.bmp"
  76 !define MUI_ICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  77 !define MUI_UNICON "${SRCDIR}\pc-bios\qemu-nsis.ico"
  78 !define MUI_WELCOMEFINISHPAGE_BITMAP "${SRCDIR}\pc-bios\qemu-nsis.bmp"
  79 ; !define MUI_HEADERIMAGE_BITMAP "qemu-install.bmp"
  80 ; !define MUI_HEADERIMAGE_UNBITMAP "qemu-uninstall.bmp"
  81 ; !define MUI_COMPONENTSPAGE_SMALLDESC
  82 ; !define MUI_WELCOMEPAGE_TEXT "Insert text here.$\r$\n$\r$\n$\r$\n$_CLICK"
  83
  84 ;--------------------------------
  85 ; Pages.
  86
  87 !insertmacro MUI_PAGE_WELCOME
  88 !insertmacro MUI_PAGE_LICENSE "${SRCDIR}\COPYING"
  89 !insertmacro MUI_PAGE_COMPONENTS
  90 !insertmacro MUI_PAGE_DIRECTORY
  91 !insertmacro MUI_PAGE_INSTFILES
  92 !define MUI_FINISHPAGE_LINK "Visit the QEMU Wiki online!"
  93 !define MUI_FINISHPAGE_LINK_LOCATION "${URL}"
  94 !insertmacro MUI_PAGE_FINISH
  95
  96 !insertmacro MUI_UNPAGE_CONFIRM
  97 !insertmacro MUI_UNPAGE_INSTFILES
  98
  99 ;--------------------------------
 100 ; Languages.
 101
 102 !insertmacro MUI_LANGUAGE "English"
 103 !insertmacro MUI_LANGUAGE "French"
 104 !insertmacro MUI_LANGUAGE "German"
 105
 106 ;--------------------------------
 107
 108 ; The stuff to install.
 109 Section "${PRODUCT} (required)"
 110
 111     SectionIn RO
 112
 113     ; Set output path to the installation directory.
 114     SetOutPath "$INSTDIR"
 115
 116     File "${SRCDIR}\Changelog"
 117     File "${SRCDIR}\COPYING"
 118     File "${SRCDIR}\COPYING.LIB"
 119     File "${SRCDIR}\README"
 120     File "${SRCDIR}\VERSION"
 121
 122     File "${BINDIR}\*.aml"
 123     File "${BINDIR}\*.bmp"
 124     File "${BINDIR}\*.bin"
 125     File "${BINDIR}\*.dtb"
 126     File "${BINDIR}\*.img"
 127     File "${BINDIR}\*.lid"
 128     File "${BINDIR}\*.ndrv"
 129     File "${BINDIR}\*.rom"
 130     File "${BINDIR}\openbios-*"
 131     File "${BINDIR}\palcode-clipper"
 132     File "${BINDIR}\u-boot.e500"
 133     File "${BINDIR}\qemu_logo_no_text.svg"
 134
 135     File /r "${BINDIR}\keymaps"
 136 !ifdef CONFIG_GTK
 137     File /r "${BINDIR}\share"
 138 !endif
 139
 140 !ifdef W64
 141     SetRegView 64
 142 !endif
 143
 144     ; Write the installation path into the registry
 145     WriteRegStr HKLM SOFTWARE\${PRODUCT} "Install_Dir" "$INSTDIR"
 146
 147     ; Write the uninstall keys for Windows
 148     WriteRegStr HKLM "${UNINST_KEY}" "DisplayName" "QEMU"
 149 !ifdef DISPLAYVERSION
 150     WriteRegStr HKLM "${UNINST_KEY}" "DisplayVersion" "${DISPLAYVERSION}"
 151 !endif
 152     WriteRegStr HKLM "${UNINST_KEY}" "UninstallString" '"${UNINST_EXE}"'
 153     WriteRegDWORD HKLM "${UNINST_KEY}" "NoModify" 1
 154     WriteRegDWORD HKLM "${UNINST_KEY}" "NoRepair" 1
 155     WriteUninstaller "qemu-uninstall.exe"
 156 SectionEnd
 157
 158 Section "Tools" SectionTools
 159     SetOutPath "$INSTDIR"
 160     File "${BINDIR}\qemu-img.exe"
 161     File "${BINDIR}\qemu-io.exe"
 162 SectionEnd
 163
 164 SectionGroup "System Emulations" SectionSystem
 165
 166 !include "${BINDIR}\system-emulations.nsh"
 167
 168 SectionGroupEnd
 169
 170 Section "Desktop icons" SectionGnome
 171     SetOutPath "$INSTDIR\share"
 172 !ifdef W64
 173     File /r /usr/x86_64-w64-mingw32/sys-root/mingw/share/icons
 174 !else
 175     File /r /usr/i686-w64-mingw32/sys-root/mingw/share/icons
 176 !endif
 177 SectionEnd
 178
 179 !ifdef DLLDIR
 180 Section "Libraries (DLL)" SectionDll
 181     SetOutPath "$INSTDIR"
 182     File "${DLLDIR}\*.dll"
 183 SectionEnd
 184 !endif
 185
 186 !ifdef CONFIG_DOCUMENTATION
 187 Section "Documentation" SectionDoc
 188     SetOutPath "$INSTDIR"
 189     File "${BINDIR}\qemu-doc.html"
 190     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 191     CreateShortCut "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk" "$INSTDIR\qemu-doc.html" "" "$INSTDIR\qemu-doc.html" 0
 192 SectionEnd
 193 !endif
 194
 195 ; Optional section (can be disabled by the user)
 196 Section "Start Menu Shortcuts" SectionMenu
 197     CreateDirectory "$SMPROGRAMS\${PRODUCT}"
 198     CreateShortCut "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk" "${UNINST_EXE}" "" "${UNINST_EXE}" 0
 199 SectionEnd
 200
 201 ;--------------------------------
 202
 203 ; Uninstaller
 204
 205 Section "Uninstall"
 206     ; Remove registry keys
 207 !ifdef W64
 208     SetRegView 64
 209 !endif
 210     DeleteRegKey HKLM "${UNINST_KEY}"
 211     DeleteRegKey HKLM SOFTWARE\${PRODUCT}
 212
 213     ; Remove shortcuts, if any
 214     Delete "$SMPROGRAMS\${PRODUCT}\User Documentation.lnk"
 215     Delete "$SMPROGRAMS\${PRODUCT}\Technical Documentation.lnk"
 216     Delete "$SMPROGRAMS\${PRODUCT}\Uninstall.lnk"
 217     RMDir "$SMPROGRAMS\${PRODUCT}"
 218
 219     ; Remove files and directories used
 220     Delete "$INSTDIR\Changelog"
 221     Delete "$INSTDIR\COPYING"
 222     Delete "$INSTDIR\COPYING.LIB"
 223     Delete "$INSTDIR\README"
 224     Delete "$INSTDIR\VERSION"
 225     Delete "$INSTDIR\*.aml"
 226     Delete "$INSTDIR\*.bmp"
 227     Delete "$INSTDIR\*.bin"
 228     Delete "$INSTDIR\*.dll"
 229     Delete "$INSTDIR\*.dtb"
 230     Delete "$INSTDIR\*.img"
 231     Delete "$INSTDIR\*.lid"
 232     Delete "$INSTDIR\*.ndrv"
 233     Delete "$INSTDIR\*.rom"
 234     Delete "$INSTDIR\openbios-*"
 235     Delete "$INSTDIR\palcode-clipper"
 236     Delete "$INSTDIR\u-boot.e500"
 237     Delete "$INSTDIR\qemu_logo_no_text.svg"
 238     Delete "$INSTDIR\qemu-img.exe"
 239     Delete "$INSTDIR\qemu-io.exe"
 240     Delete "$INSTDIR\qemu.exe"
 241     Delete "$INSTDIR\qemu-system-*.exe"
 242     Delete "$INSTDIR\qemu-doc.html"
 243     RMDir /r "$INSTDIR\keymaps"
 244     RMDir /r "$INSTDIR\share"
 245     ; Remove generated files
 246     Delete "$INSTDIR\stderr.txt"
 247     Delete "$INSTDIR\stdout.txt"
 248     ; Remove uninstaller
 249     Delete "${UNINST_EXE}"
 250     RMDir "$INSTDIR"
 251 SectionEnd
 252
 253 ;--------------------------------
 254
 255 ; Descriptions (mouse-over).
 256 !insertmacro MUI_FUNCTION_DESCRIPTION_BEGIN
 257     !insertmacro MUI_DESCRIPTION_TEXT ${SectionGnome}   "GNOME desktop icon theme."
 258     !insertmacro MUI_DESCRIPTION_TEXT ${SectionSystem}  "System emulation."
 259     !insertmacro MUI_DESCRIPTION_TEXT ${Section_alpha}  "Alpha system emulation."
 260     !insertmacro MUI_DESCRIPTION_TEXT ${Section_i386}   "PC i386 system emulation."
 261     !insertmacro MUI_DESCRIPTION_TEXT ${SectionTools} "Tools."
 262 !ifdef DLLDIR
 263     !insertmacro MUI_DESCRIPTION_TEXT ${SectionDll}   "Runtime Libraries (DLL)."
 264 !endif
 265 !ifdef CONFIG_DOCUMENTATION
 266     !insertmacro MUI_DESCRIPTION_TEXT ${SectionDoc}   "Documentation."
 267 !endif
 268     !insertmacro MUI_DESCRIPTION_TEXT ${SectionMenu}  "Menu entries."
 269 !insertmacro MUI_FUNCTION_DESCRIPTION_END
 270
 271 ;--------------------------------
 272 ; Functions.
 273
 274 Function .onInit
 275     !insertmacro MUI_LANGDLL_DISPLAY
 276 FunctionEnd