meson.build

   1 project('qemu', ['c'], meson_version: '>=0.61.3',
   2         default_options: ['warning_level=1', 'c_std=gnu11', 'cpp_std=gnu++11', 'b_colorout=auto',
   3                           'b_staticpic=false', 'stdsplit=false', 'optimization=2', 'b_pie=true'],
   4         version: files('VERSION'))
   5
   6 add_test_setup('quick', exclude_suites: ['slow', 'thorough'], is_default: true)
   7 add_test_setup('slow', exclude_suites: ['thorough'], env: ['G_TEST_SLOW=1', 'SPEED=slow'])
   8 add_test_setup('thorough', env: ['G_TEST_SLOW=1', 'SPEED=thorough'])
   9
  10 meson.add_postconf_script(find_program('scripts/symlink-install-tree.py'))
  11
  12 not_found = dependency('', required: false)
  13 keyval = import('keyval')
  14 ss = import('sourceset')
  15 fs = import('fs')
  16
  17 sh = find_program('sh')
  18 cc = meson.get_compiler('c')
  19 config_host = keyval.load(meson.current_build_dir() / 'config-host.mak')
  20 enable_modules = 'CONFIG_MODULES' in config_host
  21 enable_static = 'CONFIG_STATIC' in config_host
  22
  23 # Allow both shared and static libraries unless --enable-static
  24 static_kwargs = enable_static ? {'static': true} : {}
  25
  26 # Temporary directory used for files created while
  27 # configure runs. Since it is in the build directory
  28 # we can safely blow away any previous version of it
  29 # (and we need not jump through hoops to try to delete
  30 # it when configure exits.)
  31 tmpdir = meson.current_build_dir() / 'meson-private/temp'
  32
  33 if get_option('qemu_suffix').startswith('/')
  34   error('qemu_suffix cannot start with a /')
  35 endif
  36
  37 qemu_confdir = get_option('sysconfdir') / get_option('qemu_suffix')
  38 qemu_datadir = get_option('datadir') / get_option('qemu_suffix')
  39 qemu_docdir = get_option('docdir') / get_option('qemu_suffix')
  40 qemu_moddir = get_option('libdir') / get_option('qemu_suffix')
  41
  42 qemu_desktopdir = get_option('datadir') / 'applications'
  43 qemu_icondir = get_option('datadir') / 'icons'
  44
  45 config_host_data = configuration_data()
  46 genh = []
  47 qapi_trace_events = []
  48
  49 bsd_oses = ['gnu/kfreebsd', 'freebsd', 'netbsd', 'openbsd', 'dragonfly', 'darwin']
  50 supported_oses = ['windows', 'freebsd', 'netbsd', 'openbsd', 'darwin', 'sunos', 'linux']
  51 supported_cpus = ['ppc', 'ppc64', 's390x', 'riscv', 'x86', 'x86_64',
  52   'arm', 'aarch64', 'loongarch64', 'mips', 'mips64', 'sparc', 'sparc64']
  53
  54 cpu = host_machine.cpu_family()
  55
  56 # Unify riscv* to a single family.
  57 if cpu in ['riscv32', 'riscv64']
  58   cpu = 'riscv'
  59 endif
  60
  61 targetos = host_machine.system()
  62
  63 target_dirs = config_host['TARGET_DIRS'].split()
  64 have_linux_user = false
  65 have_bsd_user = false
  66 have_system = false
  67 foreach target : target_dirs
  68   have_linux_user = have_linux_user or target.endswith('linux-user')
  69   have_bsd_user = have_bsd_user or target.endswith('bsd-user')
  70   have_system = have_system or target.endswith('-softmmu')
  71 endforeach
  72 have_user = have_linux_user or have_bsd_user
  73 have_tools = get_option('tools') \
  74   .disable_auto_if(not have_system) \
  75   .allowed()
  76 have_ga = get_option('guest_agent') \
  77   .disable_auto_if(not have_system and not have_tools) \
  78   .require(targetos in ['sunos', 'linux', 'windows', 'freebsd'],
  79            error_message: 'unsupported OS for QEMU guest agent') \
  80   .allowed()
  81 have_block = have_system or have_tools
  82
  83 python = import('python').find_installation()
  84
  85 if cpu not in supported_cpus
  86   host_arch = 'unknown'
  87 elif cpu == 'x86'
  88   host_arch = 'i386'
  89 elif cpu == 'mips64'
  90   host_arch = 'mips'
  91 else
  92   host_arch = cpu
  93 endif
  94
  95 if cpu in ['x86', 'x86_64']
  96   kvm_targets = ['i386-softmmu', 'x86_64-softmmu']
  97 elif cpu == 'aarch64'
  98   kvm_targets = ['aarch64-softmmu']
  99 elif cpu == 's390x'
 100   kvm_targets = ['s390x-softmmu']
 101 elif cpu in ['ppc', 'ppc64']
 102   kvm_targets = ['ppc-softmmu', 'ppc64-softmmu']
 103 elif cpu in ['mips', 'mips64']
 104   kvm_targets = ['mips-softmmu', 'mipsel-softmmu', 'mips64-softmmu', 'mips64el-softmmu']
 105 elif cpu in ['riscv']
 106   kvm_targets = ['riscv32-softmmu', 'riscv64-softmmu']
 107 else
 108   kvm_targets = []
 109 endif
 110
 111 kvm_targets_c = '""'
 112 if get_option('kvm').allowed() and targetos == 'linux'
 113   kvm_targets_c = '"' + '" ,"'.join(kvm_targets) + '"'
 114 endif
 115 config_host_data.set('CONFIG_KVM_TARGETS', kvm_targets_c)
 116
 117 accelerator_targets = { 'CONFIG_KVM': kvm_targets }
 118
 119 if cpu in ['aarch64']
 120   accelerator_targets += {
 121     'CONFIG_HVF': ['aarch64-softmmu']
 122   }
 123 endif
 124
 125 if cpu in ['x86', 'x86_64', 'arm', 'aarch64']
 126   # i386 emulator provides xenpv machine type for multiple architectures
 127   accelerator_targets += {
 128     'CONFIG_XEN': ['i386-softmmu', 'x86_64-softmmu'],
 129   }
 130 endif
 131 if cpu in ['x86', 'x86_64']
 132   accelerator_targets += {
 133     'CONFIG_HAX': ['i386-softmmu', 'x86_64-softmmu'],
 134     'CONFIG_HVF': ['x86_64-softmmu'],
 135     'CONFIG_NVMM': ['i386-softmmu', 'x86_64-softmmu'],
 136     'CONFIG_WHPX': ['i386-softmmu', 'x86_64-softmmu'],
 137   }
 138 endif
 139
 140 modular_tcg = []
 141 # Darwin does not support references to thread-local variables in modules
 142 if targetos != 'darwin'
 143   modular_tcg = ['i386-softmmu', 'x86_64-softmmu']
 144 endif
 145
 146 edk2_targets = [ 'arm-softmmu', 'aarch64-softmmu', 'i386-softmmu', 'x86_64-softmmu' ]
 147 unpack_edk2_blobs = false
 148 foreach target : edk2_targets
 149   if target in target_dirs
 150     bzip2 = find_program('bzip2', required: get_option('install_blobs'))
 151     unpack_edk2_blobs = bzip2.found()
 152     break
 153   endif
 154 endforeach
 155
 156 dtrace = not_found
 157 stap = not_found
 158 if 'dtrace' in get_option('trace_backends')
 159   dtrace = find_program('dtrace', required: true)
 160   stap = find_program('stap', required: false)
 161   if stap.found()
 162     # Workaround to avoid dtrace(1) producing a file with 'hidden' symbol
 163     # visibility. Define STAP_SDT_V2 to produce 'default' symbol visibility
 164     # instead. QEMU --enable-modules depends on this because the SystemTap
 165     # semaphores are linked into the main binary and not the module's shared
 166     # object.
 167     add_global_arguments('-DSTAP_SDT_V2',
 168                          native: false, language: ['c', 'cpp', 'objc'])
 169   endif
 170 endif
 171
 172 if get_option('iasl') == ''
 173   iasl = find_program('iasl', required: false)
 174 else
 175   iasl = find_program(get_option('iasl'), required: true)
 176 endif
 177
 178 ##################
 179 # Compiler flags #
 180 ##################
 181
 182 qemu_cflags = config_host['QEMU_CFLAGS'].split()
 183 qemu_objcflags = config_host['QEMU_OBJCFLAGS'].split()
 184 qemu_ldflags = config_host['QEMU_LDFLAGS'].split()
 185
 186 if enable_static
 187   qemu_ldflags += get_option('b_pie') ? '-static-pie' : '-static'
 188 endif
 189
 190 # Detect support for PT_GNU_RELRO + DT_BIND_NOW.
 191 # The combination is known as "full relro", because .got.plt is read-only too.
 192 qemu_ldflags += cc.get_supported_link_arguments('-Wl,-z,relro', '-Wl,-z,now')
 193
 194 if targetos == 'windows'
 195   qemu_ldflags += cc.get_supported_link_arguments('-Wl,--no-seh', '-Wl,--nxcompat')
 196   # Disable ASLR for debug builds to allow debugging with gdb
 197   if get_option('optimization') == '0'
 198     qemu_ldflags += cc.get_supported_link_arguments('-Wl,--dynamicbase')
 199   endif
 200 endif
 201
 202 if get_option('gprof')
 203   qemu_cflags += ['-p']
 204   qemu_objcflags += ['-p']
 205   qemu_ldflags += ['-p']
 206 endif
 207
 208 # Specify linker-script with add_project_link_arguments so that it is not placed
 209 # within a linker --start-group/--end-group pair
 210 if get_option('fuzzing')
 211   add_project_link_arguments(['-Wl,-T,',
 212                               (meson.current_source_dir() / 'tests/qtest/fuzz/fork_fuzz.ld')],
 213                              native: false, language: ['c', 'cpp', 'objc'])
 214
 215   # Specify a filter to only instrument code that is directly related to
 216   # virtual-devices.
 217   configure_file(output: 'instrumentation-filter',
 218                  input: 'scripts/oss-fuzz/instrumentation-filter-template',
 219                  copy: true)
 220
 221   if cc.compiles('int main () { return 0; }',
 222                   name: '-fsanitize-coverage-allowlist=/dev/null',
 223                  args: ['-fsanitize-coverage-allowlist=/dev/null',
 224                         '-fsanitize-coverage=trace-pc'] )
 225     add_global_arguments('-fsanitize-coverage-allowlist=instrumentation-filter',
 226                          native: false, language: ['c', 'cpp', 'objc'])
 227   endif
 228
 229   if get_option('fuzzing_engine') == ''
 230     # Add CFLAGS to tell clang to add fuzzer-related instrumentation to all the
 231     # compiled code.  To build non-fuzzer binaries with --enable-fuzzing, link
 232     # everything with fsanitize=fuzzer-no-link. Otherwise, the linker will be
 233     # unable to bind the fuzzer-related callbacks added by instrumentation.
 234     add_global_arguments('-fsanitize=fuzzer-no-link',
 235                          native: false, language: ['c', 'cpp', 'objc'])
 236     add_global_link_arguments('-fsanitize=fuzzer-no-link',
 237                               native: false, language: ['c', 'cpp', 'objc'])
 238     # For the actual fuzzer binaries, we need to link against the libfuzzer
 239     # library. They need to be configurable, to support OSS-Fuzz
 240     fuzz_exe_ldflags = ['-fsanitize=fuzzer']
 241   else
 242     # LIB_FUZZING_ENGINE was set; assume we are running on OSS-Fuzz, and
 243     # the needed CFLAGS have already been provided
 244     fuzz_exe_ldflags = get_option('fuzzing_engine').split()
 245   endif
 246 endif
 247
 248 add_global_arguments(qemu_cflags, native: false, language: ['c'])
 249 add_global_arguments(qemu_objcflags, native: false, language: ['objc'])
 250
 251 # Check that the C++ compiler exists and works with the C compiler.
 252 link_language = 'c'
 253 linker = cc
 254 qemu_cxxflags = []
 255 if add_languages('cpp', required: false, native: false)
 256   cxx = meson.get_compiler('cpp')
 257   add_global_arguments(['-D__STDC_LIMIT_MACROS', '-D__STDC_CONSTANT_MACROS', '-D__STDC_FORMAT_MACROS'],
 258                        native: false, language: 'cpp')
 259   foreach k: qemu_cflags
 260     if k not in ['-Wstrict-prototypes', '-Wmissing-prototypes', '-Wnested-externs',
 261                  '-Wold-style-declaration', '-Wold-style-definition', '-Wredundant-decls']
 262       qemu_cxxflags += [k]
 263     endif
 264   endforeach
 265   add_global_arguments(qemu_cxxflags, native: false, language: 'cpp')
 266
 267   if cxx.links(files('scripts/main.c'), args: qemu_cflags)
 268     link_language = 'cpp'
 269     linker = cxx
 270   else
 271     message('C++ compiler does not work with C compiler')
 272     message('Disabling C++-specific optional code')
 273   endif
 274 endif
 275
 276 # Exclude --warn-common with TSan to suppress warnings from the TSan libraries.
 277 if targetos != 'sunos' and not config_host.has_key('CONFIG_TSAN')
 278   qemu_ldflags += linker.get_supported_link_arguments('-Wl,--warn-common')
 279 endif
 280
 281 add_global_link_arguments(qemu_ldflags, native: false, language: ['c', 'cpp', 'objc'])
 282
 283 if targetos == 'linux'
 284   add_project_arguments('-isystem', meson.current_source_dir() / 'linux-headers',
 285                         '-isystem', 'linux-headers',
 286                         language: ['c', 'cpp'])
 287 endif
 288
 289 add_project_arguments('-iquote', '.',
 290                       '-iquote', meson.current_source_dir(),
 291                       '-iquote', meson.current_source_dir() / 'include',
 292                       language: ['c', 'cpp', 'objc'])
 293
 294 if host_machine.system() == 'darwin'
 295   add_languages('objc', required: false, native: false)
 296 endif
 297
 298 sparse = find_program('cgcc', required: get_option('sparse'))
 299 if sparse.found()
 300   run_target('sparse',
 301              command: [find_program('scripts/check_sparse.py'),
 302                        'compile_commands.json', sparse.full_path(), '-Wbitwise',
 303                        '-Wno-transparent-union', '-Wno-old-initializer',
 304                        '-Wno-non-pointer-null'])
 305 endif
 306
 307 ###########################################
 308 # Target-specific checks and dependencies #
 309 ###########################################
 310
 311 # Fuzzing
 312 if get_option('fuzzing') and get_option('fuzzing_engine') == '' and \
 313     not cc.links('''
 314           #include <stdint.h>
 315           #include <sys/types.h>
 316           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size);
 317           int LLVMFuzzerTestOneInput(const uint8_t *Data, size_t Size) { return 0; }
 318         ''',
 319         args: ['-Werror', '-fsanitize=fuzzer'])
 320   error('Your compiler does not support -fsanitize=fuzzer')
 321 endif
 322
 323 # Tracing backends
 324 if 'ftrace' in get_option('trace_backends') and targetos != 'linux'
 325   error('ftrace is supported only on Linux')
 326 endif
 327 if 'syslog' in get_option('trace_backends') and not cc.compiles('''
 328     #include <syslog.h>
 329     int main(void) {
 330         openlog("qemu", LOG_PID, LOG_DAEMON);
 331         syslog(LOG_INFO, "configure");
 332         return 0;
 333     }''')
 334   error('syslog is not supported on this system')
 335 endif
 336
 337 # Miscellaneous Linux-only features
 338 get_option('mpath') \
 339   .require(targetos == 'linux', error_message: 'Multipath is supported only on Linux')
 340
 341 multiprocess_allowed = get_option('multiprocess') \
 342   .require(targetos == 'linux', error_message: 'Multiprocess QEMU is supported only on Linux') \
 343   .allowed()
 344
 345 vfio_user_server_allowed = get_option('vfio_user_server') \
 346   .require(targetos == 'linux', error_message: 'vfio-user server is supported only on Linux') \
 347   .allowed()
 348
 349 have_tpm = get_option('tpm') \
 350   .require(targetos != 'windows', error_message: 'TPM emulation only available on POSIX systems') \
 351   .allowed()
 352
 353 # vhost
 354 have_vhost_user = get_option('vhost_user') \
 355   .disable_auto_if(targetos != 'linux') \
 356   .require(targetos != 'windows',
 357            error_message: 'vhost-user is not available on Windows').allowed()
 358 have_vhost_vdpa = get_option('vhost_vdpa') \
 359   .require(targetos == 'linux',
 360            error_message: 'vhost-vdpa is only available on Linux').allowed()
 361 have_vhost_kernel = get_option('vhost_kernel') \
 362   .require(targetos == 'linux',
 363            error_message: 'vhost-kernel is only available on Linux').allowed()
 364 have_vhost_user_crypto = get_option('vhost_crypto') \
 365   .require(have_vhost_user,
 366            error_message: 'vhost-crypto requires vhost-user to be enabled').allowed()
 367
 368 have_vhost = have_vhost_user or have_vhost_vdpa or have_vhost_kernel
 369
 370 have_vhost_net_user = have_vhost_user and get_option('vhost_net').allowed()
 371 have_vhost_net_vdpa = have_vhost_vdpa and get_option('vhost_net').allowed()
 372 have_vhost_net_kernel = have_vhost_kernel and get_option('vhost_net').allowed()
 373 have_vhost_net = have_vhost_net_kernel or have_vhost_net_user or have_vhost_net_vdpa
 374
 375 # Target-specific libraries and flags
 376 libm = cc.find_library('m', required: false)
 377 threads = dependency('threads')
 378 util = cc.find_library('util', required: false)
 379 winmm = []
 380 socket = []
 381 version_res = []
 382 coref = []
 383 iokit = []
 384 emulator_link_args = []
 385 nvmm =not_found
 386 hvf = not_found
 387 midl = not_found
 388 widl = not_found
 389 pathcch = not_found
 390 host_dsosuf = '.so'
 391 if targetos == 'windows'
 392   midl = find_program('midl', required: false)
 393   widl = find_program('widl', required: false)
 394   pathcch = cc.find_library('pathcch')
 395   socket = cc.find_library('ws2_32')
 396   winmm = cc.find_library('winmm')
 397
 398   win = import('windows')
 399   version_res = win.compile_resources('version.rc',
 400                                       depend_files: files('pc-bios/qemu-nsis.ico'),
 401                                       include_directories: include_directories('.'))
 402   host_dsosuf = '.dll'
 403 elif targetos == 'darwin'
 404   coref = dependency('appleframeworks', modules: 'CoreFoundation')
 405   iokit = dependency('appleframeworks', modules: 'IOKit', required: false)
 406   host_dsosuf = '.dylib'
 407 elif targetos == 'sunos'
 408   socket = [cc.find_library('socket'),
 409             cc.find_library('nsl'),
 410             cc.find_library('resolv')]
 411 elif targetos == 'haiku'
 412   socket = [cc.find_library('posix_error_mapper'),
 413             cc.find_library('network'),
 414             cc.find_library('bsd')]
 415 elif targetos == 'openbsd'
 416   if get_option('tcg').allowed() and target_dirs.length() > 0
 417     # Disable OpenBSD W^X if available
 418     emulator_link_args = cc.get_supported_link_arguments('-Wl,-z,wxneeded')
 419   endif
 420 endif
 421
 422 # Target-specific configuration of accelerators
 423 accelerators = []
 424 if get_option('kvm').allowed() and targetos == 'linux'
 425   accelerators += 'CONFIG_KVM'
 426 endif
 427 if get_option('whpx').allowed() and targetos == 'windows'
 428   if get_option('whpx').enabled() and host_machine.cpu() != 'x86_64'
 429     error('WHPX requires 64-bit host')
 430   elif cc.has_header('WinHvPlatform.h', required: get_option('whpx')) and \
 431        cc.has_header('WinHvEmulation.h', required: get_option('whpx'))
 432     accelerators += 'CONFIG_WHPX'
 433   endif
 434 endif
 435 if get_option('hvf').allowed()
 436   hvf = dependency('appleframeworks', modules: 'Hypervisor',
 437                    required: get_option('hvf'))
 438   if hvf.found()
 439     accelerators += 'CONFIG_HVF'
 440   endif
 441 endif
 442 if get_option('hax').allowed()
 443   if get_option('hax').enabled() or targetos in ['windows', 'darwin', 'netbsd']
 444     accelerators += 'CONFIG_HAX'
 445   endif
 446 endif
 447 if targetos == 'netbsd'
 448   nvmm = cc.find_library('nvmm', required: get_option('nvmm'))
 449   if nvmm.found()
 450     accelerators += 'CONFIG_NVMM'
 451   endif
 452 endif
 453
 454 tcg_arch = host_arch
 455 if get_option('tcg').allowed()
 456   if host_arch == 'unknown'
 457     if get_option('tcg_interpreter')
 458       warning('Unsupported CPU @0@, will use TCG with TCI (slow)'.format(cpu))
 459     else
 460       error('Unsupported CPU @0@, try --enable-tcg-interpreter'.format(cpu))
 461     endif
 462   elif get_option('tcg_interpreter')
 463     warning('Use of the TCG interpreter is not recommended on this host')
 464     warning('architecture. There is a native TCG execution backend available')
 465     warning('which provides substantially better performance and reliability.')
 466     warning('It is strongly recommended to remove the --enable-tcg-interpreter')
 467     warning('configuration option on this architecture to use the native')
 468     warning('backend.')
 469   endif
 470   if get_option('tcg_interpreter')
 471     tcg_arch = 'tci'
 472   elif host_arch == 'sparc64'
 473     tcg_arch = 'sparc'
 474   elif host_arch == 'x86_64'
 475     tcg_arch = 'i386'
 476   elif host_arch == 'ppc64'
 477     tcg_arch = 'ppc'
 478   endif
 479   add_project_arguments('-iquote', meson.current_source_dir() / 'tcg' / tcg_arch,
 480                         language: ['c', 'cpp', 'objc'])
 481
 482   accelerators += 'CONFIG_TCG'
 483   config_host += { 'CONFIG_TCG': 'y' }
 484 endif
 485
 486 if 'CONFIG_KVM' not in accelerators and get_option('kvm').enabled()
 487   error('KVM not available on this platform')
 488 endif
 489 if 'CONFIG_HVF' not in accelerators and get_option('hvf').enabled()
 490   error('HVF not available on this platform')
 491 endif
 492 if 'CONFIG_NVMM' not in accelerators and get_option('nvmm').enabled()
 493   error('NVMM not available on this platform')
 494 endif
 495 if 'CONFIG_WHPX' not in accelerators and get_option('whpx').enabled()
 496   error('WHPX not available on this platform')
 497 endif
 498
 499 ################
 500 # Dependencies #
 501 ################
 502
 503 # The path to glib.h is added to all compilation commands.  This was
 504 # grandfathered in from the QEMU Makefiles.
 505 add_project_arguments(config_host['GLIB_CFLAGS'].split(),
 506                       native: false, language: ['c', 'cpp', 'objc'])
 507 glib = declare_dependency(compile_args: config_host['GLIB_CFLAGS'].split(),
 508                           link_args: config_host['GLIB_LIBS'].split(),
 509                           version: config_host['GLIB_VERSION'],
 510                           variables: {
 511                             'bindir': config_host['GLIB_BINDIR'],
 512                           })
 513 # override glib dep with the configure results (for subprojects)
 514 meson.override_dependency('glib-2.0', glib)
 515
 516 gio = not_found
 517 gdbus_codegen = not_found
 518 gdbus_codegen_error = '@0@ requires gdbus-codegen, please install libgio'
 519 if not get_option('gio').auto() or have_system
 520   gio = dependency('gio-2.0', required: get_option('gio'),
 521                    method: 'pkg-config', kwargs: static_kwargs)
 522   if gio.found() and not cc.links('''
 523     #include <gio/gio.h>
 524     int main(void)
 525     {
 526       g_dbus_proxy_new_sync(0, 0, 0, 0, 0, 0, 0, 0);
 527       return 0;
 528     }''', dependencies: [glib, gio])
 529     if get_option('gio').enabled()
 530       error('The installed libgio is broken for static linking')
 531     endif
 532     gio = not_found
 533   endif
 534   if gio.found()
 535     gdbus_codegen = find_program(gio.get_variable('gdbus_codegen'),
 536                                  required: get_option('gio'))
 537     gio_unix = dependency('gio-unix-2.0', required: get_option('gio'),
 538                           method: 'pkg-config', kwargs: static_kwargs)
 539     gio = declare_dependency(dependencies: [gio, gio_unix],
 540                              version: gio.version())
 541   endif
 542 endif
 543 if gdbus_codegen.found() and get_option('cfi')
 544   gdbus_codegen = not_found
 545   gdbus_codegen_error = '@0@ uses gdbus-codegen, which does not support control flow integrity'
 546 endif
 547
 548 lttng = not_found
 549 if 'ust' in get_option('trace_backends')
 550   lttng = dependency('lttng-ust', required: true, version: '>= 2.1',
 551                      method: 'pkg-config', kwargs: static_kwargs)
 552 endif
 553 pixman = not_found
 554 if have_system or have_tools
 555   pixman = dependency('pixman-1', required: have_system, version:'>=0.21.8',
 556                       method: 'pkg-config', kwargs: static_kwargs)
 557 endif
 558 zlib = dependency('zlib', required: true, kwargs: static_kwargs)
 559
 560 libaio = not_found
 561 if not get_option('linux_aio').auto() or have_block
 562   libaio = cc.find_library('aio', has_headers: ['libaio.h'],
 563                            required: get_option('linux_aio'),
 564                            kwargs: static_kwargs)
 565 endif
 566
 567 linux_io_uring_test = '''
 568   #include <liburing.h>
 569   #include <linux/errqueue.h>
 570
 571   int main(void) { return 0; }'''
 572
 573 linux_io_uring = not_found
 574 if not get_option('linux_io_uring').auto() or have_block
 575   linux_io_uring = dependency('liburing', version: '>=0.3',
 576                               required: get_option('linux_io_uring'),
 577                               method: 'pkg-config', kwargs: static_kwargs)
 578   if not cc.links(linux_io_uring_test)
 579     linux_io_uring = not_found
 580   endif
 581 endif
 582
 583 libnfs = not_found
 584 if not get_option('libnfs').auto() or have_block
 585   libnfs = dependency('libnfs', version: '>=1.9.3',
 586                       required: get_option('libnfs'),
 587                       method: 'pkg-config', kwargs: static_kwargs)
 588 endif
 589
 590 libattr_test = '''
 591   #include <stddef.h>
 592   #include <sys/types.h>
 593   #ifdef CONFIG_LIBATTR
 594   #include <attr/xattr.h>
 595   #else
 596   #include <sys/xattr.h>
 597   #endif
 598   int main(void) { getxattr(NULL, NULL, NULL, 0); setxattr(NULL, NULL, NULL, 0, 0); return 0; }'''
 599
 600 libattr = not_found
 601 have_old_libattr = false
 602 if get_option('attr').allowed()
 603   if cc.links(libattr_test)
 604     libattr = declare_dependency()
 605   else
 606     libattr = cc.find_library('attr', has_headers: ['attr/xattr.h'],
 607                               required: get_option('attr'),
 608                               kwargs: static_kwargs)
 609     if libattr.found() and not \
 610       cc.links(libattr_test, dependencies: libattr, args: '-DCONFIG_LIBATTR')
 611       libattr = not_found
 612       if get_option('attr').enabled()
 613         error('could not link libattr')
 614       else
 615         warning('could not link libattr, disabling')
 616       endif
 617     else
 618       have_old_libattr = libattr.found()
 619     endif
 620   endif
 621 endif
 622
 623 cocoa = dependency('appleframeworks', modules: ['Cocoa', 'CoreVideo'],
 624                    required: get_option('cocoa'))
 625
 626 vmnet = dependency('appleframeworks', modules: 'vmnet', required: get_option('vmnet'))
 627 if vmnet.found() and not cc.has_header_symbol('vmnet/vmnet.h',
 628                                               'VMNET_BRIDGED_MODE',
 629                                               dependencies: vmnet)
 630   vmnet = not_found
 631   if get_option('vmnet').enabled()
 632     error('vmnet.framework API is outdated')
 633   else
 634     warning('vmnet.framework API is outdated, disabling')
 635   endif
 636 endif
 637
 638 seccomp = not_found
 639 seccomp_has_sysrawrc = false
 640 if not get_option('seccomp').auto() or have_system or have_tools
 641   seccomp = dependency('libseccomp', version: '>=2.3.0',
 642                        required: get_option('seccomp'),
 643                        method: 'pkg-config', kwargs: static_kwargs)
 644   if seccomp.found()
 645     seccomp_has_sysrawrc = cc.has_header_symbol('seccomp.h',
 646                                                 'SCMP_FLTATR_API_SYSRAWRC',
 647                                                 dependencies: seccomp)
 648   endif
 649 endif
 650
 651 libcap_ng = not_found
 652 if not get_option('cap_ng').auto() or have_system or have_tools
 653   libcap_ng = cc.find_library('cap-ng', has_headers: ['cap-ng.h'],
 654                               required: get_option('cap_ng'),
 655                               kwargs: static_kwargs)
 656 endif
 657 if libcap_ng.found() and not cc.links('''
 658    #include <cap-ng.h>
 659    int main(void)
 660    {
 661      capng_capability_to_name(CAPNG_EFFECTIVE);
 662      return 0;
 663    }''', dependencies: libcap_ng)
 664   libcap_ng = not_found
 665   if get_option('cap_ng').enabled()
 666     error('could not link libcap-ng')
 667   else
 668     warning('could not link libcap-ng, disabling')
 669   endif
 670 endif
 671
 672 if get_option('xkbcommon').auto() and not have_system and not have_tools
 673   xkbcommon = not_found
 674 else
 675   xkbcommon = dependency('xkbcommon', required: get_option('xkbcommon'),
 676                          method: 'pkg-config', kwargs: static_kwargs)
 677 endif
 678
 679 slirp = not_found
 680 if not get_option('slirp').auto() or have_system
 681   slirp = dependency('slirp', required: get_option('slirp'),
 682                      method: 'pkg-config', kwargs: static_kwargs)
 683   # slirp < 4.7 is incompatible with CFI support in QEMU.  This is because
 684   # it passes function pointers within libslirp as callbacks for timers.
 685   # When using a system-wide shared libslirp, the type information for the
 686   # callback is missing and the timer call produces a false positive with CFI.
 687   # Do not use the "version" keyword argument to produce a better error.
 688   # with control-flow integrity.
 689   if get_option('cfi') and slirp.found() and slirp.version().version_compare('<4.7')
 690     if get_option('slirp').enabled()
 691       error('Control-Flow Integrity requires libslirp 4.7.')
 692     else
 693       warning('Cannot use libslirp since Control-Flow Integrity requires libslirp >= 4.7.')
 694       slirp = not_found
 695     endif
 696   endif
 697 endif
 698
 699 vde = not_found
 700 if not get_option('vde').auto() or have_system or have_tools
 701   vde = cc.find_library('vdeplug', has_headers: ['libvdeplug.h'],
 702                            required: get_option('vde'),
 703                            kwargs: static_kwargs)
 704 endif
 705 if vde.found() and not cc.links('''
 706    #include <libvdeplug.h>
 707    int main(void)
 708    {
 709      struct vde_open_args a = {0, 0, 0};
 710      char s[] = "";
 711      vde_open(s, s, &a);
 712      return 0;
 713    }''', dependencies: vde)
 714   vde = not_found
 715   if get_option('cap_ng').enabled()
 716     error('could not link libvdeplug')
 717   else
 718     warning('could not link libvdeplug, disabling')
 719   endif
 720 endif
 721
 722 pulse = not_found
 723 if not get_option('pa').auto() or (targetos == 'linux' and have_system)
 724   pulse = dependency('libpulse', required: get_option('pa'),
 725                      method: 'pkg-config', kwargs: static_kwargs)
 726 endif
 727 alsa = not_found
 728 if not get_option('alsa').auto() or (targetos == 'linux' and have_system)
 729   alsa = dependency('alsa', required: get_option('alsa'),
 730                     method: 'pkg-config', kwargs: static_kwargs)
 731 endif
 732 jack = not_found
 733 if not get_option('jack').auto() or have_system
 734   jack = dependency('jack', required: get_option('jack'),
 735                     method: 'pkg-config', kwargs: static_kwargs)
 736 endif
 737 sndio = not_found
 738 if not get_option('sndio').auto() or have_system
 739   sndio = dependency('sndio', required: get_option('sndio'),
 740                     method: 'pkg-config', kwargs: static_kwargs)
 741 endif
 742
 743 spice_protocol = not_found
 744 if not get_option('spice_protocol').auto() or have_system
 745   spice_protocol = dependency('spice-protocol', version: '>=0.12.3',
 746                               required: get_option('spice_protocol'),
 747                               method: 'pkg-config', kwargs: static_kwargs)
 748 endif
 749 spice = not_found
 750 if not get_option('spice').auto() or have_system
 751   spice = dependency('spice-server', version: '>=0.12.5',
 752                      required: get_option('spice'),
 753                      method: 'pkg-config', kwargs: static_kwargs)
 754 endif
 755 spice_headers = spice.partial_dependency(compile_args: true, includes: true)
 756
 757 rt = cc.find_library('rt', required: false)
 758
 759 libiscsi = not_found
 760 if not get_option('libiscsi').auto() or have_block
 761   libiscsi = dependency('libiscsi', version: '>=1.9.0',
 762                          required: get_option('libiscsi'),
 763                          method: 'pkg-config', kwargs: static_kwargs)
 764 endif
 765 zstd = not_found
 766 if not get_option('zstd').auto() or have_block
 767   zstd = dependency('libzstd', version: '>=1.4.0',
 768                     required: get_option('zstd'),
 769                     method: 'pkg-config', kwargs: static_kwargs)
 770 endif
 771 virgl = not_found
 772
 773 have_vhost_user_gpu = have_tools and targetos == 'linux' and pixman.found()
 774 if not get_option('virglrenderer').auto() or have_system or have_vhost_user_gpu
 775   virgl = dependency('virglrenderer',
 776                      method: 'pkg-config',
 777                      required: get_option('virglrenderer'),
 778                      kwargs: static_kwargs)
 779 endif
 780 blkio = not_found
 781 if not get_option('blkio').auto() or have_block
 782   blkio = dependency('blkio',
 783                      method: 'pkg-config',
 784                      required: get_option('blkio'),
 785                      kwargs: static_kwargs)
 786 endif
 787 curl = not_found
 788 if not get_option('curl').auto() or have_block
 789   curl = dependency('libcurl', version: '>=7.29.0',
 790                     method: 'pkg-config',
 791                     required: get_option('curl'),
 792                     kwargs: static_kwargs)
 793 endif
 794 libudev = not_found
 795 if targetos == 'linux' and (have_system or have_tools)
 796   libudev = dependency('libudev',
 797                        method: 'pkg-config',
 798                        required: get_option('libudev'),
 799                        kwargs: static_kwargs)
 800 endif
 801
 802 mpathlibs = [libudev]
 803 mpathpersist = not_found
 804 mpathpersist_new_api = false
 805 if targetos == 'linux' and have_tools and get_option('mpath').allowed()
 806   mpath_test_source_new = '''
 807     #include <libudev.h>
 808     #include <mpath_persist.h>
 809     unsigned mpath_mx_alloc_len = 1024;
 810     int logsink;
 811     static struct config *multipath_conf;
 812     extern struct udev *udev;
 813     extern struct config *get_multipath_config(void);
 814     extern void put_multipath_config(struct config *conf);
 815     struct udev *udev;
 816     struct config *get_multipath_config(void) { return multipath_conf; }
 817     void put_multipath_config(struct config *conf) { }
 818     int main(void) {
 819         udev = udev_new();
 820         multipath_conf = mpath_lib_init();
 821         return 0;
 822     }'''
 823   mpath_test_source_old = '''
 824       #include <libudev.h>
 825       #include <mpath_persist.h>
 826       unsigned mpath_mx_alloc_len = 1024;
 827       int logsink;
 828       int main(void) {
 829           struct udev *udev = udev_new();
 830           mpath_lib_init(udev);
 831           return 0;
 832       }'''
 833   libmpathpersist = cc.find_library('mpathpersist',
 834                                     required: get_option('mpath'),
 835                                     kwargs: static_kwargs)
 836   if libmpathpersist.found()
 837     mpathlibs += libmpathpersist
 838     if enable_static
 839       mpathlibs += cc.find_library('devmapper',
 840                                      required: get_option('mpath'),
 841                                      kwargs: static_kwargs)
 842     endif
 843     mpathlibs += cc.find_library('multipath',
 844                                  required: get_option('mpath'),
 845                                  kwargs: static_kwargs)
 846     foreach lib: mpathlibs
 847       if not lib.found()
 848         mpathlibs = []
 849         break
 850       endif
 851     endforeach
 852     if mpathlibs.length() == 0
 853       msg = 'Dependencies missing for libmpathpersist'
 854     elif cc.links(mpath_test_source_new, dependencies: mpathlibs)
 855       mpathpersist = declare_dependency(dependencies: mpathlibs)
 856       mpathpersist_new_api = true
 857     elif cc.links(mpath_test_source_old, dependencies: mpathlibs)
 858       mpathpersist = declare_dependency(dependencies: mpathlibs)
 859     else
 860       msg = 'Cannot detect libmpathpersist API'
 861     endif
 862     if not mpathpersist.found()
 863       if get_option('mpath').enabled()
 864         error(msg)
 865       else
 866         warning(msg + ', disabling')
 867       endif
 868     endif
 869   endif
 870 endif
 871
 872 iconv = not_found
 873 curses = not_found
 874 if have_system and get_option('curses').allowed()
 875   curses_test = '''
 876     #if defined(__APPLE__) || defined(__OpenBSD__)
 877     #define _XOPEN_SOURCE_EXTENDED 1
 878     #endif
 879     #include <locale.h>
 880     #include <curses.h>
 881     #include <wchar.h>
 882     int main(void) {
 883       wchar_t wch = L'w';
 884       setlocale(LC_ALL, "");
 885       resize_term(0, 0);
 886       addwstr(L"wide chars\n");
 887       addnwstr(&wch, 1);
 888       add_wch(WACS_DEGREE);
 889       return 0;
 890     }'''
 891
 892   curses_dep_list = targetos == 'windows' ? ['ncurses', 'ncursesw'] : ['ncursesw']
 893   curses = dependency(curses_dep_list,
 894                       required: false,
 895                       method: 'pkg-config',
 896                       kwargs: static_kwargs)
 897   msg = get_option('curses').enabled() ? 'curses library not found' : ''
 898   curses_compile_args = ['-DNCURSES_WIDECHAR=1']
 899   if curses.found()
 900     if cc.links(curses_test, args: curses_compile_args, dependencies: [curses])
 901       curses = declare_dependency(compile_args: curses_compile_args, dependencies: [curses])
 902     else
 903       msg = 'curses package not usable'
 904       curses = not_found
 905     endif
 906   endif
 907   if not curses.found()
 908     has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 909     if targetos != 'windows' and not has_curses_h
 910       message('Trying with /usr/include/ncursesw')
 911       curses_compile_args += ['-I/usr/include/ncursesw']
 912       has_curses_h = cc.has_header('curses.h', args: curses_compile_args)
 913     endif
 914     if has_curses_h
 915       curses_libname_list = (targetos == 'windows' ? ['pdcurses'] : ['ncursesw', 'cursesw'])
 916       foreach curses_libname : curses_libname_list
 917         libcurses = cc.find_library(curses_libname,
 918                                     required: false,
 919                                     kwargs: static_kwargs)
 920         if libcurses.found()
 921           if cc.links(curses_test, args: curses_compile_args, dependencies: libcurses)
 922             curses = declare_dependency(compile_args: curses_compile_args,
 923                                         dependencies: [libcurses])
 924             break
 925           else
 926             msg = 'curses library not usable'
 927           endif
 928         endif
 929       endforeach
 930     endif
 931   endif
 932   if get_option('iconv').allowed()
 933     foreach link_args : [ ['-liconv'], [] ]
 934       # Programs will be linked with glib and this will bring in libiconv on FreeBSD.
 935       # We need to use libiconv if available because mixing libiconv's headers with
 936       # the system libc does not work.
 937       # However, without adding glib to the dependencies -L/usr/local/lib will not be
 938       # included in the command line and libiconv will not be found.
 939       if cc.links('''
 940         #include <iconv.h>
 941         int main(void) {
 942           iconv_t conv = iconv_open("WCHAR_T", "UCS-2");
 943           return conv != (iconv_t) -1;
 944         }''', args: config_host['GLIB_CFLAGS'].split() + config_host['GLIB_LIBS'].split() + link_args)
 945         iconv = declare_dependency(link_args: link_args, dependencies: glib)
 946         break
 947       endif
 948     endforeach
 949   endif
 950   if curses.found() and not iconv.found()
 951     if get_option('iconv').enabled()
 952       error('iconv not available')
 953     endif
 954     msg = 'iconv required for curses UI but not available'
 955     curses = not_found
 956   endif
 957   if not curses.found() and msg != ''
 958     if get_option('curses').enabled()
 959       error(msg)
 960     else
 961       warning(msg + ', disabling')
 962     endif
 963   endif
 964 endif
 965
 966 brlapi = not_found
 967 if not get_option('brlapi').auto() or have_system
 968   brlapi = cc.find_library('brlapi', has_headers: ['brlapi.h'],
 969                          required: get_option('brlapi'),
 970                          kwargs: static_kwargs)
 971   if brlapi.found() and not cc.links('''
 972      #include <brlapi.h>
 973      #include <stddef.h>
 974      int main(void) { return brlapi__openConnection (NULL, NULL, NULL); }''', dependencies: brlapi)
 975     brlapi = not_found
 976     if get_option('brlapi').enabled()
 977       error('could not link brlapi')
 978     else
 979       warning('could not link brlapi, disabling')
 980     endif
 981   endif
 982 endif
 983
 984 sdl = not_found
 985 if not get_option('sdl').auto() or have_system
 986   sdl = dependency('sdl2', required: get_option('sdl'), kwargs: static_kwargs)
 987   sdl_image = not_found
 988 endif
 989 if sdl.found()
 990   # work around 2.0.8 bug
 991   sdl = declare_dependency(compile_args: '-Wno-undef',
 992                            dependencies: sdl)
 993   sdl_image = dependency('SDL2_image', required: get_option('sdl_image'),
 994                          method: 'pkg-config', kwargs: static_kwargs)
 995 else
 996   if get_option('sdl_image').enabled()
 997     error('sdl-image required, but SDL was @0@'.format(
 998           get_option('sdl').disabled() ? 'disabled' : 'not found'))
 999   endif
