meson.build

   1 project('qemu', ['c'], meson_version: '>=0.55.0',
   2         default_options: ['warning_level=1', 'c_std=gnu99', 'cpp_std=gnu++11', 'b_colorout=auto'] +
   3                          (meson.version().version_compare('>=0.56.0') ? [ 'b_staticpic=false' ] : []),
   4         version: run_command('head', meson.source_root() / 'VERSION').stdout().strip())
   5
   6 not_found = dependency('', required: false)
   7 if meson.version().version_compare('>=0.56.0')
   8   keyval = import('keyval')
   9 else
  10   keyval = import('unstable-keyval')
  11 endif
  12 ss = import('sourceset')
  13 fs = import('fs')
  14
  15 sh = find_program('sh')
  16 cc = meson.get_compiler('c')
  17 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  18 enable_modules = 'CONFIG_MODULES' in config_host
  19 enable_static = 'CONFIG_STATIC' in config_host
  20
  21 # Temporary directory used for files created while
  22 # configure runs. Since it is in the build directory
  23 # we can safely blow away any previous version of it
  24 # (and we need not jump through hoops to try to delete
  25 # it when configure exits.)
  26 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  27
  28 if get_option('qemu_suffix').startswith('/')
  29   error('qemu_suffix cannot start with a /')
  30 endif
  31
  32 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  33 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  34 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  35 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  36
  37 qemu_desktopdir = get_option('datadir') / 'applications'
  38 qemu_icondir = get_option('datadir') / 'icons'
  39
  40 config_host_data = configuration_data()
  41 genh = []
  42
  43 target_dirs = config_host['TARGET_DIRS'].split()
  44 have_user = false
  45 have_system = false
  46 foreach target : target_dirs
  47   have_user = have_user or target.endswith('-user')
  48   have_system = have_system or target.endswith('-softmmu')
  49 endforeach
  50 have_tools = 'CONFIG_TOOLS' in config_host
  51 have_block = have_system or have_tools
  52
  53 python = import('python').find_installation()
  54
  55 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  56 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv32', 'riscv64', 'x86', 'x86_64',
  57   'arm', 'aarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  58
  59 cpu = host_machine.cpu_family()
  60 targetos = host_machine.system()
  61
  62 if cpu in ['x86', 'x86_64']
  63   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  64 elif cpu == 'aarch64'
  65   kvm_targets = ['aarch64-softmmu']
  66 elif cpu == 's390x'
  67   kvm_targets = ['s390x-softmmu']
  68 elif cpu in ['ppc', 'ppc64']
  69   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
  70 elif cpu in ['mips', 'mips64']
  71   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
  72 else
  73   kvm_targets = []
  74 endif
  75
  76 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
  77 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
  78   # i368 emulator provides xenpv machine type for multiple architectures
  79   accelerator_targets += {
  80     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
  81   }
  82 endif
  83 if cpu in ['x86', 'x86_64']
  84   accelerator_targets += {
  85     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
  86     'CONFIG_HVF': ['x86_64-softmmu'],
  87     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
  88   }
  89 endif
  90
  91 ##################
  92 # Compiler flags #
  93 ##################
  94
  95 # Specify linker-script with add_project_link_arguments so that it is not placed
  96 # within a linker --start-group/--end-group pair
  97 if 'CONFIG_FUZZ' in config_host
  98    add_project_link_arguments(['-Wl,-T,',
  99                                (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 100                               native: false, language: ['c', 'cpp', 'objc'])
 101 endif
 102
 103 add_project_arguments(config_host['QEMU_CFLAGS'].split(),
 104                       native: false, language: ['c', 'objc'])
 105 add_project_arguments(config_host['QEMU_CXXFLAGS'].split(),
 106                       native: false, language: 'cpp')
 107 add_project_link_arguments(config_host['QEMU_LDFLAGS'].split(),
 108                            native: false, language: ['c', 'cpp', 'objc'])
 109
 110 if targetos == 'linux'
 111   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 112                         '-isystem', 'linux-headers',
 113                         language: ['c', 'cpp'])
 114 endif
 115
 116 if 'CONFIG_TCG_INTERPRETER' in config_host
 117   tcg_arch = 'tci'
 118 elif config_host['ARCH'] == 'sparc64'
 119   tcg_arch = 'sparc'
 120 elif config_host['ARCH'] == 's390x'
 121   tcg_arch = 's390'
 122 elif config_host['ARCH'] in ['x86_64', 'x32']
 123   tcg_arch = 'i386'
 124 elif config_host['ARCH'] == 'ppc64'
 125   tcg_arch = 'ppc'
 126 elif config_host['ARCH'] in ['riscv32', 'riscv64']
 127   tcg_arch = 'riscv'
 128 else
 129   tcg_arch = config_host['ARCH']
 130 endif
 131 add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 132                       '-iquote', '.',
 133                       '-iquote', meson.current_source_dir(),
 134                       '-iquote', meson.current_source_dir() / 'accel/tcg',
 135                       '-iquote', meson.current_source_dir() / 'include',
 136                       '-iquote', meson.current_source_dir() / 'disas/libvixl',
 137                       language: ['c', 'cpp', 'objc'])
 138
 139 link_language = meson.get_external_property('link_language', 'cpp')
 140 if link_language == 'cpp'
 141   add_languages('cpp', required: true, native: false)
 142 endif
 143 if host_machine.system() == 'darwin'
 144   add_languages('objc', required: false, native: false)
 145 endif
 146
 147 sparse = find_program('cgcc', required: get_option('sparse'))
 148 if sparse.found()
 149   run_target('sparse',
 150              command: [find_program('scripts/check_sparse.py'),
 151                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 152                        '-Wno-transparent-union', '-Wno-old-initializer',
 153                        '-Wno-non-pointer-null'])
 154 endif
 155
 156 ###########################################
 157 # Target-specific checks and dependencies #
 158 ###########################################
 159
 160 if targetos != 'linux' and get_option('mpath').enabled()
 161   error('Multipath is supported only on Linux')
 162 endif
 163
 164 m = cc.find_library('m', required: false)
 165 util = cc.find_library('util', required: false)
 166 winmm = []
 167 socket = []
 168 version_res = []
 169 coref = []
 170 iokit = []
 171 emulator_link_args = []
 172 cocoa = not_found
 173 hvf = not_found
 174 if targetos == 'windows'
 175   socket = cc.find_library('ws2_32')
 176   winmm = cc.find_library('winmm')
 177
 178   win = import('windows')
 179   version_res = win.compile_resources('version.rc',
 180                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 181                                       include_directories: include_directories('.'))
 182 elif targetos == 'darwin'
 183   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 184   iokit = dependency('appleframeworks', modules: 'IOKit')
 185   cocoa = dependency('appleframeworks', modules: 'Cocoa', required: get_option('cocoa'))
 186 elif targetos == 'sunos'
 187   socket = [cc.find_library('socket'),
 188             cc.find_library('nsl'),
 189             cc.find_library('resolv')]
 190 elif targetos == 'haiku'
 191   socket = [cc.find_library('posix_error_mapper'),
 192             cc.find_library('network'),
 193             cc.find_library('bsd')]
 194 elif targetos == 'openbsd'
 195   if not get_option('tcg').disabled() and target_dirs.length() > 0
 196     # Disable OpenBSD W^X if available
 197     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 198   endif
 199 endif
 200
 201 accelerators = []
 202 if not get_option('kvm').disabled() and targetos == 'linux'
 203   accelerators += 'CONFIG_KVM'
 204 endif
 205 if not get_option('xen').disabled() and 'CONFIG_XEN_BACKEND' in config_host
 206   accelerators += 'CONFIG_XEN'
 207   have_xen_pci_passthrough = not get_option('xen_pci_passthrough').disabled() and targetos == 'linux'
 208 else
 209   have_xen_pci_passthrough = false
 210 endif
 211 if not get_option('whpx').disabled() and targetos == 'windows'
 212   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 213     error('WHPX requires 64-bit host')
 214   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 215        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 216     accelerators += 'CONFIG_WHPX'
 217   endif
 218 endif
 219 if not get_option('hvf').disabled()
 220   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 221                    required: get_option('hvf'))
 222   if hvf.found()
 223     accelerators += 'CONFIG_HVF'
 224   endif
 225 endif
 226 if not get_option('hax').disabled()
 227   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 228     accelerators += 'CONFIG_HAX'
 229   endif
 230 endif
 231 if not get_option('tcg').disabled()
 232   if cpu not in supported_cpus
 233     if 'CONFIG_TCG_INTERPRETER' in config_host
 234       warning('Unsupported CPU @0@, will use TCG with TCI (experimental)'.format(cpu))
 235     else
 236       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 237     endif
 238   endif
 239   accelerators += 'CONFIG_TCG'
 240   config_host += { 'CONFIG_TCG': 'y' }
 241 endif
 242
 243 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 244   error('KVM not available on this platform')
 245 endif
 246 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 247   error('HVF not available on this platform')
 248 endif
 249 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 250   error('WHPX not available on this platform')
 251 endif
 252 if not have_xen_pci_passthrough and get_option('xen_pci_passthrough').enabled()
 253   if 'CONFIG_XEN' in accelerators
 254     error('Xen PCI passthrough not available on this platform')
 255   else
 256     error('Xen PCI passthrough requested but Xen not enabled')
 257   endif
 258 endif
 259 if not cocoa.found() and get_option('cocoa').enabled()
 260   error('Cocoa not available on this platform')
 261 endif
 262
 263 ################
 264 # Dependencies #
 265 ################
 266
 267 # The path to glib.h is added to all compilation commands.  This was
 268 # grandfathered in from the QEMU Makefiles.
 269 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 270                       native: false, language: ['c', 'cpp', 'objc'])
 271 glib = declare_dependency(link_args: config_host['GLIB_LIBS'].split())
 272 gio = not_found
 273 if 'CONFIG_GIO' in config_host
 274   gio = declare_dependency(compile_args: config_host['GIO_CFLAGS'].split(),
 275                            link_args: config_host['GIO_LIBS'].split())
 276 endif
 277 lttng = not_found
 278 if 'CONFIG_TRACE_UST' in config_host
 279   lttng = declare_dependency(link_args: config_host['LTTNG_UST_LIBS'].split())
 280 endif
 281 urcubp = not_found
 282 if 'CONFIG_TRACE_UST' in config_host
 283   urcubp = declare_dependency(link_args: config_host['URCU_BP_LIBS'].split())
 284 endif
 285 gcrypt = not_found
 286 if 'CONFIG_GCRYPT' in config_host
 287   gcrypt = declare_dependency(compile_args: config_host['GCRYPT_CFLAGS'].split(),
 288                               link_args: config_host['GCRYPT_LIBS'].split())
 289 endif
 290 nettle = not_found
 291 if 'CONFIG_NETTLE' in config_host
 292   nettle = declare_dependency(compile_args: config_host['NETTLE_CFLAGS'].split(),
 293                               link_args: config_host['NETTLE_LIBS'].split())
 294 endif
 295 gnutls = not_found
 296 if 'CONFIG_GNUTLS' in config_host
 297   gnutls = declare_dependency(compile_args: config_host['GNUTLS_CFLAGS'].split(),
 298                               link_args: config_host['GNUTLS_LIBS'].split())
 299 endif
 300 pixman = not_found
 301 if have_system or have_tools
 302   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 303                       method: 'pkg-config', static: enable_static)
 304 endif
 305 pam = not_found
 306 if 'CONFIG_AUTH_PAM' in config_host
 307   pam = cc.find_library('pam')
 308 endif
 309 libaio = cc.find_library('aio', required: false)
 310 zlib = dependency('zlib', required: true, static: enable_static)
 311 linux_io_uring = not_found
 312 if 'CONFIG_LINUX_IO_URING' in config_host
 313   linux_io_uring = declare_dependency(compile_args: config_host['LINUX_IO_URING_CFLAGS'].split(),
 314                                       link_args: config_host['LINUX_IO_URING_LIBS'].split())
 315 endif
 316 libxml2 = not_found
 317 if 'CONFIG_LIBXML2' in config_host
 318   libxml2 = declare_dependency(compile_args: config_host['LIBXML2_CFLAGS'].split(),
 319                                link_args: config_host['LIBXML2_LIBS'].split())
 320 endif
 321 libnfs = not_found
 322 if 'CONFIG_LIBNFS' in config_host
 323   libnfs = declare_dependency(link_args: config_host['LIBNFS_LIBS'].split())
 324 endif
 325 libattr = not_found
 326 if 'CONFIG_ATTR' in config_host
 327   libattr = declare_dependency(link_args: config_host['LIBATTR_LIBS'].split())
 328 endif
 329 seccomp = not_found
 330 if 'CONFIG_SECCOMP' in config_host
 331   seccomp = declare_dependency(compile_args: config_host['SECCOMP_CFLAGS'].split(),
 332                                link_args: config_host['SECCOMP_LIBS'].split())
 333 endif
 334 libcap_ng = not_found
 335 if 'CONFIG_LIBCAP_NG' in config_host
 336   libcap_ng = declare_dependency(link_args: config_host['LIBCAP_NG_LIBS'].split())
 337 endif
 338 if get_option('xkbcommon').auto() and not have_system and not have_tools
 339   xkbcommon = not_found
 340 else
 341   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 342                          method: 'pkg-config', static: enable_static)
 343 endif
 344 vde = not_found
 345 if config_host.has_key('CONFIG_VDE')
 346   vde = declare_dependency(link_args: config_host['VDE_LIBS'].split())
 347 endif
 348 pulse = not_found
 349 if 'CONFIG_LIBPULSE' in config_host
 350   pulse = declare_dependency(compile_args: config_host['PULSE_CFLAGS'].split(),
 351                              link_args: config_host['PULSE_LIBS'].split())
 352 endif
 353 alsa = not_found
 354 if 'CONFIG_ALSA' in config_host
 355   alsa = declare_dependency(compile_args: config_host['ALSA_CFLAGS'].split(),
 356                             link_args: config_host['ALSA_LIBS'].split())
 357 endif
 358 jack = not_found
 359 if 'CONFIG_LIBJACK' in config_host
 360   jack = declare_dependency(link_args: config_host['JACK_LIBS'].split())
 361 endif
 362 spice = not_found
 363 spice_headers = not_found
 364 if 'CONFIG_SPICE' in config_host
 365   spice = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split(),
 366                              link_args: config_host['SPICE_LIBS'].split())
 367   spice_headers = declare_dependency(compile_args: config_host['SPICE_CFLAGS'].split())
 368 endif
 369 rt = cc.find_library('rt', required: false)
 370 libdl = not_found
 371 if 'CONFIG_PLUGIN' in config_host
 372   libdl = cc.find_library('dl', required: true)
 373 endif
 374 libiscsi = not_found
 375 if 'CONFIG_LIBISCSI' in config_host
 376   libiscsi = declare_dependency(compile_args: config_host['LIBISCSI_CFLAGS'].split(),
 377                                 link_args: config_host['LIBISCSI_LIBS'].split())
 378 endif
 379 zstd = not_found
 380 if 'CONFIG_ZSTD' in config_host
 381   zstd = declare_dependency(compile_args: config_host['ZSTD_CFLAGS'].split(),
 382                             link_args: config_host['ZSTD_LIBS'].split())
 383 endif
 384 gbm = not_found
 385 if 'CONFIG_GBM' in config_host
 386   gbm = declare_dependency(compile_args: config_host['GBM_CFLAGS'].split(),
 387                            link_args: config_host['GBM_LIBS'].split())
 388 endif
 389 virgl = not_found
 390 if 'CONFIG_VIRGL' in config_host
 391   virgl = declare_dependency(compile_args: config_host['VIRGL_CFLAGS'].split(),
 392                              link_args: config_host['VIRGL_LIBS'].split())
 393 endif
 394 curl = not_found
 395 if 'CONFIG_CURL' in config_host
 396   curl = declare_dependency(compile_args: config_host['CURL_CFLAGS'].split(),
 397                             link_args: config_host['CURL_LIBS'].split())
 398 endif
 399 libudev = not_found
 400 if targetos == 'linux' and (have_system or have_tools)
 401   libudev = dependency('libudev',
 402                        required: get_option('libudev'),
 403                        static: enable_static)
 404 endif
 405
 406 mpathlibs = [libudev]
 407 mpathpersist = not_found
 408 mpathpersist_new_api = false
 409 if targetos == 'linux' and have_tools and not get_option('mpath').disabled()
 410   mpath_test_source_new = '''
 411     #include <libudev.h>
 412     #include <mpath_persist.h>
 413     unsigned mpath_mx_alloc_len = 1024;
 414     int logsink;
 415     static struct config *multipath_conf;
 416     extern struct udev *udev;
 417     extern struct config *get_multipath_config(void);
 418     extern void put_multipath_config(struct config *conf);
 419     struct udev *udev;
 420     struct config *get_multipath_config(void) { return multipath_conf; }
 421     void put_multipath_config(struct config *conf) { }
 422     int main(void) {
 423         udev = udev_new();
 424         multipath_conf = mpath_lib_init();
 425         return 0;
 426     }'''
 427   mpath_test_source_old = '''
 428       #include <libudev.h>
 429       #include <mpath_persist.h>
 430       unsigned mpath_mx_alloc_len = 1024;
 431       int logsink;
 432       int main(void) {
 433           struct udev *udev = udev_new();
 434           mpath_lib_init(udev);
 435           return 0;
 436       }'''
 437   libmpathpersist = cc.find_library('mpathpersist',
 438                                     required: get_option('mpath'),
 439                                     static: enable_static)
 440   if libmpathpersist.found()
 441     mpathlibs += libmpathpersist
 442     if enable_static
 443       mpathlibs += cc.find_library('devmapper',
 444                                      required: get_option('mpath'),
 445                                      static: enable_static)
 446     endif
 447     mpathlibs += cc.find_library('multipath',
 448                                  required: get_option('mpath'),
 449                                  static: enable_static)
 450     foreach lib: mpathlibs
 451       if not lib.found()
 452         mpathlibs = []
 453         break
 454       endif
 455     endforeach
 456     if mpathlibs.length() == 0
 457       msg = 'Dependencies missing for libmpathpersist'
 458     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 459       mpathpersist = declare_dependency(dependencies: mpathlibs)
 460       mpathpersist_new_api = true
 461     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 462       mpathpersist = declare_dependency(dependencies: mpathlibs)
 463     else
 464       msg = 'Cannot detect libmpathpersist API'
 465     endif
 466     if not mpathpersist.found()
 467       if get_option('mpath').enabled()
 468         error(msg)
 469       else
 470         warning(msg + ', disabling')
 471       endif
 472     endif
 473   endif
 474 endif
 475
 476 iconv = not_found
 477 curses = not_found
 478 if have_system and not get_option('curses').disabled()
 479   curses_test = '''
 480     #include <locale.h>
 481     #include <curses.h>
 482     #include <wchar.h>
 483     int main(void) {
 484       wchar_t wch = L'w';
 485       setlocale(LC_ALL, "");
 486       resize_term(0, 0);
 487       addwstr(L"wide chars\n");
 488       addnwstr(&wch, 1);
 489       add_wch(WACS_DEGREE);
 490       return 0;
 491     }'''
 492
 493   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 494   foreach curses_dep : curses_dep_list
 495     if not curses.found()
 496       curses = dependency(curses_dep,
 497                           required: false,
 498                           method: 'pkg-config',
 499                           static: enable_static)
 500     endif
 501   endforeach
 502   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 503   if curses.found()
 504     if cc.links(curses_test, dependencies: [curses])
 505       curses = declare_dependency(compile_args: '-DNCURSES_WIDECHAR', dependencies: [curses])
 506     else
 507       msg = 'curses package not usable'
 508       curses = not_found
 509     endif
 510   endif
 511   if not curses.found()
 512     curses_compile_args = ['-DNCURSES_WIDECHAR']
 513     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 514     if targetos != 'windows' and not has_curses_h
 515       message('Trying with /usr/include/ncursesw')
 516       curses_compile_args += ['-I/usr/include/ncursesw']
 517       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 518     endif
 519     if has_curses_h
 520       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 521       foreach curses_libname : curses_libname_list
 522         libcurses = cc.find_library(curses_libname,
 523                                     required: false,
 524                                     static: enable_static)
 525         if libcurses.found()
 526           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 527             curses = declare_dependency(compile_args: curses_compile_args,
 528                                         dependencies: [libcurses])
 529             break
 530           else
 531             msg = 'curses library not usable'
 532           endif
 533         endif
 534       endforeach
 535     endif
 536   endif
 537   if not get_option('iconv').disabled()
 538     foreach link_args : [ ['-liconv'], [] ]
 539       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 540       # We need to use libiconv if available because mixing libiconv's headers with
 541       # the system libc does not work.
 542       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 543       # included in the command line and libiconv will not be found.
 544       if cc.links('''
 545         #include <iconv.h>
 546         int main(void) {
 547           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 548           return conv != (iconv_t) -1;
 549         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 550         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 551         break
 552       endif
 553     endforeach
 554   endif
 555   if curses.found() and not iconv.found()
 556     if get_option('iconv').enabled()
 557       error('iconv not available')
 558     endif
 559     msg = 'iconv required for curses UI but not available'
 560     curses = not_found
 561   endif
 562   if not curses.found() and msg != ''
 563     if get_option('curses').enabled()
 564       error(msg)
 565     else
 566       warning(msg + ', disabling')
 567     endif
 568   endif
 569 endif
 570
 571 brlapi = not_found
 572 if 'CONFIG_BRLAPI' in config_host
 573   brlapi = declare_dependency(link_args: config_host['BRLAPI_LIBS'].split())
 574 endif
 575
 576 sdl = not_found
 577 if have_system
 578   sdl = dependency('sdl2', required: get_option('sdl'), static: enable_static)
 579   sdl_image = not_found
 580 endif
 581 if sdl.found()
 582   # work around 2.0.8 bug
 583   sdl = declare_dependency(compile_args: '-Wno-undef',
 584                            dependencies: sdl)
 585   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 586                          method: 'pkg-config', static: enable_static)
 587 else
 588   if get_option('sdl_image').enabled()
 589     error('sdl-image required, but SDL was @0@'.format(
 590           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 591   endif
 592   sdl_image = not_found
 593 endif
 594
 595 rbd = not_found
 596 if 'CONFIG_RBD' in config_host
 597   rbd = declare_dependency(link_args: config_host['RBD_LIBS'].split())
 598 endif
 599 glusterfs = not_found
 600 if 'CONFIG_GLUSTERFS' in config_host
 601   glusterfs = declare_dependency(compile_args: config_host['GLUSTERFS_CFLAGS'].split(),
 602                                  link_args: config_host['GLUSTERFS_LIBS'].split())
 603 endif
 604 libssh = not_found
 605 if 'CONFIG_LIBSSH' in config_host
 606   libssh = declare_dependency(compile_args: config_host['LIBSSH_CFLAGS'].split(),
 607                               link_args: config_host['LIBSSH_LIBS'].split())
 608 endif
 609 libbzip2 = not_found
 610 if 'CONFIG_BZIP2' in config_host
 611   libbzip2 = declare_dependency(link_args: config_host['BZIP2_LIBS'].split())
 612 endif
 613 liblzfse = not_found
 614 if 'CONFIG_LZFSE' in config_host
 615   liblzfse = declare_dependency(link_args: config_host['LZFSE_LIBS'].split())
 616 endif
 617 oss = not_found
 618 if 'CONFIG_AUDIO_OSS' in config_host
 619   oss = declare_dependency(link_args: config_host['OSS_LIBS'].split())
 620 endif
 621 dsound = not_found
 622 if 'CONFIG_AUDIO_DSOUND' in config_host
 623   dsound = declare_dependency(link_args: config_host['DSOUND_LIBS'].split())
 624 endif
 625 coreaudio = not_found
 626 if 'CONFIG_AUDIO_COREAUDIO' in config_host
 627   coreaudio = declare_dependency(link_args: config_host['COREAUDIO_LIBS'].split())
 628 endif
 629 opengl = not_found
 630 if 'CONFIG_OPENGL' in config_host
 631   opengl = declare_dependency(compile_args: config_host['OPENGL_CFLAGS'].split(),
 632                               link_args: config_host['OPENGL_LIBS'].split())
 633 endif
 634 gtk = not_found
 635 if 'CONFIG_GTK' in config_host
 636   gtk = declare_dependency(compile_args: config_host['GTK_CFLAGS'].split(),
 637                               link_args: config_host['GTK_LIBS'].split())
 638 endif
 639 vte = not_found
 640 if 'CONFIG_VTE' in config_host
 641   vte = declare_dependency(compile_args: config_host['VTE_CFLAGS'].split(),
 642                            link_args: config_host['VTE_LIBS'].split())
 643 endif
 644 x11 = not_found
 645 if 'CONFIG_X11' in config_host
 646   x11 = declare_dependency(compile_args: config_host['X11_CFLAGS'].split(),
 647                            link_args: config_host['X11_LIBS'].split())
 648 endif
 649 vnc = not_found
 650 png = not_found
 651 jpeg = not_found
 652 sasl = not_found
 653 if get_option('vnc').enabled()
 654   vnc = declare_dependency() # dummy dependency
 655   png = dependency('libpng', required: get_option('vnc_png'),
 656                    method: 'pkg-config', static: enable_static)
 657   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
 658                     method: 'pkg-config', static: enable_static)
 659   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
 660                          required: get_option('vnc_sasl'),
 661                          static: enable_static)
 662   if sasl.found()
 663     sasl = declare_dependency(dependencies: sasl,
 664                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
 665   endif
 666 endif
 667 snappy = not_found
 668 if 'CONFIG_SNAPPY' in config_host
 669   snappy = declare_dependency(link_args: config_host['SNAPPY_LIBS'].split())
 670 endif
 671 lzo = not_found
 672 if 'CONFIG_LZO' in config_host
 673   lzo = declare_dependency(link_args: config_host['LZO_LIBS'].split())
 674 endif
 675 rdma = not_found
 676 if 'CONFIG_RDMA' in config_host
 677   rdma = declare_dependency(link_args: config_host['RDMA_LIBS'].split())
 678 endif
 679 numa = not_found
 680 if 'CONFIG_NUMA' in config_host
 681   numa = declare_dependency(link_args: config_host['NUMA_LIBS'].split())
 682 endif
 683 xen = not_found
 684 if 'CONFIG_XEN_BACKEND' in config_host
 685   xen = declare_dependency(compile_args: config_host['XEN_CFLAGS'].split(),
 686                            link_args: config_host['XEN_LIBS'].split())
 687 endif
 688 cacard = not_found
 689 if 'CONFIG_SMARTCARD' in config_host
 690   cacard = declare_dependency(compile_args: config_host['SMARTCARD_CFLAGS'].split(),
 691                               link_args: config_host['SMARTCARD_LIBS'].split())
 692 endif
 693 u2f = not_found
 694 if have_system
 695   u2f = dependency('u2f-emu', required: get_option('u2f'),
 696                    method: 'pkg-config',
 697                    static: enable_static)
 698 endif
 699 usbredir = not_found
 700 if 'CONFIG_USB_REDIR' in config_host
 701   usbredir = declare_dependency(compile_args: config_host['USB_REDIR_CFLAGS'].split(),
 702                                 link_args: config_host['USB_REDIR_LIBS'].split())
 703 endif
 704 libusb = not_found
 705 if 'CONFIG_USB_LIBUSB' in config_host
 706   libusb = declare_dependency(compile_args: config_host['LIBUSB_CFLAGS'].split(),
 707                               link_args: config_host['LIBUSB_LIBS'].split())
 708 endif
 709 libpmem = not_found
 710 if 'CONFIG_LIBPMEM' in config_host
 711   libpmem = declare_dependency(compile_args: config_host['LIBPMEM_CFLAGS'].split(),
 712                                link_args: config_host['LIBPMEM_LIBS'].split())
 713 endif
 714 libdaxctl = not_found
 715 if 'CONFIG_LIBDAXCTL' in config_host
 716   libdaxctl = declare_dependency(link_args: config_host['LIBDAXCTL_LIBS'].split())
 717 endif
 718 tasn1 = not_found
 719 if 'CONFIG_TASN1' in config_host
 720   tasn1 = declare_dependency(compile_args: config_host['TASN1_CFLAGS'].split(),
 721                              link_args: config_host['TASN1_LIBS'].split())
 722 endif
 723 keyutils = dependency('libkeyutils', required: false,
 724                       method: 'pkg-config', static: enable_static)
 725
 726 has_gettid = cc.has_function('gettid')
 727
 728 # Malloc tests
 729
 730 malloc = []
 731 if get_option('malloc') == 'system'
 732   has_malloc_trim = \
 733     not get_option('malloc_trim').disabled() and \
 734     cc.links('''#include <malloc.h>
 735                 int main(void) { malloc_trim(0); return 0; }''')
 736 else
 737   has_malloc_trim = false
 738   malloc = cc.find_library(get_option('malloc'), required: true)
 739 endif
 740 if not has_malloc_trim and get_option('malloc_trim').enabled()
 741   if get_option('malloc') == 'system'
 742     error('malloc_trim not available on this platform.')
 743   else
 744     error('malloc_trim not available with non-libc memory allocator')
 745   endif
 746 endif
 747
 748 # Check whether the glibc provides statx()
 749
 750 statx_test = '''
 751   #ifndef _GNU_SOURCE
 752   #define _GNU_SOURCE
 753   #endif
 754   #include <sys/stat.h>
 755   int main(void) {
 756     struct statx statxbuf;
 757     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
 758     return 0;
 759   }'''
 760
 761 has_statx = cc.links(statx_test)
 762
 763 have_vhost_user_blk_server = (targetos == 'linux' and
 764     'CONFIG_VHOST_USER' in config_host)
 765
 766 if get_option('vhost_user_blk_server').enabled()
 767     if targetos != 'linux'
 768         error('vhost_user_blk_server requires linux')
 769     elif 'CONFIG_VHOST_USER' not in config_host
 770         error('vhost_user_blk_server requires vhost-user support')
 771     endif
 772 elif get_option('vhost_user_blk_server').disabled() or not have_system
 773     have_vhost_user_blk_server = false
 774 endif
 775
 776 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
 777   error('Cannot enable fuse-lseek while fuse is disabled')
 778 endif
 779
 780 fuse = dependency('fuse3', required: get_option('fuse'),
 781                   version: '>=3.1', method: 'pkg-config',
 782                   static: enable_static)
 783
 784 fuse_lseek = not_found
 785 if not get_option('fuse_lseek').disabled()
 786   if fuse.version().version_compare('>=3.8')
 787     # Dummy dependency
 788     fuse_lseek = declare_dependency()
 789   elif get_option('fuse_lseek').enabled()
 790     if fuse.found()
 791       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
 792     else
 793       error('fuse-lseek requires libfuse, which was not found')
 794     endif
 795   endif
 796 endif
 797
 798 #################
 799 # config-host.h #
 800 #################
 801
 802 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
 803 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
 804 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
 805 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
 806 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
 807 config_host_data.set_quoted('CONFIG_QEMU_FIRMWAREPATH', get_option('qemu_firmwarepath'))
 808 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
 809 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
 810 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
 811 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
 812 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
 813 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
 814
 815 config_host_data.set('CONFIG_COCOA', cocoa.found())
 816 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
 817 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
 818 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
 819 config_host_data.set('CONFIG_CURSES', curses.found())
 820 config_host_data.set('CONFIG_SDL', sdl.found())
 821 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
 822 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
 823 config_host_data.set('CONFIG_VNC', vnc.found())
 824 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
 825 config_host_data.set('CONFIG_VNC_PNG', png.found())
 826 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
 827 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
 828 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
 829 config_host_data.set('CONFIG_GETTID', has_gettid)
 830 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
 831 config_host_data.set('CONFIG_STATX', has_statx)
 832 config_host_data.set('CONFIG_FUSE', fuse.found())
 833 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
 834 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
 835 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
 836 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
 837 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
 838
 839 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
 840 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
 841 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
 842 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
 843 config_host_data.set('HAVE_SYS_SIGNAL_H', cc.has_header('sys/signal.h'))
 844
 845 ignored = ['CONFIG_QEMU_INTERP_PREFIX'] # actually per-target
 846 arrays = ['CONFIG_AUDIO_DRIVERS', 'CONFIG_BDRV_RW_WHITELIST', 'CONFIG_BDRV_RO_WHITELIST']
 847 strings = ['HOST_DSOSUF', 'CONFIG_IASL']
 848 foreach k, v: config_host
 849   if ignored.contains(k)
 850     # do nothing
 851   elif arrays.contains(k)
 852     if v != ''
 853       v = '"' + '", "'.join(v.split()) + '", '
 854     endif
 855     config_host_data.set(k, v)
 856   elif k == 'ARCH'
 857     config_host_data.set('HOST_' + v.to_upper(), 1)
 858   elif strings.contains(k)
 859     if not k.startswith('CONFIG_')
 860       k = 'CONFIG_' + k.to_upper()
 861     endif
 862     config_host_data.set_quoted(k, v)
 863   elif k.startswith('CONFIG_') or k.startswith('HAVE_') or k.startswith('HOST_')
 864     config_host_data.set(k, v == 'y' ? 1 : v)
 865   endif
 866 endforeach
 867
 868 ########################
 869 # Target configuration #
 870 ########################
 871
 872 minikconf = find_program('scripts/minikconf.py')
 873 config_all = {}
 874 config_all_devices = {}
 875 config_all_disas = {}
 876 config_devices_mak_list = []
 877 config_devices_h = {}
 878 config_target_h = {}
 879 config_target_mak = {}
 880
 881 disassemblers = {
 882   'alpha' : ['CONFIG_ALPHA_DIS'],
 883   'arm' : ['CONFIG_ARM_DIS'],
 884   'avr' : ['CONFIG_AVR_DIS'],
 885   'cris' : ['CONFIG_CRIS_DIS'],
 886   'hppa' : ['CONFIG_HPPA_DIS'],
 887   'i386' : ['CONFIG_I386_DIS'],
 888   'x86_64' : ['CONFIG_I386_DIS'],
 889   'x32' : ['CONFIG_I386_DIS'],
 890   'lm32' : ['CONFIG_LM32_DIS'],
 891   'm68k' : ['CONFIG_M68K_DIS'],
 892   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
 893   'mips' : ['CONFIG_MIPS_DIS'],
 894   'moxie' : ['CONFIG_MOXIE_DIS'],
 895   'nios2' : ['CONFIG_NIOS2_DIS'],
 896   'or1k' : ['CONFIG_OPENRISC_DIS'],
 897   'ppc' : ['CONFIG_PPC_DIS'],
 898   'riscv' : ['CONFIG_RISCV_DIS'],
 899   'rx' : ['CONFIG_RX_DIS'],
 900   's390' : ['CONFIG_S390_DIS'],
 901   'sh4' : ['CONFIG_SH4_DIS'],
 902   'sparc' : ['CONFIG_SPARC_DIS'],
 903   'xtensa' : ['CONFIG_XTENSA_DIS'],
 904 }
 905 if link_language == 'cpp'
 906   disassemblers += {
 907     'aarch64' : [ 'CONFIG_ARM_A64_DIS'],
 908     'arm' : [ 'CONFIG_ARM_DIS', 'CONFIG_ARM_A64_DIS'],
 909     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
 910   }
 911 endif
 912
 913 kconfig_external_symbols = [
 914   'CONFIG_KVM',
 915   'CONFIG_XEN',
 916   'CONFIG_TPM',
 917   'CONFIG_SPICE',
 918   'CONFIG_IVSHMEM',
 919   'CONFIG_OPENGL',
 920   'CONFIG_X11',
 921   'CONFIG_VHOST_USER',
 922   'CONFIG_VHOST_VDPA',
 923   'CONFIG_VHOST_KERNEL',
 924   'CONFIG_VIRTFS',
 925   'CONFIG_LINUX',
 926   'CONFIG_PVRDMA',
 927 ]
 928 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
 929
 930 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
 931 actual_target_dirs = []
 932 fdt_required = []
 933 foreach target : target_dirs
 934   config_target = { 'TARGET_NAME': target.split('-')[0] }
 935   if target.endswith('linux-user')
 936     if targetos != 'linux'
 937       if default_targets
 938         continue
 939       endif
 940       error('Target @0@ is only available on a Linux host'.format(target))
 941     endif
 942     config_target += { 'CONFIG_LINUX_USER': 'y' }
 943   elif target.endswith('bsd-user')
 944     if 'CONFIG_BSD' not in config_host
 945       if default_targets
 946         continue
 947       endif
 948       error('Target @0@ is only available on a BSD host'.format(target))
 949     endif
 950     config_target += { 'CONFIG_BSD_USER': 'y' }
 951   elif target.endswith('softmmu')
 952     config_target += { 'CONFIG_SOFTMMU': 'y' }
 953   endif
 954   if target.endswith('-user')
 955     config_target += {
 956       'CONFIG_USER_ONLY': 'y',
 957       'CONFIG_QEMU_INTERP_PREFIX':
 958         config_host['CONFIG_QEMU_INTERP_PREFIX'].format(config_target['TARGET_NAME'])
 959     }
 960   endif
 961
 962   have_accel = false
 963   foreach sym: accelerators
 964     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
 965       config_target += { sym: 'y' }
 966       config_all += { sym: 'y' }
 967       if sym == 'CONFIG_XEN' and have_xen_pci_passthrough
 968         config_target += { 'CONFIG_XEN_PCI_PASSTHROUGH': 'y' }
 969       endif
 970       have_accel = true
 971     endif
 972   endforeach
 973   if not have_accel
 974     if default_targets
 975       continue
 976     endif
 977     error('No accelerator available for target @0@'.format(target))
 978   endif
 979
 980   actual_target_dirs += target
 981   config_target += keyval.load('default-configs/targets' / target + '.mak')
 982   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
 983
 984   if 'TARGET_NEED_FDT' in config_target
 985     fdt_required += target
 986   endif
 987
 988   # Add default keys
 989   if 'TARGET_BASE_ARCH' not in config_target
 990     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
 991   endif
 992   if 'TARGET_ABI_DIR' not in config_target
 993     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
 994   endif
 995
 996   foreach k, v: disassemblers
 997     if config_host['ARCH'].startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
 998       foreach sym: v
 999         config_target += { sym: 'y' }
1000         config_all_disas += { sym: 'y' }
1001       endforeach
1002     endif
1003   endforeach
1004
1005   config_target_data = configuration_data()
1006   foreach k, v: config_target
1007     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
1008       # do nothing
1009     elif ignored.contains(k)
1010       # do nothing
1011     elif k == 'TARGET_BASE_ARCH'
1012       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
1013       # not used to select files from sourcesets.
1014       config_target_data.set('TARGET_' + v.to_upper(), 1)
1015     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
1016       config_target_data.set_quoted(k, v)
1017     elif v == 'y'
1018       config_target_data.set(k, 1)
1019     else
1020       config_target_data.set(k, v)
1021     endif
1022   endforeach
1023   config_target_h += {target: configure_file(output: target + '-config-target.h',
1024                                                configuration: config_target_data)}
1025
1026   if target.endswith('-softmmu')
1027     base_kconfig = []
1028     foreach sym : kconfig_external_symbols
1029       if sym in config_target or sym in config_host
1030         base_kconfig += '@0@=y'.format(sym)
1031       endif
1032     endforeach
1033
1034     config_devices_mak = target + '-config-devices.mak'
1035     config_devices_mak = configure_file(
1036       input: ['default-configs/devices' / target + '.mak', 'Kconfig'],
1037       output: config_devices_mak,
1038       depfile: config_devices_mak + '.d',
1039       capture: true,
1040       command: [minikconf, config_host['CONFIG_MINIKCONF_MODE'],
1041                 config_devices_mak, '@DEPFILE@', '@INPUT@',
1042                 base_kconfig])
1043
1044     config_devices_data = configuration_data()
1045     config_devices = keyval.load(config_devices_mak)
1046     foreach k, v: config_devices
1047       config_devices_data.set(k, 1)
1048     endforeach
1049     config_devices_mak_list += config_devices_mak
1050     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
1051                                                 configuration: config_devices_data)}
1052     config_target += config_devices
1053     config_all_devices += config_devices
1054   endif
1055   config_target_mak += {target: config_target}
1056 endforeach
1057 target_dirs = actual_target_dirs
1058
1059 # This configuration is used to build files that are shared by
1060 # multiple binaries, and then extracted out of the "common"
1061 # static_library target.
1062 #
1063 # We do not use all_sources()/all_dependencies(), because it would
1064 # build literally all source files, including devices only used by
1065 # targets that are not built for this compilation.  The CONFIG_ALL
1066 # pseudo symbol replaces it.
1067
1068 config_all += config_all_devices
1069 config_all += config_host
1070 config_all += config_all_disas
1071 config_all += {
1072   'CONFIG_XEN': config_host.has_key('CONFIG_XEN_BACKEND'),
1073   'CONFIG_SOFTMMU': have_system,
1074   'CONFIG_USER_ONLY': have_user,
1075   'CONFIG_ALL': true,
1076 }
1077
1078 ##############
1079 # Submodules #
1080 ##############
1081
1082 capstone = not_found
1083 capstone_opt = get_option('capstone')
1084 if capstone_opt in ['enabled', 'auto', 'system']
1085   have_internal = fs.exists(meson.current_source_dir() / 'capstone/Makefile')
1086   capstone = dependency('capstone', version: '>=4.0',
1087                         static: enable_static, method: 'pkg-config',
1088                         required: capstone_opt == 'system' or
1089                                   capstone_opt == 'enabled' and not have_internal)
1090   if capstone.found()
1091     capstone_opt = 'system'
1092   elif have_internal
1093     capstone_opt = 'internal'
1094   else
1095     capstone_opt = 'disabled'
1096   endif
1097 endif
1098 if capstone_opt == 'internal'
1099   capstone_data = configuration_data()
1100   capstone_data.set('CAPSTONE_USE_SYS_DYN_MEM', '1')
1101
1102   capstone_files = files(
1103     'capstone/cs.c',
1104     'capstone/MCInst.c',
1105     'capstone/MCInstrDesc.c',
1106     'capstone/MCRegisterInfo.c',
1107     'capstone/SStream.c',
1108     'capstone/utils.c'
1109   )
1110
1111   if 'CONFIG_ARM_DIS' in config_all_disas
1112     capstone_data.set('CAPSTONE_HAS_ARM', '1')
1113     capstone_files += files(
1114       'capstone/arch/ARM/ARMDisassembler.c',
1115       'capstone/arch/ARM/ARMInstPrinter.c',
1116       'capstone/arch/ARM/ARMMapping.c',
1117       'capstone/arch/ARM/ARMModule.c'
1118     )
1119   endif
1120
1121   # FIXME: This config entry currently depends on a c++ compiler.
1122   # Which is needed for building libvixl, but not for capstone.
1123   if 'CONFIG_ARM_A64_DIS' in config_all_disas
1124     capstone_data.set('CAPSTONE_HAS_ARM64', '1')
1125     capstone_files += files(
1126       'capstone/arch/AArch64/AArch64BaseInfo.c',
1127       'capstone/arch/AArch64/AArch64Disassembler.c',
1128       'capstone/arch/AArch64/AArch64InstPrinter.c',
1129       'capstone/arch/AArch64/AArch64Mapping.c',
1130       'capstone/arch/AArch64/AArch64Module.c'
1131     )
1132   endif
1133
1134   if 'CONFIG_PPC_DIS' in config_all_disas
1135     capstone_data.set('CAPSTONE_HAS_POWERPC', '1')
1136     capstone_files += files(
1137       'capstone/arch/PowerPC/PPCDisassembler.c',
1138       'capstone/arch/PowerPC/PPCInstPrinter.c',
1139       'capstone/arch/PowerPC/PPCMapping.c',
1140       'capstone/arch/PowerPC/PPCModule.c'
1141     )
1142   endif
1143
1144   if 'CONFIG_S390_DIS' in config_all_disas
1145     capstone_data.set('CAPSTONE_HAS_SYSZ', '1')
1146     capstone_files += files(
1147       'capstone/arch/SystemZ/SystemZDisassembler.c',
1148       'capstone/arch/SystemZ/SystemZInstPrinter.c',
1149       'capstone/arch/SystemZ/SystemZMapping.c',
1150       'capstone/arch/SystemZ/SystemZModule.c',
1151       'capstone/arch/SystemZ/SystemZMCTargetDesc.c'
1152     )
1153   endif
1154
1155   if 'CONFIG_I386_DIS' in config_all_disas
1156     capstone_data.set('CAPSTONE_HAS_X86', 1)
1157     capstone_files += files(
1158       'capstone/arch/X86/X86Disassembler.c',
1159       'capstone/arch/X86/X86DisassemblerDecoder.c',
1160       'capstone/arch/X86/X86ATTInstPrinter.c',
1161       'capstone/arch/X86/X86IntelInstPrinter.c',
1162       'capstone/arch/X86/X86InstPrinterCommon.c',
1163       'capstone/arch/X86/X86Mapping.c',
1164       'capstone/arch/X86/X86Module.c'
1165     )
1166   endif
1167
1168   configure_file(output: 'capstone-defs.h', configuration: capstone_data)
1169
1170   capstone_cargs = [
1171     # FIXME: There does not seem to be a way to completely replace the c_args
1172     # that come from add_project_arguments() -- we can only add to them.
1173     # So: disable all warnings with a big hammer.
1174     '-Wno-error', '-w',
1175
1176     # Include all configuration defines via a header file, which will wind up
1177     # as a dependency on the object file, and thus changes here will result
1178     # in a rebuild.
1179     '-include', 'capstone-defs.h'
1180   ]
1181
1182   libcapstone = static_library('capstone',
1183                                sources: capstone_files,
1184                                c_args: capstone_cargs,
1185                                include_directories: 'capstone/include')
1186   capstone = declare_dependency(link_with: libcapstone,
1187                                 include_directories: 'capstone/include/capstone')
1188 endif
1189
1190 slirp = not_found
1191 slirp_opt = 'disabled'
1192 if have_system
1193   slirp_opt = get_option('slirp')
1194   if slirp_opt in ['enabled', 'auto', 'system']
1195     have_internal = fs.exists(meson.current_source_dir() / 'slirp/meson.build')
1196     slirp = dependency('slirp', static: enable_static,
1197                        method: 'pkg-config',
1198                        required: slirp_opt == 'system' or
1199                                  slirp_opt == 'enabled' and not have_internal)
1200     if slirp.found()
1201       slirp_opt = 'system'
1202     elif have_internal
1203       slirp_opt = 'internal'
1204     else
1205       slirp_opt = 'disabled'
1206     endif
1207   endif
1208   if slirp_opt == 'internal'
1209     slirp_deps = []
1210     if targetos == 'windows'
1211       slirp_deps = cc.find_library('iphlpapi')
1212     endif
1213     slirp_conf = configuration_data()
1214     slirp_conf.set('SLIRP_MAJOR_VERSION', meson.project_version().split('.')[0])
1215     slirp_conf.set('SLIRP_MINOR_VERSION', meson.project_version().split('.')[1])
1216     slirp_conf.set('SLIRP_MICRO_VERSION', meson.project_version().split('.')[2])
1217     slirp_conf.set_quoted('SLIRP_VERSION_STRING', meson.project_version())
1218     slirp_cargs = ['-DG_LOG_DOMAIN="Slirp"']
1219     slirp_files = [
1220       'slirp/src/arp_table.c',
1221       'slirp/src/bootp.c',
1222       'slirp/src/cksum.c',
1223       'slirp/src/dhcpv6.c',
1224       'slirp/src/dnssearch.c',
1225       'slirp/src/if.c',
1226       'slirp/src/ip6_icmp.c',
1227       'slirp/src/ip6_input.c',
1228       'slirp/src/ip6_output.c',
1229       'slirp/src/ip_icmp.c',
1230       'slirp/src/ip_input.c',
1231       'slirp/src/ip_output.c',
1232       'slirp/src/mbuf.c',
1233       'slirp/src/misc.c',
1234       'slirp/src/ncsi.c',
1235       'slirp/src/ndp_table.c',
1236       'slirp/src/sbuf.c',
1237       'slirp/src/slirp.c',
1238       'slirp/src/socket.c',
1239       'slirp/src/state.c',
1240       'slirp/src/stream.c',
1241       'slirp/src/tcp_input.c',
1242       'slirp/src/tcp_output.c',
1243       'slirp/src/tcp_subr.c',
1244       'slirp/src/tcp_timer.c',
1245       'slirp/src/tftp.c',
1246       'slirp/src/udp.c',
1247       'slirp/src/udp6.c',
1248       'slirp/src/util.c',
1249       'slirp/src/version.c',
1250       'slirp/src/vmstate.c',
1251     ]
1252
1253     configure_file(
1254       input : 'slirp/src/libslirp-version.h.in',
1255       output : 'libslirp-version.h',
1256       configuration: slirp_conf)
1257
1258     slirp_inc = include_directories('slirp', 'slirp/src')
1259     libslirp = static_library('slirp',
1260                               sources: slirp_files,
1261                               c_args: slirp_cargs,
1262                               include_directories: slirp_inc)
1263     slirp = declare_dependency(link_with: libslirp,
1264                                dependencies: slirp_deps,
1265                                include_directories: slirp_inc)
1266   endif
1267 endif
1268
1269 fdt = not_found
1270 fdt_opt = get_option('fdt')
1271 if have_system
1272   if fdt_opt in ['enabled', 'auto', 'system']
1273     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
1274     fdt = cc.find_library('fdt', static: enable_static,
1275                           required: fdt_opt == 'system' or
1276                                     fdt_opt == 'enabled' and not have_internal)
1277     if fdt.found() and cc.links('''
1278        #include <libfdt.h>
1279        #include <libfdt_env.h>
1280        int main(void) { fdt_check_full(NULL, 0); return 0; }''',
1281          dependencies: fdt)
1282       fdt_opt = 'system'
1283     elif have_internal
1284       fdt_opt = 'internal'
1285     else
1286       fdt_opt = 'disabled'
1287     endif
1288   endif
1289   if fdt_opt == 'internal'
1290     fdt_files = files(
1291       'dtc/libfdt/fdt.c',
1292       'dtc/libfdt/fdt_ro.c',
1293       'dtc/libfdt/fdt_wip.c',
1294       'dtc/libfdt/fdt_sw.c',
1295       'dtc/libfdt/fdt_rw.c',
1296       'dtc/libfdt/fdt_strerror.c',
1297       'dtc/libfdt/fdt_empty_tree.c',
1298       'dtc/libfdt/fdt_addresses.c',
1299       'dtc/libfdt/fdt_overlay.c',
1300       'dtc/libfdt/fdt_check.c',
1301     )
1302
1303     fdt_inc = include_directories('dtc/libfdt')
1304     libfdt = static_library('fdt',
1305                             sources: fdt_files,
1306                             include_directories: fdt_inc)
1307     fdt = declare_dependency(link_with: libfdt,
1308                              include_directories: fdt_inc)
1309   endif
1310 endif
1311 if not fdt.found() and fdt_required.length() > 0
1312   error('fdt not available but required by targets ' + ', '.join(fdt_required))
1313 endif
1314
1315 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
1316 config_host_data.set('CONFIG_FDT', fdt.found())
1317 config_host_data.set('CONFIG_SLIRP', slirp.found())
1318
1319 #####################
1320 # Generated sources #
1321 #####################
1322
1323 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
1324
1325 hxtool = find_program('scripts/hxtool')
1326 shaderinclude = find_program('scripts/shaderinclude.pl')
1327 qapi_gen = find_program('scripts/qapi-gen.py')
1328 qapi_gen_depends = [ meson.source_root() / 'scripts/qapi/__init__.py',
1329                      meson.source_root() / 'scripts/qapi/commands.py',
1330                      meson.source_root() / 'scripts/qapi/common.py',
1331                      meson.source_root() / 'scripts/qapi/error.py',
1332                      meson.source_root() / 'scripts/qapi/events.py',
1333                      meson.source_root() / 'scripts/qapi/expr.py',
1334                      meson.source_root() / 'scripts/qapi/gen.py',
1335                      meson.source_root() / 'scripts/qapi/introspect.py',
1336                      meson.source_root() / 'scripts/qapi/parser.py',
1337                      meson.source_root() / 'scripts/qapi/schema.py',
1338                      meson.source_root() / 'scripts/qapi/source.py',
1339                      meson.source_root() / 'scripts/qapi/types.py',
1340                      meson.source_root() / 'scripts/qapi/visit.py',
1341                      meson.source_root() / 'scripts/qapi/common.py',
1342                      meson.source_root() / 'scripts/qapi-gen.py'
1343 ]
1344
1345 tracetool = [
1346   python, files('scripts/tracetool.py'),
1347    '--backend=' + config_host['TRACE_BACKENDS']
1348 ]
1349
1350 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
1351                     meson.current_source_dir(),
1352                     config_host['PKGVERSION'], meson.project_version()]
1353 qemu_version = custom_target('qemu-version.h',
1354                              output: 'qemu-version.h',
1355                              command: qemu_version_cmd,
1356                              capture: true,
1357                              build_by_default: true,
1358                              build_always_stale: true)
1359 genh += qemu_version
1360
1361 hxdep = []
1362 hx_headers = [
1363   ['qemu-options.hx', 'qemu-options.def'],
1364   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
1365 ]
1366 if have_system
1367   hx_headers += [
1368     ['hmp-commands.hx', 'hmp-commands.h'],
1369     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
1370   ]
1371 endif
1372 foreach d : hx_headers
1373   hxdep += custom_target(d[1],
1374                 input: files(d[0]),
1375                 output: d[1],
1376                 capture: true,
1377                 build_by_default: true, # to be removed when added to a target
1378                 command: [hxtool, '-h', '@INPUT0@'])
1379 endforeach
1380 genh += hxdep
1381
1382 ###################
1383 # Collect sources #
1384 ###################
1385
1386 authz_ss = ss.source_set()
1387 blockdev_ss = ss.source_set()
1388 block_ss = ss.source_set()
1389 bsd_user_ss = ss.source_set()
1390 chardev_ss = ss.source_set()
1391 common_ss = ss.source_set()
1392 crypto_ss = ss.source_set()
1393 io_ss = ss.source_set()
1394 linux_user_ss = ss.source_set()
1395 qmp_ss = ss.source_set()
1396 qom_ss = ss.source_set()
1397 softmmu_ss = ss.source_set()
1398 specific_fuzz_ss = ss.source_set()
1399 specific_ss = ss.source_set()
1400 stub_ss = ss.source_set()
1401 trace_ss = ss.source_set()
1402 user_ss = ss.source_set()
1403 util_ss = ss.source_set()
1404
1405 modules = {}
1406 hw_arch = {}
1407 target_arch = {}
1408 target_softmmu_arch = {}
1409
1410 ###############
1411 # Trace files #
1412 ###############
1413
1414 # TODO: add each directory to the subdirs from its own meson.build, once
1415 # we have those
1416 trace_events_subdirs = [
1417   'accel/kvm',
1418   'accel/tcg',
1419   'crypto',
1420   'monitor',
1421 ]
1422 if have_user
1423   trace_events_subdirs += [ 'linux-user' ]
1424 endif
1425 if have_block
1426   trace_events_subdirs += [
1427     'authz',
1428     'block',
1429     'io',
1430     'nbd',
1431     'scsi',
1432   ]
1433 endif
1434 if have_system
1435   trace_events_subdirs += [
1436     'audio',
1437     'backends',
1438     'backends/tpm',
1439     'chardev',
1440     'hw/9pfs',
1441     'hw/acpi',
1442     'hw/alpha',
1443     'hw/arm',
1444     'hw/audio',
1445     'hw/block',
1446     'hw/block/dataplane',
1447     'hw/char',
1448     'hw/display',
1449     'hw/dma',
1450     'hw/hppa',
1451     'hw/hyperv',
1452     'hw/i2c',
1453     'hw/i386',
1454     'hw/i386/xen',
1455     'hw/ide',
1456     'hw/input',
1457     'hw/intc',
1458     'hw/isa',
1459     'hw/mem',
1460     'hw/mips',
1461     'hw/misc',
1462     'hw/misc/macio',
1463     'hw/net',
1464     'hw/net/can',
1465     'hw/nvram',
1466     'hw/pci',
1467     'hw/pci-host',
1468     'hw/ppc',
1469     'hw/rdma',
1470     'hw/rdma/vmw',
1471     'hw/rtc',
1472     'hw/s390x',
1473     'hw/scsi',
1474     'hw/sd',
1475     'hw/sparc',
1476     'hw/sparc64',
1477     'hw/ssi',
1478     'hw/timer',
1479     'hw/tpm',
1480     'hw/usb',
1481     'hw/vfio',
1482     'hw/virtio',
1483     'hw/watchdog',
1484     'hw/xen',
1485     'hw/gpio',
1486     'migration',
1487     'net',
1488     'softmmu',
1489     'ui',
1490   ]
1491 endif
1492 trace_events_subdirs += [
1493   'hw/core',
1494   'qapi',
1495   'qom',
1496   'target/arm',
1497   'target/hppa',
1498   'target/i386',
1499   'target/mips',
1500   'target/ppc',
1501   'target/riscv',
1502   'target/s390x',
1503   'target/sparc',
1504   'util',
1505 ]
1506
1507 vhost_user = not_found
1508 if 'CONFIG_VHOST_USER' in config_host
1509   libvhost_user = subproject('libvhost-user')
1510   vhost_user = libvhost_user.get_variable('vhost_user_dep')
1511 endif
1512
1513 subdir('qapi')
1514 subdir('qobject')
1515 subdir('stubs')
1516 subdir('trace')
1517 subdir('util')
1518 subdir('qom')
1519 subdir('authz')
1520 subdir('crypto')
1521 subdir('ui')
1522
1523
1524 if enable_modules
1525   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
1526   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
1527 endif
1528
1529 stub_ss = stub_ss.apply(config_all, strict: false)
1530
1531 util_ss.add_all(trace_ss)
1532 util_ss = util_ss.apply(config_all, strict: false)
1533 libqemuutil = static_library('qemuutil',
1534                              sources: util_ss.sources() + stub_ss.sources() + genh,
1535                              dependencies: [util_ss.dependencies(), m, glib, socket, malloc])
1536 qemuutil = declare_dependency(link_with: libqemuutil,
1537                               sources: genh + version_res)
1538
1539 decodetree = generator(find_program('scripts/decodetree.py'),
1540                        output: 'decode-@BASENAME@.c.inc',
1541                        arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
1542
1543 subdir('audio')
1544 subdir('io')
1545 subdir('chardev')
1546 subdir('fsdev')
1547 subdir('libdecnumber')
1548 subdir('target')
1549 subdir('dump')
1550
1551 block_ss.add(files(
1552   'block.c',
1553   'blockjob.c',
1554   'job.c',
1555   'qemu-io-cmds.c',
1556 ))
1557 block_ss.add(when: 'CONFIG_REPLICATION', if_true: files('replication.c'))
1558
1559 subdir('nbd')
1560 subdir('scsi')
1561 subdir('block')
1562
1563 blockdev_ss.add(files(
1564   'blockdev.c',
1565   'blockdev-nbd.c',
1566   'iothread.c',
1567   'job-qmp.c',
1568 ))
1569
1570 # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
1571 # os-win32.c does not
1572 blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
1573 softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
1574
1575 common_ss.add(files('cpus-common.c'))
1576
1577 subdir('softmmu')
1578
1579 common_ss.add(capstone)
1580 specific_ss.add(files('cpu.c', 'disas.c', 'gdbstub.c'), capstone)
1581 specific_ss.add(files('exec-vary.c'))
1582 specific_ss.add(when: 'CONFIG_TCG', if_true: files(
1583   'fpu/softfloat.c',
1584   'tcg/optimize.c',
1585   'tcg/tcg-common.c',
1586   'tcg/tcg-op-gvec.c',
1587   'tcg/tcg-op-vec.c',
1588   'tcg/tcg-op.c',
1589   'tcg/tcg.c',
1590 ))
1591 specific_ss.add(when: 'CONFIG_TCG_INTERPRETER', if_true: files('disas/tci.c', 'tcg/tci.c'))
1592
1593 subdir('backends')
1594 subdir('disas')
1595 subdir('migration')
1596 subdir('monitor')
1597 subdir('net')
1598 subdir('replay')
1599 subdir('hw')
1600 subdir('accel')
1601 subdir('plugins')
1602 subdir('bsd-user')
1603 subdir('linux-user')
1604
1605 bsd_user_ss.add(files('gdbstub.c'))
1606 specific_ss.add_all(when: 'CONFIG_BSD_USER', if_true: bsd_user_ss)
1607
1608 linux_user_ss.add(files('gdbstub.c', 'thunk.c'))
1609 specific_ss.add_all(when: 'CONFIG_LINUX_USER', if_true: linux_user_ss)
1610
1611 # needed for fuzzing binaries
1612 subdir('tests/qtest/libqos')
1613 subdir('tests/qtest/fuzz')
1614
1615 ########################
1616 # Library dependencies #
1617 ########################
1618
1619 block_mods = []
1620 softmmu_mods = []
1621 foreach d, list : modules
1622   foreach m, module_ss : list
1623     if enable_modules and targetos != 'windows'
1624       module_ss = module_ss.apply(config_all, strict: false)
1625       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
1626                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
1627       if d == 'block'
1628         block_mods += sl
1629       else
1630         softmmu_mods += sl
1631       endif
1632     else
1633       if d == 'block'
1634         block_ss.add_all(module_ss)
1635       else
1636         softmmu_ss.add_all(module_ss)
1637       endif
1638     endif
1639   endforeach
1640 endforeach
1641
1642 nm = find_program('nm')
1643 undefsym = find_program('scripts/undefsym.py')
1644 block_syms = custom_target('block.syms', output: 'block.syms',
1645                              input: [libqemuutil, block_mods],
1646                              capture: true,
1647                              command: [undefsym, nm, '@INPUT@'])
1648 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
1649                              input: [libqemuutil, softmmu_mods],
1650                              capture: true,
1651                              command: [undefsym, nm, '@INPUT@'])
1652
1653 qom_ss = qom_ss.apply(config_host, strict: false)
1654 libqom = static_library('qom', qom_ss.sources() + genh,
1655                         dependencies: [qom_ss.dependencies()],
1656                         name_suffix: 'fa')
1657
1658 qom = declare_dependency(link_whole: libqom)
1659
1660 authz_ss = authz_ss.apply(config_host, strict: false)
1661 libauthz = static_library('authz', authz_ss.sources() + genh,
1662                           dependencies: [authz_ss.dependencies()],
1663                           name_suffix: 'fa',
1664                           build_by_default: false)
1665
1666 authz = declare_dependency(link_whole: libauthz,
1667                            dependencies: qom)
1668
1669 crypto_ss = crypto_ss.apply(config_host, strict: false)
1670 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
1671                            dependencies: [crypto_ss.dependencies()],
1672                            name_suffix: 'fa',
1673                            build_by_default: false)
1674
1675 crypto = declare_dependency(link_whole: libcrypto,
1676                             dependencies: [authz, qom])
1677
1678 io_ss = io_ss.apply(config_host, strict: false)
1679 libio = static_library('io', io_ss.sources() + genh,
1680                        dependencies: [io_ss.dependencies()],
1681                        link_with: libqemuutil,
1682                        name_suffix: 'fa',
1683                        build_by_default: false)
1684
1685 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
1686
1687 libmigration = static_library('migration', sources: migration_files + genh,
1688                               name_suffix: 'fa',
1689                               build_by_default: false)
1690 migration = declare_dependency(link_with: libmigration,
1691                                dependencies: [zlib, qom, io])
1692 softmmu_ss.add(migration)
1693
1694 block_ss = block_ss.apply(config_host, strict: false)
1695 libblock = static_library('block', block_ss.sources() + genh,
1696                           dependencies: block_ss.dependencies(),
1697                           link_depends: block_syms,
1698                           name_suffix: 'fa',
1699                           build_by_default: false)
1700
1701 block = declare_dependency(link_whole: [libblock],
1702                            link_args: '@block.syms',
1703                            dependencies: [crypto, io])
1704
1705 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
1706 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
1707                              dependencies: blockdev_ss.dependencies(),
1708                              name_suffix: 'fa',
1709                              build_by_default: false)
1710
1711 blockdev = declare_dependency(link_whole: [libblockdev],
1712                               dependencies: [block])
1713
1714 qmp_ss = qmp_ss.apply(config_host, strict: false)
1715 libqmp = static_library('qmp', qmp_ss.sources() + genh,
1716                         dependencies: qmp_ss.dependencies(),
1717                         name_suffix: 'fa',
1718                         build_by_default: false)
1719
1720 qmp = declare_dependency(link_whole: [libqmp])
1721
1722 libchardev = static_library('chardev', chardev_ss.sources() + genh,
1723                             name_suffix: 'fa',
1724                             build_by_default: false)
1725
1726 chardev = declare_dependency(link_whole: libchardev)
1727
1728 libhwcore = static_library('hwcore', sources: hwcore_files + genh,
1729                            name_suffix: 'fa',
1730                            build_by_default: false)
1731 hwcore = declare_dependency(link_whole: libhwcore)
1732 common_ss.add(hwcore)
1733
1734 ###########
1735 # Targets #
1736 ###########
1737
1738 foreach m : block_mods + softmmu_mods
1739   shared_module(m.name(),
1740                 name_prefix: '',
1741                 link_whole: m,
1742                 install: true,
1743                 install_dir: qemu_moddir)
1744 endforeach
1745
1746 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
1747 common_ss.add(qom, qemuutil)
1748
1749 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
1750 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
1751
1752 common_all = common_ss.apply(config_all, strict: false)
1753 common_all = static_library('common',
1754                             build_by_default: false,
1755                             sources: common_all.sources() + genh,
1756                             dependencies: common_all.dependencies(),
1757                             name_suffix: 'fa')
1758
1759 feature_to_c = find_program('scripts/feature_to_c.sh')
1760
1761 emulators = {}
1762 foreach target : target_dirs
1763   config_target = config_target_mak[target]
1764   target_name = config_target['TARGET_NAME']
1765   arch = config_target['TARGET_BASE_ARCH']
1766   arch_srcs = [config_target_h[target]]
1767   arch_deps = []
1768   c_args = ['-DNEED_CPU_H',
1769             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
1770             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
1771   link_args = emulator_link_args
1772
1773   config_target += config_host
1774   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
1775   if targetos == 'linux'
1776     target_inc += include_directories('linux-headers', is_system: true)
1777   endif
1778   if target.endswith('-softmmu')
1779     qemu_target_name = 'qemu-system-' + target_name
1780     target_type='system'
1781     t = target_softmmu_arch[arch].apply(config_target, strict: false)
1782     arch_srcs += t.sources()
1783     arch_deps += t.dependencies()
1784
1785     hw_dir = target_name == 'sparc64' ? 'sparc64' : arch
1786     hw = hw_arch[hw_dir].apply(config_target, strict: false)
1787     arch_srcs += hw.sources()
1788     arch_deps += hw.dependencies()
1789
1790     arch_srcs += config_devices_h[target]
1791     link_args += ['@block.syms', '@qemu.syms']
1792   else
1793     abi = config_target['TARGET_ABI_DIR']
1794     target_type='user'
1795     qemu_target_name = 'qemu-' + target_name
1796     if 'CONFIG_LINUX_USER' in config_target
1797       base_dir = 'linux-user'
1798       target_inc += include_directories('linux-user/host/' / config_host['ARCH'])
1799     else
1800       base_dir = 'bsd-user'
1801     endif
1802     target_inc += include_directories(
1803       base_dir,
1804       base_dir / abi,
1805     )
1806     if 'CONFIG_LINUX_USER' in config_target
1807       dir = base_dir / abi
1808       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
1809       if config_target.has_key('TARGET_SYSTBL_ABI')
1810         arch_srcs += \
1811           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
1812                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
1813       endif
1814     endif
1815   endif
1816
1817   if 'TARGET_XML_FILES' in config_target
1818     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
1819                                 output: target + '-gdbstub-xml.c',
1820                                 input: files(config_target['TARGET_XML_FILES'].split()),
1821                                 command: [feature_to_c, '@INPUT@'],
1822                                 capture: true)
1823     arch_srcs += gdbstub_xml
1824   endif
1825
1826   t = target_arch[arch].apply(config_target, strict: false)
1827   arch_srcs += t.sources()
1828   arch_deps += t.dependencies()
1829
1830   target_common = common_ss.apply(config_target, strict: false)
1831   objects = common_all.extract_objects(target_common.sources())
1832   deps = target_common.dependencies()
1833
1834   target_specific = specific_ss.apply(config_target, strict: false)
1835   arch_srcs += target_specific.sources()
1836   arch_deps += target_specific.dependencies()
1837
1838   lib = static_library('qemu-' + target,
1839                  sources: arch_srcs + genh,
1840                  dependencies: arch_deps,
1841                  objects: objects,
1842                  include_directories: target_inc,
1843                  c_args: c_args,
1844                  build_by_default: false,
1845                  name_suffix: 'fa')
1846
1847   if target.endswith('-softmmu')
1848     execs = [{
1849       'name': 'qemu-system-' + target_name,
1850       'gui': false,
1851       'sources': files('softmmu/main.c'),
1852       'dependencies': []
1853     }]
1854     if targetos == 'windows' and (sdl.found() or gtk.found())
1855       execs += [{
1856         'name': 'qemu-system-' + target_name + 'w',
1857         'gui': true,
1858         'sources': files('softmmu/main.c'),
1859         'dependencies': []
1860       }]
1861     endif
1862     if config_host.has_key('CONFIG_FUZZ')
1863       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
1864       execs += [{
1865         'name': 'qemu-fuzz-' + target_name,
1866         'gui': false,
1867         'sources': specific_fuzz.sources(),
1868         'dependencies': specific_fuzz.dependencies(),
1869       }]
1870     endif
1871   else
1872     execs = [{
1873       'name': 'qemu-' + target_name,
1874       'gui': false,
1875       'sources': [],
1876       'dependencies': []
1877     }]
1878   endif
1879   foreach exe: execs
1880     emulators += {exe['name']:
1881          executable(exe['name'], exe['sources'],
1882                install: true,
1883                c_args: c_args,
1884                dependencies: arch_deps + deps + exe['dependencies'],
1885                objects: lib.extract_all_objects(recursive: true),
1886                link_language: link_language,
1887                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
1888                link_args: link_args,
1889                gui_app: exe['gui'])
1890     }
1891
1892     if 'CONFIG_TRACE_SYSTEMTAP' in config_host
1893       foreach stp: [
1894         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
1895         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
1896         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
1897         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
1898       ]
1899         custom_target(exe['name'] + stp['ext'],
1900                       input: trace_events_all,
1901                       output: exe['name'] + stp['ext'],
1902                       capture: true,
1903                       install: stp['install'],
1904                       install_dir: get_option('datadir') / 'systemtap/tapset',
1905                       command: [
1906                         tracetool, '--group=all', '--format=' + stp['fmt'],
1907                         '--binary=' + stp['bin'],
1908                         '--target-name=' + target_name,
1909                         '--target-type=' + target_type,
1910                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
1911                         '@INPUT@',
1912                       ])
1913       endforeach
1914     endif
1915   endforeach
1916 endforeach
1917
1918 # Other build targets
1919
1920 if 'CONFIG_PLUGIN' in config_host
1921   install_headers('include/qemu/qemu-plugin.h')
1922 endif
1923
1924 if 'CONFIG_GUEST_AGENT' in config_host
1925   subdir('qga')
1926 endif
1927
1928 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
1929 # when we don't build tools or system
1930 if xkbcommon.found()
1931   # used for the update-keymaps target, so include rules even if !have_tools
1932   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
1933                            dependencies: [qemuutil, xkbcommon], install: have_tools)
1934 endif
1935
1936 if have_tools
1937   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
1938              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
1939   qemu_io = executable('qemu-io', files('qemu-io.c'),
1940              dependencies: [block, qemuutil], install: true)
1941   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
1942                dependencies: [blockdev, qemuutil], install: true)
1943
1944   subdir('storage-daemon')
1945   subdir('contrib/rdmacm-mux')
1946   subdir('contrib/elf2dmp')
1947
1948   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
1949              dependencies: qemuutil,
1950              install: true)
1951
1952   if 'CONFIG_VHOST_USER' in config_host
1953     subdir('contrib/vhost-user-blk')
1954     subdir('contrib/vhost-user-gpu')
1955     subdir('contrib/vhost-user-input')
1956     subdir('contrib/vhost-user-scsi')
1957   endif
1958
1959   if targetos == 'linux'
1960     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
1961                dependencies: [qemuutil, libcap_ng],
1962                install: true,
1963                install_dir: get_option('libexecdir'))
1964
1965     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
1966                dependencies: [authz, crypto, io, qom, qemuutil,
1967                               libcap_ng, mpathpersist],
1968                install: true)
1969   endif
1970
1971   if 'CONFIG_IVSHMEM' in config_host
1972     subdir('contrib/ivshmem-client')
1973     subdir('contrib/ivshmem-server')
1974   endif
1975 endif
1976
1977 subdir('scripts')
1978 subdir('tools')
1979 subdir('pc-bios')
1980 subdir('docs')
1981 subdir('tests')
1982 if 'CONFIG_GTK' in config_host
1983   subdir('po')
1984 endif
1985
1986 if host_machine.system() == 'windows'
1987   nsis_cmd = [
1988     find_program('scripts/nsis.py'),
1989     '@OUTPUT@',
1990     get_option('prefix'),
1991     meson.current_source_dir(),
1992     host_machine.cpu(),
1993     '--',
1994     '-DDISPLAYVERSION=' + meson.project_version(),
1995   ]
1996   if build_docs
1997     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
1998   endif
1999   if 'CONFIG_GTK' in config_host
2000     nsis_cmd += '-DCONFIG_GTK=y'
2001   endif
2002
2003   nsis = custom_target('nsis',
2004                        output: 'qemu-setup-' + meson.project_version() + '.exe',
2005                        input: files('qemu.nsi'),
2006                        build_always_stale: true,
2007                        command: nsis_cmd + ['@INPUT@'])
2008   alias_target('installer', nsis)
2009 endif
2010
2011 #########################
2012 # Configuration summary #
2013 #########################
2014
2015 summary_info = {}
2016 summary_info += {'Install prefix':    get_option('prefix')}
2017 summary_info += {'BIOS directory':    qemu_datadir}
2018 summary_info += {'firmware path':     get_option('qemu_firmwarepath')}
2019 summary_info += {'binary directory':  get_option('bindir')}
2020 summary_info += {'library directory': get_option('libdir')}
2021 summary_info += {'module directory':  qemu_moddir}
2022 summary_info += {'libexec directory': get_option('libexecdir')}
2023 summary_info += {'include directory': get_option('includedir')}
2024 summary_info += {'config directory':  get_option('sysconfdir')}
2025 if targetos != 'windows'
2026   summary_info += {'local state directory': get_option('localstatedir')}
2027   summary_info += {'Manual directory':      get_option('mandir')}
2028 else
2029   summary_info += {'local state directory': 'queried at runtime'}
2030 endif
2031 summary_info += {'Doc directory':     get_option('docdir')}
2032 summary_info += {'Build directory':   meson.current_build_dir()}
2033 summary_info += {'Source path':       meson.current_source_dir()}
2034 summary_info += {'GIT binary':        config_host['GIT']}
2035 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
2036 summary_info += {'C compiler':        meson.get_compiler('c').cmd_array()[0]}
2037 summary_info += {'Host C compiler':   meson.get_compiler('c', native: true).cmd_array()[0]}
2038 if link_language == 'cpp'
2039   summary_info += {'C++ compiler':      meson.get_compiler('cpp').cmd_array()[0]}
2040 else
2041   summary_info += {'C++ compiler':      false}
2042 endif
2043 if targetos == 'darwin'
2044   summary_info += {'Objective-C compiler': meson.get_compiler('objc').cmd_array()[0]}
2045 endif
2046 summary_info += {'ARFLAGS':           config_host['ARFLAGS']}
2047 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
2048                                                + ['-O' + get_option('optimization')]
2049                                                + (get_option('debug') ? ['-g'] : []))}
2050 if link_language == 'cpp'
2051   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
2052                                                + ['-O' + get_option('optimization')]
2053                                                + (get_option('debug') ? ['-g'] : []))}
2054 endif
2055 link_args = get_option(link_language + '_link_args')
2056 if link_args.length() > 0
2057   summary_info += {'LDFLAGS':         ' '.join(link_args)}
2058 endif
2059 summary_info += {'QEMU_CFLAGS':       config_host['QEMU_CFLAGS']}
2060 summary_info += {'QEMU_LDFLAGS':      config_host['QEMU_LDFLAGS']}
2061 summary_info += {'make':              config_host['MAKE']}
2062 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
2063 summary_info += {'sphinx-build':      sphinx_build.found()}
2064 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
2065 # TODO: add back version
2066 summary_info += {'slirp support':     slirp_opt == 'disabled' ? false : slirp_opt}
2067 if slirp_opt != 'disabled'
2068   summary_info += {'smbd':            config_host['CONFIG_SMBD_COMMAND']}
2069 endif
2070 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
2071 if config_host.has_key('CONFIG_MODULES')
2072   summary_info += {'alternative module path': config_host.has_key('CONFIG_MODULE_UPGRADES')}
2073 endif
2074 summary_info += {'host CPU':          cpu}
2075 summary_info += {'host endianness':   build_machine.endian()}
2076 summary_info += {'target list':       ' '.join(target_dirs)}
2077 summary_info += {'gprof enabled':     config_host.has_key('CONFIG_GPROF')}
2078 summary_info += {'sparse enabled':    sparse.found()}
2079 summary_info += {'strip binaries':    get_option('strip')}
2080 summary_info += {'profiler':          config_host.has_key('CONFIG_PROFILER')}
2081 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
2082 if targetos == 'darwin'
2083   summary_info += {'Cocoa support': config_host.has_key('CONFIG_COCOA')}
2084 endif
2085 # TODO: add back version
2086 summary_info += {'SDL support':       sdl.found()}
2087 summary_info += {'SDL image support': sdl_image.found()}
2088 # TODO: add back version
2089 summary_info += {'GTK support':       config_host.has_key('CONFIG_GTK')}
2090 summary_info += {'GTK GL support':    config_host.has_key('CONFIG_GTK_GL')}
2091 summary_info += {'pixman':            pixman.found()}
2092 # TODO: add back version
2093 summary_info += {'VTE support':       config_host.has_key('CONFIG_VTE')}
2094 summary_info += {'TLS priority':      config_host['CONFIG_TLS_PRIORITY']}
2095 summary_info += {'GNUTLS support':    config_host.has_key('CONFIG_GNUTLS')}
2096 # TODO: add back version
2097 summary_info += {'libgcrypt':         config_host.has_key('CONFIG_GCRYPT')}
2098 if config_host.has_key('CONFIG_GCRYPT')
2099    summary_info += {'  hmac':            config_host.has_key('CONFIG_GCRYPT_HMAC')}
2100    summary_info += {'  XTS':             not config_host.has_key('CONFIG_QEMU_PRIVATE_XTS')}
2101 endif
2102 # TODO: add back version
2103 summary_info += {'nettle':            config_host.has_key('CONFIG_NETTLE')}
2104 if config_host.has_key('CONFIG_NETTLE')
2105    summary_info += {'  XTS':             not config_host.has_key('CONFIG_QEMU_PRIVATE_XTS')}
2106 endif
2107 summary_info += {'libtasn1':          config_host.has_key('CONFIG_TASN1')}
2108 summary_info += {'PAM':               config_host.has_key('CONFIG_AUTH_PAM')}
2109 summary_info += {'iconv support':     iconv.found()}
2110 summary_info += {'curses support':    curses.found()}
2111 # TODO: add back version
2112 summary_info += {'virgl support':     config_host.has_key('CONFIG_VIRGL')}
2113 summary_info += {'curl support':      config_host.has_key('CONFIG_CURL')}
2114 summary_info += {'mingw32 support':   targetos == 'windows'}
2115 summary_info += {'Audio drivers':     config_host['CONFIG_AUDIO_DRIVERS']}
2116 summary_info += {'Block whitelist (rw)': config_host['CONFIG_BDRV_RW_WHITELIST']}
2117 summary_info += {'Block whitelist (ro)': config_host['CONFIG_BDRV_RO_WHITELIST']}
2118 summary_info += {'VirtFS support':    config_host.has_key('CONFIG_VIRTFS')}
2119 summary_info += {'build virtiofs daemon': have_virtiofsd}
2120 summary_info += {'Multipath support': mpathpersist.found()}
2121 summary_info += {'VNC support':       vnc.found()}
2122 if vnc.found()
2123   summary_info += {'VNC SASL support':  sasl.found()}
2124   summary_info += {'VNC JPEG support':  jpeg.found()}
2125   summary_info += {'VNC PNG support':   png.found()}
2126 endif
2127 summary_info += {'xen support':       config_host.has_key('CONFIG_XEN_BACKEND')}
2128 if config_host.has_key('CONFIG_XEN_BACKEND')
2129   summary_info += {'xen ctrl version':  config_host['CONFIG_XEN_CTRL_INTERFACE_VERSION']}
2130 endif
2131 summary_info += {'brlapi support':    config_host.has_key('CONFIG_BRLAPI')}
2132 summary_info += {'Documentation':     build_docs}
2133 summary_info += {'PIE':               get_option('b_pie')}
2134 summary_info += {'vde support':       config_host.has_key('CONFIG_VDE')}
2135 summary_info += {'netmap support':    config_host.has_key('CONFIG_NETMAP')}
2136 summary_info += {'Linux AIO support': config_host.has_key('CONFIG_LINUX_AIO')}
2137 summary_info += {'Linux io_uring support': config_host.has_key('CONFIG_LINUX_IO_URING')}
2138 summary_info += {'ATTR/XATTR support': config_host.has_key('CONFIG_ATTR')}
2139 summary_info += {'Install blobs':     get_option('install_blobs')}
2140 summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
2141 summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
2142 summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
2143 summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
2144 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
2145 if config_all.has_key('CONFIG_TCG')
2146   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
2147   summary_info += {'TCG interpreter':   config_host.has_key('CONFIG_TCG_INTERPRETER')}
2148 endif
2149 summary_info += {'malloc trim support': has_malloc_trim}
2150 summary_info += {'RDMA support':      config_host.has_key('CONFIG_RDMA')}
2151 summary_info += {'PVRDMA support':    config_host.has_key('CONFIG_PVRDMA')}
2152 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
2153 summary_info += {'membarrier':        config_host.has_key('CONFIG_MEMBARRIER')}
2154 summary_info += {'preadv support':    config_host.has_key('CONFIG_PREADV')}
2155 summary_info += {'fdatasync':         config_host.has_key('CONFIG_FDATASYNC')}
2156 summary_info += {'madvise':           config_host.has_key('CONFIG_MADVISE')}
2157 summary_info += {'posix_madvise':     config_host.has_key('CONFIG_POSIX_MADVISE')}
2158 summary_info += {'posix_memalign':    config_host.has_key('CONFIG_POSIX_MEMALIGN')}
2159 summary_info += {'libcap-ng support': config_host.has_key('CONFIG_LIBCAP_NG')}
2160 summary_info += {'vhost-kernel support': config_host.has_key('CONFIG_VHOST_KERNEL')}
2161 summary_info += {'vhost-net support': config_host.has_key('CONFIG_VHOST_NET')}
2162 summary_info += {'vhost-crypto support': config_host.has_key('CONFIG_VHOST_CRYPTO')}
2163 summary_info += {'vhost-scsi support': config_host.has_key('CONFIG_VHOST_SCSI')}
2164 summary_info += {'vhost-vsock support': config_host.has_key('CONFIG_VHOST_VSOCK')}
2165 summary_info += {'vhost-user support': config_host.has_key('CONFIG_VHOST_USER')}
2166 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
2167 summary_info += {'vhost-user-fs support': config_host.has_key('CONFIG_VHOST_USER_FS')}
2168 summary_info += {'vhost-vdpa support': config_host.has_key('CONFIG_VHOST_VDPA')}
2169 summary_info += {'Trace backends':    config_host['TRACE_BACKENDS']}
2170 if config_host['TRACE_BACKENDS'].split().contains('simple')
2171   summary_info += {'Trace output file': config_host['CONFIG_TRACE_FILE'] + '-<pid>'}
2172 endif
2173 # TODO: add back protocol and server version
2174 summary_info += {'spice support':     config_host.has_key('CONFIG_SPICE')}
2175 summary_info += {'rbd support':       config_host.has_key('CONFIG_RBD')}
2176 summary_info += {'xfsctl support':    config_host.has_key('CONFIG_XFS')}
2177 summary_info += {'smartcard support': config_host.has_key('CONFIG_SMARTCARD')}
2178 summary_info += {'U2F support':       u2f.found()}
2179 summary_info += {'libusb':            config_host.has_key('CONFIG_USB_LIBUSB')}
2180 summary_info += {'usb net redir':     config_host.has_key('CONFIG_USB_REDIR')}
2181 summary_info += {'OpenGL support':    config_host.has_key('CONFIG_OPENGL')}
2182 summary_info += {'OpenGL dmabufs':    config_host.has_key('CONFIG_OPENGL_DMABUF')}
2183 summary_info += {'libiscsi support':  config_host.has_key('CONFIG_LIBISCSI')}
2184 summary_info += {'libnfs support':    config_host.has_key('CONFIG_LIBNFS')}
2185 summary_info += {'build guest agent': config_host.has_key('CONFIG_GUEST_AGENT')}
2186 if targetos == 'windows'
2187   if 'WIN_SDK' in config_host
2188     summary_info += {'Windows SDK':       config_host['WIN_SDK']}
2189   endif
2190   summary_info += {'QGA VSS support':   config_host.has_key('CONFIG_QGA_VSS')}
2191   summary_info += {'QGA w32 disk info': config_host.has_key('CONFIG_QGA_NTDDSCSI')}
2192   summary_info += {'QGA MSI support':   config_host.has_key('CONFIG_QGA_MSI')}
2193 endif
2194 summary_info += {'seccomp support':   config_host.has_key('CONFIG_SECCOMP')}
2195 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
2196 summary_info += {'coroutine pool':    config_host['CONFIG_COROUTINE_POOL'] == '1'}
2197 summary_info += {'debug stack usage': config_host.has_key('CONFIG_DEBUG_STACK_USAGE')}
2198 summary_info += {'mutex debugging':   config_host.has_key('CONFIG_DEBUG_MUTEX')}
2199 summary_info += {'crypto afalg':      config_host.has_key('CONFIG_AF_ALG')}
2200 summary_info += {'GlusterFS support': config_host.has_key('CONFIG_GLUSTERFS')}
2201 summary_info += {'gcov':              get_option('b_coverage')}
2202 summary_info += {'TPM support':       config_host.has_key('CONFIG_TPM')}
2203 summary_info += {'libssh support':    config_host.has_key('CONFIG_LIBSSH')}
2204 summary_info += {'QOM debugging':     config_host.has_key('CONFIG_QOM_CAST_DEBUG')}
2205 summary_info += {'Live block migration': config_host.has_key('CONFIG_LIVE_BLOCK_MIGRATION')}
2206 summary_info += {'lzo support':       config_host.has_key('CONFIG_LZO')}
2207 summary_info += {'snappy support':    config_host.has_key('CONFIG_SNAPPY')}
2208 summary_info += {'bzip2 support':     config_host.has_key('CONFIG_BZIP2')}
2209 summary_info += {'lzfse support':     config_host.has_key('CONFIG_LZFSE')}
2210 summary_info += {'zstd support':      config_host.has_key('CONFIG_ZSTD')}
2211 summary_info += {'NUMA host support': config_host.has_key('CONFIG_NUMA')}
2212 summary_info += {'libxml2':           config_host.has_key('CONFIG_LIBXML2')}
2213 summary_info += {'memory allocator':  get_option('malloc')}
2214 summary_info += {'avx2 optimization': config_host.has_key('CONFIG_AVX2_OPT')}
2215 summary_info += {'avx512f optimization': config_host.has_key('CONFIG_AVX512F_OPT')}
2216 summary_info += {'replication support': config_host.has_key('CONFIG_REPLICATION')}
2217 summary_info += {'bochs support':     config_host.has_key('CONFIG_BOCHS')}
2218 summary_info += {'cloop support':     config_host.has_key('CONFIG_CLOOP')}
2219 summary_info += {'dmg support':       config_host.has_key('CONFIG_DMG')}
2220 summary_info += {'qcow v1 support':   config_host.has_key('CONFIG_QCOW1')}
2221 summary_info += {'vdi support':       config_host.has_key('CONFIG_VDI')}
2222 summary_info += {'vvfat support':     config_host.has_key('CONFIG_VVFAT')}
2223 summary_info += {'qed support':       config_host.has_key('CONFIG_QED')}
2224 summary_info += {'parallels support': config_host.has_key('CONFIG_PARALLELS')}
2225 summary_info += {'sheepdog support':  config_host.has_key('CONFIG_SHEEPDOG')}
2226 summary_info += {'capstone':          capstone_opt == 'disabled' ? false : capstone_opt}
2227 summary_info += {'libpmem support':   config_host.has_key('CONFIG_LIBPMEM')}
2228 summary_info += {'libdaxctl support': config_host.has_key('CONFIG_LIBDAXCTL')}
2229 summary_info += {'libudev':           libudev.found()}
2230 summary_info += {'default devices':   config_host['CONFIG_MINIKCONF_MODE'] == '--defconfig'}
2231 summary_info += {'plugin support':    config_host.has_key('CONFIG_PLUGIN')}
2232 summary_info += {'fuzzing support':   config_host.has_key('CONFIG_FUZZ')}
2233 if config_host.has_key('HAVE_GDB_BIN')
2234   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
2235 endif
2236 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
2237 summary_info += {'rng-none':          config_host.has_key('CONFIG_RNG_NONE')}
2238 summary_info += {'Linux keyring':     config_host.has_key('CONFIG_SECRET_KEYRING')}
2239 summary_info += {'FUSE exports':      fuse.found()}
2240 summary_info += {'FUSE lseek':        fuse_lseek.found()}
2241 summary(summary_info, bool_yn: true)
2242
2243 if not supported_cpus.contains(cpu)
2244   message()
2245   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
2246   message()
2247   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
2248   message('The QEMU project intends to remove support for this host CPU in')
2249   message('a future release if nobody volunteers to maintain it and to')
2250   message('provide a build host for our continuous integration setup.')
2251   message('configure has succeeded and you can continue to build, but')
2252   message('if you care about QEMU on this platform you should contact')
2253   message('us upstream at qemu-devel@nongnu.org.')
2254 endif
2255
2256 if not supported_oses.contains(targetos)
2257   message()
2258   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
2259   message()
2260   message('Host OS ' + targetos + 'support is not currently maintained.')
2261   message('The QEMU project intends to remove support for this host OS in')
2262   message('a future release if nobody volunteers to maintain it and to')
2263   message('provide a build host for our continuous integration setup.')
2264   message('configure has succeeded and you can continue to build, but')
2265   message('if you care about QEMU on this platform you should contact')
2266   message('us upstream at qemu-devel@nongnu.org.')
2267 endif