qapi/meson.build

   1 util_ss.add(files(
   2   'opts-visitor.c',
   3   'qapi-clone-visitor.c',
   4   'qapi-dealloc-visitor.c',
   5   'qapi-util.c',
   6   'qapi-visit-core.c',
   7   'qobject-input-visitor.c',
   8   'qobject-output-visitor.c',
   9   'string-input-visitor.c',
  10   'string-output-visitor.c',
  11 ))
  12 if have_system or have_tools
  13   util_ss.add(files(
  14     'qmp-dispatch.c',
  15     'qmp-event.c',
  16     'qmp-registry.c',
  17   ))
  18 endif
  19
  20 qapi_all_modules = [
  21   'acpi',
  22   'audio',
  23   'authz',
  24   'block',
  25   'block-core',
  26   'block-export',
  27   'char',
  28   'common',
  29   'control',
  30   'crypto',
  31   'dump',
  32   'error',
  33   'introspect',
  34   'job',
  35   'machine',
  36   'machine-target',
  37   'migration',
  38   'misc',
  39   'misc-target',
  40   'net',
  41   'pragma',
  42   'pci',
  43   'qom',
  44   'rdma',
  45   'replay',
  46   'rocker',
  47   'run-state',
  48   'sockets',
  49   'tpm',
  50   'trace',
  51   'transaction',
  52   'ui',
  53   'yank',
  54 ]
  55 if have_system
  56   qapi_all_modules += [
  57     'qdev',
  58   ]
  59 endif
  60
  61 qapi_storage_daemon_modules = [
  62   'block-core',
  63   'block-export',
  64   'char',
  65   'common',
  66   'control',
  67   'crypto',
  68   'introspect',
  69   'job',
  70   'qom',
  71   'sockets',
  72   'pragma',
  73   'transaction',
  74 ]
  75
  76 qapi_nonmodule_outputs = [
  77   'qapi-introspect.c', 'qapi-introspect.h',
  78   'qapi-types.c', 'qapi-types.h',
  79   'qapi-visit.h', 'qapi-visit.c',
  80   'qapi-commands.h', 'qapi-commands.c',
  81   'qapi-init-commands.h', 'qapi-init-commands.c',
  82   'qapi-events.h', 'qapi-events.c',
  83   'qapi-emit-events.c', 'qapi-emit-events.h',
  84 ]
  85
  86 # First build all sources
  87 qapi_util_outputs = [
  88   'qapi-builtin-types.c', 'qapi-builtin-visit.c',
  89   'qapi-builtin-types.h', 'qapi-builtin-visit.h',
  90 ]
  91
  92 qapi_inputs = []
  93 qapi_specific_outputs = []
  94 foreach module : qapi_all_modules
  95   qapi_inputs += [ files(module + '.json') ]
  96   qapi_module_outputs = [
  97     'qapi-types-@0@.c'.format(module),
  98     'qapi-types-@0@.h'.format(module),
  99     'qapi-visit-@0@.c'.format(module),
 100     'qapi-visit-@0@.h'.format(module),
 101     'qapi-events-@0@.c'.format(module),
 102     'qapi-events-@0@.h'.format(module),
 103     'qapi-commands-@0@.c'.format(module),
 104     'qapi-commands-@0@.h'.format(module),
 105   ]
 106   if module.endswith('-target')
 107     qapi_specific_outputs += qapi_module_outputs
 108   else
 109     qapi_util_outputs += qapi_module_outputs
 110   endif
 111 endforeach
 112
 113 qapi_files = custom_target('shared QAPI source files',
 114   output: qapi_util_outputs + qapi_specific_outputs + qapi_nonmodule_outputs,
 115   input: [ files('qapi-schema.json') ],
 116   command: [ qapi_gen, '-o', 'qapi', '-b', '@INPUT0@' ],
 117   depend_files: [ qapi_inputs, qapi_gen_depends ])
 118
 119 # Now go through all the outputs and add them to the right sourceset.
 120 # These loops must be synchronized with the output of the above custom target.
 121
 122 i = 0
 123 foreach output : qapi_util_outputs
 124   if output.endswith('.h')
 125     genh += qapi_files[i]
 126   endif
 127   util_ss.add(qapi_files[i])
 128   i = i + 1
 129 endforeach
 130
 131 foreach output : qapi_specific_outputs + qapi_nonmodule_outputs
 132   if output.endswith('.h')
 133     genh += qapi_files[i]
 134   endif
 135   specific_ss.add(when: 'CONFIG_SOFTMMU', if_true: qapi_files[i])
 136   i = i + 1
 137 endforeach