1000   sdl_image = not_found
1001 endif
1002
1003 rbd = not_found
1004 if not get_option('rbd').auto() or have_block
1005   librados = cc.find_library('rados', required: get_option('rbd'),
1006                              kwargs: static_kwargs)
1007   librbd = cc.find_library('rbd', has_headers: ['rbd/librbd.h'],
1008                            required: get_option('rbd'),
1009                            kwargs: static_kwargs)
1010   if librados.found() and librbd.found()
1011     if cc.links('''
1012       #include <stdio.h>
1013       #include <rbd/librbd.h>
1014       int main(void) {
1015         rados_t cluster;
1016         rados_create(&cluster, NULL);
1017         #if LIBRBD_VERSION_CODE < LIBRBD_VERSION(1, 12, 0)
1018         #error
1019         #endif
1020         return 0;
1021       }''', dependencies: [librbd, librados])
1022       rbd = declare_dependency(dependencies: [librbd, librados])
1023     elif get_option('rbd').enabled()
1024       error('librbd >= 1.12.0 required')
1025     else
1026       warning('librbd >= 1.12.0 not found, disabling')
1027     endif
1028   endif
1029 endif
1030
1031 glusterfs = not_found
1032 glusterfs_ftruncate_has_stat = false
1033 glusterfs_iocb_has_stat = false
1034 if not get_option('glusterfs').auto() or have_block
1035   glusterfs = dependency('glusterfs-api', version: '>=3',
1036                          required: get_option('glusterfs'),
1037                          method: 'pkg-config', kwargs: static_kwargs)
1038   if glusterfs.found()
1039     glusterfs_ftruncate_has_stat = cc.links('''
1040       #include <glusterfs/api/glfs.h>
1041
1042       int
1043       main(void)
1044       {
1045           /* new glfs_ftruncate() passes two additional args */
1046           return glfs_ftruncate(NULL, 0, NULL, NULL);
1047       }
1048     ''', dependencies: glusterfs)
1049     glusterfs_iocb_has_stat = cc.links('''
1050       #include <glusterfs/api/glfs.h>
1051
1052       /* new glfs_io_cbk() passes two additional glfs_stat structs */
1053       static void
1054       glusterfs_iocb(glfs_fd_t *fd, ssize_t ret, struct glfs_stat *prestat, struct glfs_stat *poststat, void *data)
1055       {}
1056
1057       int
1058       main(void)
1059       {
1060           glfs_io_cbk iocb = &glusterfs_iocb;
1061           iocb(NULL, 0 , NULL, NULL, NULL);
1062           return 0;
1063       }
1064     ''', dependencies: glusterfs)
1065   endif
1066 endif
1067
1068 libssh = not_found
1069 if not get_option('libssh').auto() or have_block
1070   libssh = dependency('libssh', version: '>=0.8.7',
1071                     method: 'pkg-config',
1072                     required: get_option('libssh'),
1073                     kwargs: static_kwargs)
1074 endif
1075
1076 libbzip2 = not_found
1077 if not get_option('bzip2').auto() or have_block
1078   libbzip2 = cc.find_library('bz2', has_headers: ['bzlib.h'],
1079                              required: get_option('bzip2'),
1080                              kwargs: static_kwargs)
1081   if libbzip2.found() and not cc.links('''
1082      #include <bzlib.h>
1083      int main(void) { BZ2_bzlibVersion(); return 0; }''', dependencies: libbzip2)
1084     libbzip2 = not_found
1085     if get_option('bzip2').enabled()
1086       error('could not link libbzip2')
1087     else
1088       warning('could not link libbzip2, disabling')
1089     endif
1090   endif
1091 endif
1092
1093 liblzfse = not_found
1094 if not get_option('lzfse').auto() or have_block
1095   liblzfse = cc.find_library('lzfse', has_headers: ['lzfse.h'],
1096                              required: get_option('lzfse'),
1097                              kwargs: static_kwargs)
1098 endif
1099 if liblzfse.found() and not cc.links('''
1100    #include <lzfse.h>
1101    int main(void) { lzfse_decode_scratch_size(); return 0; }''', dependencies: liblzfse)
1102   liblzfse = not_found
1103   if get_option('lzfse').enabled()
1104     error('could not link liblzfse')
1105   else
1106     warning('could not link liblzfse, disabling')
1107   endif
1108 endif
1109
1110 oss = not_found
1111 if get_option('oss').allowed() and have_system
1112   if not cc.has_header('sys/soundcard.h')
1113     # not found
1114   elif targetos == 'netbsd'
1115     oss = cc.find_library('ossaudio', required: get_option('oss'),
1116                           kwargs: static_kwargs)
1117   else
1118     oss = declare_dependency()
1119   endif
1120
1121   if not oss.found()
1122     if get_option('oss').enabled()
1123       error('OSS not found')
1124     endif
1125   endif
1126 endif
1127 dsound = not_found
1128 if not get_option('dsound').auto() or (targetos == 'windows' and have_system)
1129   if cc.has_header('dsound.h')
1130     dsound = declare_dependency(link_args: ['-lole32', '-ldxguid'])
1131   endif
1132
1133   if not dsound.found()
1134     if get_option('dsound').enabled()
1135       error('DirectSound not found')
1136     endif
1137   endif
1138 endif
1139
1140 coreaudio = not_found
1141 if not get_option('coreaudio').auto() or (targetos == 'darwin' and have_system)
1142   coreaudio = dependency('appleframeworks', modules: 'CoreAudio',
1143                          required: get_option('coreaudio'))
1144 endif
1145
1146 opengl = not_found
1147 if not get_option('opengl').auto() or have_system or have_vhost_user_gpu
1148   epoxy = dependency('epoxy', method: 'pkg-config',
1149                       required: get_option('opengl'), kwargs: static_kwargs)
1150   if cc.has_header('epoxy/egl.h', dependencies: epoxy)
1151     opengl = epoxy
1152   elif get_option('opengl').enabled()
1153     error('epoxy/egl.h not found')
1154   endif
1155 endif
1156 gbm = not_found
1157 if (have_system or have_tools) and (virgl.found() or opengl.found())
1158   gbm = dependency('gbm', method: 'pkg-config', required: false,
1159                    kwargs: static_kwargs)
1160 endif
1161 have_vhost_user_gpu = have_vhost_user_gpu and virgl.found() and opengl.found() and gbm.found()
1162
1163 gnutls = not_found
1164 gnutls_crypto = not_found
1165 if get_option('gnutls').enabled() or (get_option('gnutls').auto() and have_system)
1166   # For general TLS support our min gnutls matches
1167   # that implied by our platform support matrix
1168   #
1169   # For the crypto backends, we look for a newer
1170   # gnutls:
1171   #
1172   #   Version 3.6.8  is needed to get XTS
1173   #   Version 3.6.13 is needed to get PBKDF
1174   #   Version 3.6.14 is needed to get HW accelerated XTS
1175   #
1176   # If newer enough gnutls isn't available, we can
1177   # still use a different crypto backend to satisfy
1178   # the platform support requirements
1179   gnutls_crypto = dependency('gnutls', version: '>=3.6.14',
1180                              method: 'pkg-config',
1181                              required: false,
1182                              kwargs: static_kwargs)
1183   if gnutls_crypto.found()
1184     gnutls = gnutls_crypto
1185   else
1186     # Our min version if all we need is TLS
1187     gnutls = dependency('gnutls', version: '>=3.5.18',
1188                         method: 'pkg-config',
1189                         required: get_option('gnutls'),
1190                         kwargs: static_kwargs)
1191   endif
1192 endif
1193
1194 # We prefer use of gnutls for crypto, unless the options
1195 # explicitly asked for nettle or gcrypt.
1196 #
1197 # If gnutls isn't available for crypto, then we'll prefer
1198 # gcrypt over nettle for performance reasons.
1199 gcrypt = not_found
1200 nettle = not_found
1201 hogweed = not_found
1202 xts = 'none'
1203
1204 if get_option('nettle').enabled() and get_option('gcrypt').enabled()
1205   error('Only one of gcrypt & nettle can be enabled')
1206 endif
1207
1208 # Explicit nettle/gcrypt request, so ignore gnutls for crypto
1209 if get_option('nettle').enabled() or get_option('gcrypt').enabled()
1210   gnutls_crypto = not_found
1211 endif
1212
1213 if not gnutls_crypto.found()
1214   if (not get_option('gcrypt').auto() or have_system) and not get_option('nettle').enabled()
1215     gcrypt = dependency('libgcrypt', version: '>=1.8',
1216                         method: 'config-tool',
1217                         required: get_option('gcrypt'),
1218                         kwargs: static_kwargs)
1219     # Debian has removed -lgpg-error from libgcrypt-config
1220     # as it "spreads unnecessary dependencies" which in
1221     # turn breaks static builds...
1222     if gcrypt.found() and enable_static
1223       gcrypt = declare_dependency(dependencies: [
1224         gcrypt,
1225         cc.find_library('gpg-error', required: true, kwargs: static_kwargs)])
1226     endif
1227   endif
1228   if (not get_option('nettle').auto() or have_system) and not gcrypt.found()
1229     nettle = dependency('nettle', version: '>=3.4',
1230                         method: 'pkg-config',
1231                         required: get_option('nettle'),
1232                         kwargs: static_kwargs)
1233     if nettle.found() and not cc.has_header('nettle/xts.h', dependencies: nettle)
1234       xts = 'private'
1235     endif
1236   endif
1237 endif
1238
1239 gmp = dependency('gmp', required: false, method: 'pkg-config', kwargs: static_kwargs)
1240 if nettle.found() and gmp.found()
1241   hogweed = dependency('hogweed', version: '>=3.4',
1242                        method: 'pkg-config',
1243                        required: get_option('nettle'),
1244                        kwargs: static_kwargs)
1245 endif
1246
1247
1248 gtk = not_found
1249 gtkx11 = not_found
1250 vte = not_found
1251 if not get_option('gtk').auto() or have_system
1252   gtk = dependency('gtk+-3.0', version: '>=3.22.0',
1253                    method: 'pkg-config',
1254                    required: get_option('gtk'),
1255                    kwargs: static_kwargs)
1256   if gtk.found()
1257     gtkx11 = dependency('gtk+-x11-3.0', version: '>=3.22.0',
1258                         method: 'pkg-config',
1259                         required: false,
1260                         kwargs: static_kwargs)
1261     gtk = declare_dependency(dependencies: [gtk, gtkx11])
1262
1263     if not get_option('vte').auto() or have_system
1264       vte = dependency('vte-2.91',
1265                        method: 'pkg-config',
1266                        required: get_option('vte'),
1267                        kwargs: static_kwargs)
1268     endif
1269   endif
1270 endif
1271
1272 x11 = not_found
1273 if gtkx11.found()
1274   x11 = dependency('x11', method: 'pkg-config', required: gtkx11.found(),
1275                    kwargs: static_kwargs)
1276 endif
1277 png = not_found
1278 if get_option('png').allowed() and have_system
1279    png = dependency('libpng', version: '>=1.6.34', required: get_option('png'),
1280                     method: 'pkg-config', kwargs: static_kwargs)
1281 endif
1282 vnc = not_found
1283 jpeg = not_found
1284 sasl = not_found
1285 if get_option('vnc').allowed() and have_system
1286   vnc = declare_dependency() # dummy dependency
1287   jpeg = dependency('libjpeg', required: get_option('vnc_jpeg'),
1288                     method: 'pkg-config', kwargs: static_kwargs)
1289   sasl = cc.find_library('sasl2', has_headers: ['sasl/sasl.h'],
1290                          required: get_option('vnc_sasl'),
1291                          kwargs: static_kwargs)
1292   if sasl.found()
1293     sasl = declare_dependency(dependencies: sasl,
1294                               compile_args: '-DSTRUCT_IOVEC_DEFINED')
1295   endif
1296 endif
1297
1298 pam = not_found
1299 if not get_option('auth_pam').auto() or have_system
1300   pam = cc.find_library('pam', has_headers: ['security/pam_appl.h'],
1301                         required: get_option('auth_pam'),
1302                         kwargs: static_kwargs)
1303 endif
1304 if pam.found() and not cc.links('''
1305    #include <stddef.h>
1306    #include <security/pam_appl.h>
1307    int main(void) {
1308      const char *service_name = "qemu";
1309      const char *user = "frank";
1310      const struct pam_conv pam_conv = { 0 };
1311      pam_handle_t *pamh = NULL;
1312      pam_start(service_name, user, &pam_conv, &pamh);
1313      return 0;
1314    }''', dependencies: pam)
1315   pam = not_found
1316   if get_option('auth_pam').enabled()
1317     error('could not link libpam')
1318   else
1319     warning('could not link libpam, disabling')
1320   endif
1321 endif
1322
1323 snappy = not_found
1324 if not get_option('snappy').auto() or have_system
1325   snappy = cc.find_library('snappy', has_headers: ['snappy-c.h'],
1326                            required: get_option('snappy'),
1327                            kwargs: static_kwargs)
1328 endif
1329 if snappy.found() and not linker.links('''
1330    #include <snappy-c.h>
1331    int main(void) { snappy_max_compressed_length(4096); return 0; }''', dependencies: snappy)
1332   snappy = not_found
1333   if get_option('snappy').enabled()
1334     error('could not link libsnappy')
1335   else
1336     warning('could not link libsnappy, disabling')
1337   endif
1338 endif
1339
1340 lzo = not_found
1341 if not get_option('lzo').auto() or have_system
1342   lzo = cc.find_library('lzo2', has_headers: ['lzo/lzo1x.h'],
1343                         required: get_option('lzo'),
1344                         kwargs: static_kwargs)
1345 endif
1346 if lzo.found() and not cc.links('''
1347    #include <lzo/lzo1x.h>
1348    int main(void) { lzo_version(); return 0; }''', dependencies: lzo)
1349   lzo = not_found
1350   if get_option('lzo').enabled()
1351     error('could not link liblzo2')
1352   else
1353     warning('could not link liblzo2, disabling')
1354   endif
1355 endif
1356
1357 numa = not_found
1358 if not get_option('numa').auto() or have_system or have_tools
1359   numa = cc.find_library('numa', has_headers: ['numa.h'],
1360                               required: get_option('numa'),
1361                               kwargs: static_kwargs)
1362 endif
1363 if numa.found() and not cc.links('''
1364    #include <numa.h>
1365    int main(void) { return numa_available(); }
1366    ''', dependencies: numa)
1367   numa = not_found
1368   if get_option('numa').enabled()
1369     error('could not link numa')
1370   else
1371     warning('could not link numa, disabling')
1372   endif
1373 endif
1374
1375 rdma = not_found
1376 if not get_option('rdma').auto() or have_system
1377   libumad = cc.find_library('ibumad', required: get_option('rdma'))
1378   rdma_libs = [cc.find_library('rdmacm', has_headers: ['rdma/rdma_cma.h'],
1379                                required: get_option('rdma'),
1380                                kwargs: static_kwargs),
1381                cc.find_library('ibverbs', required: get_option('rdma'),
1382                                kwargs: static_kwargs),
1383                libumad]
1384   rdma = declare_dependency(dependencies: rdma_libs)
1385   foreach lib: rdma_libs
1386     if not lib.found()
1387       rdma = not_found
1388     endif
1389   endforeach
1390 endif
1391
1392 xen = not_found
1393 if get_option('xen').enabled() or (get_option('xen').auto() and have_system)
1394   xencontrol = dependency('xencontrol', required: false,
1395                           method: 'pkg-config', kwargs: static_kwargs)
1396   if xencontrol.found()
1397     xen_pc = declare_dependency(version: xencontrol.version(),
1398       dependencies: [
1399         xencontrol,
1400         # disabler: true makes xen_pc.found() return false if any is not found
1401         dependency('xenstore', required: false,
1402                    method: 'pkg-config', kwargs: static_kwargs,
1403                    disabler: true),
1404         dependency('xenforeignmemory', required: false,
1405                    method: 'pkg-config', kwargs: static_kwargs,
1406                    disabler: true),
1407         dependency('xengnttab', required: false,
1408                    method: 'pkg-config', kwargs: static_kwargs,
1409                    disabler: true),
1410         dependency('xenevtchn', required: false,
1411                    method: 'pkg-config', kwargs: static_kwargs,
1412                    disabler: true),
1413         dependency('xendevicemodel', required: false,
1414                    method: 'pkg-config', kwargs: static_kwargs,
1415                    disabler: true),
1416         # optional, no "disabler: true"
1417         dependency('xentoolcore', required: false,
1418                    method: 'pkg-config', kwargs: static_kwargs)])
1419     if xen_pc.found()
1420       xen = xen_pc
1421     endif
1422   endif
1423   if not xen.found()
1424     xen_tests = [ '4.11.0', '4.10.0', '4.9.0', '4.8.0', '4.7.1', '4.6.0', '4.5.0', '4.2.0' ]
1425     xen_libs = {
1426       '4.11.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1427       '4.10.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn', 'xentoolcore' ],
1428       '4.9.0': [ 'xenstore', 'xenctrl', 'xendevicemodel', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1429       '4.8.0': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1430       '4.7.1': [ 'xenstore', 'xenctrl', 'xenforeignmemory', 'xengnttab', 'xenevtchn' ],
1431       '4.6.0': [ 'xenstore', 'xenctrl' ],
1432       '4.5.0': [ 'xenstore', 'xenctrl' ],
1433       '4.2.0': [ 'xenstore', 'xenctrl' ],
1434     }
1435     xen_deps = {}
1436     foreach ver: xen_tests
1437       # cache the various library tests to avoid polluting the logs
1438       xen_test_deps = []
1439       foreach l: xen_libs[ver]
1440         if l not in xen_deps
1441           xen_deps += { l: cc.find_library(l, required: false) }
1442         endif
1443         xen_test_deps += xen_deps[l]
1444       endforeach
1445
1446       # Use -D to pick just one of the test programs in scripts/xen-detect.c
1447       xen_version = ver.split('.')
1448       xen_ctrl_version = xen_version[0] + \
1449         ('0' + xen_version[1]).substring(-2) + \
1450         ('0' + xen_version[2]).substring(-2)
1451       if cc.links(files('scripts/xen-detect.c'),
1452                   args: '-DCONFIG_XEN_CTRL_INTERFACE_VERSION=' + xen_ctrl_version,
1453                   dependencies: xen_test_deps)
1454         xen = declare_dependency(version: ver, dependencies: xen_test_deps)
1455         break
1456       endif
1457     endforeach
1458   endif
1459   if xen.found()
1460     accelerators += 'CONFIG_XEN'
1461   elif get_option('xen').enabled()
1462     error('could not compile and link Xen test program')
1463   endif
1464 endif
1465 have_xen_pci_passthrough = get_option('xen_pci_passthrough') \
1466   .require(xen.found(),
1467            error_message: 'Xen PCI passthrough requested but Xen not enabled') \
1468   .require(targetos == 'linux',
1469            error_message: 'Xen PCI passthrough not available on this platform') \
1470   .allowed()
1471
1472
1473 cacard = not_found
1474 if not get_option('smartcard').auto() or have_system
1475   cacard = dependency('libcacard', required: get_option('smartcard'),
1476                       version: '>=2.5.1', method: 'pkg-config',
1477                       kwargs: static_kwargs)
1478 endif
1479 u2f = not_found
1480 if have_system
1481   u2f = dependency('u2f-emu', required: get_option('u2f'),
1482                    method: 'pkg-config',
1483                    kwargs: static_kwargs)
1484 endif
1485 canokey = not_found
1486 if have_system
1487   canokey = dependency('canokey-qemu', required: get_option('canokey'),
1488                    method: 'pkg-config',
1489                    kwargs: static_kwargs)
1490 endif
1491 usbredir = not_found
1492 if not get_option('usb_redir').auto() or have_system
1493   usbredir = dependency('libusbredirparser-0.5', required: get_option('usb_redir'),
1494                         version: '>=0.6', method: 'pkg-config',
1495                         kwargs: static_kwargs)
1496 endif
1497 libusb = not_found
1498 if not get_option('libusb').auto() or have_system
1499   libusb = dependency('libusb-1.0', required: get_option('libusb'),
1500                       version: '>=1.0.13', method: 'pkg-config',
1501                       kwargs: static_kwargs)
1502 endif
1503
1504 libpmem = not_found
1505 if not get_option('libpmem').auto() or have_system
1506   libpmem = dependency('libpmem', required: get_option('libpmem'),
1507                        method: 'pkg-config', kwargs: static_kwargs)
1508 endif
1509 libdaxctl = not_found
1510 if not get_option('libdaxctl').auto() or have_system
1511   libdaxctl = dependency('libdaxctl', required: get_option('libdaxctl'),
1512                          version: '>=57', method: 'pkg-config',
1513                          kwargs: static_kwargs)
1514 endif
1515 tasn1 = not_found
1516 if gnutls.found()
1517   tasn1 = dependency('libtasn1',
1518                      method: 'pkg-config',
1519                      kwargs: static_kwargs)
1520 endif
1521 keyutils = dependency('libkeyutils', required: false,
1522                       method: 'pkg-config', kwargs: static_kwargs)
1523
1524 has_gettid = cc.has_function('gettid')
1525
1526 # libselinux
1527 selinux = dependency('libselinux',
1528                      required: get_option('selinux'),
1529                      method: 'pkg-config', kwargs: static_kwargs)
1530
1531 # Malloc tests
1532
1533 malloc = []
1534 if get_option('malloc') == 'system'
1535   has_malloc_trim = \
1536     get_option('malloc_trim').allowed() and \
1537     cc.links('''#include <malloc.h>
1538                 int main(void) { malloc_trim(0); return 0; }''')
1539 else
1540   has_malloc_trim = false
1541   malloc = cc.find_library(get_option('malloc'), required: true)
1542 endif
1543 if not has_malloc_trim and get_option('malloc_trim').enabled()
1544   if get_option('malloc') == 'system'
1545     error('malloc_trim not available on this platform.')
1546   else
1547     error('malloc_trim not available with non-libc memory allocator')
1548   endif
1549 endif
1550
1551 # Check whether the glibc provides statx()
1552
1553 gnu_source_prefix = '''
1554   #ifndef _GNU_SOURCE
1555   #define _GNU_SOURCE
1556   #endif
1557 '''
1558 statx_test = gnu_source_prefix + '''
1559   #include <sys/stat.h>
1560   int main(void) {
1561     struct statx statxbuf;
1562     statx(0, "", 0, STATX_BASIC_STATS, &statxbuf);
1563     return 0;
1564   }'''
1565
1566 has_statx = cc.links(statx_test)
1567
1568 # Check whether statx() provides mount ID information
1569
1570 statx_mnt_id_test = gnu_source_prefix + '''
1571   #include <sys/stat.h>
1572   int main(void) {
1573     struct statx statxbuf;
1574     statx(0, "", 0, STATX_BASIC_STATS | STATX_MNT_ID, &statxbuf);
1575     return statxbuf.stx_mnt_id;
1576   }'''
1577
1578 has_statx_mnt_id = cc.links(statx_mnt_id_test)
1579
1580 have_vhost_user_blk_server = get_option('vhost_user_blk_server') \
1581   .require(targetos == 'linux',
1582            error_message: 'vhost_user_blk_server requires linux') \
1583   .require(have_vhost_user,
1584            error_message: 'vhost_user_blk_server requires vhost-user support') \
1585   .disable_auto_if(not have_tools and not have_system) \
1586   .allowed()
1587
1588 if get_option('fuse').disabled() and get_option('fuse_lseek').enabled()
1589   error('Cannot enable fuse-lseek while fuse is disabled')
1590 endif
1591
1592 fuse = dependency('fuse3', required: get_option('fuse'),
1593                   version: '>=3.1', method: 'pkg-config',
1594                   kwargs: static_kwargs)
1595
1596 fuse_lseek = not_found
1597 if get_option('fuse_lseek').allowed()
1598   if fuse.version().version_compare('>=3.8')
1599     # Dummy dependency
1600     fuse_lseek = declare_dependency()
1601   elif get_option('fuse_lseek').enabled()
1602     if fuse.found()
1603       error('fuse-lseek requires libfuse >=3.8, found ' + fuse.version())
1604     else
1605       error('fuse-lseek requires libfuse, which was not found')
1606     endif
1607   endif
1608 endif
1609
1610 have_libvduse = (targetos == 'linux')
1611 if get_option('libvduse').enabled()
1612     if targetos != 'linux'
1613         error('libvduse requires linux')
1614     endif
1615 elif get_option('libvduse').disabled()
1616     have_libvduse = false
1617 endif
1618
1619 have_vduse_blk_export = (have_libvduse and targetos == 'linux')
1620 if get_option('vduse_blk_export').enabled()
1621     if targetos != 'linux'
1622         error('vduse_blk_export requires linux')
1623     elif not have_libvduse
1624         error('vduse_blk_export requires libvduse support')
1625     endif
1626 elif get_option('vduse_blk_export').disabled()
1627     have_vduse_blk_export = false
1628 endif
1629
1630 # libbpf
1631 libbpf = dependency('libbpf', required: get_option('bpf'), method: 'pkg-config')
1632 if libbpf.found() and not cc.links('''
1633    #include <bpf/libbpf.h>
1634    int main(void)
1635    {
1636      bpf_object__destroy_skeleton(NULL);
1637      return 0;
1638    }''', dependencies: libbpf)
1639   libbpf = not_found
1640   if get_option('bpf').enabled()
1641     error('libbpf skeleton test failed')
1642   else
1643     warning('libbpf skeleton test failed, disabling')
1644   endif
1645 endif
1646
1647 #################
1648 # config-host.h #
1649 #################
1650
1651 audio_drivers_selected = []
1652 if have_system
1653   audio_drivers_available = {
1654     'alsa': alsa.found(),
1655     'coreaudio': coreaudio.found(),
1656     'dsound': dsound.found(),
1657     'jack': jack.found(),
1658     'oss': oss.found(),
1659     'pa': pulse.found(),
1660     'sdl': sdl.found(),
1661     'sndio': sndio.found(),
1662   }
1663   foreach k, v: audio_drivers_available
1664     config_host_data.set('CONFIG_AUDIO_' + k.to_upper(), v)
1665   endforeach
1666
1667   # Default to native drivers first, OSS second, SDL third
1668   audio_drivers_priority = \
1669     [ 'pa', 'coreaudio', 'dsound', 'sndio', 'oss' ] + \
1670     (targetos == 'linux' ? [] : [ 'sdl' ])
1671   audio_drivers_default = []
1672   foreach k: audio_drivers_priority
1673     if audio_drivers_available[k]
1674       audio_drivers_default += k
1675     endif
1676   endforeach
1677
1678   foreach k: get_option('audio_drv_list')
1679     if k == 'default'
1680       audio_drivers_selected += audio_drivers_default
1681     elif not audio_drivers_available[k]
1682       error('Audio driver "@0@" not available.'.format(k))
1683     else
1684       audio_drivers_selected += k
1685     endif
1686   endforeach
1687 endif
1688 config_host_data.set('CONFIG_AUDIO_DRIVERS',
1689                      '"' + '", "'.join(audio_drivers_selected) + '", ')
1690
1691 if get_option('cfi')
1692   cfi_flags=[]
1693   # Check for dependency on LTO
1694   if not get_option('b_lto')
1695     error('Selected Control-Flow Integrity but LTO is disabled')
1696   endif
1697   if config_host.has_key('CONFIG_MODULES')
1698     error('Selected Control-Flow Integrity is not compatible with modules')
1699   endif
1700   # Check for cfi flags. CFI requires LTO so we can't use
1701   # get_supported_arguments, but need a more complex "compiles" which allows
1702   # custom arguments
1703   if cc.compiles('int main () { return 0; }', name: '-fsanitize=cfi-icall',
1704                  args: ['-flto', '-fsanitize=cfi-icall'] )
1705     cfi_flags += '-fsanitize=cfi-icall'
1706   else
1707     error('-fsanitize=cfi-icall is not supported by the compiler')
1708   endif
1709   if cc.compiles('int main () { return 0; }',
1710                  name: '-fsanitize-cfi-icall-generalize-pointers',
1711                  args: ['-flto', '-fsanitize=cfi-icall',
1712                         '-fsanitize-cfi-icall-generalize-pointers'] )
1713     cfi_flags += '-fsanitize-cfi-icall-generalize-pointers'
1714   else
1715     error('-fsanitize-cfi-icall-generalize-pointers is not supported by the compiler')
1716   endif
1717   if get_option('cfi_debug')
1718     if cc.compiles('int main () { return 0; }',
1719                    name: '-fno-sanitize-trap=cfi-icall',
1720                    args: ['-flto', '-fsanitize=cfi-icall',
1721                           '-fno-sanitize-trap=cfi-icall'] )
1722       cfi_flags += '-fno-sanitize-trap=cfi-icall'
1723     else
1724       error('-fno-sanitize-trap=cfi-icall is not supported by the compiler')
1725     endif
1726   endif
1727   add_global_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1728   add_global_link_arguments(cfi_flags, native: false, language: ['c', 'cpp', 'objc'])
1729 endif
1730
1731 have_host_block_device = (targetos != 'darwin' or
1732     cc.has_header('IOKit/storage/IOMedia.h'))
1733
1734 dbus_display = get_option('dbus_display') \
1735   .require(gio.version().version_compare('>=2.64'),
1736            error_message: '-display dbus requires glib>=2.64') \
1737   .require(gdbus_codegen.found(),
1738            error_message: gdbus_codegen_error.format('-display dbus')) \
1739   .require(opengl.found() and gbm.found(),
1740            error_message: '-display dbus requires epoxy/egl and gbm') \
1741   .allowed()
1742
1743 have_virtfs = get_option('virtfs') \
1744     .require(targetos == 'linux' or targetos == 'darwin',
1745              error_message: 'virtio-9p (virtfs) requires Linux or macOS') \
1746     .require(targetos == 'linux' or cc.has_function('pthread_fchdir_np'),
1747              error_message: 'virtio-9p (virtfs) on macOS requires the presence of pthread_fchdir_np') \
1748     .require(targetos == 'darwin' or (libattr.found() and libcap_ng.found()),
1749              error_message: 'virtio-9p (virtfs) on Linux requires libcap-ng-devel and libattr-devel') \
1750     .disable_auto_if(not have_tools and not have_system) \
1751     .allowed()
1752
1753 have_virtfs_proxy_helper = targetos != 'darwin' and have_virtfs and have_tools
1754
1755 if get_option('block_drv_ro_whitelist') == ''
1756   config_host_data.set('CONFIG_BDRV_RO_WHITELIST', '')
1757 else
1758   config_host_data.set('CONFIG_BDRV_RO_WHITELIST',
1759         '"' + get_option('block_drv_ro_whitelist').replace(',', '", "') + '", ')
1760 endif
1761 if get_option('block_drv_rw_whitelist') == ''
1762   config_host_data.set('CONFIG_BDRV_RW_WHITELIST', '')
1763 else
1764   config_host_data.set('CONFIG_BDRV_RW_WHITELIST',
1765         '"' + get_option('block_drv_rw_whitelist').replace(',', '", "') + '", ')
1766 endif
1767
1768 foreach k : get_option('trace_backends')
1769   config_host_data.set('CONFIG_TRACE_' + k.to_upper(), true)
1770 endforeach
1771 config_host_data.set_quoted('CONFIG_TRACE_FILE', get_option('trace_file'))
1772 config_host_data.set_quoted('CONFIG_TLS_PRIORITY', get_option('tls_priority'))
1773 if iasl.found()
1774   config_host_data.set_quoted('CONFIG_IASL', iasl.full_path())
1775 endif
1776 config_host_data.set_quoted('CONFIG_BINDIR', get_option('prefix') / get_option('bindir'))
1777 config_host_data.set_quoted('CONFIG_PREFIX', get_option('prefix'))
1778 config_host_data.set_quoted('CONFIG_QEMU_CONFDIR', get_option('prefix') / qemu_confdir)
1779 config_host_data.set_quoted('CONFIG_QEMU_DATADIR', get_option('prefix') / qemu_datadir)
1780 config_host_data.set_quoted('CONFIG_QEMU_DESKTOPDIR', get_option('prefix') / qemu_desktopdir)
1781
1782 qemu_firmwarepath = ''
1783 foreach k : get_option('qemu_firmwarepath')
1784   qemu_firmwarepath += '"' + get_option('prefix') / k + '", '
1785 endforeach
1786 config_host_data.set('CONFIG_QEMU_FIRMWAREPATH', qemu_firmwarepath)
1787
1788 config_host_data.set_quoted('CONFIG_QEMU_HELPERDIR', get_option('prefix') / get_option('libexecdir'))
1789 config_host_data.set_quoted('CONFIG_QEMU_ICONDIR', get_option('prefix') / qemu_icondir)
1790 config_host_data.set_quoted('CONFIG_QEMU_LOCALEDIR', get_option('prefix') / get_option('localedir'))
1791 config_host_data.set_quoted('CONFIG_QEMU_LOCALSTATEDIR', get_option('prefix') / get_option('localstatedir'))
1792 config_host_data.set_quoted('CONFIG_QEMU_MODDIR', get_option('prefix') / qemu_moddir)
1793 config_host_data.set_quoted('CONFIG_SYSCONFDIR', get_option('prefix') / get_option('sysconfdir'))
1794
1795 if config_host.has_key('CONFIG_MODULES')
1796   config_host_data.set('CONFIG_STAMP', run_command(
1797       meson.current_source_dir() / 'scripts/qemu-stamp.py',
1798       meson.project_version(), get_option('pkgversion'), '--',
1799       meson.current_source_dir() / 'configure',
1800       capture: true, check: true).stdout().strip())
1801 endif
1802
1803 have_slirp_smbd = get_option('slirp_smbd') \
1804   .require(targetos != 'windows', error_message: 'Host smbd not supported on this platform.') \
1805   .allowed()
1806 if have_slirp_smbd
1807   smbd_path = get_option('smbd')
1808   if smbd_path == ''
1809     smbd_path = (targetos == 'solaris' ? '/usr/sfw/sbin/smbd' : '/usr/sbin/smbd')
1810   endif
1811   config_host_data.set_quoted('CONFIG_SMBD_COMMAND', smbd_path)
1812 endif
1813
1814 config_host_data.set('HOST_' + host_arch.to_upper(), 1)
1815
1816 if get_option('module_upgrades') and not enable_modules
1817   error('Cannot enable module-upgrades as modules are not enabled')
1818 endif
1819 config_host_data.set('CONFIG_MODULE_UPGRADES', get_option('module_upgrades'))
1820
1821 config_host_data.set('CONFIG_ATTR', libattr.found())
1822 config_host_data.set('CONFIG_BDRV_WHITELIST_TOOLS', get_option('block_drv_whitelist_in_tools'))
1823 config_host_data.set('CONFIG_BRLAPI', brlapi.found())
1824 config_host_data.set('CONFIG_COCOA', cocoa.found())
1825 config_host_data.set('CONFIG_FUZZ', get_option('fuzzing'))
1826 config_host_data.set('CONFIG_GCOV', get_option('b_coverage'))
1827 config_host_data.set('CONFIG_LIBUDEV', libudev.found())
1828 config_host_data.set('CONFIG_LZO', lzo.found())
1829 config_host_data.set('CONFIG_MPATH', mpathpersist.found())
1830 config_host_data.set('CONFIG_MPATH_NEW_API', mpathpersist_new_api)
1831 config_host_data.set('CONFIG_BLKIO', blkio.found())
1832 config_host_data.set('CONFIG_CURL', curl.found())
1833 config_host_data.set('CONFIG_CURSES', curses.found())
1834 config_host_data.set('CONFIG_GBM', gbm.found())
1835 config_host_data.set('CONFIG_GIO', gio.found())
1836 config_host_data.set('CONFIG_GLUSTERFS', glusterfs.found())
1837 if glusterfs.found()
1838   config_host_data.set('CONFIG_GLUSTERFS_XLATOR_OPT', glusterfs.version().version_compare('>=4'))
1839   config_host_data.set('CONFIG_GLUSTERFS_DISCARD', glusterfs.version().version_compare('>=5'))
1840   config_host_data.set('CONFIG_GLUSTERFS_FALLOCATE', glusterfs.version().version_compare('>=6'))
1841   config_host_data.set('CONFIG_GLUSTERFS_ZEROFILL', glusterfs.version().version_compare('>=6'))
1842   config_host_data.set('CONFIG_GLUSTERFS_FTRUNCATE_HAS_STAT', glusterfs_ftruncate_has_stat)
1843   config_host_data.set('CONFIG_GLUSTERFS_IOCB_HAS_STAT', glusterfs_iocb_has_stat)
1844 endif
1845 config_host_data.set('CONFIG_GTK', gtk.found())
1846 config_host_data.set('CONFIG_VTE', vte.found())
1847 config_host_data.set('CONFIG_LIBATTR', have_old_libattr)
1848 config_host_data.set('CONFIG_LIBCAP_NG', libcap_ng.found())
1849 config_host_data.set('CONFIG_EBPF', libbpf.found())
1850 config_host_data.set('CONFIG_LIBDAXCTL', libdaxctl.found())
1851 config_host_data.set('CONFIG_LIBISCSI', libiscsi.found())
1852 config_host_data.set('CONFIG_LIBNFS', libnfs.found())
1853 config_host_data.set('CONFIG_LIBSSH', libssh.found())
1854 config_host_data.set('CONFIG_LINUX_AIO', libaio.found())
1855 config_host_data.set('CONFIG_LINUX_IO_URING', linux_io_uring.found())
1856 config_host_data.set('CONFIG_LIBPMEM', libpmem.found())
1857 config_host_data.set('CONFIG_NUMA', numa.found())
1858 config_host_data.set('CONFIG_OPENGL', opengl.found())
1859 config_host_data.set('CONFIG_PROFILER', get_option('profiler'))
1860 config_host_data.set('CONFIG_RBD', rbd.found())
1861 config_host_data.set('CONFIG_RDMA', rdma.found())
1862 config_host_data.set('CONFIG_SDL', sdl.found())
1863 config_host_data.set('CONFIG_SDL_IMAGE', sdl_image.found())
1864 config_host_data.set('CONFIG_SECCOMP', seccomp.found())
1865 if seccomp.found()
1866   config_host_data.set('CONFIG_SECCOMP_SYSRAWRC', seccomp_has_sysrawrc)
1867 endif
1868 config_host_data.set('CONFIG_SNAPPY', snappy.found())
1869 config_host_data.set('CONFIG_TPM', have_tpm)
1870 config_host_data.set('CONFIG_USB_LIBUSB', libusb.found())
1871 config_host_data.set('CONFIG_VDE', vde.found())
1872 config_host_data.set('CONFIG_VHOST_NET', have_vhost_net)
1873 config_host_data.set('CONFIG_VHOST_NET_USER', have_vhost_net_user)
1874 config_host_data.set('CONFIG_VHOST_NET_VDPA', have_vhost_net_vdpa)
1875 config_host_data.set('CONFIG_VHOST_KERNEL', have_vhost_kernel)
1876 config_host_data.set('CONFIG_VHOST_USER', have_vhost_user)
1877 config_host_data.set('CONFIG_VHOST_CRYPTO', have_vhost_user_crypto)
1878 config_host_data.set('CONFIG_VHOST_VDPA', have_vhost_vdpa)
1879 config_host_data.set('CONFIG_VMNET', vmnet.found())
1880 config_host_data.set('CONFIG_VHOST_USER_BLK_SERVER', have_vhost_user_blk_server)
1881 config_host_data.set('CONFIG_VDUSE_BLK_EXPORT', have_vduse_blk_export)
1882 config_host_data.set('CONFIG_PNG', png.found())
1883 config_host_data.set('CONFIG_VNC', vnc.found())
1884 config_host_data.set('CONFIG_VNC_JPEG', jpeg.found())
1885 config_host_data.set('CONFIG_VNC_SASL', sasl.found())
1886 config_host_data.set('CONFIG_VIRTFS', have_virtfs)
1887 config_host_data.set('CONFIG_VTE', vte.found())
1888 config_host_data.set('CONFIG_XKBCOMMON', xkbcommon.found())
1889 config_host_data.set('CONFIG_KEYUTILS', keyutils.found())
1890 config_host_data.set('CONFIG_GETTID', has_gettid)
1891 config_host_data.set('CONFIG_GNUTLS', gnutls.found())
1892 config_host_data.set('CONFIG_GNUTLS_CRYPTO', gnutls_crypto.found())
1893 config_host_data.set('CONFIG_TASN1', tasn1.found())
1894 config_host_data.set('CONFIG_GCRYPT', gcrypt.found())
1895 config_host_data.set('CONFIG_NETTLE', nettle.found())
1896 config_host_data.set('CONFIG_HOGWEED', hogweed.found())
1897 config_host_data.set('CONFIG_QEMU_PRIVATE_XTS', xts == 'private')
1898 config_host_data.set('CONFIG_MALLOC_TRIM', has_malloc_trim)
1899 config_host_data.set('CONFIG_STATX', has_statx)
1900 config_host_data.set('CONFIG_STATX_MNT_ID', has_statx_mnt_id)
1901 config_host_data.set('CONFIG_ZSTD', zstd.found())
1902 config_host_data.set('CONFIG_FUSE', fuse.found())
1903 config_host_data.set('CONFIG_FUSE_LSEEK', fuse_lseek.found())
1904 config_host_data.set('CONFIG_SPICE_PROTOCOL', spice_protocol.found())
1905 if spice_protocol.found()
1906 config_host_data.set('CONFIG_SPICE_PROTOCOL_MAJOR', spice_protocol.version().split('.')[0])
1907 config_host_data.set('CONFIG_SPICE_PROTOCOL_MINOR', spice_protocol.version().split('.')[1])
1908 config_host_data.set('CONFIG_SPICE_PROTOCOL_MICRO', spice_protocol.version().split('.')[2])
1909 endif
1910 config_host_data.set('CONFIG_SPICE', spice.found())
1911 config_host_data.set('CONFIG_X11', x11.found())
1912 config_host_data.set('CONFIG_DBUS_DISPLAY', dbus_display)
1913 config_host_data.set('CONFIG_CFI', get_option('cfi'))
1914 config_host_data.set('CONFIG_SELINUX', selinux.found())
1915 config_host_data.set('CONFIG_XEN_BACKEND', xen.found())
1916 if xen.found()
1917   # protect from xen.version() having less than three components
1918   xen_version = xen.version().split('.') + ['0', '0']
1919   xen_ctrl_version = xen_version[0] + \
1920     ('0' + xen_version[1]).substring(-2) + \
1921     ('0' + xen_version[2]).substring(-2)
1922   config_host_data.set('CONFIG_XEN_CTRL_INTERFACE_VERSION', xen_ctrl_version)
1923 endif
1924 config_host_data.set('QEMU_VERSION', '"@0@"'.format(meson.project_version()))
1925 config_host_data.set('QEMU_VERSION_MAJOR', meson.project_version().split('.')[0])
1926 config_host_data.set('QEMU_VERSION_MINOR', meson.project_version().split('.')[1])
1927 config_host_data.set('QEMU_VERSION_MICRO', meson.project_version().split('.')[2])
1928
1929 config_host_data.set_quoted('CONFIG_HOST_DSOSUF', host_dsosuf)
1930 config_host_data.set('HAVE_HOST_BLOCK_DEVICE', have_host_block_device)
1931
1932 have_coroutine_pool = get_option('coroutine_pool')
1933 if get_option('debug_stack_usage') and have_coroutine_pool
1934   message('Disabling coroutine pool to measure stack usage')
1935   have_coroutine_pool = false
1936 endif
1937 config_host_data.set10('CONFIG_COROUTINE_POOL', have_coroutine_pool)
1938 config_host_data.set('CONFIG_DEBUG_MUTEX', get_option('debug_mutex'))
1939 config_host_data.set('CONFIG_DEBUG_STACK_USAGE', get_option('debug_stack_usage'))
1940 config_host_data.set('CONFIG_GPROF', get_option('gprof'))
1941 config_host_data.set('CONFIG_LIVE_BLOCK_MIGRATION', get_option('live_block_migration').allowed())
1942 config_host_data.set('CONFIG_QOM_CAST_DEBUG', get_option('qom_cast_debug'))
1943 config_host_data.set('CONFIG_REPLICATION', get_option('replication').allowed())
1944
1945 # has_header
1946 config_host_data.set('CONFIG_EPOLL', cc.has_header('sys/epoll.h'))
1947 config_host_data.set('CONFIG_LINUX_MAGIC_H', cc.has_header('linux/magic.h'))
1948 config_host_data.set('CONFIG_VALGRIND_H', cc.has_header('valgrind/valgrind.h'))
1949 config_host_data.set('HAVE_BTRFS_H', cc.has_header('linux/btrfs.h'))
1950 config_host_data.set('HAVE_DRM_H', cc.has_header('libdrm/drm.h'))
1951 config_host_data.set('HAVE_PTY_H', cc.has_header('pty.h'))
1952 config_host_data.set('HAVE_SYS_DISK_H', cc.has_header('sys/disk.h'))
1953 config_host_data.set('HAVE_SYS_IOCCOM_H', cc.has_header('sys/ioccom.h'))
1954 config_host_data.set('HAVE_SYS_KCOV_H', cc.has_header('sys/kcov.h'))
1955 if targetos == 'windows'
1956   config_host_data.set('HAVE_AFUNIX_H', cc.has_header('afunix.h'))
1957 endif
1958
1959 # has_function
1960 config_host_data.set('CONFIG_ACCEPT4', cc.has_function('accept4'))
1961 config_host_data.set('CONFIG_CLOCK_ADJTIME', cc.has_function('clock_adjtime'))
1962 config_host_data.set('CONFIG_DUP3', cc.has_function('dup3'))
1963 config_host_data.set('CONFIG_FALLOCATE', cc.has_function('fallocate'))
1964 config_host_data.set('CONFIG_POSIX_FALLOCATE', cc.has_function('posix_fallocate'))
1965 # Note that we need to specify prefix: here to avoid incorrectly
1966 # thinking that Windows has posix_memalign()
1967 config_host_data.set('CONFIG_POSIX_MEMALIGN', cc.has_function('posix_memalign', prefix: '#include <stdlib.h>'))
1968 config_host_data.set('CONFIG_ALIGNED_MALLOC', cc.has_function('_aligned_malloc'))
1969 config_host_data.set('CONFIG_VALLOC', cc.has_function('valloc'))
1970 config_host_data.set('CONFIG_MEMALIGN', cc.has_function('memalign'))
1971 config_host_data.set('CONFIG_PPOLL', cc.has_function('ppoll'))
1972 config_host_data.set('CONFIG_PREADV', cc.has_function('preadv', prefix: '#include <sys/uio.h>'))
1973 config_host_data.set('CONFIG_PTHREAD_FCHDIR_NP', cc.has_function('pthread_fchdir_np'))
1974 config_host_data.set('CONFIG_SENDFILE', cc.has_function('sendfile'))
1975 config_host_data.set('CONFIG_SETNS', cc.has_function('setns') and cc.has_function('unshare'))
1976 config_host_data.set('CONFIG_SYNCFS', cc.has_function('syncfs'))
1977 config_host_data.set('CONFIG_SYNC_FILE_RANGE', cc.has_function('sync_file_range'))
1978 config_host_data.set('CONFIG_TIMERFD', cc.has_function('timerfd_create'))
1979 config_host_data.set('HAVE_COPY_FILE_RANGE', cc.has_function('copy_file_range'))
1980 config_host_data.set('HAVE_GETIFADDRS', cc.has_function('getifaddrs'))
1981 config_host_data.set('HAVE_OPENPTY', cc.has_function('openpty', dependencies: util))
1982 config_host_data.set('HAVE_STRCHRNUL', cc.has_function('strchrnul'))
1983 config_host_data.set('HAVE_SYSTEM_FUNCTION', cc.has_function('system', prefix: '#include <stdlib.h>'))
1984 if rbd.found()
1985   config_host_data.set('HAVE_RBD_NAMESPACE_EXISTS',
1986                        cc.has_function('rbd_namespace_exists',
1987                                        dependencies: rbd,
1988                                        prefix: '#include <rbd/librbd.h>'))
1989 endif
1990 if rdma.found()
1991   config_host_data.set('HAVE_IBV_ADVISE_MR',
1992                        cc.has_function('ibv_advise_mr',
1993                                        dependencies: rdma,
1994                                        prefix: '#include <infiniband/verbs.h>'))
1995 endif
1996
1997 # has_header_symbol
1998 config_host_data.set('CONFIG_BYTESWAP_H',
1999                      cc.has_header_symbol('byteswap.h', 'bswap_32'))
2000 config_host_data.set('CONFIG_EPOLL_CREATE1',
2001                      cc.has_header_symbol('sys/epoll.h', 'epoll_create1'))
2002 config_host_data.set('CONFIG_FALLOCATE_PUNCH_HOLE',
2003                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_PUNCH_HOLE') and
2004                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_KEEP_SIZE'))
2005 config_host_data.set('CONFIG_FALLOCATE_ZERO_RANGE',
2006                      cc.has_header_symbol('linux/falloc.h', 'FALLOC_FL_ZERO_RANGE'))
2007 config_host_data.set('CONFIG_FIEMAP',
2008                      cc.has_header('linux/fiemap.h') and
2009                      cc.has_header_symbol('linux/fs.h', 'FS_IOC_FIEMAP'))
2010 config_host_data.set('CONFIG_GETRANDOM',
2011                      cc.has_function('getrandom') and
2012                      cc.has_header_symbol('sys/random.h', 'GRND_NONBLOCK'))
2013 config_host_data.set('CONFIG_INOTIFY',
2014                      cc.has_header_symbol('sys/inotify.h', 'inotify_init'))
2015 config_host_data.set('CONFIG_INOTIFY1',
2016                      cc.has_header_symbol('sys/inotify.h', 'inotify_init1'))
2017 config_host_data.set('CONFIG_MACHINE_BSWAP_H',
2018                      cc.has_header_symbol('machine/bswap.h', 'bswap32',
2019                                           prefix: '''#include <sys/endian.h>
2020                                                      #include <sys/types.h>'''))
2021 config_host_data.set('CONFIG_PRCTL_PR_SET_TIMERSLACK',
2022                      cc.has_header_symbol('sys/prctl.h', 'PR_SET_TIMERSLACK'))
2023 config_host_data.set('CONFIG_RTNETLINK',
2024                      cc.has_header_symbol('linux/rtnetlink.h', 'IFLA_PROTO_DOWN'))
2025 config_host_data.set('CONFIG_SYSMACROS',
2026                      cc.has_header_symbol('sys/sysmacros.h', 'makedev'))
2027 config_host_data.set('HAVE_OPTRESET',
2028                      cc.has_header_symbol('getopt.h', 'optreset'))
2029 config_host_data.set('HAVE_IPPROTO_MPTCP',
2030                      cc.has_header_symbol('netinet/in.h', 'IPPROTO_MPTCP'))
2031 config_host_data.set('HAVE_SYS_MOUNT_FSCONFIG',
2032                      cc.has_header_symbol('sys/mount.h', 'FSCONFIG_SET_FLAG'))
2033
2034 # has_member
2035 config_host_data.set('HAVE_SIGEV_NOTIFY_THREAD_ID',
2036                      cc.has_member('struct sigevent', 'sigev_notify_thread_id',
2037                                    prefix: '#include <signal.h>'))
2038 config_host_data.set('HAVE_STRUCT_STAT_ST_ATIM',
2039                      cc.has_member('struct stat', 'st_atim',
2040                                    prefix: '#include <sys/stat.h>'))
2041
2042 # has_type
2043 config_host_data.set('CONFIG_IOVEC',
2044                      cc.has_type('struct iovec',
2045                                  prefix: '#include <sys/uio.h>'))
2046 config_host_data.set('HAVE_UTMPX',
2047                      cc.has_type('struct utmpx',
2048                                  prefix: '#include <utmpx.h>'))
2049
2050 config_host_data.set('CONFIG_EVENTFD', cc.links('''
2051   #include <sys/eventfd.h>
2052   int main(void) { return eventfd(0, EFD_NONBLOCK | EFD_CLOEXEC); }'''))
2053 config_host_data.set('CONFIG_FDATASYNC', cc.links(gnu_source_prefix + '''
2054   #include <unistd.h>
2055   int main(void) {
2056   #if defined(_POSIX_SYNCHRONIZED_IO) && _POSIX_SYNCHRONIZED_IO > 0
2057   return fdatasync(0);
2058   #else
2059   #error Not supported
2060   #endif
2061   }'''))
2062
2063 has_madvise = cc.links(gnu_source_prefix + '''
2064   #include <sys/types.h>
2065   #include <sys/mman.h>
2066   #include <stddef.h>
2067   int main(void) { return madvise(NULL, 0, MADV_DONTNEED); }''')
2068 missing_madvise_proto = false
2069 if has_madvise
2070   # Some platforms (illumos and Solaris before Solaris 11) provide madvise()
2071   # but forget to prototype it. In this case, has_madvise will be true (the
2072   # test program links despite a compile warning). To detect the
2073   # missing-prototype case, we try again with a definitely-bogus prototype.
2074   # This will only compile if the system headers don't provide the prototype;
2075   # otherwise the conflicting prototypes will cause a compiler error.
2076   missing_madvise_proto = cc.links(gnu_source_prefix + '''
2077     #include <sys/types.h>
2078     #include <sys/mman.h>
2079     #include <stddef.h>
2080     extern int madvise(int);
2081     int main(void) { return madvise(0); }''')
2082 endif
2083 config_host_data.set('CONFIG_MADVISE', has_madvise)
2084 config_host_data.set('HAVE_MADVISE_WITHOUT_PROTOTYPE', missing_madvise_proto)
2085
2086 config_host_data.set('CONFIG_MEMFD', cc.links(gnu_source_prefix + '''
2087   #include <sys/mman.h>
2088   int main(void) { return memfd_create("foo", MFD_ALLOW_SEALING); }'''))
2089 config_host_data.set('CONFIG_OPEN_BY_HANDLE', cc.links(gnu_source_prefix + '''
2090   #include <fcntl.h>
2091   #if !defined(AT_EMPTY_PATH)
2092   # error missing definition
2093   #else
2094   int main(void) { struct file_handle fh; return open_by_handle_at(0, &fh, 0); }
2095   #endif'''))
2096 config_host_data.set('CONFIG_POSIX_MADVISE', cc.links(gnu_source_prefix + '''
2097   #include <sys/mman.h>
2098   #include <stddef.h>
2099   int main(void) { return posix_madvise(NULL, 0, POSIX_MADV_DONTNEED); }'''))
2100
2101 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_W_TID', cc.links(gnu_source_prefix + '''
2102   #include <pthread.h>
2103
2104   static void *f(void *p) { return NULL; }
2105   int main(void)
2106   {
2107     pthread_t thread;
2108     pthread_create(&thread, 0, f, 0);
2109     pthread_setname_np(thread, "QEMU");
2110     return 0;
2111   }''', dependencies: threads))
2112 config_host_data.set('CONFIG_PTHREAD_SETNAME_NP_WO_TID', cc.links(gnu_source_prefix + '''
2113   #include <pthread.h>
2114
2115   static void *f(void *p) { pthread_setname_np("QEMU"); return NULL; }
2116   int main(void)
2117   {
2118     pthread_t thread;
2119     pthread_create(&thread, 0, f, 0);
2120     return 0;
2121   }''', dependencies: threads))
2122 config_host_data.set('CONFIG_PTHREAD_CONDATTR_SETCLOCK', cc.links(gnu_source_prefix + '''
2123   #include <pthread.h>
2124   #include <time.h>
2125
2126   int main(void)
2127   {
2128     pthread_condattr_t attr
2129     pthread_condattr_init(&attr);
2130     pthread_condattr_setclock(&attr, CLOCK_MONOTONIC);
2131     return 0;
2132   }''', dependencies: threads))
2133 config_host_data.set('CONFIG_PTHREAD_AFFINITY_NP', cc.links(gnu_source_prefix + '''
2134   #include <pthread.h>
2135
2136   static void *f(void *p) { return NULL; }
2137   int main(void)
2138   {
2139     int setsize = CPU_ALLOC_SIZE(64);
2140     pthread_t thread;
2141     cpu_set_t *cpuset;
2142     pthread_create(&thread, 0, f, 0);
2143     cpuset = CPU_ALLOC(64);
2144     CPU_ZERO_S(setsize, cpuset);
2145     pthread_setaffinity_np(thread, setsize, cpuset);
2146     pthread_getaffinity_np(thread, setsize, cpuset);
2147     CPU_FREE(cpuset);
2148     return 0;
2149   }''', dependencies: threads))
2150 config_host_data.set('CONFIG_SIGNALFD', cc.links(gnu_source_prefix + '''
2151   #include <sys/signalfd.h>
2152   #include <stddef.h>
2153   int main(void) { return signalfd(-1, NULL, SFD_CLOEXEC); }'''))
2154 config_host_data.set('CONFIG_SPLICE', cc.links(gnu_source_prefix + '''
2155   #include <unistd.h>
2156   #include <fcntl.h>
2157   #include <limits.h>
2158
2159   int main(void)
2160   {
2161     int len, fd = 0;
2162     len = tee(STDIN_FILENO, STDOUT_FILENO, INT_MAX, SPLICE_F_NONBLOCK);
2163     splice(STDIN_FILENO, NULL, fd, NULL, len, SPLICE_F_MOVE);
2164     return 0;
2165   }'''))
2166
2167 config_host_data.set('HAVE_MLOCKALL', cc.links(gnu_source_prefix + '''
2168   #include <sys/mman.h>
2169   int main(int argc, char *argv[]) {
2170     return mlockall(MCL_FUTURE);
2171   }'''))
2172
2173 have_l2tpv3 = false
2174 if get_option('l2tpv3').allowed() and have_system
2175   have_l2tpv3 = cc.has_type('struct mmsghdr',
2176     prefix: gnu_source_prefix + '''
2177       #include <sys/socket.h>
2178       #include <linux/ip.h>''')
2179 endif
2180 config_host_data.set('CONFIG_L2TPV3', have_l2tpv3)
2181
2182 have_netmap = false
2183 if get_option('netmap').allowed() and have_system
2184   have_netmap = cc.compiles('''
2185     #include <inttypes.h>
2186     #include <net/if.h>
2187     #include <net/netmap.h>
2188     #include <net/netmap_user.h>
2189     #if (NETMAP_API < 11) || (NETMAP_API > 15)
2190     #error
2191     #endif
2192     int main(void) { return 0; }''')
2193   if not have_netmap and get_option('netmap').enabled()
2194     error('Netmap headers not available')
2195   endif
2196 endif
2197 config_host_data.set('CONFIG_NETMAP', have_netmap)
2198
2199 # Work around a system header bug with some kernel/XFS header
2200 # versions where they both try to define 'struct fsxattr':
2201 # xfs headers will not try to redefine structs from linux headers
2202 # if this macro is set.
2203 config_host_data.set('HAVE_FSXATTR', cc.links('''
2204   #include <linux/fs.h>
2205   struct fsxattr foo;
2206   int main(void) {
2207     return 0;
2208   }'''))
2209
2210 # Some versions of Mac OS X incorrectly define SIZE_MAX
2211 config_host_data.set('HAVE_BROKEN_SIZE_MAX', not cc.compiles('''
2212     #include <stdint.h>
2213     #include <stdio.h>
2214     int main(int argc, char *argv[]) {
2215         return printf("%zu", SIZE_MAX);
2216     }''', args: ['-Werror']))
2217
2218 atomic_test = '''
2219   #include <stdint.h>
2220   int main(void)
2221   {
2222     @0@ x = 0, y = 0;
2223     y = __atomic_load_n(&x, __ATOMIC_RELAXED);
2224     __atomic_store_n(&x, y, __ATOMIC_RELAXED);
2225     __atomic_compare_exchange_n(&x, &y, x, 0, __ATOMIC_RELAXED, __ATOMIC_RELAXED);
2226     __atomic_exchange_n(&x, y, __ATOMIC_RELAXED);
2227     __atomic_fetch_add(&x, y, __ATOMIC_RELAXED);
2228     return 0;
2229   }'''
2230
2231 # See if 64-bit atomic operations are supported.
2232 # Note that without __atomic builtins, we can only
2233 # assume atomic loads/stores max at pointer size.
2234 config_host_data.set('CONFIG_ATOMIC64', cc.links(atomic_test.format('uint64_t')))
2235
2236 has_int128 = cc.links('''
2237   __int128_t a;
2238   __uint128_t b;
2239   int main (void) {
2240     a = a + b;
2241     b = a * b;
2242     a = a * a;
2243     return 0;
2244   }''')
2245
2246 config_host_data.set('CONFIG_INT128', has_int128)
2247
2248 if has_int128
2249   # "do we have 128-bit atomics which are handled inline and specifically not
2250   # via libatomic". The reason we can't use libatomic is documented in the
2251   # comment starting "GCC is a house divided" in include/qemu/atomic128.h.
2252   has_atomic128 = cc.links(atomic_test.format('unsigned __int128'))
2253
2254   config_host_data.set('CONFIG_ATOMIC128', has_atomic128)
2255
2256   if not has_atomic128
2257     has_cmpxchg128 = cc.links('''
2258       int main(void)
2259       {
2260         unsigned __int128 x = 0, y = 0;
2261         __sync_val_compare_and_swap_16(&x, y, x);
2262         return 0;
2263       }
2264     ''')
2265
2266     config_host_data.set('CONFIG_CMPXCHG128', has_cmpxchg128)
2267   endif
2268 endif
2269
2270 config_host_data.set('CONFIG_GETAUXVAL', cc.links(gnu_source_prefix + '''
2271   #include <sys/auxv.h>
2272   int main(void) {
2273     return getauxval(AT_HWCAP) == 0;
2274   }'''))
2275
2276 config_host_data.set('CONFIG_USBFS', have_linux_user and cc.compiles('''
2277   #include <linux/usbdevice_fs.h>
2278
2279   #ifndef USBDEVFS_GET_CAPABILITIES
2280   #error "USBDEVFS_GET_CAPABILITIES undefined"
2281   #endif
2282
2283   #ifndef USBDEVFS_DISCONNECT_CLAIM
2284   #error "USBDEVFS_DISCONNECT_CLAIM undefined"
2285   #endif
2286
2287   int main(void) { return 0; }'''))
2288
2289 have_keyring = get_option('keyring') \
2290   .require(targetos == 'linux', error_message: 'keyring is only available on Linux') \
2291   .require(cc.compiles('''
2292     #include <errno.h>
2293     #include <asm/unistd.h>
2294     #include <linux/keyctl.h>
2295     #include <sys/syscall.h>
2296     #include <unistd.h>
2297     int main(void) {
2298         return syscall(__NR_keyctl, KEYCTL_READ, 0, NULL, NULL, 0);
2299     }'''), error_message: 'keyctl syscall not available on this system').allowed()
2300 config_host_data.set('CONFIG_SECRET_KEYRING', have_keyring)
2301
2302 have_cpuid_h = cc.links('''
2303   #include <cpuid.h>
2304   int main(void) {
2305     unsigned a, b, c, d;
2306     unsigned max = __get_cpuid_max(0, 0);
2307
2308     if (max >= 1) {
2309         __cpuid(1, a, b, c, d);
2310     }
2311
2312     if (max >= 7) {
2313         __cpuid_count(7, 0, a, b, c, d);
2314     }
2315
2316     return 0;
2317   }''')
2318 config_host_data.set('CONFIG_CPUID_H', have_cpuid_h)
2319
2320 config_host_data.set('CONFIG_AVX2_OPT', get_option('avx2') \
2321   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX2') \
2322   .require(cc.links('''
2323     #pragma GCC push_options
2324     #pragma GCC target("avx2")
2325     #include <cpuid.h>
2326     #include <immintrin.h>
2327     static int bar(void *a) {
2328       __m256i x = *(__m256i *)a;
2329       return _mm256_testz_si256(x, x);
2330     }
2331     int main(int argc, char *argv[]) { return bar(argv[0]); }
2332   '''), error_message: 'AVX2 not available').allowed())
2333
2334 config_host_data.set('CONFIG_AVX512F_OPT', get_option('avx512f') \
2335   .require(have_cpuid_h, error_message: 'cpuid.h not available, cannot enable AVX512F') \
2336   .require(cc.links('''
2337     #pragma GCC push_options
2338     #pragma GCC target("avx512f")
2339     #include <cpuid.h>
2340     #include <immintrin.h>
2341     static int bar(void *a) {
2342       __m512i x = *(__m512i *)a;
2343       return _mm512_test_epi64_mask(x, x);
2344     }
2345     int main(int argc, char *argv[]) { return bar(argv[0]); }
2346   '''), error_message: 'AVX512F not available').allowed())
2347
2348 have_pvrdma = get_option('pvrdma') \
2349   .require(rdma.found(), error_message: 'PVRDMA requires OpenFabrics libraries') \
2350   .require(cc.compiles(gnu_source_prefix + '''
2351     #include <sys/mman.h>
2352     int main(void)
2353     {
2354       char buf = 0;
2355       void *addr = &buf;
2356       addr = mremap(addr, 0, 1, MREMAP_MAYMOVE | MREMAP_FIXED);
2357
2358       return 0;
2359     }'''), error_message: 'PVRDMA requires mremap').allowed()
2360
2361 if have_pvrdma
2362   config_host_data.set('LEGACY_RDMA_REG_MR', not cc.links('''
2363     #include <infiniband/verbs.h>
2364     int main(void)
2365     {
2366       struct ibv_mr *mr;
2367       struct ibv_pd *pd = NULL;
2368       size_t length = 10;
2369       uint64_t iova = 0;
2370       int access = 0;
2371       void *addr = NULL;
2372
2373       mr = ibv_reg_mr_iova(pd, addr, length, iova, access);
2374       ibv_dereg_mr(mr);
2375       return 0;
2376     }'''))
2377 endif
2378
2379 if get_option('membarrier').disabled()
2380   have_membarrier = false
2381 elif targetos == 'windows'
2382   have_membarrier = true
2383 elif targetos == 'linux'
2384   have_membarrier = cc.compiles('''
2385     #include <linux/membarrier.h>
2386     #include <sys/syscall.h>
2387     #include <unistd.h>
2388     #include <stdlib.h>
2389     int main(void) {
2390         syscall(__NR_membarrier, MEMBARRIER_CMD_QUERY, 0);
2391         syscall(__NR_membarrier, MEMBARRIER_CMD_SHARED, 0);
2392         exit(0);
2393     }''')
2394 endif
2395 config_host_data.set('CONFIG_MEMBARRIER', get_option('membarrier') \
2396   .require(have_membarrier, error_message: 'membarrier system call not available') \
2397   .allowed())
2398
2399 have_afalg = get_option('crypto_afalg') \
2400   .require(cc.compiles(gnu_source_prefix + '''
2401     #include <errno.h>
2402     #include <sys/types.h>
2403     #include <sys/socket.h>
2404     #include <linux/if_alg.h>
2405     int main(void) {
2406       int sock;
2407       sock = socket(AF_ALG, SOCK_SEQPACKET, 0);
2408       return sock;
2409     }
2410   '''), error_message: 'AF_ALG requested but could not be detected').allowed()
2411 config_host_data.set('CONFIG_AF_ALG', have_afalg)
2412
2413 config_host_data.set('CONFIG_AF_VSOCK', cc.has_header_symbol(
2414   'linux/vm_sockets.h', 'AF_VSOCK',
2415   prefix: '#include <sys/socket.h>',
2416 ))
2417
2418 have_vss = false
2419 have_vss_sdk = false # old xp/2003 SDK
2420 if targetos == 'windows' and link_language == 'cpp'
2421   have_vss = cxx.compiles('''
2422     #define __MIDL_user_allocate_free_DEFINED__
2423     #include <vss.h>
2424     int main(void) { return VSS_CTX_BACKUP; }''')
2425   have_vss_sdk = cxx.has_header('vscoordint.h')
2426 endif
2427 config_host_data.set('HAVE_VSS_SDK', have_vss_sdk)
2428
2429 foreach k, v: config_host
2430   if k.startswith('CONFIG_')
2431     config_host_data.set(k, v == 'y' ? 1 : v)
2432   endif
2433 endforeach
2434
2435 # Older versions of MinGW do not import _lock_file and _unlock_file properly.
2436 # This was fixed for v6.0.0 with commit b48e3ac8969d.
2437 if targetos == 'windows'
2438   config_host_data.set('HAVE__LOCK_FILE', cc.links('''
2439     #include <stdio.h>
2440     int main(void) {
2441       _lock_file(NULL);
2442       _unlock_file(NULL);
2443       return 0;
2444     }''', name: '_lock_file and _unlock_file'))
2445 endif
2446
2447 ########################
2448 # Target configuration #
2449 ########################
2450
2451 minikconf = find_program('scripts/minikconf.py')
2452 config_all = {}
2453 config_all_devices = {}
2454 config_all_disas = {}
2455 config_devices_mak_list = []
2456 config_devices_h = {}
2457 config_target_h = {}
2458 config_target_mak = {}
2459
2460 disassemblers = {
2461   'alpha' : ['CONFIG_ALPHA_DIS'],
2462   'avr' : ['CONFIG_AVR_DIS'],
2463   'cris' : ['CONFIG_CRIS_DIS'],
2464   'hexagon' : ['CONFIG_HEXAGON_DIS'],
2465   'hppa' : ['CONFIG_HPPA_DIS'],
2466   'i386' : ['CONFIG_I386_DIS'],
2467   'x86_64' : ['CONFIG_I386_DIS'],
2468   'm68k' : ['CONFIG_M68K_DIS'],
2469   'microblaze' : ['CONFIG_MICROBLAZE_DIS'],
2470   'mips' : ['CONFIG_MIPS_DIS'],
2471   'nios2' : ['CONFIG_NIOS2_DIS'],
2472   'or1k' : ['CONFIG_OPENRISC_DIS'],
2473   'ppc' : ['CONFIG_PPC_DIS'],
2474   'riscv' : ['CONFIG_RISCV_DIS'],
2475   'rx' : ['CONFIG_RX_DIS'],
2476   's390' : ['CONFIG_S390_DIS'],
2477   'sh4' : ['CONFIG_SH4_DIS'],
2478   'sparc' : ['CONFIG_SPARC_DIS'],
2479   'xtensa' : ['CONFIG_XTENSA_DIS'],
2480   'loongarch' : ['CONFIG_LOONGARCH_DIS'],
2481 }
2482 if link_language == 'cpp'
2483   disassemblers += {
2484     'mips' : [ 'CONFIG_MIPS_DIS', 'CONFIG_NANOMIPS_DIS'],
2485   }
2486 endif
2487
2488 have_ivshmem = config_host_data.get('CONFIG_EVENTFD')
2489 host_kconfig = \
2490   (get_option('fuzzing') ? ['CONFIG_FUZZ=y'] : []) + \
2491   (have_tpm ? ['CONFIG_TPM=y'] : []) + \
2492   (spice.found() ? ['CONFIG_SPICE=y'] : []) + \
2493   (have_ivshmem ? ['CONFIG_IVSHMEM=y'] : []) + \
2494   (opengl.found() ? ['CONFIG_OPENGL=y'] : []) + \
2495   (x11.found() ? ['CONFIG_X11=y'] : []) + \
2496   (have_vhost_user ? ['CONFIG_VHOST_USER=y'] : []) + \
2497   (have_vhost_vdpa ? ['CONFIG_VHOST_VDPA=y'] : []) + \
2498   (have_vhost_kernel ? ['CONFIG_VHOST_KERNEL=y'] : []) + \
2499   (have_virtfs ? ['CONFIG_VIRTFS=y'] : []) + \
2500   ('CONFIG_LINUX' in config_host ? ['CONFIG_LINUX=y'] : []) + \
2501   (have_pvrdma ? ['CONFIG_PVRDMA=y'] : []) + \
2502   (multiprocess_allowed ? ['CONFIG_MULTIPROCESS_ALLOWED=y'] : []) + \
2503   (vfio_user_server_allowed ? ['CONFIG_VFIO_USER_SERVER_ALLOWED=y'] : [])
2504
2505 ignored = [ 'TARGET_XML_FILES', 'TARGET_ABI_DIR', 'TARGET_ARCH' ]
2506
2507 default_targets = 'CONFIG_DEFAULT_TARGETS' in config_host
2508 actual_target_dirs = []
2509 fdt_required = []
2510 foreach target : target_dirs
2511   config_target = { 'TARGET_NAME': target.split('-')[0] }
2512   if target.endswith('linux-user')
2513     if targetos != 'linux'
2514       if default_targets
2515         continue
2516       endif
2517       error('Target @0@ is only available on a Linux host'.format(target))
2518     endif
2519     config_target += { 'CONFIG_LINUX_USER': 'y' }
2520   elif target.endswith('bsd-user')
2521     if 'CONFIG_BSD' not in config_host
2522       if default_targets
2523         continue
2524       endif
2525       error('Target @0@ is only available on a BSD host'.format(target))
2526     endif
2527     config_target += { 'CONFIG_BSD_USER': 'y' }
2528   elif target.endswith('softmmu')
2529     config_target += { 'CONFIG_SOFTMMU': 'y' }
2530   endif
2531   if target.endswith('-user')
2532     config_target += {
2533       'CONFIG_USER_ONLY': 'y',
2534       'CONFIG_QEMU_INTERP_PREFIX':
2535         get_option('interp_prefix').replace('%M', config_target['TARGET_NAME'])
2536     }
2537   endif
2538
2539   accel_kconfig = []
2540   foreach sym: accelerators
2541     if sym == 'CONFIG_TCG' or target in accelerator_targets.get(sym, [])
2542       config_target += { sym: 'y' }
2543       config_all += { sym: 'y' }
2544       if sym == 'CONFIG_TCG' and tcg_arch == 'tci'
2545         config_target += { 'CONFIG_TCG_INTERPRETER': 'y' }
2546       endif
2547       if target in modular_tcg
2548         config_target += { 'CONFIG_TCG_MODULAR': 'y' }
2549       else
2550         config_target += { 'CONFIG_TCG_BUILTIN': 'y' }
2551       endif
2552       accel_kconfig += [ sym + '=y' ]
2553     endif
2554   endforeach
2555   if accel_kconfig.length() == 0
2556     if default_targets
2557       continue
2558     endif
2559     error('No accelerator available for target @0@'.format(target))
2560   endif
2561
2562   actual_target_dirs += target
2563   config_target += keyval.load('configs/targets' / target + '.mak')
2564   config_target += { 'TARGET_' + config_target['TARGET_ARCH'].to_upper(): 'y' }
2565
2566   if 'TARGET_NEED_FDT' in config_target
2567     fdt_required += target
2568   endif
2569
2570   # Add default keys
2571   if 'TARGET_BASE_ARCH' not in config_target
2572     config_target += {'TARGET_BASE_ARCH': config_target['TARGET_ARCH']}
2573   endif
2574   if 'TARGET_ABI_DIR' not in config_target
2575     config_target += {'TARGET_ABI_DIR': config_target['TARGET_ARCH']}
2576   endif
2577   if 'TARGET_BIG_ENDIAN' not in config_target
2578     config_target += {'TARGET_BIG_ENDIAN': 'n'}
2579   endif
2580
2581   foreach k, v: disassemblers
2582     if host_arch.startswith(k) or config_target['TARGET_BASE_ARCH'].startswith(k)
2583       foreach sym: v
2584         config_target += { sym: 'y' }
2585         config_all_disas += { sym: 'y' }
2586       endforeach
2587     endif
2588   endforeach
2589
2590   config_target_data = configuration_data()
2591   foreach k, v: config_target
2592     if not k.startswith('TARGET_') and not k.startswith('CONFIG_')
2593       # do nothing
2594     elif ignored.contains(k)
2595       # do nothing
2596     elif k == 'TARGET_BASE_ARCH'
2597       # Note that TARGET_BASE_ARCH ends up in config-target.h but it is
2598       # not used to select files from sourcesets.
2599       config_target_data.set('TARGET_' + v.to_upper(), 1)
2600     elif k == 'TARGET_NAME' or k == 'CONFIG_QEMU_INTERP_PREFIX'
2601       config_target_data.set_quoted(k, v)
2602     elif v == 'y'
2603       config_target_data.set(k, 1)
2604     elif v == 'n'
2605       config_target_data.set(k, 0)
2606     else
2607       config_target_data.set(k, v)
2608     endif
2609   endforeach
2610   config_target_data.set('QEMU_ARCH',
2611                          'QEMU_ARCH_' + config_target['TARGET_BASE_ARCH'].to_upper())
2612   config_target_h += {target: configure_file(output: target + '-config-target.h',
2613                                                configuration: config_target_data)}
2614
2615   if target.endswith('-softmmu')
2616     config_input = meson.get_external_property(target, 'default')
2617     config_devices_mak = target + '-config-devices.mak'
2618     config_devices_mak = configure_file(
2619       input: ['configs/devices' / target / config_input + '.mak', 'Kconfig'],
2620       output: config_devices_mak,
2621       depfile: config_devices_mak + '.d',
2622       capture: true,
2623       command: [minikconf,
2624                 get_option('default_devices') ? '--defconfig' : '--allnoconfig',
2625                 config_devices_mak, '@DEPFILE@', '@INPUT@',
2626                 host_kconfig, accel_kconfig,
2627                 'CONFIG_' + config_target['TARGET_ARCH'].to_upper() + '=y'])
2628
2629     config_devices_data = configuration_data()
2630     config_devices = keyval.load(config_devices_mak)
2631     foreach k, v: config_devices
2632       config_devices_data.set(k, 1)
2633     endforeach
2634     config_devices_mak_list += config_devices_mak
2635     config_devices_h += {target: configure_file(output: target + '-config-devices.h',
2636                                                 configuration: config_devices_data)}
2637     config_target += config_devices
2638     config_all_devices += config_devices
2639   endif
2640   config_target_mak += {target: config_target}
2641 endforeach
2642 target_dirs = actual_target_dirs
2643
2644 # This configuration is used to build files that are shared by
2645 # multiple binaries, and then extracted out of the "common"
2646 # static_library target.
2647 #
2648 # We do not use all_sources()/all_dependencies(), because it would
2649 # build literally all source files, including devices only used by
2650 # targets that are not built for this compilation.  The CONFIG_ALL
2651 # pseudo symbol replaces it.
2652
2653 config_all += config_all_devices
2654 config_all += config_host
2655 config_all += config_all_disas
2656 config_all += {
2657   'CONFIG_XEN': xen.found(),
2658   'CONFIG_SOFTMMU': have_system,
2659   'CONFIG_USER_ONLY': have_user,
2660   'CONFIG_ALL': true,
2661 }
2662
2663 target_configs_h = []
2664 foreach target: target_dirs
2665   target_configs_h += config_target_h[target]
2666   target_configs_h += config_devices_h.get(target, [])
2667 endforeach
2668 genh += custom_target('config-poison.h',
2669                       input: [target_configs_h],
2670                       output: 'config-poison.h',
2671                       capture: true,
2672                       command: [find_program('scripts/make-config-poison.sh'),
2673                                 target_configs_h])
2674
2675 ##############
2676 # Submodules #
2677 ##############
2678
2679 capstone = not_found
2680 if not get_option('capstone').auto() or have_system or have_user
2681   capstone = dependency('capstone', version: '>=3.0.5',
2682                         kwargs: static_kwargs, method: 'pkg-config',
2683                         required: get_option('capstone'))
2684
2685   # Some versions of capstone have broken pkg-config file
2686   # that reports a wrong -I path, causing the #include to
2687   # fail later. If the system has such a broken version
2688   # do not use it.
2689   if capstone.found() and not cc.compiles('#include <capstone.h>',
2690                                           dependencies: [capstone])
2691     capstone = not_found
2692     if get_option('capstone').enabled()
2693       error('capstone requested, but it does not appear to work')
2694     endif
2695   endif
2696 endif
2697
2698 libvfio_user_dep = not_found
2699 if have_system and vfio_user_server_allowed
2700   have_internal = fs.exists(meson.current_source_dir() / 'subprojects/libvfio-user/meson.build')
2701
2702   if not have_internal
2703     error('libvfio-user source not found - please pull git submodule')
2704   endif
2705
2706   libvfio_user_proj = subproject('libvfio-user')
2707
2708   libvfio_user_lib = libvfio_user_proj.get_variable('libvfio_user_dep')
2709
2710   libvfio_user_dep = declare_dependency(dependencies: [libvfio_user_lib])
2711 endif
2712
2713 fdt = not_found
2714 if have_system
2715   fdt_opt = get_option('fdt')
2716   if fdt_opt in ['enabled', 'auto', 'system']
2717     have_internal = fs.exists(meson.current_source_dir() / 'dtc/libfdt/Makefile.libfdt')
2718     fdt = cc.find_library('fdt', kwargs: static_kwargs,
2719                           required: fdt_opt == 'system' or
2720                                     fdt_opt == 'enabled' and not have_internal)
2721     if fdt.found() and cc.links('''
2722        #include <libfdt.h>
2723        #include <libfdt_env.h>
2724        int main(void) { fdt_find_max_phandle(NULL, NULL); return 0; }''',
2725          dependencies: fdt)
2726       fdt_opt = 'system'
2727     elif fdt_opt == 'system'
2728        error('system libfdt requested, but it is too old (1.5.1 or newer required)')
2729     elif have_internal
2730       fdt_opt = 'internal'
2731     else
2732       fdt_opt = 'disabled'
2733       fdt = not_found
2734     endif
2735   endif
2736   if fdt_opt == 'internal'
2737     fdt_files = files(
2738       'dtc/libfdt/fdt.c',
2739       'dtc/libfdt/fdt_ro.c',
2740       'dtc/libfdt/fdt_wip.c',
2741       'dtc/libfdt/fdt_sw.c',
2742       'dtc/libfdt/fdt_rw.c',
2743       'dtc/libfdt/fdt_strerror.c',
2744       'dtc/libfdt/fdt_empty_tree.c',
2745       'dtc/libfdt/fdt_addresses.c',
2746       'dtc/libfdt/fdt_overlay.c',
2747       'dtc/libfdt/fdt_check.c',
2748     )
2749
2750     fdt_inc = include_directories('dtc/libfdt')
2751     libfdt = static_library('fdt',
2752                             build_by_default: false,
2753                             sources: fdt_files,
2754                             include_directories: fdt_inc)
2755     fdt = declare_dependency(link_with: libfdt,
2756                              include_directories: fdt_inc)
2757   endif
2758 else
2759   fdt_opt = 'disabled'
2760 endif
2761 if not fdt.found() and fdt_required.length() > 0
2762   error('fdt not available but required by targets ' + ', '.join(fdt_required))
2763 endif
2764
2765 config_host_data.set('CONFIG_CAPSTONE', capstone.found())
2766 config_host_data.set('CONFIG_FDT', fdt.found())
2767 config_host_data.set('CONFIG_SLIRP', slirp.found())
2768
2769 #####################
2770 # Generated sources #
2771 #####################
2772
2773 genh += configure_file(output: 'config-host.h', configuration: config_host_data)
2774
2775 hxtool = find_program('scripts/hxtool')
2776 shaderinclude = find_program('scripts/shaderinclude.pl')
2777 qapi_gen = find_program('scripts/qapi-gen.py')
2778 qapi_gen_depends = [ meson.current_source_dir() / 'scripts/qapi/__init__.py',
2779                      meson.current_source_dir() / 'scripts/qapi/commands.py',
2780                      meson.current_source_dir() / 'scripts/qapi/common.py',
2781                      meson.current_source_dir() / 'scripts/qapi/error.py',
2782                      meson.current_source_dir() / 'scripts/qapi/events.py',
2783                      meson.current_source_dir() / 'scripts/qapi/expr.py',
2784                      meson.current_source_dir() / 'scripts/qapi/gen.py',
2785                      meson.current_source_dir() / 'scripts/qapi/introspect.py',
2786                      meson.current_source_dir() / 'scripts/qapi/parser.py',
2787                      meson.current_source_dir() / 'scripts/qapi/schema.py',
2788                      meson.current_source_dir() / 'scripts/qapi/source.py',
2789                      meson.current_source_dir() / 'scripts/qapi/types.py',
2790                      meson.current_source_dir() / 'scripts/qapi/visit.py',
2791                      meson.current_source_dir() / 'scripts/qapi/common.py',
2792                      meson.current_source_dir() / 'scripts/qapi-gen.py'
2793 ]
2794
2795 tracetool = [
2796   python, files('scripts/tracetool.py'),
2797    '--backend=' + ','.join(get_option('trace_backends'))
2798 ]
2799 tracetool_depends = files(
2800   'scripts/tracetool/backend/log.py',
2801   'scripts/tracetool/backend/__init__.py',
2802   'scripts/tracetool/backend/dtrace.py',
2803   'scripts/tracetool/backend/ftrace.py',
2804   'scripts/tracetool/backend/simple.py',
2805   'scripts/tracetool/backend/syslog.py',
2806   'scripts/tracetool/backend/ust.py',
2807   'scripts/tracetool/format/ust_events_c.py',
2808   'scripts/tracetool/format/ust_events_h.py',
2809   'scripts/tracetool/format/__init__.py',
2810   'scripts/tracetool/format/d.py',
2811   'scripts/tracetool/format/simpletrace_stap.py',
2812   'scripts/tracetool/format/c.py',
2813   'scripts/tracetool/format/h.py',
2814   'scripts/tracetool/format/log_stap.py',
2815   'scripts/tracetool/format/stap.py',
2816   'scripts/tracetool/__init__.py',
2817   'scripts/tracetool/transform.py',
2818   'scripts/tracetool/vcpu.py'
2819 )
2820
2821 qemu_version_cmd = [find_program('scripts/qemu-version.sh'),
2822                     meson.current_source_dir(),
2823                     get_option('pkgversion'), meson.project_version()]
2824 qemu_version = custom_target('qemu-version.h',
2825                              output: 'qemu-version.h',
2826                              command: qemu_version_cmd,
2827                              capture: true,
2828                              build_by_default: true,
2829                              build_always_stale: true)
2830 genh += qemu_version
2831
2832 hxdep = []
2833 hx_headers = [
2834   ['qemu-options.hx', 'qemu-options.def'],
2835   ['qemu-img-cmds.hx', 'qemu-img-cmds.h'],
2836 ]
2837 if have_system
2838   hx_headers += [
2839     ['hmp-commands.hx', 'hmp-commands.h'],
2840     ['hmp-commands-info.hx', 'hmp-commands-info.h'],
2841   ]
2842 endif
2843 foreach d : hx_headers
2844   hxdep += custom_target(d[1],
2845                 input: files(d[0]),
2846                 output: d[1],
2847                 capture: true,
2848                 build_by_default: true, # to be removed when added to a target
2849                 command: [hxtool, '-h', '@INPUT0@'])
2850 endforeach
2851 genh += hxdep
2852
2853 ###################
2854 # Collect sources #
2855 ###################
2856
2857 authz_ss = ss.source_set()
2858 blockdev_ss = ss.source_set()
2859 block_ss = ss.source_set()
2860 chardev_ss = ss.source_set()
2861 common_ss = ss.source_set()
2862 crypto_ss = ss.source_set()
2863 hwcore_ss = ss.source_set()
2864 io_ss = ss.source_set()
2865 qmp_ss = ss.source_set()
2866 qom_ss = ss.source_set()
2867 softmmu_ss = ss.source_set()
2868 specific_fuzz_ss = ss.source_set()
2869 specific_ss = ss.source_set()
2870 stub_ss = ss.source_set()
2871 trace_ss = ss.source_set()
2872 user_ss = ss.source_set()
2873 util_ss = ss.source_set()
2874
2875 # accel modules
2876 qtest_module_ss = ss.source_set()
2877 tcg_module_ss = ss.source_set()
2878
2879 modules = {}
2880 target_modules = {}
2881 hw_arch = {}
2882 target_arch = {}
2883 target_softmmu_arch = {}
2884 target_user_arch = {}
2885
2886 ###############
2887 # Trace files #
2888 ###############
2889
2890 # TODO: add each directory to the subdirs from its own meson.build, once
2891 # we have those
2892 trace_events_subdirs = [
2893   'crypto',
2894   'qapi',
2895   'qom',
2896   'monitor',
2897   'util',
2898   'gdbstub',
2899 ]
2900 if have_linux_user
2901   trace_events_subdirs += [ 'linux-user' ]
2902 endif
2903 if have_bsd_user
2904   trace_events_subdirs += [ 'bsd-user' ]
2905 endif
2906 if have_block
2907   trace_events_subdirs += [
2908     'authz',
2909     'block',
2910     'io',
2911     'nbd',
2912     'scsi',
2913   ]
2914 endif
2915 if have_system
2916   trace_events_subdirs += [
2917     'accel/kvm',
2918     'audio',
2919     'backends',
2920     'backends/tpm',
2921     'chardev',
2922     'ebpf',
2923     'hw/9pfs',
2924     'hw/acpi',
2925     'hw/adc',
2926     'hw/alpha',
2927     'hw/arm',
2928     'hw/audio',
2929     'hw/block',
2930     'hw/block/dataplane',
2931     'hw/char',
2932     'hw/display',
2933     'hw/dma',
2934     'hw/hyperv',
2935     'hw/i2c',
2936     'hw/i386',
2937     'hw/i386/xen',
2938     'hw/ide',
2939     'hw/input',
2940     'hw/intc',
2941     'hw/isa',
2942     'hw/mem',
2943     'hw/mips',
2944     'hw/misc',
2945     'hw/misc/macio',
2946     'hw/net',
2947     'hw/net/can',
2948     'hw/nubus',
2949     'hw/nvme',
2950     'hw/nvram',
2951     'hw/pci',
2952     'hw/pci-host',
2953     'hw/ppc',
2954     'hw/rdma',
2955     'hw/rdma/vmw',
2956     'hw/rtc',
2957     'hw/s390x',
2958     'hw/scsi',
2959     'hw/sd',
2960     'hw/sh4',
2961     'hw/sparc',
2962     'hw/sparc64',
2963     'hw/ssi',
2964     'hw/timer',
2965     'hw/tpm',
2966     'hw/usb',
2967     'hw/vfio',
2968     'hw/virtio',
2969     'hw/watchdog',
2970     'hw/xen',
2971     'hw/gpio',
2972     'migration',
2973     'net',
2974     'softmmu',
2975     'ui',
2976     'hw/remote',
2977   ]
2978 endif
2979 if have_system or have_user
2980   trace_events_subdirs += [
2981     'accel/tcg',
2982     'hw/core',
2983     'target/arm',
2984     'target/arm/hvf',
2985     'target/hppa',
2986     'target/i386',
2987     'target/i386/kvm',
2988     'target/mips/tcg',
2989     'target/nios2',
2990     'target/ppc',
2991     'target/riscv',
2992     'target/s390x',
2993     'target/s390x/kvm',
2994     'target/sparc',
2995   ]
2996 endif
2997
2998 vhost_user = not_found
2999 if targetos == 'linux' and have_vhost_user
3000   libvhost_user = subproject('libvhost-user')
3001   vhost_user = libvhost_user.get_variable('vhost_user_dep')
3002 endif
3003
3004 libvduse = not_found
3005 if have_libvduse
3006   libvduse_proj = subproject('libvduse')
3007   libvduse = libvduse_proj.get_variable('libvduse_dep')
3008 endif
3009
3010 # NOTE: the trace/ subdirectory needs the qapi_trace_events variable
3011 # that is filled in by qapi/.
3012 subdir('qapi')
3013 subdir('qobject')
3014 subdir('stubs')
3015 subdir('trace')
3016 subdir('util')
3017 subdir('qom')
3018 subdir('authz')
3019 subdir('crypto')
3020 subdir('ui')
3021 subdir('hw')
3022 subdir('gdbstub')
3023
3024
3025 if enable_modules
3026   libmodulecommon = static_library('module-common', files('module-common.c') + genh, pic: true, c_args: '-DBUILD_DSO')
3027   modulecommon = declare_dependency(link_whole: libmodulecommon, compile_args: '-DBUILD_DSO')
3028 endif
3029
3030 qom_ss = qom_ss.apply(config_host, strict: false)
3031 libqom = static_library('qom', qom_ss.sources() + genh,
3032                         dependencies: [qom_ss.dependencies()],
3033                         name_suffix: 'fa')
3034 qom = declare_dependency(link_whole: libqom)
3035
3036 event_loop_base = files('event-loop-base.c')
3037 event_loop_base = static_library('event-loop-base', sources: event_loop_base + genh,
3038                                  build_by_default: true)
3039 event_loop_base = declare_dependency(link_whole: event_loop_base,
3040                                      dependencies: [qom])
3041
3042 stub_ss = stub_ss.apply(config_all, strict: false)
3043
3044 util_ss.add_all(trace_ss)
3045 util_ss = util_ss.apply(config_all, strict: false)
3046 libqemuutil = static_library('qemuutil',
3047                              sources: util_ss.sources() + stub_ss.sources() + genh,
3048                              dependencies: [util_ss.dependencies(), libm, threads, glib, socket, malloc, pixman])
3049 qemuutil = declare_dependency(link_with: libqemuutil,
3050                               sources: genh + version_res,
3051                               dependencies: [event_loop_base])
3052
3053 if have_system or have_user
3054   decodetree = generator(find_program('scripts/decodetree.py'),
3055                          output: 'decode-@BASENAME@.c.inc',
3056                          arguments: ['@INPUT@', '@EXTRA_ARGS@', '-o', '@OUTPUT@'])
3057   subdir('libdecnumber')
3058   subdir('target')
3059 endif
3060
3061 subdir('audio')
3062 subdir('io')
3063 subdir('chardev')
3064 subdir('fsdev')
3065 subdir('dump')
3066
3067 if have_block
3068   block_ss.add(files(
3069     'block.c',
3070     'blockjob.c',
3071     'job.c',
3072     'qemu-io-cmds.c',
3073   ))
3074   if config_host_data.get('CONFIG_REPLICATION')
3075     block_ss.add(files('replication.c'))
3076   endif
3077
3078   subdir('nbd')
3079   subdir('scsi')
3080   subdir('block')
3081
3082   blockdev_ss.add(files(
3083     'blockdev.c',
3084     'blockdev-nbd.c',
3085     'iothread.c',
3086     'job-qmp.c',
3087   ), gnutls)
3088
3089   # os-posix.c contains POSIX-specific functions used by qemu-storage-daemon,
3090   # os-win32.c does not
3091   blockdev_ss.add(when: 'CONFIG_POSIX', if_true: files('os-posix.c'))
3092   softmmu_ss.add(when: 'CONFIG_WIN32', if_true: [files('os-win32.c')])
3093 endif
3094
3095 common_ss.add(files('cpus-common.c'))
3096
3097 subdir('softmmu')
3098
3099 common_ss.add(capstone)
3100 specific_ss.add(files('cpu.c', 'disas.c'), capstone)
3101
3102 # Work around a gcc bug/misfeature wherein constant propagation looks
3103 # through an alias:
3104 #   https://gcc.gnu.org/bugzilla/show_bug.cgi?id=99696
3105 # to guess that a const variable is always zero.  Without lto, this is
3106 # impossible, as the alias is restricted to page-vary-common.c.  Indeed,
3107 # without lto, not even the alias is required -- we simply use different
3108 # declarations in different compilation units.
3109 pagevary = files('page-vary-common.c')
3110 if get_option('b_lto')
3111   pagevary_flags = ['-fno-lto']
3112   if get_option('cfi')
3113     pagevary_flags += '-fno-sanitize=cfi-icall'
3114   endif
3115   pagevary = static_library('page-vary-common', sources: pagevary + genh,
3116                             c_args: pagevary_flags)
3117   pagevary = declare_dependency(link_with: pagevary)
3118 endif
3119 common_ss.add(pagevary)
3120 specific_ss.add(files('page-vary.c'))
3121
3122 subdir('backends')
3123 subdir('disas')
3124 subdir('migration')
3125 subdir('monitor')
3126 subdir('net')
3127 subdir('replay')
3128 subdir('semihosting')
3129 subdir('tcg')
3130 subdir('fpu')
3131 subdir('accel')
3132 subdir('plugins')
3133 subdir('ebpf')
3134
3135 common_user_inc = []
3136
3137 subdir('common-user')
3138 subdir('bsd-user')
3139 subdir('linux-user')
3140
3141 # needed for fuzzing binaries
3142 subdir('tests/qtest/libqos')
3143 subdir('tests/qtest/fuzz')
3144
3145 # accel modules
3146 tcg_real_module_ss = ss.source_set()
3147 tcg_real_module_ss.add_all(when: 'CONFIG_TCG_MODULAR', if_true: tcg_module_ss)
3148 specific_ss.add_all(when: 'CONFIG_TCG_BUILTIN', if_true: tcg_module_ss)
3149 target_modules += { 'accel' : { 'qtest': qtest_module_ss,
3150                                 'tcg': tcg_real_module_ss }}
3151
3152 ########################
3153 # Library dependencies #
3154 ########################
3155
3156 modinfo_collect = find_program('scripts/modinfo-collect.py')
3157 modinfo_generate = find_program('scripts/modinfo-generate.py')
3158 modinfo_files = []
3159
3160 block_mods = []
3161 softmmu_mods = []
3162 foreach d, list : modules
3163   foreach m, module_ss : list
3164     if enable_modules and targetos != 'windows'
3165       module_ss = module_ss.apply(config_all, strict: false)
3166       sl = static_library(d + '-' + m, [genh, module_ss.sources()],
3167                           dependencies: [modulecommon, module_ss.dependencies()], pic: true)
3168       if d == 'block'
3169         block_mods += sl
3170       else
3171         softmmu_mods += sl
3172       endif
3173       if module_ss.sources() != []
3174         # FIXME: Should use sl.extract_all_objects(recursive: true) as
3175         # input. Sources can be used multiple times but objects are
3176         # unique when it comes to lookup in compile_commands.json.
3177         # Depnds on a mesion version with
3178         # https://github.com/mesonbuild/meson/pull/8900
3179         modinfo_files += custom_target(d + '-' + m + '.modinfo',
3180                                        output: d + '-' + m + '.modinfo',
3181                                        input: module_ss.sources() + genh,
3182                                        capture: true,
3183                                        command: [modinfo_collect, module_ss.sources()])
3184       endif
3185     else
3186       if d == 'block'
3187         block_ss.add_all(module_ss)
3188       else
3189         softmmu_ss.add_all(module_ss)
3190       endif
3191     endif
3192   endforeach
3193 endforeach
3194
3195 foreach d, list : target_modules
3196   foreach m, module_ss : list
3197     if enable_modules and targetos != 'windows'
3198       foreach target : target_dirs
3199         if target.endswith('-softmmu')
3200           config_target = config_target_mak[target]
3201           config_target += config_host
3202           target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3203           c_args = ['-DNEED_CPU_H',
3204                     '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3205                     '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3206           target_module_ss = module_ss.apply(config_target, strict: false)
3207           if target_module_ss.sources() != []
3208             module_name = d + '-' + m + '-' + config_target['TARGET_NAME']
3209             sl = static_library(module_name,
3210                                 [genh, target_module_ss.sources()],
3211                                 dependencies: [modulecommon, target_module_ss.dependencies()],
3212                                 include_directories: target_inc,
3213                                 c_args: c_args,
3214                                 pic: true)
3215             softmmu_mods += sl
3216             # FIXME: Should use sl.extract_all_objects(recursive: true) too.
3217             modinfo_files += custom_target(module_name + '.modinfo',
3218                                            output: module_name + '.modinfo',
3219                                            input: target_module_ss.sources() + genh,
3220                                            capture: true,
3221                                            command: [modinfo_collect, '--target', target, target_module_ss.sources()])
3222           endif
3223         endif
3224       endforeach
3225     else
3226       specific_ss.add_all(module_ss)
3227     endif
3228   endforeach
3229 endforeach
3230
3231 if enable_modules
3232   foreach target : target_dirs
3233     if target.endswith('-softmmu')
3234       config_target = config_target_mak[target]
3235       config_devices_mak = target + '-config-devices.mak'
3236       modinfo_src = custom_target('modinfo-' + target + '.c',
3237                                   output: 'modinfo-' + target + '.c',
3238                                   input: modinfo_files,
3239                                   command: [modinfo_generate, '--devices', config_devices_mak, '@INPUT@'],
3240                                   capture: true)
3241
3242       modinfo_lib = static_library('modinfo-' + target + '.c', modinfo_src)
3243       modinfo_dep = declare_dependency(link_with: modinfo_lib)
3244
3245       arch = config_target['TARGET_NAME'] == 'sparc64' ? 'sparc64' : config_target['TARGET_BASE_ARCH']
3246       hw_arch[arch].add(modinfo_dep)
3247     endif
3248   endforeach
3249 endif
3250
3251 nm = find_program('nm')
3252 undefsym = find_program('scripts/undefsym.py')
3253 block_syms = custom_target('block.syms', output: 'block.syms',
3254                              input: [libqemuutil, block_mods],
3255                              capture: true,
3256                              command: [undefsym, nm, '@INPUT@'])
3257 qemu_syms = custom_target('qemu.syms', output: 'qemu.syms',
3258                              input: [libqemuutil, softmmu_mods],
3259                              capture: true,
3260                              command: [undefsym, nm, '@INPUT@'])
3261
3262 authz_ss = authz_ss.apply(config_host, strict: false)
3263 libauthz = static_library('authz', authz_ss.sources() + genh,
3264                           dependencies: [authz_ss.dependencies()],
3265                           name_suffix: 'fa',
3266                           build_by_default: false)
3267
3268 authz = declare_dependency(link_whole: libauthz,
3269                            dependencies: qom)
3270
3271 crypto_ss = crypto_ss.apply(config_host, strict: false)
3272 libcrypto = static_library('crypto', crypto_ss.sources() + genh,
3273                            dependencies: [crypto_ss.dependencies()],
3274                            name_suffix: 'fa',
3275                            build_by_default: false)
3276
3277 crypto = declare_dependency(link_whole: libcrypto,
3278                             dependencies: [authz, qom])
3279
3280 io_ss = io_ss.apply(config_host, strict: false)
3281 libio = static_library('io', io_ss.sources() + genh,
3282                        dependencies: [io_ss.dependencies()],
3283                        link_with: libqemuutil,
3284                        name_suffix: 'fa',
3285                        build_by_default: false)
3286
3287 io = declare_dependency(link_whole: libio, dependencies: [crypto, qom])
3288
3289 libmigration = static_library('migration', sources: migration_files + genh,
3290                               name_suffix: 'fa',
3291                               build_by_default: false)
3292 migration = declare_dependency(link_with: libmigration,
3293                                dependencies: [zlib, qom, io])
3294 softmmu_ss.add(migration)
3295
3296 block_ss = block_ss.apply(config_host, strict: false)
3297 libblock = static_library('block', block_ss.sources() + genh,
3298                           dependencies: block_ss.dependencies(),
3299                           link_depends: block_syms,
3300                           name_suffix: 'fa',
3301                           build_by_default: false)
3302
3303 block = declare_dependency(link_whole: [libblock],
3304                            link_args: '@block.syms',
3305                            dependencies: [crypto, io])
3306
3307 blockdev_ss = blockdev_ss.apply(config_host, strict: false)
3308 libblockdev = static_library('blockdev', blockdev_ss.sources() + genh,
3309                              dependencies: blockdev_ss.dependencies(),
3310                              name_suffix: 'fa',
3311                              build_by_default: false)
3312
3313 blockdev = declare_dependency(link_whole: [libblockdev],
3314                               dependencies: [block, event_loop_base])
3315
3316 qmp_ss = qmp_ss.apply(config_host, strict: false)
3317 libqmp = static_library('qmp', qmp_ss.sources() + genh,
3318                         dependencies: qmp_ss.dependencies(),
3319                         name_suffix: 'fa',
3320                         build_by_default: false)
3321
3322 qmp = declare_dependency(link_whole: [libqmp])
3323
3324 libchardev = static_library('chardev', chardev_ss.sources() + genh,
3325                             name_suffix: 'fa',
3326                             dependencies: chardev_ss.dependencies(),
3327                             build_by_default: false)
3328
3329 chardev = declare_dependency(link_whole: libchardev)
3330
3331 hwcore_ss = hwcore_ss.apply(config_host, strict: false)
3332 libhwcore = static_library('hwcore', sources: hwcore_ss.sources() + genh,
3333                            name_suffix: 'fa',
3334                            build_by_default: false)
3335 hwcore = declare_dependency(link_whole: libhwcore)
3336 common_ss.add(hwcore)
3337
3338 ###########
3339 # Targets #
3340 ###########
3341
3342 emulator_modules = []
3343 foreach m : block_mods + softmmu_mods
3344   emulator_modules += shared_module(m.name(),
3345                 build_by_default: true,
3346                 name_prefix: '',
3347                 link_whole: m,
3348                 install: true,
3349                 install_dir: qemu_moddir)
3350 endforeach
3351 if emulator_modules.length() > 0
3352   alias_target('modules', emulator_modules)
3353 endif
3354
3355 softmmu_ss.add(authz, blockdev, chardev, crypto, io, qmp)
3356 common_ss.add(qom, qemuutil)
3357
3358 common_ss.add_all(when: 'CONFIG_SOFTMMU', if_true: [softmmu_ss])
3359 common_ss.add_all(when: 'CONFIG_USER_ONLY', if_true: user_ss)
3360
3361 common_all = common_ss.apply(config_all, strict: false)
3362 common_all = static_library('common',
3363                             build_by_default: false,
3364                             sources: common_all.sources() + genh,
3365                             include_directories: common_user_inc,
3366                             implicit_include_directories: false,
3367                             dependencies: common_all.dependencies(),
3368                             name_suffix: 'fa')
3369
3370 feature_to_c = find_program('scripts/feature_to_c.sh')
3371
3372 if targetos == 'darwin'
3373   entitlement = find_program('scripts/entitlement.sh')
3374 endif
3375
3376 emulators = {}
3377 foreach target : target_dirs
3378   config_target = config_target_mak[target]
3379   target_name = config_target['TARGET_NAME']
3380   target_base_arch = config_target['TARGET_BASE_ARCH']
3381   arch_srcs = [config_target_h[target]]
3382   arch_deps = []
3383   c_args = ['-DNEED_CPU_H',
3384             '-DCONFIG_TARGET="@0@-config-target.h"'.format(target),
3385             '-DCONFIG_DEVICES="@0@-config-devices.h"'.format(target)]
3386   link_args = emulator_link_args
3387
3388   config_target += config_host
3389   target_inc = [include_directories('target' / config_target['TARGET_BASE_ARCH'])]
3390   if targetos == 'linux'
3391     target_inc += include_directories('linux-headers', is_system: true)
3392   endif
3393   if target.endswith('-softmmu')
3394     target_type='system'
3395     t = target_softmmu_arch[target_base_arch].apply(config_target, strict: false)
3396     arch_srcs += t.sources()
3397     arch_deps += t.dependencies()
3398
3399     hw_dir = target_name == 'sparc64' ? 'sparc64' : target_base_arch
3400     hw = hw_arch[hw_dir].apply(config_target, strict: false)
3401     arch_srcs += hw.sources()
3402     arch_deps += hw.dependencies()
3403
3404     arch_srcs += config_devices_h[target]
3405     link_args += ['@block.syms', '@qemu.syms']
3406   else
3407     abi = config_target['TARGET_ABI_DIR']
3408     target_type='user'
3409     target_inc += common_user_inc
3410     if target_base_arch in target_user_arch
3411       t = target_user_arch[target_base_arch].apply(config_target, strict: false)
3412       arch_srcs += t.sources()
3413       arch_deps += t.dependencies()
3414     endif
3415     if 'CONFIG_LINUX_USER' in config_target
3416       base_dir = 'linux-user'
3417     endif
3418     if 'CONFIG_BSD_USER' in config_target
3419       base_dir = 'bsd-user'
3420       target_inc += include_directories('bsd-user/' / targetos)
3421       target_inc += include_directories('bsd-user/host/' / host_arch)
3422       dir = base_dir / abi
3423       arch_srcs += files(dir / 'signal.c', dir / 'target_arch_cpu.c')
3424     endif
3425     target_inc += include_directories(
3426       base_dir,
3427       base_dir / abi,
3428     )
3429     if 'CONFIG_LINUX_USER' in config_target
3430       dir = base_dir / abi
3431       arch_srcs += files(dir / 'signal.c', dir / 'cpu_loop.c')
3432       if config_target.has_key('TARGET_SYSTBL_ABI')
3433         arch_srcs += \
3434           syscall_nr_generators[abi].process(base_dir / abi / config_target['TARGET_SYSTBL'],
3435                                              extra_args : config_target['TARGET_SYSTBL_ABI'])
3436       endif
3437     endif
3438   endif
3439
3440   if 'TARGET_XML_FILES' in config_target
3441     gdbstub_xml = custom_target(target + '-gdbstub-xml.c',
3442                                 output: target + '-gdbstub-xml.c',
3443                                 input: files(config_target['TARGET_XML_FILES'].split()),
3444                                 command: [feature_to_c, '@INPUT@'],
3445                                 capture: true)
3446     arch_srcs += gdbstub_xml
3447   endif
3448
3449   t = target_arch[target_base_arch].apply(config_target, strict: false)
3450   arch_srcs += t.sources()
3451   arch_deps += t.dependencies()
3452
3453   target_common = common_ss.apply(config_target, strict: false)
3454   objects = common_all.extract_objects(target_common.sources())
3455   deps = target_common.dependencies()
3456
3457   target_specific = specific_ss.apply(config_target, strict: false)
3458   arch_srcs += target_specific.sources()
3459   arch_deps += target_specific.dependencies()
3460
3461   lib = static_library('qemu-' + target,
3462                  sources: arch_srcs + genh,
3463                  dependencies: arch_deps,
3464                  objects: objects,
3465                  include_directories: target_inc,
3466                  c_args: c_args,
3467                  build_by_default: false,
3468                  name_suffix: 'fa')
3469
3470   if target.endswith('-softmmu')
3471     execs = [{
3472       'name': 'qemu-system-' + target_name,
3473       'win_subsystem': 'console',
3474       'sources': files('softmmu/main.c'),
3475       'dependencies': []
3476     }]
3477     if targetos == 'windows' and (sdl.found() or gtk.found())
3478       execs += [{
3479         'name': 'qemu-system-' + target_name + 'w',
3480         'win_subsystem': 'windows',
3481         'sources': files('softmmu/main.c'),
3482         'dependencies': []
3483       }]
3484     endif
3485     if get_option('fuzzing')
3486       specific_fuzz = specific_fuzz_ss.apply(config_target, strict: false)
3487       execs += [{
3488         'name': 'qemu-fuzz-' + target_name,
3489         'win_subsystem': 'console',
3490         'sources': specific_fuzz.sources(),
3491         'dependencies': specific_fuzz.dependencies(),
3492       }]
3493     endif
3494   else
3495     execs = [{
3496       'name': 'qemu-' + target_name,
3497       'win_subsystem': 'console',
3498       'sources': [],
3499       'dependencies': []
3500     }]
3501   endif
3502   foreach exe: execs
3503     exe_name = exe['name']
3504     if targetos == 'darwin'
3505       exe_name += '-unsigned'
3506     endif
3507
3508     emulator = executable(exe_name, exe['sources'],
3509                install: true,
3510                c_args: c_args,
3511                dependencies: arch_deps + deps + exe['dependencies'],
3512                objects: lib.extract_all_objects(recursive: true),
3513                link_language: link_language,
3514                link_depends: [block_syms, qemu_syms] + exe.get('link_depends', []),
3515                link_args: link_args,
3516                win_subsystem: exe['win_subsystem'])
3517
3518     if targetos == 'darwin'
3519       icon = 'pc-bios/qemu.rsrc'
3520       build_input = [emulator, files(icon)]
3521       install_input = [
3522         get_option('bindir') / exe_name,
3523         meson.current_source_dir() / icon
3524       ]
3525       if 'CONFIG_HVF' in config_target
3526         entitlements = 'accel/hvf/entitlements.plist'
3527         build_input += files(entitlements)
3528         install_input += meson.current_source_dir() / entitlements
3529       endif
3530
3531       emulators += {exe['name'] : custom_target(exe['name'],
3532                    input: build_input,
3533                    output: exe['name'],
3534                    command: [entitlement, '@OUTPUT@', '@INPUT@'])
3535       }
3536
3537       meson.add_install_script(entitlement, '--install',
3538                                get_option('bindir') / exe['name'],
3539                                install_input)
3540     else
3541       emulators += {exe['name']: emulator}
3542     endif
3543
3544     if stap.found()
3545       foreach stp: [
3546         {'ext': '.stp-build', 'fmt': 'stap', 'bin': meson.current_build_dir() / exe['name'], 'install': false},
3547         {'ext': '.stp', 'fmt': 'stap', 'bin': get_option('prefix') / get_option('bindir') / exe['name'], 'install': true},
3548         {'ext': '-simpletrace.stp', 'fmt': 'simpletrace-stap', 'bin': '', 'install': true},
3549         {'ext': '-log.stp', 'fmt': 'log-stap', 'bin': '', 'install': true},
3550       ]
3551         custom_target(exe['name'] + stp['ext'],
3552                       input: trace_events_all,
3553                       output: exe['name'] + stp['ext'],
3554                       install: stp['install'],
3555                       install_dir: get_option('datadir') / 'systemtap/tapset',
3556                       command: [
3557                         tracetool, '--group=all', '--format=' + stp['fmt'],
3558                         '--binary=' + stp['bin'],
3559                         '--target-name=' + target_name,
3560                         '--target-type=' + target_type,
3561                         '--probe-prefix=qemu.' + target_type + '.' + target_name,
3562                         '@INPUT@', '@OUTPUT@'
3563                       ],
3564                       depend_files: tracetool_depends)
3565       endforeach
3566     endif
3567   endforeach
3568 endforeach
3569
3570 # Other build targets
3571
3572 if 'CONFIG_PLUGIN' in config_host
3573   install_headers('include/qemu/qemu-plugin.h')
3574 endif
3575
3576 subdir('qga')
3577
3578 # Don't build qemu-keymap if xkbcommon is not explicitly enabled
3579 # when we don't build tools or system
3580 if xkbcommon.found()
3581   # used for the update-keymaps target, so include rules even if !have_tools
3582   qemu_keymap = executable('qemu-keymap', files('qemu-keymap.c', 'ui/input-keymap.c') + genh,
3583                            dependencies: [qemuutil, xkbcommon], install: have_tools)
3584 endif
3585
3586 if have_tools
3587   qemu_img = executable('qemu-img', [files('qemu-img.c'), hxdep],
3588              dependencies: [authz, block, crypto, io, qom, qemuutil], install: true)
3589   qemu_io = executable('qemu-io', files('qemu-io.c'),
3590              dependencies: [block, qemuutil], install: true)
3591   qemu_nbd = executable('qemu-nbd', files('qemu-nbd.c'),
3592                dependencies: [blockdev, qemuutil, gnutls, selinux],
3593                install: true)
3594
3595   subdir('storage-daemon')
3596   subdir('contrib/rdmacm-mux')
3597   subdir('contrib/elf2dmp')
3598
3599   executable('qemu-edid', files('qemu-edid.c', 'hw/display/edid-generate.c'),
3600              dependencies: qemuutil,
3601              install: true)
3602
3603   if have_vhost_user
3604     subdir('contrib/vhost-user-blk')
3605     subdir('contrib/vhost-user-gpu')
3606     subdir('contrib/vhost-user-input')
3607     subdir('contrib/vhost-user-scsi')
3608   endif
3609
3610   if targetos == 'linux'
3611     executable('qemu-bridge-helper', files('qemu-bridge-helper.c'),
3612                dependencies: [qemuutil, libcap_ng],
3613                install: true,
3614                install_dir: get_option('libexecdir'))
3615
3616     executable('qemu-pr-helper', files('scsi/qemu-pr-helper.c', 'scsi/utils.c'),
3617                dependencies: [authz, crypto, io, qom, qemuutil,
3618                               libcap_ng, mpathpersist],
3619                install: true)
3620   endif
3621
3622   if have_ivshmem
3623     subdir('contrib/ivshmem-client')
3624     subdir('contrib/ivshmem-server')
3625   endif
3626 endif
3627
3628 subdir('scripts')
3629 subdir('tools')
3630 subdir('pc-bios')
3631 subdir('docs')
3632 subdir('tests')
3633 if gtk.found()
3634   subdir('po')
3635 endif
3636
3637 if host_machine.system() == 'windows'
3638   nsis_cmd = [
3639     find_program('scripts/nsis.py'),
3640     '@OUTPUT@',
3641     get_option('prefix'),
3642     meson.current_source_dir(),
3643     config_host['GLIB_BINDIR'],
3644     host_machine.cpu(),
3645     '--',
3646     '-DDISPLAYVERSION=' + meson.project_version(),
3647   ]
3648   if build_docs
3649     nsis_cmd += '-DCONFIG_DOCUMENTATION=y'
3650   endif
3651   if gtk.found()
3652     nsis_cmd += '-DCONFIG_GTK=y'
3653   endif
3654
3655   nsis = custom_target('nsis',
3656                        output: 'qemu-setup-' + meson.project_version() + '.exe',
3657                        input: files('qemu.nsi'),
3658                        build_always_stale: true,
3659                        command: nsis_cmd + ['@INPUT@'])
3660   alias_target('installer', nsis)
3661 endif
3662
3663 #########################
3664 # Configuration summary #
3665 #########################
3666
3667 # Directories
3668 summary_info = {}
3669 summary_info += {'Install prefix':    get_option('prefix')}
3670 summary_info += {'BIOS directory':    qemu_datadir}
3671 pathsep = targetos == 'windows' ? ';' : ':'
3672 summary_info += {'firmware path':     pathsep.join(get_option('qemu_firmwarepath'))}
3673 summary_info += {'binary directory':  get_option('prefix') / get_option('bindir')}
3674 summary_info += {'library directory': get_option('prefix') / get_option('libdir')}
3675 summary_info += {'module directory':  qemu_moddir}
3676 summary_info += {'libexec directory': get_option('prefix') / get_option('libexecdir')}
3677 summary_info += {'include directory': get_option('prefix') / get_option('includedir')}
3678 summary_info += {'config directory':  get_option('prefix') / get_option('sysconfdir')}
3679 if targetos != 'windows'
3680   summary_info += {'local state directory': get_option('prefix') / get_option('localstatedir')}
3681   summary_info += {'Manual directory':      get_option('prefix') / get_option('mandir')}
3682 else
3683   summary_info += {'local state directory': 'queried at runtime'}
3684 endif
3685 summary_info += {'Doc directory':     get_option('prefix') / get_option('docdir')}
3686 summary_info += {'Build directory':   meson.current_build_dir()}
3687 summary_info += {'Source path':       meson.current_source_dir()}
3688 summary_info += {'GIT submodules':    config_host['GIT_SUBMODULES']}
3689 summary(summary_info, bool_yn: true, section: 'Directories')
3690
3691 # Host binaries
3692 summary_info = {}
3693 summary_info += {'git':               config_host['GIT']}
3694 summary_info += {'make':              config_host['MAKE']}
3695 summary_info += {'python':            '@0@ (version: @1@)'.format(python.full_path(), python.language_version())}
3696 summary_info += {'sphinx-build':      sphinx_build}
3697 if config_host.has_key('HAVE_GDB_BIN')
3698   summary_info += {'gdb':             config_host['HAVE_GDB_BIN']}
3699 endif
3700 summary_info += {'iasl':              iasl}
3701 summary_info += {'genisoimage':       config_host['GENISOIMAGE']}
3702 if targetos == 'windows' and have_ga
3703   summary_info += {'wixl':            wixl}
3704 endif
3705 if slirp.found() and have_system
3706   summary_info += {'smbd':            have_slirp_smbd ? smbd_path : false}
3707 endif
3708 summary(summary_info, bool_yn: true, section: 'Host binaries')
3709
3710 # Configurable features
3711 summary_info = {}
3712 summary_info += {'Documentation':     build_docs}
3713 summary_info += {'system-mode emulation': have_system}
3714 summary_info += {'user-mode emulation': have_user}
3715 summary_info += {'block layer':       have_block}
3716 summary_info += {'Install blobs':     get_option('install_blobs')}
3717 summary_info += {'module support':    config_host.has_key('CONFIG_MODULES')}
3718 if config_host.has_key('CONFIG_MODULES')
3719   summary_info += {'alternative module path': get_option('module_upgrades')}
3720 endif
3721 summary_info += {'fuzzing support':   get_option('fuzzing')}
3722 if have_system
3723   summary_info += {'Audio drivers':     ' '.join(audio_drivers_selected)}
3724 endif
3725 summary_info += {'Trace backends':    ','.join(get_option('trace_backends'))}
3726 if 'simple' in get_option('trace_backends')
3727   summary_info += {'Trace output file': get_option('trace_file') + '-<pid>'}
3728 endif
3729 summary_info += {'D-Bus display':     dbus_display}
3730 summary_info += {'QOM debugging':     get_option('qom_cast_debug')}
3731 summary_info += {'vhost-kernel support': have_vhost_kernel}
3732 summary_info += {'vhost-net support': have_vhost_net}
3733 summary_info += {'vhost-user support': have_vhost_user}
3734 summary_info += {'vhost-user-crypto support': have_vhost_user_crypto}
3735 summary_info += {'vhost-user-blk server support': have_vhost_user_blk_server}
3736 summary_info += {'vhost-vdpa support': have_vhost_vdpa}
3737 summary_info += {'build guest agent': have_ga}
3738 summary(summary_info, bool_yn: true, section: 'Configurable features')
3739
3740 # Compilation information
3741 summary_info = {}
3742 summary_info += {'host CPU':          cpu}
3743 summary_info += {'host endianness':   build_machine.endian()}
3744 summary_info += {'C compiler':        ' '.join(meson.get_compiler('c').cmd_array())}
3745 summary_info += {'Host C compiler':   ' '.join(meson.get_compiler('c', native: true).cmd_array())}
3746 if link_language == 'cpp'
3747   summary_info += {'C++ compiler':    ' '.join(meson.get_compiler('cpp').cmd_array())}
3748 else
3749   summary_info += {'C++ compiler':      false}
3750 endif
3751 if targetos == 'darwin'
3752   summary_info += {'Objective-C compiler': ' '.join(meson.get_compiler('objc').cmd_array())}
3753 endif
3754 summary_info += {'CFLAGS':            ' '.join(get_option('c_args')
3755                                                + ['-O' + get_option('optimization')]
3756                                                + (get_option('debug') ? ['-g'] : []))}
3757 if link_language == 'cpp'
3758   summary_info += {'CXXFLAGS':        ' '.join(get_option('cpp_args')
3759                                                + ['-O' + get_option('optimization')]
3760                                                + (get_option('debug') ? ['-g'] : []))}
3761 endif
3762 if targetos == 'darwin'
3763   summary_info += {'OBJCFLAGS':       ' '.join(get_option('objc_args')
3764                                                + ['-O' + get_option('optimization')]
3765                                                + (get_option('debug') ? ['-g'] : []))}
3766 endif
3767 link_args = get_option(link_language + '_link_args')
3768 if link_args.length() > 0
3769   summary_info += {'LDFLAGS':         ' '.join(link_args)}
3770 endif
3771 summary_info += {'QEMU_CFLAGS':       ' '.join(qemu_cflags)}
3772 summary_info += {'QEMU_CXXFLAGS':     ' '.join(qemu_cxxflags)}
3773 summary_info += {'QEMU_OBJCFLAGS':    ' '.join(qemu_objcflags)}
3774 summary_info += {'QEMU_LDFLAGS':      ' '.join(qemu_ldflags)}
3775 summary_info += {'profiler':          get_option('profiler')}
3776 summary_info += {'link-time optimization (LTO)': get_option('b_lto')}
3777 summary_info += {'PIE':               get_option('b_pie')}
3778 summary_info += {'static build':      config_host.has_key('CONFIG_STATIC')}
3779 summary_info += {'malloc trim support': has_malloc_trim}
3780 summary_info += {'membarrier':        have_membarrier}
3781 summary_info += {'debug stack usage': get_option('debug_stack_usage')}
3782 summary_info += {'mutex debugging':   get_option('debug_mutex')}
3783 summary_info += {'memory allocator':  get_option('malloc')}
3784 summary_info += {'avx2 optimization': config_host_data.get('CONFIG_AVX2_OPT')}
3785 summary_info += {'avx512f optimization': config_host_data.get('CONFIG_AVX512F_OPT')}
3786 summary_info += {'gprof enabled':     get_option('gprof')}
3787 summary_info += {'gcov':              get_option('b_coverage')}
3788 summary_info += {'thread sanitizer':  config_host.has_key('CONFIG_TSAN')}
3789 summary_info += {'CFI support':       get_option('cfi')}
3790 if get_option('cfi')
3791   summary_info += {'CFI debug support': get_option('cfi_debug')}
3792 endif
3793 summary_info += {'strip binaries':    get_option('strip')}
3794 summary_info += {'sparse':            sparse}
3795 summary_info += {'mingw32 support':   targetos == 'windows'}
3796 summary(summary_info, bool_yn: true, section: 'Compilation')
3797
3798 # snarf the cross-compilation information for tests
3799 summary_info = {}
3800 have_cross = false
3801 foreach target: target_dirs
3802   tcg_mak = meson.current_build_dir() / 'tests/tcg' / target / 'config-target.mak'
3803   if fs.exists(tcg_mak)
3804     config_cross_tcg = keyval.load(tcg_mak)
3805     if 'CC' in config_cross_tcg
3806       summary_info += {config_cross_tcg['TARGET_NAME']: config_cross_tcg['CC']}
3807       have_cross = true
3808     endif
3809   endif
3810 endforeach
3811 if have_cross
3812   summary(summary_info, bool_yn: true, section: 'Cross compilers')
3813 endif
3814
3815 # Targets and accelerators
3816 summary_info = {}
3817 if have_system
3818   summary_info += {'KVM support':       config_all.has_key('CONFIG_KVM')}
3819   summary_info += {'HAX support':       config_all.has_key('CONFIG_HAX')}
3820   summary_info += {'HVF support':       config_all.has_key('CONFIG_HVF')}
3821   summary_info += {'WHPX support':      config_all.has_key('CONFIG_WHPX')}
3822   summary_info += {'NVMM support':      config_all.has_key('CONFIG_NVMM')}
3823   summary_info += {'Xen support':       xen.found()}
3824   if xen.found()
3825     summary_info += {'xen ctrl version':  xen.version()}
3826   endif
3827 endif
3828 summary_info += {'TCG support':       config_all.has_key('CONFIG_TCG')}
3829 if config_all.has_key('CONFIG_TCG')
3830   if get_option('tcg_interpreter')
3831     summary_info += {'TCG backend':   'TCI (TCG with bytecode interpreter, slow)'}
3832   else
3833     summary_info += {'TCG backend':   'native (@0@)'.format(cpu)}
3834   endif
3835   summary_info += {'TCG plugins': config_host.has_key('CONFIG_PLUGIN')}
3836   summary_info += {'TCG debug enabled': config_host.has_key('CONFIG_DEBUG_TCG')}
3837 endif
3838 summary_info += {'target list':       ' '.join(target_dirs)}
3839 if have_system
3840   summary_info += {'default devices':   get_option('default_devices')}
3841   summary_info += {'out of process emulation': multiprocess_allowed}
3842   summary_info += {'vfio-user server': vfio_user_server_allowed}
3843 endif
3844 summary(summary_info, bool_yn: true, section: 'Targets and accelerators')
3845
3846 # Block layer
3847 summary_info = {}
3848 summary_info += {'coroutine backend': config_host['CONFIG_COROUTINE_BACKEND']}
3849 summary_info += {'coroutine pool':    have_coroutine_pool}
3850 if have_block
3851   summary_info += {'Block whitelist (rw)': get_option('block_drv_rw_whitelist')}
3852   summary_info += {'Block whitelist (ro)': get_option('block_drv_ro_whitelist')}
3853   summary_info += {'Use block whitelist in tools': get_option('block_drv_whitelist_in_tools')}
3854   summary_info += {'VirtFS support':    have_virtfs}
3855   summary_info += {'build virtiofs daemon': have_virtiofsd}
3856   summary_info += {'Live block migration': config_host_data.get('CONFIG_LIVE_BLOCK_MIGRATION')}
3857   summary_info += {'replication support': config_host_data.get('CONFIG_REPLICATION')}
3858   summary_info += {'bochs support':     get_option('bochs').allowed()}
3859   summary_info += {'cloop support':     get_option('cloop').allowed()}
3860   summary_info += {'dmg support':       get_option('dmg').allowed()}
3861   summary_info += {'qcow v1 support':   get_option('qcow1').allowed()}
3862   summary_info += {'vdi support':       get_option('vdi').allowed()}
3863   summary_info += {'vvfat support':     get_option('vvfat').allowed()}
3864   summary_info += {'qed support':       get_option('qed').allowed()}
3865   summary_info += {'parallels support': get_option('parallels').allowed()}
3866   summary_info += {'FUSE exports':      fuse}
3867   summary_info += {'VDUSE block exports': have_vduse_blk_export}
3868 endif
3869 summary(summary_info, bool_yn: true, section: 'Block layer support')
3870
3871 # Crypto
3872 summary_info = {}
3873 summary_info += {'TLS priority':      get_option('tls_priority')}
3874 summary_info += {'GNUTLS support':    gnutls}
3875 if gnutls.found()
3876   summary_info += {'  GNUTLS crypto':   gnutls_crypto.found()}
3877 endif
3878 summary_info += {'libgcrypt':         gcrypt}
3879 summary_info += {'nettle':            nettle}
3880 if nettle.found()
3881    summary_info += {'  XTS':             xts != 'private'}
3882 endif
3883 summary_info += {'AF_ALG support':    have_afalg}
3884 summary_info += {'rng-none':          get_option('rng_none')}
3885 summary_info += {'Linux keyring':     have_keyring}
3886 summary(summary_info, bool_yn: true, section: 'Crypto')
3887
3888 # Libraries
3889 summary_info = {}
3890 if targetos == 'darwin'
3891   summary_info += {'Cocoa support':           cocoa}
3892   summary_info += {'vmnet.framework support': vmnet}
3893 endif
3894 summary_info += {'SDL support':       sdl}
3895 summary_info += {'SDL image support': sdl_image}
3896 summary_info += {'GTK support':       gtk}
3897 summary_info += {'pixman':            pixman}
3898 summary_info += {'VTE support':       vte}
3899 summary_info += {'slirp support':     slirp}
3900 summary_info += {'libtasn1':          tasn1}
3901 summary_info += {'PAM':               pam}
3902 summary_info += {'iconv support':     iconv}
3903 summary_info += {'curses support':    curses}
3904 summary_info += {'virgl support':     virgl}
3905 summary_info += {'blkio support':     blkio}
3906 summary_info += {'curl support':      curl}
3907 summary_info += {'Multipath support': mpathpersist}
3908 summary_info += {'PNG support':       png}
3909 summary_info += {'VNC support':       vnc}
3910 if vnc.found()
3911   summary_info += {'VNC SASL support':  sasl}
3912   summary_info += {'VNC JPEG support':  jpeg}
3913 endif
3914 if targetos not in ['darwin', 'haiku', 'windows']
3915   summary_info += {'OSS support':     oss}
3916   summary_info += {'sndio support':   sndio}
3917 elif targetos == 'darwin'
3918   summary_info += {'CoreAudio support': coreaudio}
3919 elif targetos == 'windows'
3920   summary_info += {'DirectSound support': dsound}
3921 endif
3922 if targetos == 'linux'
3923   summary_info += {'ALSA support':    alsa}
3924   summary_info += {'PulseAudio support': pulse}
3925 endif
3926 summary_info += {'JACK support':      jack}
3927 summary_info += {'brlapi support':    brlapi}
3928 summary_info += {'vde support':       vde}
3929 summary_info += {'netmap support':    have_netmap}
3930 summary_info += {'l2tpv3 support':    have_l2tpv3}
3931 summary_info += {'Linux AIO support': libaio}
3932 summary_info += {'Linux io_uring support': linux_io_uring}
3933 summary_info += {'ATTR/XATTR support': libattr}
3934 summary_info += {'RDMA support':      rdma}
3935 summary_info += {'PVRDMA support':    have_pvrdma}
3936 summary_info += {'fdt support':       fdt_opt == 'disabled' ? false : fdt_opt}
3937 summary_info += {'libcap-ng support': libcap_ng}
3938 summary_info += {'bpf support':       libbpf}
3939 summary_info += {'spice protocol support': spice_protocol}
3940 if spice_protocol.found()
3941   summary_info += {'  spice server support': spice}
3942 endif
3943 summary_info += {'rbd support':       rbd}
3944 summary_info += {'smartcard support': cacard}
3945 summary_info += {'U2F support':       u2f}
3946 summary_info += {'libusb':            libusb}
3947 summary_info += {'usb net redir':     usbredir}
3948 summary_info += {'OpenGL support (epoxy)': opengl}
3949 summary_info += {'GBM':               gbm}
3950 summary_info += {'libiscsi support':  libiscsi}
3951 summary_info += {'libnfs support':    libnfs}
3952 if targetos == 'windows'
3953   if have_ga
3954     summary_info += {'QGA VSS support':   have_qga_vss}
3955   endif
3956 endif
3957 summary_info += {'seccomp support':   seccomp}
3958 summary_info += {'GlusterFS support': glusterfs}
3959 summary_info += {'TPM support':       have_tpm}
3960 summary_info += {'libssh support':    libssh}
3961 summary_info += {'lzo support':       lzo}
3962 summary_info += {'snappy support':    snappy}
3963 summary_info += {'bzip2 support':     libbzip2}
3964 summary_info += {'lzfse support':     liblzfse}
3965 summary_info += {'zstd support':      zstd}
3966 summary_info += {'NUMA host support': numa}
3967 summary_info += {'capstone':          capstone}
3968 summary_info += {'libpmem support':   libpmem}
3969 summary_info += {'libdaxctl support': libdaxctl}
3970 summary_info += {'libudev':           libudev}
3971 # Dummy dependency, keep .found()
3972 summary_info += {'FUSE lseek':        fuse_lseek.found()}
3973 summary_info += {'selinux':           selinux}
3974 summary(summary_info, bool_yn: true, section: 'Dependencies')
3975
3976 if not supported_cpus.contains(cpu)
3977   message()
3978   warning('SUPPORT FOR THIS HOST CPU WILL GO AWAY IN FUTURE RELEASES!')
3979   message()
3980   message('CPU host architecture ' + cpu + ' support is not currently maintained.')
3981   message('The QEMU project intends to remove support for this host CPU in')
3982   message('a future release if nobody volunteers to maintain it and to')
3983   message('provide a build host for our continuous integration setup.')
3984   message('configure has succeeded and you can continue to build, but')
3985   message('if you care about QEMU on this platform you should contact')
3986   message('us upstream at qemu-devel@nongnu.org.')
3987 endif
3988
3989 if not supported_oses.contains(targetos)
3990   message()
3991   warning('WARNING: SUPPORT FOR THIS HOST OS WILL GO AWAY IN FUTURE RELEASES!')
3992   message()
3993   message('Host OS ' + targetos + 'support is not currently maintained.')
3994   message('The QEMU project intends to remove support for this host OS in')
3995   message('a future release if nobody volunteers to maintain it and to')
3996   message('provide a build host for our continuous integration setup.')
3997   message('configure has succeeded and you can continue to build, but')
3998   message('if you care about QEMU on this platform you should contact')
3999   message('us upstream at qemu-devel@nongnu.org.')
4000 endif