target/arm/meson.build

   1 gen = [
   2   decodetree.process('sve.decode', extra_args: '--decode=disas_sve'),
   3   decodetree.process('neon-shared.decode', extra_args: '--decode=disas_neon_shared'),
   4   decodetree.process('neon-dp.decode', extra_args: '--decode=disas_neon_dp'),
   5   decodetree.process('neon-ls.decode', extra_args: '--decode=disas_neon_ls'),
   6   decodetree.process('vfp.decode', extra_args: '--decode=disas_vfp'),
   7   decodetree.process('vfp-uncond.decode', extra_args: '--decode=disas_vfp_uncond'),
   8   decodetree.process('m-nocp.decode', extra_args: '--decode=disas_m_nocp'),
   9   decodetree.process('a32.decode', extra_args: '--static-decode=disas_a32'),
  10   decodetree.process('a32-uncond.decode', extra_args: '--static-decode=disas_a32_uncond'),
  11   decodetree.process('t32.decode', extra_args: '--static-decode=disas_t32'),
  12   decodetree.process('t16.decode', extra_args: ['-w', '16', '--static-decode=disas_t16']),
  13 ]
  14
  15 arm_ss = ss.source_set()
  16 arm_ss.add(gen)
  17 arm_ss.add(files(
  18   'cpu.c',
  19   'crypto_helper.c',
  20   'debug_helper.c',
  21   'gdbstub.c',
  22   'helper.c',
  23   'iwmmxt_helper.c',
  24   'm_helper.c',
  25   'neon_helper.c',
  26   'op_helper.c',
  27   'tlb_helper.c',
  28   'translate.c',
  29   'translate-m-nocp.c',
  30   'translate-neon.c',
  31   'translate-vfp.c',
  32   'vec_helper.c',
  33   'vfp_helper.c',
  34   'cpu_tcg.c',
  35 ))
  36 arm_ss.add(zlib)
  37
  38 arm_ss.add(when: 'CONFIG_KVM', if_true: files('kvm.c', 'kvm64.c'), if_false: files('kvm-stub.c'))
  39
  40 arm_ss.add(when: 'TARGET_AARCH64', if_true: files(
  41   'cpu64.c',
  42   'gdbstub64.c',
  43   'helper-a64.c',
  44   'mte_helper.c',
  45   'pauth_helper.c',
  46   'sve_helper.c',
  47   'translate-a64.c',
  48   'translate-sve.c',
  49 ))
  50
  51 arm_softmmu_ss = ss.source_set()
  52 arm_softmmu_ss.add(files(
  53   'arch_dump.c',
  54   'arm-powerctl.c',
  55   'machine.c',
  56   'monitor.c',
  57   'psci.c',
  58 ))
  59
  60 target_arch += {'arm': arm_ss}
  61 target_softmmu_arch += {'arm': arm_softmmu_ss}