qga/meson.build

   1 qga_qapi_outputs = [
   2   'qga-qapi-commands.c',
   3   'qga-qapi-commands.h',
   4   'qga-qapi-emit-events.c',
   5   'qga-qapi-emit-events.h',
   6   'qga-qapi-events.c',
   7   'qga-qapi-events.h',
   8   'qga-qapi-init-commands.c',
   9   'qga-qapi-init-commands.h',
  10   'qga-qapi-introspect.c',
  11   'qga-qapi-introspect.h',
  12   'qga-qapi-types.c',
  13   'qga-qapi-types.h',
  14   'qga-qapi-visit.c',
  15   'qga-qapi-visit.h',
  16 ]
  17
  18 qga_qapi_files = custom_target('QGA QAPI files',
  19                                output: qga_qapi_outputs,
  20                                input: 'qapi-schema.json',
  21                                command: [ qapi_gen, '-o', 'qga', '-p', 'qga-', '@INPUT0@' ],
  22                                depend_files: qapi_gen_depends)
  23
  24 qga_ss = ss.source_set()
  25 qga_ss.add(qga_qapi_files.to_list())
  26 qga_ss.add(files(
  27   'commands.c',
  28   'guest-agent-command-state.c',
  29   'main.c',
  30 ))
  31 qga_ss.add(when: 'CONFIG_POSIX', if_true: files(
  32   'channel-posix.c',
  33   'commands-posix.c',
  34   'commands-posix-ssh.c',
  35 ))
  36 qga_ss.add(when: 'CONFIG_WIN32', if_true: files(
  37   'channel-win32.c',
  38   'commands-win32.c',
  39   'service-win32.c',
  40   'vss-win32.c'
  41 ))
  42
  43 qga_ss = qga_ss.apply(config_host, strict: false)
  44
  45 qga = executable('qemu-ga', qga_ss.sources(),
  46                  link_args: config_host['LIBS_QGA'].split(),
  47                  dependencies: [qemuutil, libudev],
  48                  install: true)
  49 all_qga = [qga]
  50
  51 if targetos == 'windows'
  52   if 'CONFIG_QGA_VSS' in config_host
  53     subdir('vss-win32')
  54   else
  55     gen_tlb = []
  56   endif
  57
  58   wixl = find_program('wixl', required: false)
  59   if wixl.found()
  60     deps = [gen_tlb, qga]
  61     if 'CONFIG_QGA_VSS' in config_host and 'QEMU_GA_MSI_WITH_VSS' in config_host
  62       deps += qga_vss
  63     endif
  64     qga_msi = custom_target('QGA MSI',
  65                             input: files('installer/qemu-ga.wxs'),
  66                             output: 'qemu-ga-@0@.msi'.format(config_host['ARCH']),
  67                             depends: deps,
  68                             command: [
  69                               find_program('env'),
  70                               'QEMU_GA_VERSION=' + config_host['QEMU_GA_VERSION'],
  71                               'QEMU_GA_MANUFACTURER=' + config_host['QEMU_GA_MANUFACTURER'],
  72                               'QEMU_GA_DISTRO=' + config_host['QEMU_GA_DISTRO'],
  73                               'BUILD_DIR=' + meson.build_root(),
  74                               wixl, '-o', '@OUTPUT0@', '@INPUT0@',
  75                               config_host['QEMU_GA_MSI_ARCH'].split(),
  76                               config_host['QEMU_GA_MSI_WITH_VSS'].split(),
  77                               config_host['QEMU_GA_MSI_MINGW_DLL_PATH'].split(),
  78                             ])
  79     all_qga += [qga_msi]
  80     alias_target('msi', qga_msi)
  81   endif
  82 else
  83   install_subdir('run', install_dir: get_option('localstatedir'))
  84 endif
  85
  86 alias_target('qemu-ga', all_qga)
  87
  88 test_env = environment()
  89 test_env.set('G_TEST_SRCDIR', meson.current_source_dir())
  90 test_env.set('G_TEST_BUILDDIR', meson.current_build_dir())
  91
  92 # disable qga-ssh-test for now. glib's G_TEST_OPTION_ISOLATE_DIRS triggers
  93 # the leak detector in build-oss-fuzz Gitlab CI test. we should re-enable
  94 # this when an alternative is implemented or when the underlying glib
  95 # issue is identified/fix
  96 #if 'CONFIG_POSIX' in config_host
  97 if false
  98   srcs = [files('commands-posix-ssh.c')]
  99   i = 0
 100   foreach output: qga_qapi_outputs
 101     if output.startswith('qga-qapi-types') or output.startswith('qga-qapi-visit')
 102       srcs += qga_qapi_files[i]
 103     endif
 104     i = i + 1
 105   endforeach
 106   qga_ssh_test = executable('qga-ssh-test', srcs,
 107                             dependencies: [qemuutil],
 108                             c_args: ['-DQGA_BUILD_UNIT_TEST'])
 109
 110   test('qga-ssh-test',
 111        qga_ssh_test,
 112        env: test_env,
 113        suite: ['unit', 'qga'])
 114 endif